lib/Catalyst/Engine/CGI.pm

   1 package Catalyst::Engine::CGI;
   2
   3 use Moose;
   4 extends 'Catalyst::Engine';
   5
   6 has _header_buf => (is => 'rw', clearer => '_clear_header_buf', predicate => '_has_header_buf');
   7
   8 =head1 NAME
   9
  10 Catalyst::Engine::CGI - The CGI Engine
  11
  12 =head1 SYNOPSIS
  13
  14 A script using the Catalyst::Engine::CGI module might look like:
  15
  16     #!/usr/bin/perl -w
  17
  18     use strict;
  19     use lib '/path/to/MyApp/lib';
  20     use MyApp;
  21
  22     MyApp->run;
  23
  24 The application module (C<MyApp>) would use C<Catalyst>, which loads the
  25 appropriate engine module.
  26
  27 =head1 DESCRIPTION
  28
  29 This is the Catalyst engine specialized for the CGI environment.
  30
  31 =head1 OVERLOADED METHODS
  32
  33 This class overloads some methods from C<Catalyst::Engine>.
  34
  35 =head2 $self->finalize_headers($c)
  36
  37 =cut
  38
  39 sub finalize_headers {
  40     my ( $self, $c ) = @_;
  41
  42     $c->response->header( Status => $c->response->status );
  43
  44     $self->_header_buf($c->response->headers->as_string("\015\012") . "\015\012");
  45 }
  46
  47 =head2 $self->prepare_connection($c)
  48
  49 =cut
  50
  51 sub prepare_connection {
  52     my ( $self, $c ) = @_;
  53     local (*ENV) = $self->env || \%ENV;
  54
  55     my $request = $c->request;
  56     $request->address( $ENV{REMOTE_ADDR} );
  57
  58   PROXY_CHECK:
  59     {
  60         unless ( ref($c)->config->{using_frontend_proxy} ) {
  61             last PROXY_CHECK if $ENV{REMOTE_ADDR} ne '127.0.0.1';
  62             last PROXY_CHECK if ref($c)->config->{ignore_frontend_proxy};
  63         }
  64         last PROXY_CHECK unless $ENV{HTTP_X_FORWARDED_FOR};
  65
  66         # If we are running as a backend server, the user will always appear
  67         # as 127.0.0.1. Select the most recent upstream IP (last in the list)
  68         my ($ip) = $ENV{HTTP_X_FORWARDED_FOR} =~ /([^,\s]+)$/;
  69         $request->address($ip);
  70         if ( defined $ENV{HTTP_X_FORWARDED_PORT} ) {
  71             $ENV{SERVER_PORT} = $ENV{HTTP_X_FORWARDED_PORT};
  72         }
  73     }
  74
  75     $request->hostname( $ENV{REMOTE_HOST} ) if exists $ENV{REMOTE_HOST};
  76     $request->protocol( $ENV{SERVER_PROTOCOL} );
  77     $request->user( $ENV{REMOTE_USER} );  # XXX: Deprecated. See Catalyst::Request for removal information
  78     $request->remote_user( $ENV{REMOTE_USER} );
  79     $request->method( $ENV{REQUEST_METHOD} );
  80
  81     if ( $ENV{HTTPS} && uc( $ENV{HTTPS} ) eq 'ON' ) {
  82         $request->secure(1);
  83     }
  84
  85     if ( $ENV{SERVER_PORT} == 443 ) {
  86         $request->secure(1);
  87     }
  88     binmode(STDOUT); # Ensure we are sending bytes.
  89 }
  90
  91 =head2 $self->prepare_headers($c)
  92
  93 =cut
  94
  95 sub prepare_headers {
  96     my ( $self, $c ) = @_;
  97     local (*ENV) = $self->env || \%ENV;
  98     my $headers = $c->request->headers;
  99     # Read headers from %ENV
 100     foreach my $header ( keys %ENV ) {
 101         next unless $header =~ /^(?:HTTP|CONTENT|COOKIE)/i;
 102         ( my $field = $header ) =~ s/^HTTPS?_//;
 103         $headers->header( $field => $ENV{$header} );
 104     }
 105 }
 106
 107 =head2 $self->prepare_path($c)
 108
 109 =cut
 110
 111 # Please don't touch this method without adding tests in
 112 # t/aggregate/unit_core_engine_cgi-prepare_path.t
 113 sub prepare_path {
 114     my ( $self, $c ) = @_;
 115     local (*ENV) = $self->env || \%ENV;
 116
 117     my $scheme = $c->request->secure ? 'https' : 'http';
 118     my $host      = $ENV{HTTP_HOST}   || $ENV{SERVER_NAME};
 119     my $port      = $ENV{SERVER_PORT} || 80;
 120     my $script_name = $ENV{SCRIPT_NAME};
 121     $script_name =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go if $script_name;
 122
 123     my $base_path;
 124     if ( exists $ENV{REDIRECT_URL} ) {
 125         $base_path = $ENV{REDIRECT_URL};
 126         $base_path =~ s/\Q$ENV{PATH_INFO}\E$//;
 127     }
 128     else {
 129         $base_path = $script_name || '/';
 130     }
 131
 132     # If we are running as a backend proxy, get the true hostname
 133   PROXY_CHECK:
 134     {
 135         unless ( ref($c)->config->{using_frontend_proxy} ) {
 136             last PROXY_CHECK if $host !~ /localhost|127.0.0.1/;
 137             last PROXY_CHECK if ref($c)->config->{ignore_frontend_proxy};
 138         }
 139         last PROXY_CHECK unless $ENV{HTTP_X_FORWARDED_HOST};
 140
 141         $host = $ENV{HTTP_X_FORWARDED_HOST};
 142
 143         # backend could be on any port, so
 144         # assume frontend is on the default port
 145         $port = $c->request->secure ? 443 : 80;
 146         if ( $ENV{HTTP_X_FORWARDED_PORT} ) {
 147             $port = $ENV{HTTP_X_FORWARDED_PORT};
 148         }
 149     }
 150
 151     # RFC 3875: "Unlike a URI path, the PATH_INFO is not URL-encoded,
 152     # and cannot contain path-segment parameters." This means PATH_INFO
 153     # is always decoded, and the script can't distinguish / vs %2F.
 154     # See https://issues.apache.org/bugzilla/show_bug.cgi?id=35256
 155     # Here we try to resurrect the original encoded URI from REQUEST_URI.
 156     my $path_info   = $ENV{PATH_INFO};
 157 #    if (my $req_uri = $ENV{REQUEST_URI}) {
 158 #        $req_uri =~ s/^\Q$base_path\E//;
 159 #        $req_uri =~ s/\?.*$//;
 160 #        if ($req_uri && $req_uri ne '/') {
 161             # This means that REQUEST_URI needs information from PATH_INFO
 162             # prepending to it to be useful, otherwise the sub path which is
 163             # being redirected to becomes the app base address which is
 164             # incorrect.
 165 #            my ($match) = $req_uri =~ m{^(/?[^/]+)};
 166 #            my ($path_info_part) = $path_info =~ m|^(.*?\Q$match\E)|;
 167 #            substr($req_uri, 0, length($match), $path_info_part)
 168 #                if $path_info_part;
 169 #            $path_info = $req_uri;
 170 #        }
 171 #    }
 172     $path_info =~ s/%2F/%252F/g;
 173     # set the request URI
 174     warn("Base path $base_path, path_info $path_info");
 175     my $path = $base_path . ( $path_info || '' );
 176     $path =~ s{^/+}{};
 177     $base_path .= '/' unless $base_path =~ m{/$};
 178
 179     # Using URI directly is way too slow, so we construct the URLs manually
 180     my $uri_class = "URI::$scheme";
 181
 182     # HTTP_HOST will include the port even if it's 80/443
 183     $host =~ s/:(?:80|443)$//;
 184
 185     if ( $port !~ /^(?:80|443)$/ && $host !~ /:/ ) {
 186         $host .= ":$port";
 187     }
 188
 189     # Escape the path
 190     $path =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
 191     $path =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
 192
 193     my $query = $ENV{QUERY_STRING} ? '?' . $ENV{QUERY_STRING} : '';
 194     my $uri   = $scheme . '://' . $host . '/' . $path . $query;
 195
 196     $c->request->uri( bless(\$uri, $uri_class)->canonical );
 197
 198     # set the base URI
 199     # base must end in a slash
 200     $base_path .= '/' unless $base_path =~ m{/$};
 201
 202     my $base_uri = $scheme . '://' . $host . $base_path;
 203
 204     $c->request->base( bless \$base_uri, $uri_class );
 205 }
 206
 207 =head2 $self->prepare_query_parameters($c)
 208
 209 =cut
 210
 211 around prepare_query_parameters => sub {
 212     my $orig = shift;
 213     my ( $self, $c ) = @_;
 214     local (*ENV) = $self->env || \%ENV;
 215
 216     if ( $ENV{QUERY_STRING} ) {
 217         $self->$orig( $c, $ENV{QUERY_STRING} );
 218     }
 219 };
 220
 221 =head2 $self->prepare_request($c, (env => \%env))
 222
 223 =cut
 224
 225 sub prepare_request {
 226     my ( $self, $c, %args ) = @_;
 227
 228     if ( $args{env} ) {
 229         $self->env( $args{env} );
 230     }
 231 }
 232
 233 =head2 $self->prepare_write($c)
 234
 235 Enable autoflush on the output handle for CGI-based engines.
 236
 237 =cut
 238
 239 around prepare_write => sub {
 240     *STDOUT->autoflush(1);
 241     return shift->(@_);
 242 };
 243
 244 =head2 $self->write($c, $buffer)
 245
 246 Writes the buffer to the client.
 247
 248 =cut
 249
 250 around write => sub {
 251     my $orig = shift;
 252     my ( $self, $c, $buffer ) = @_;
 253
 254     # Prepend the headers if they have not yet been sent
 255     if ( $self->_has_header_buf ) {
 256         $buffer = $self->_clear_header_buf . $buffer;
 257     }
 258
 259     return $self->$orig( $c, $buffer );
 260 };
 261
 262 =head2 $self->read_chunk($c, $buffer, $length)
 263
 264 =cut
 265
 266 sub read_chunk { shift; shift; *STDIN->sysread(@_); }
 267
 268 =head2 $self->run
 269
 270 =cut
 271
 272 sub run { shift; shift->handle_request( env => \%ENV ) }
 273
 274 =head1 SEE ALSO
 275
 276 L<Catalyst>, L<Catalyst::Engine>
 277
 278 =head1 AUTHORS
 279
 280 Catalyst Contributors, see Catalyst.pm
 281
 282 =head1 COPYRIGHT
 283
 284 This library is free software. You can redistribute it and/or modify it under
 285 the same terms as Perl itself.
 286
 287 =cut
 288 no Moose;
 289
 290 1;