lib/Catalyst/Engine/Apache/MP13.pm

   1 package Catalyst::Engine::Apache::MP13;
   2
   3 use strict;
   4 use base 'Catalyst::Engine::Apache';
   5
   6 use Apache            ();
   7 use Apache::Constants ();
   8 use Apache::Request   ();
   9 use Apache::Cookie    ();
  10
  11 Apache::Constants->import(':common');
  12
  13 =head1 NAME
  14
  15 Catalyst::Engine::Apache::MP13 - Catalyst Apache MP1.3 Engine
  16
  17 =head1 SYNOPSIS
  18
  19 See L<Catalyst>.
  20
  21 =head1 DESCRIPTION
  22
  23 This is the Catalyst engine specialized for Apache mod_perl version 1.3x.
  24
  25 =head1 OVERLOADED METHODS
  26
  27 This class overloads some methods from C<Catalyst::Engine::Apache>.
  28
  29 =over 4
  30
  31 =item $c->finalize_headers
  32
  33 =cut
  34
  35 sub finalize_headers {
  36     my $c = shift;
  37
  38     for my $name ( $c->response->headers->header_field_names ) {
  39         next if $name =~ /Content-Type/i;
  40         my @values = $c->response->header($name);
  41         $c->apache->headers_out->add( $name => $_ ) for @values;
  42     }
  43
  44     if ( $c->response->header('Set-Cookie') && $c->response->status >= 300 ) {
  45         my @values = $c->response->header('Set-Cookie');
  46         $c->apache->err_headers_out->add( 'Set-Cookie' => $_ ) for @values;
  47     }
  48
  49     $c->apache->status( $c->response->status );
  50     $c->apache->content_type( $c->response->header('Content-Type') );
  51
  52     $c->apache->send_http_header;
  53
  54     return 0;
  55 }
  56
  57 =item $c->handler
  58
  59 =cut
  60
  61 sub handler ($$) {
  62     shift->SUPER::handler(@_);
  63 }
  64
  65 =item $c->prepare_uploads
  66
  67 =cut
  68
  69 sub prepare_uploads {
  70     my $c = shift;
  71
  72     my @uploads;
  73
  74     for my $upload ( $c->apache->upload ) {
  75
  76         my $object = Catalyst::Request::Upload->new(
  77             filename => $upload->filename,
  78             size     => $upload->size,
  79             tempname => $upload->tempname,
  80             type     => $upload->type
  81         );
  82
  83         push( @uploads, $upload->name, $object );
  84     }
  85
  86     $c->req->_assign_values( $c->req->uploads, \@uploads );
  87 }
  88
  89 =item $c->prepare_request($r)
  90
  91 =cut
  92
  93 sub prepare_request {
  94     my ( $c, $r ) = @_;
  95     $c->apache( Apache::Request->new($r) );
  96 }
  97
  98 =back
  99
 100 =head1 SEE ALSO
 101
 102 L<Catalyst>, L<Catalyst::Engine>, L<Catalyst::Engine::Apache>.
 103
 104 =head1 AUTHOR
 105
 106 Sebastian Riedel, C<sri@cpan.org>
 107
 108 =head1 COPYRIGHT
 109
 110 This program is free software, you can redistribute it and/or modify it under
 111 the same terms as Perl itself.
 112
 113 =cut
 114
 115 1;