lib/Catalyst/Dispatcher.pm

   1 package Catalyst::Dispatcher;
   2
   3 use strict;
   4 use base 'Class::Accessor::Fast';
   5 use Catalyst::Exception;
   6 use Catalyst::Utils;
   7 use Catalyst::Action;
   8 use Catalyst::ActionContainer;
   9 use Catalyst::DispatchType::Default;
  10 use Catalyst::DispatchType::Index;
  11 use Text::SimpleTable;
  12 use Tree::Simple;
  13 use Tree::Simple::Visitor::FindByPath;
  14
  15 # Stringify to class
  16 use overload '""' => sub { return ref shift }, fallback => 1;
  17
  18 __PACKAGE__->mk_accessors(
  19     qw/tree dispatch_types registered_dispatch_types
  20       method_action_class action_container_class/
  21 );
  22
  23 # Preload these action types
  24 our @PRELOAD = qw/Path Regex/;
  25
  26 # Postload these action types
  27 our @POSTLOAD = qw/Index Default/;
  28
  29 =head1 NAME
  30
  31 Catalyst::Dispatcher - The Catalyst Dispatcher
  32
  33 =head1 SYNOPSIS
  34
  35 See L<Catalyst>.
  36
  37 =head1 DESCRIPTION
  38
  39 =head1 METHODS
  40
  41 =over 4
  42
  43 =item $self->detach( $c, $command [, \@arguments ] )
  44
  45 =cut
  46
  47 sub detach {
  48     my ( $self, $c, $command, @args ) = @_;
  49     $c->forward( $command, @args ) if $command;
  50     die $Catalyst::DETACH;
  51 }
  52
  53 =item $self->dispatch($c)
  54
  55 =cut
  56
  57 sub dispatch {
  58     my ( $self, $c ) = @_;
  59
  60     if ( $c->action ) {
  61         $c->forward( join( '/', '', $c->action->namespace, '_DISPATCH' ) );
  62     }
  63
  64     else {
  65         my $path  = $c->req->path;
  66         my $error = $path
  67           ? qq/Unknown resource "$path"/
  68           : "No default action defined";
  69         $c->log->error($error) if $c->debug;
  70         $c->error($error);
  71     }
  72 }
  73
  74 =item $self->forward( $c, $command [, \@arguments ] )
  75
  76 =cut
  77
  78 sub forward {
  79     my $self    = shift;
  80     my $c       = shift;
  81     my $command = shift;
  82
  83     unless ($command) {
  84         $c->log->debug('Nothing to forward to') if $c->debug;
  85         return 0;
  86     }
  87
  88     my $local_args = 0;
  89     my $arguments  = $c->req->args;
  90     if ( ref( $_[-1] ) eq 'ARRAY' ) {
  91         $arguments  = pop(@_);
  92         $local_args = 1;
  93     }
  94
  95     my $result;
  96
  97     unless ( ref $command ) {
  98         my $command_copy = $command;
  99
 100         unless ( $command_copy =~ s/^\/// ) {
 101             my $namespace = $c->stack->[-1]->namespace;
 102             $command_copy = "${namespace}/${command}";
 103         }
 104
 105         unless ( $command_copy =~ /\// ) {
 106             $result = $c->get_action( $command_copy, '/' );
 107         }
 108         else {
 109             my @extra_args;
 110           DESCEND: while ( $command_copy =~ s/^(.*)\/(\w+)$/$1/ ) {
 111                 my $tail = $2;
 112                 $result = $c->get_action( $tail, $1 );
 113                 if ($result) {
 114                     $local_args = 1;
 115                     $command    = $tail;
 116                     unshift( @{$arguments}, @extra_args );
 117                     last DESCEND;
 118                 }
 119                 unshift( @extra_args, $tail );
 120             }
 121         }
 122     }
 123
 124     unless ($result) {
 125
 126         my $class  = ref($command) || ref( $c->component($command) );
 127         my $method = shift         || 'process';
 128
 129         unless ($class) {
 130             my $error =
 131 qq/Couldn't forward to command "$command". Invalid action or component./;
 132             $c->error($error);
 133             $c->log->debug($error) if $c->debug;
 134             return 0;
 135         }
 136
 137         if ( my $code = $class->can($method) ) {
 138             my $action = $self->method_action_class->new(
 139                 {
 140                     name      => $method,
 141                     code      => $code,
 142                     reverse   => "$class->$method",
 143                     class     => $class,
 144                     namespace => Catalyst::Utils::class2prefix(
 145                         $class, $c->config->{case_sensitive}
 146                     ),
 147                 }
 148             );
 149             $result = $action;
 150         }
 151
 152         else {
 153             my $error =
 154               qq/Couldn't forward to "$class". Does not implement "$method"/;
 155             $c->error($error);
 156             $c->log->debug($error)
 157               if $c->debug;
 158             return 0;
 159         }
 160
 161     }
 162
 163     if ($local_args) {
 164         local $c->request->{arguments} = [ @{$arguments} ];
 165         $result->execute($c);
 166     }
 167     else { $result->execute($c) }
 168
 169     return $c->state;
 170 }
 171
 172 =item $self->prepare_action($c)
 173
 174 =cut
 175
 176 sub prepare_action {
 177     my ( $self, $c ) = @_;
 178     my $path = $c->req->path;
 179     my @path = split /\//, $c->req->path;
 180     $c->req->args( \my @args );
 181
 182     push( @path, '/' ) unless @path;    # Root action
 183
 184   DESCEND: while (@path) {
 185         $path = join '/', @path;
 186
 187         $path = '' if $path eq '/';     # Root action
 188
 189         # Check out dispatch types to see if any will handle the path at
 190         # this level
 191
 192         foreach my $type ( @{ $self->dispatch_types } ) {
 193             last DESCEND if $type->match( $c, $path );
 194         }
 195
 196         # If not, move the last part path to args
 197
 198         unshift @args, pop @path;
 199     }
 200
 201     $c->log->debug( 'Path is "' . $c->req->match . '"' )
 202       if ( $c->debug && $c->req->match );
 203
 204     $c->log->debug( 'Arguments are "' . join( '/', @args ) . '"' )
 205       if ( $c->debug && @args );
 206 }
 207
 208 =item $self->get_action( $action, $namespace )
 209
 210 =cut
 211
 212 sub get_action {
 213     my ( $self, $name, $namespace ) = @_;
 214     return unless $name;
 215     $namespace ||= '';
 216     $namespace = '' if $namespace eq '/';
 217
 218     my @match = $self->get_containers($namespace);
 219
 220     return unless @match;
 221
 222     if ( my $action = $match[-1]->get_action($name) ) {
 223         return $action if $action->namespace eq $namespace;
 224     }
 225 }
 226
 227 =item $self->get_actions( $c, $action, $namespace )
 228
 229 =cut
 230
 231 sub get_actions {
 232     my ( $self, $c, $action, $namespace ) = @_;
 233     return [] unless $action;
 234     $namespace ||= '';
 235     $namespace = '' if $namespace eq '/';
 236
 237     my @match = $self->get_containers($namespace);
 238
 239     return map { $_->get_action($action) } @match;
 240 }
 241
 242 =item $self->get_containers( $namespace )
 243
 244 =cut
 245
 246 sub get_containers {
 247     my ( $self, $namespace ) = @_;
 248
 249     # If the namespace is / just return the root ActionContainer
 250
 251     return ( $self->tree->getNodeValue )
 252       if ( !$namespace || ( $namespace eq '/' ) );
 253
 254     # Use a visitor to recurse down the tree finding the ActionContainers
 255     # for each namespace in the chain.
 256
 257     my $visitor = Tree::Simple::Visitor::FindByPath->new;
 258     my @path = split( '/', $namespace );
 259     $visitor->setSearchPath(@path);
 260     $self->tree->accept($visitor);
 261
 262     my @match = $visitor->getResults;
 263     @match = ( $self->tree ) unless @match;
 264
 265     if ( !defined $visitor->getResult ) {
 266
 267         # If we don't manage to match, the visitor doesn't return the last
 268         # node is matched, so foo/bar/baz would only find the 'foo' node,
 269         # not the foo and foo/bar nodes as it should. This does another
 270         # single-level search to see if that's the case, and the 'last unless'
 271         # should catch any failures - or short-circuit this if this *is* a
 272         # bug in the visitor and gets fixed.
 273
 274         if ( my $extra = $path[ ( scalar @match ) - 1 ] ) {
 275             $visitor->setSearchPath($extra);
 276             $match[-1]->accept($visitor);
 277             push( @match, $visitor->getResult ) if defined $visitor->getResult;
 278         }
 279     }
 280
 281     return map { $_->getNodeValue } @match;
 282 }
 283
 284 =item $self->register( $c, $action )
 285
 286 =cut
 287
 288 sub register {
 289     my ( $self, $c, $action ) = @_;
 290
 291     my $registered = $self->registered_dispatch_types;
 292
 293     my $priv = 0;
 294     foreach my $key ( keys %{ $action->attributes } ) {
 295         $priv++ if $key eq 'Private';
 296         my $class = "Catalyst::DispatchType::$key";
 297         unless ( $registered->{$class} ) {
 298             eval "require $class";
 299             push( @{ $self->dispatch_types }, $class->new ) unless $@;
 300             $registered->{$class} = 1;
 301         }
 302     }
 303
 304     # Pass the action to our dispatch types so they can register it if reqd.
 305     my $reg = 0;
 306     foreach my $type ( @{ $self->dispatch_types } ) {
 307         $reg++ if $type->register( $c, $action );
 308     }
 309
 310     return unless $reg + $priv;
 311
 312     my $namespace = $action->namespace;
 313     my $parent    = $self->tree;
 314     my $visitor   = Tree::Simple::Visitor::FindByPath->new;
 315
 316     if ($namespace) {
 317         for my $part ( split '/', $namespace ) {
 318             $visitor->setSearchPath($part);
 319             $parent->accept($visitor);
 320             my $child = $visitor->getResult;
 321
 322             unless ($child) {
 323
 324                 # Create a new tree node and an ActionContainer to form
 325                 # its value.
 326
 327                 my $container =
 328                   Catalyst::ActionContainer->new(
 329                     { part => $part, actions => {} } );
 330                 $child = $parent->addChild( Tree::Simple->new($container) );
 331                 $visitor->setSearchPath($part);
 332                 $parent->accept($visitor);
 333                 $child = $visitor->getResult;
 334             }
 335
 336             $parent = $child;
 337         }
 338     }
 339
 340     # Set the method value
 341     $parent->getNodeValue->actions->{ $action->name } = $action;
 342 }
 343
 344 =item $self->setup_actions( $class, $component )
 345
 346 =cut
 347
 348 sub setup_actions {
 349     my ( $self, $c ) = @_;
 350
 351     $self->dispatch_types( [] );
 352     $self->registered_dispatch_types( {} );
 353     $self->method_action_class('Catalyst::Action');
 354     $self->action_container_class('Catalyst::ActionContainer');
 355
 356     # Preload action types
 357     for my $type (@PRELOAD) {
 358         my $class = "Catalyst::DispatchType::$type";
 359         eval "require $class";
 360         Catalyst::Exception->throw( message => qq/Couldn't load "$class"/ )
 361           if $@;
 362         push @{ $self->dispatch_types }, $class->new;
 363         $self->registered_dispatch_types->{$class} = 1;
 364     }
 365
 366     # We use a tree
 367     my $container =
 368       Catalyst::ActionContainer->new( { part => '/', actions => {} } );
 369     $self->tree( Tree::Simple->new( $container, Tree::Simple->ROOT ) );
 370
 371     foreach my $comp ( values %{ $c->components } ) {
 372         $comp->register_actions($c) if $comp->can('register_actions');
 373     }
 374
 375     # Postload action types
 376     for my $type (@POSTLOAD) {
 377         my $class = "Catalyst::DispatchType::$type";
 378         eval "require $class";
 379         Catalyst::Exception->throw( message => qq/Couldn't load "$class"/ )
 380           if $@;
 381         push @{ $self->dispatch_types }, $class->new;
 382     }
 383
 384     return unless $c->debug;
 385
 386     my $privates = Text::SimpleTable->new(
 387         [ 20, 'Private' ],
 388         [ 38, 'Class' ],
 389         [ 12, 'Method' ]
 390     );
 391
 392     my $has_private = 0;
 393     my $walker = sub {
 394         my ( $walker, $parent, $prefix ) = @_;
 395         $prefix .= $parent->getNodeValue || '';
 396         $prefix .= '/' unless $prefix =~ /\/$/;
 397         my $node = $parent->getNodeValue->actions;
 398
 399         for my $action ( keys %{$node} ) {
 400             my $action_obj = $node->{$action};
 401             next
 402               if ( ( $action =~ /^_.*/ )
 403                 && ( !$c->config->{show_internal_actions} ) );
 404             $privates->row( "$prefix$action", $action_obj->class, $action );
 405             $has_private = 1;
 406         }
 407
 408         $walker->( $walker, $_, $prefix ) for $parent->getAllChildren;
 409     };
 410
 411     $walker->( $walker, $self->tree, '' );
 412     $c->log->debug( "Loaded Private actions:\n" . $privates->draw )
 413       if ($has_private);
 414
 415     # List all public actions
 416     $_->list($c) for @{ $self->dispatch_types };
 417 }
 418
 419 =back
 420
 421 =head1 AUTHOR
 422
 423 Sebastian Riedel, C<sri@cpan.org>
 424 Matt S Trout, C<mst@shadowcatsystems.co.uk>
 425
 426 =head1 COPYRIGHT
 427
 428 This program is free software, you can redistribute it and/or modify it under
 429 the same terms as Perl itself.
 430
 431 =cut
 432
 433 1;