lib/Catalyst/Dispatcher.pm

   1 package Catalyst::Dispatcher;
   2
   3 use strict;
   4 use base 'Class::Accessor::Fast';
   5 use Catalyst::Exception;
   6 use Catalyst::Utils;
   7 use Catalyst::Action;
   8 use Catalyst::ActionContainer;
   9 use Catalyst::DispatchType::Default;
  10 use Catalyst::DispatchType::Index;
  11 use Text::ASCIITable;
  12 use Tree::Simple;
  13 use Tree::Simple::Visitor::FindByPath;
  14
  15 # Stringify to class
  16 use overload '""' => sub { return ref shift }, fallback => 1;
  17
  18 __PACKAGE__->mk_accessors(qw/tree dispatch_types/);
  19
  20 # Preload these action types
  21 our @PRELOAD = qw/Path Regex/;
  22
  23 =head1 NAME
  24
  25 Catalyst::Dispatcher - The Catalyst Dispatcher
  26
  27 =head1 SYNOPSIS
  28
  29 See L<Catalyst>.
  30
  31 =head1 DESCRIPTION
  32
  33 =head1 METHODS
  34
  35 =over 4
  36
  37 =item $self->detach( $c, $command [, \@arguments ] )
  38
  39 =cut
  40
  41 sub detach {
  42     my ( $self, $c, $command, @args ) = @_;
  43     $c->forward( $command, @args ) if $command;
  44     die $Catalyst::DETACH;
  45 }
  46
  47 =item $self->dispatch($c)
  48
  49 =cut
  50
  51 sub dispatch {
  52     my ( $self, $c ) = @_;
  53
  54     if ( $c->action ) {
  55
  56         my @containers = $self->get_containers( $c->namespace );
  57         my %actions;
  58         foreach my $name (qw/begin auto end/) {
  59
  60             # Go down the container list representing each part of the
  61             # current namespace inheritance tree, grabbing the actions hash
  62             # of the ActionContainer object and looking for actions of the
  63             # appropriate name registered to the namespace
  64
  65             $actions{$name} = [
  66                 map    { $_->{$name} }
  67                   grep { exists $_->{$name} }
  68                   map  { $_->actions } @containers
  69             ];
  70         }
  71
  72         # Errors break the normal flow and the end action is instantly run
  73         my $error = 0;
  74
  75         # Execute last begin
  76         $c->state(1);
  77         if ( my $begin = @{ $actions{begin} }[-1] ) {
  78             $begin->execute($c);
  79             $error++ if scalar @{ $c->error };
  80         }
  81
  82         # Execute the auto chain
  83         my $autorun = 0;
  84         for my $auto ( @{ $actions{auto} } ) {
  85             last if $error;
  86             $autorun++;
  87             $auto->execute($c);
  88             $error++ if scalar @{ $c->error };
  89             last unless $c->state;
  90         }
  91
  92         # Execute the action or last default
  93         my $mkay = $autorun ? $c->state ? 1 : 0 : 1;
  94         if ($mkay) {
  95             unless ($error) {
  96                 $c->action->execute($c);
  97                 $error++ if scalar @{ $c->error };
  98             }
  99         }
 100
 101         # Execute last end
 102         if ( my $end = @{ $actions{end} }[-1] ) {
 103             $end->execute($c);
 104         }
 105     }
 106
 107     else {
 108         my $path  = $c->req->path;
 109         my $error = $path
 110           ? qq/Unknown resource "$path"/
 111           : "No default action defined";
 112         $c->log->error($error) if $c->debug;
 113         $c->error($error);
 114     }
 115 }
 116
 117 =item $self->forward( $c, $command [, \@arguments ] )
 118
 119 =cut
 120
 121 sub forward {
 122     my $self    = shift;
 123     my $c       = shift;
 124     my $command = shift;
 125
 126     unless ($command) {
 127         $c->log->debug('Nothing to forward to') if $c->debug;
 128         return 0;
 129     }
 130
 131     # Relative forwards from detach
 132     my $caller = ( caller(1) )[0]->isa('Catalyst::Dispatcher')
 133       && ( ( caller(2) )[3] =~ /::detach$/ ) ? caller(3) : caller(1);
 134
 135     my $arguments = ( ref( $_[-1] ) eq 'ARRAY' ) ? pop(@_) : $c->req->args;
 136
 137     my $results = [];
 138
 139     my $command_copy = $command;
 140
 141     unless ( $command_copy =~ s/^\/// ) {
 142         my $namespace =
 143           Catalyst::Utils::class2prefix( $caller, $c->config->{case_sensitive} )
 144           || '';
 145         $command_copy = "${namespace}/${command}";
 146     }
 147
 148     unless ( $command_copy =~ /\// ) {
 149         $results = $c->get_action( $command_copy, '/' );
 150     }
 151     else {
 152         my @extra_args;
 153       DESCEND: while ( $command_copy =~ s/^(.*)\/(\w+)$/$1/ ) {
 154             my $tail = $2;
 155             $results = $c->get_action( $tail, $1 );
 156             if ( @{$results} ) {
 157                 $command = $tail;
 158                 push( @{$arguments}, @extra_args );
 159                 last DESCEND;
 160             }
 161             unshift( @extra_args, $tail );
 162         }
 163     }
 164
 165     unless ( @{$results} ) {
 166
 167         unless ( $c->components->{$command} ) {
 168             my $error =
 169 qq/Couldn't forward to command "$command". Invalid action or component./;
 170             $c->error($error);
 171             $c->log->debug($error) if $c->debug;
 172             return 0;
 173         }
 174
 175         my $class  = $command;
 176         my $method = shift || 'process';
 177
 178         if ( my $code = $c->components->{$class}->can($method) ) {
 179             my $action = Catalyst::Action->new(
 180                 {
 181                     name      => $method,
 182                     code      => $code,
 183                     reverse   => "$class->$method",
 184                     namespace => $class,
 185                     prefix    => $class,
 186                 }
 187             );
 188             $results = [ [$action] ];
 189         }
 190
 191         else {
 192             my $error =
 193               qq/Couldn't forward to "$class". Does not implement "$method"/;
 194             $c->error($error);
 195             $c->log->debug($error)
 196               if $c->debug;
 197             return 0;
 198         }
 199
 200     }
 201
 202     local $c->request->{arguments} = [ @{$arguments} ];
 203
 204     for my $result ( @{$results} ) {
 205         $result->[0]->execute($c);
 206         return if scalar @{ $c->error };
 207         last unless $c->state;
 208     }
 209
 210     return $c->state;
 211 }
 212
 213 =item $self->prepare_action($c)
 214
 215 =cut
 216
 217 sub prepare_action {
 218     my ( $self, $c ) = @_;
 219     my $path = $c->req->path;
 220     my @path = split /\//, $c->req->path;
 221     $c->req->args( \my @args );
 222
 223     push( @path, '/' ) unless @path;    # Root action
 224
 225   DESCEND: while (@path) {
 226         $path = join '/', @path;
 227
 228         $path = '' if $path eq '/';     # Root action
 229
 230         # Check out dispatch types to see if any will handle the path at
 231         # this level
 232
 233         foreach my $type ( @{ $self->dispatch_types } ) {
 234             last DESCEND if $type->match( $c, $path );
 235         }
 236
 237         # If not, move the last part path to args
 238
 239         unshift @args, pop @path;
 240     }
 241
 242     $c->log->debug( 'Arguments are "' . join( '/', @args ) . '"' )
 243       if ( $c->debug && @args );
 244 }
 245
 246 =item $self->get_action( $c, $action, $namespace, $inherit )
 247
 248 =cut
 249
 250 sub get_action {
 251     my ( $self, $c, $action, $namespace, $inherit ) = @_;
 252     return [] unless $action;
 253     $namespace ||= '';
 254     $inherit   ||= 0;
 255
 256     my @match = $self->get_containers($namespace);
 257
 258     my @results;
 259
 260     foreach my $child ( $inherit ? @match : $match[-1] ) {
 261         my $node = $child->actions;
 262         unless ($inherit) {
 263             $namespace = '' if $namespace eq '/';
 264             my $reverse = $node->{$action}->reverse;
 265             my $name    = $namespace
 266               ? $namespace =~ /\/$/ ? "$namespace$action" : "$namespace/$action"
 267               : $action;
 268             last unless $name eq $reverse;
 269         }
 270         push( @results, [ $node->{$action} ] ) if defined $node->{$action};
 271     }
 272     return \@results;
 273 }
 274
 275 =item $self->get_containers( $namespace )
 276
 277 =cut
 278
 279 sub get_containers {
 280     my ( $self, $namespace ) = @_;
 281
 282     # If the namespace is / just return the root ActionContainer
 283
 284     return ( $self->tree->getNodeValue )
 285       if ( !$namespace || ( $namespace eq '/' ) );
 286
 287     # Use a visitor to recurse down the tree finding the ActionContainers
 288     # for each namespace in the chain.
 289
 290     my $visitor = Tree::Simple::Visitor::FindByPath->new;
 291     my @path = split( '/', $namespace );
 292     $visitor->setSearchPath(@path);
 293     $self->tree->accept($visitor);
 294
 295     my @match = $visitor->getResults;
 296     @match = ( $self->tree ) unless @match;
 297
 298     if ( !defined $visitor->getResult ) {
 299
 300         # If we don't manage to match, the visitor doesn't return the last
 301         # node is matched, so foo/bar/baz would only find the 'foo' node,
 302         # not the foo and foo/bar nodes as it should. This does another
 303         # single-level search to see if that's the case, and the 'last unless'
 304         # should catch any failures - or short-circuit this if this *is* a
 305         # bug in the visitor and gets fixed.
 306
 307         my $extra = $path[ ( scalar @match ) - 1 ];
 308         last unless $extra;
 309         $visitor->setSearchPath($extra);
 310         $match[-1]->accept($visitor);
 311         push( @match, $visitor->getResult ) if defined $visitor->getResult;
 312     }
 313
 314     return map { $_->getNodeValue } @match;
 315 }
 316
 317 =item $self->set_action( $c, $action, $code, $namespace, $attrs )
 318
 319 =cut
 320
 321 sub set_action {
 322     my ( $self, $c, $method, $code, $namespace, $attrs ) = @_;
 323
 324     my $prefix =
 325       Catalyst::Utils::class2prefix( $namespace, $c->config->{case_sensitive} )
 326       || '';
 327     my %attributes;
 328
 329     for my $attr ( @{$attrs} ) {
 330
 331         # Parse out :Foo(bar) into Foo => bar etc (and arrayify)
 332
 333         my %initialized;
 334         $initialized{ ref $_ }++ for @{ $self->dispatch_types };
 335
 336         if ( my ( $key, $value ) = ( $attr =~ /^(.*?)(?:\(\s*(.+)\s*\))?$/ ) ) {
 337
 338             # Initialize types
 339             my $class = "Catalyst::DispatchType::$key";
 340             unless ( $initialized{$class} ) {
 341                 eval "require $class";
 342                 push( @{ $self->dispatch_types }, $class->new ) unless $@;
 343                 $initialized{$class}++;
 344             }
 345
 346             if ( defined $value ) {
 347                 ( $value =~ s/^'(.*)'$/$1/ ) || ( $value =~ s/^"(.*)"/$1/ );
 348             }
 349             push( @{ $attributes{$key} }, $value );
 350         }
 351     }
 352
 353     if ( $attributes{Private} && ( keys %attributes > 1 ) ) {
 354         $c->log->debug( 'Bad action definition "'
 355               . join( ' ', @{$attrs} )
 356               . qq/" for "$namespace->$method"/ )
 357           if $c->debug;
 358         return;
 359     }
 360     return unless keys %attributes;
 361
 362     my $parent  = $self->tree;
 363     my $visitor = Tree::Simple::Visitor::FindByPath->new;
 364
 365     if ($prefix) {
 366         for my $part ( split '/', $prefix ) {
 367             $visitor->setSearchPath($part);
 368             $parent->accept($visitor);
 369             my $child = $visitor->getResult;
 370
 371             unless ($child) {
 372
 373                 # Create a new tree node and an ActionContainer to form
 374                 # its value.
 375
 376                 my $container =
 377                   Catalyst::ActionContainer->new(
 378                     { part => $part, actions => {} } );
 379                 $child = $parent->addChild( Tree::Simple->new($container) );
 380                 $visitor->setSearchPath($part);
 381                 $parent->accept($visitor);
 382                 $child = $visitor->getResult;
 383             }
 384
 385             $parent = $child;
 386         }
 387     }
 388
 389     my $reverse = $prefix ? "$prefix/$method" : $method;
 390
 391     my $action = Catalyst::Action->new(
 392         {
 393             name       => $method,
 394             code       => $code,
 395             reverse    => $reverse,
 396             namespace  => $namespace,
 397             prefix     => $prefix,
 398             attributes => \%attributes,
 399         }
 400     );
 401
 402     # Set the method value
 403     $parent->getNodeValue->actions->{$method} = $action;
 404
 405     # Pass the action to our dispatch types so they can register it if reqd.
 406     foreach my $type ( @{ $self->dispatch_types } ) {
 407         $type->register( $c, $action );
 408     }
 409 }
 410
 411 =item $self->setup_actions( $class, $component )
 412
 413 =cut
 414
 415 sub setup_actions {
 416     my ( $self, $class ) = @_;
 417
 418     $self->dispatch_types( [] );
 419
 420     # Preload action types
 421     for my $type (@PRELOAD) {
 422         my $class = "Catalyst::DispatchType::$type";
 423         eval "require $class";
 424         Catalyst::Exception->throw( message => qq/Couldn't load "$class"/ )
 425           if $@;
 426         push @{ $self->dispatch_types }, $class->new;
 427     }
 428
 429     # We use a tree
 430     my $container =
 431       Catalyst::ActionContainer->new( { part => '/', actions => {} } );
 432     $self->tree( Tree::Simple->new( $container, Tree::Simple->ROOT ) );
 433
 434     for my $comp ( keys %{ $class->components } ) {
 435
 436         # We only setup components that inherit from Catalyst::Base
 437         next unless $comp->isa('Catalyst::Base');
 438
 439         for my $action ( @{ Catalyst::Utils::reflect_actions($comp) } ) {
 440             my ( $code, $attrs ) = @{$action};
 441             my $name = '';
 442             no strict 'refs';
 443             my @cache = ( $comp, @{"$comp\::ISA"} );
 444             my %namespaces;
 445
 446             while ( my $namespace = shift @cache ) {
 447                 $namespaces{$namespace}++;
 448                 for my $isa ( @{"$comp\::ISA"} ) {
 449                     next if $namespaces{$isa};
 450                     push @cache, $isa;
 451                     $namespaces{$isa}++;
 452                 }
 453             }
 454
 455             for my $namespace ( keys %namespaces ) {
 456                 for my $sym ( values %{ $namespace . '::' } ) {
 457                     if ( *{$sym}{CODE} && *{$sym}{CODE} == $code ) {
 458                         $name = *{$sym}{NAME};
 459                         $class->set_action( $name, $code, $comp, $attrs );
 460                         last;
 461                     }
 462                 }
 463             }
 464         }
 465     }
 466
 467     # Default actions are always last in the chain
 468     push @{ $self->dispatch_types }, Catalyst::DispatchType::Index->new;
 469     push @{ $self->dispatch_types }, Catalyst::DispatchType::Default->new;
 470
 471     return unless $class->debug;
 472
 473     my $privates = Text::ASCIITable->new;
 474     $privates->setCols( 'Private', 'Class' );
 475     $privates->setColWidth( 'Private', 36, 1 );
 476     $privates->setColWidth( 'Class',   37, 1 );
 477
 478     my $walker = sub {
 479         my ( $walker, $parent, $prefix ) = @_;
 480         $prefix .= $parent->getNodeValue || '';
 481         $prefix .= '/' unless $prefix =~ /\/$/;
 482         my $node = $parent->getNodeValue->actions;
 483
 484         for my $action ( keys %{$node} ) {
 485             my $action_obj = $node->{$action};
 486             $privates->addRow( "$prefix$action", $action_obj->namespace );
 487         }
 488
 489         $walker->( $walker, $_, $prefix ) for $parent->getAllChildren;
 490     };
 491
 492     $walker->( $walker, $self->tree, '' );
 493     $class->log->debug( "Loaded Private actions:\n" . $privates->draw )
 494       if ( @{ $privates->{tbl_rows} } );
 495
 496     # List all public actions
 497     $_->list($class) for @{ $self->dispatch_types };
 498 }
 499
 500 =back
 501
 502 =head1 AUTHOR
 503
 504 Sebastian Riedel, C<sri@cpan.org>
 505
 506 =head1 COPYRIGHT
 507
 508 This program is free software, you can redistribute it and/or modify it under
 509 the same terms as Perl itself.
 510
 511 =cut
 512
 513 1;