lib/Catalyst/Dispatcher.pm

   1 package Catalyst::Dispatcher;
   2
   3 use strict;
   4 use base 'Class::Accessor::Fast';
   5 use Catalyst::Exception;
   6 use Catalyst::Utils;
   7 use Catalyst::Action;
   8 use Catalyst::ActionContainer;
   9 use Catalyst::DispatchType::Default;
  10 use Catalyst::DispatchType::Index;
  11 use Text::SimpleTable;
  12 use Tree::Simple;
  13 use Tree::Simple::Visitor::FindByPath;
  14
  15 # Stringify to class
  16 use overload '""' => sub { return ref shift }, fallback => 1;
  17
  18 __PACKAGE__->mk_accessors(qw/tree dispatch_types registered_dispatch_types
  19   method_action_class action_container_class/);
  20
  21 # Preload these action types
  22 our @PRELOAD = qw/Path Regex/;
  23
  24 # Postload these action types
  25 our @POSTLOAD = qw/Index Default/;
  26
  27 =head1 NAME
  28
  29 Catalyst::Dispatcher - The Catalyst Dispatcher
  30
  31 =head1 SYNOPSIS
  32
  33 See L<Catalyst>.
  34
  35 =head1 DESCRIPTION
  36
  37 =head1 METHODS
  38
  39 =over 4
  40
  41 =item $self->detach( $c, $command [, \@arguments ] )
  42
  43 =cut
  44
  45 sub detach {
  46     my ( $self, $c, $command, @args ) = @_;
  47     $c->forward( $command, @args ) if $command;
  48     die $Catalyst::DETACH;
  49 }
  50
  51 =item $self->dispatch($c)
  52
  53 =cut
  54
  55 sub dispatch {
  56     my ( $self, $c ) = @_;
  57
  58     if ( $c->action ) {
  59         $c->forward( join( '/', '', $c->namespace, '_DISPATCH' ) );
  60     }
  61
  62     else {
  63         my $path  = $c->req->path;
  64         my $error = $path
  65           ? qq/Unknown resource "$path"/
  66           : "No default action defined";
  67         $c->log->error($error) if $c->debug;
  68         $c->error($error);
  69     }
  70 }
  71
  72 =item $self->forward( $c, $command [, \@arguments ] )
  73
  74 =cut
  75
  76 sub forward {
  77     my $self    = shift;
  78     my $c       = shift;
  79     my $command = shift;
  80
  81     unless ($command) {
  82         $c->log->debug('Nothing to forward to') if $c->debug;
  83         return 0;
  84     }
  85
  86     my $arguments = ( ref( $_[-1] ) eq 'ARRAY' ) ? pop(@_) : $c->req->args;
  87
  88     my $result;
  89
  90     my $command_copy = $command;
  91
  92     unless ( $command_copy =~ s/^\/// ) {
  93         my $namespace = $c->namespace;
  94         $command_copy = "${namespace}/${command}";
  95     }
  96
  97     unless ( $command_copy =~ /\// ) {
  98         $result = $c->get_action( $command_copy, '/' );
  99     }
 100     else {
 101         my @extra_args;
 102       DESCEND: while ( $command_copy =~ s/^(.*)\/(\w+)$/$1/ ) {
 103             my $tail = $2;
 104             $result = $c->get_action( $tail, $1 );
 105             if ( $result ) {
 106                 $command = $tail;
 107                 push( @{$arguments}, @extra_args );
 108                 last DESCEND;
 109             }
 110             unshift( @extra_args, $tail );
 111         }
 112     }
 113
 114     unless ( $result ) {
 115
 116         my $comp;
 117
 118         unless ( $comp = $c->component($command) ) {
 119             my $error =
 120 qq/Couldn't forward to command "$command". Invalid action or component./;
 121             $c->error($error);
 122             $c->log->debug($error) if $c->debug;
 123             return 0;
 124         }
 125
 126         my $class  = ref $comp;
 127         my $method = shift || 'process';
 128
 129         if ( my $code = $class->can($method) ) {
 130             my $action = $self->method_action_class->new(
 131                 {
 132                     name      => $method,
 133                     code      => $code,
 134                     reverse   => "$class->$method",
 135                     class     => $class,
 136                     namespace => $class,
 137                 }
 138             );
 139             $result = $action;
 140         }
 141
 142         else {
 143             my $error =
 144               qq/Couldn't forward to "$class". Does not implement "$method"/;
 145             $c->error($error);
 146             $c->log->debug($error)
 147               if $c->debug;
 148             return 0;
 149         }
 150
 151     }
 152
 153     local $c->request->{arguments} = [ @{$arguments} ];
 154
 155     $result->execute($c);
 156
 157     return $c->state;
 158 }
 159
 160 =item $self->prepare_action($c)
 161
 162 =cut
 163
 164 sub prepare_action {
 165     my ( $self, $c ) = @_;
 166     my $path = $c->req->path;
 167     my @path = split /\//, $c->req->path;
 168     $c->req->args( \my @args );
 169
 170     push( @path, '/' ) unless @path;    # Root action
 171
 172   DESCEND: while (@path) {
 173         $path = join '/', @path;
 174
 175         $path = '' if $path eq '/';     # Root action
 176
 177         # Check out dispatch types to see if any will handle the path at
 178         # this level
 179
 180         foreach my $type ( @{ $self->dispatch_types } ) {
 181             last DESCEND if $type->match( $c, $path );
 182         }
 183
 184         # If not, move the last part path to args
 185
 186         unshift @args, pop @path;
 187     }
 188
 189     $c->log->debug( 'Arguments are "' . join( '/', @args ) . '"' )
 190       if ( $c->debug && @args );
 191 }
 192
 193 =item $self->get_action( $c, $action, $namespace )
 194
 195 =cut
 196
 197 sub get_action {
 198     my ( $self, $c, $name, $namespace ) = @_;
 199     return unless $name;
 200     $namespace ||= '';
 201     $namespace = '' if $namespace eq '/';
 202
 203     my @match = $self->get_containers($namespace);
 204
 205     return unless @match;
 206
 207     if ( my $action = $match[-1]->get_action( $c, $name ) )
 208     {
 209         return $action if $action->namespace eq $namespace;
 210     }
 211 }
 212
 213 =item $self->get_actions( $c, $action, $namespace )
 214
 215 =cut
 216
 217 sub get_actions {
 218     my ( $self, $c, $action, $namespace ) = @_;
 219     return [] unless $action;
 220     $namespace ||= '';
 221     $namespace = '' if $namespace eq '/';
 222
 223     my @match = $self->get_containers($namespace);
 224
 225     return map { $_->get_action($c, $action) } @match;
 226 }
 227
 228 =item $self->get_containers( $namespace )
 229
 230 =cut
 231
 232 sub get_containers {
 233     my ( $self, $namespace ) = @_;
 234
 235     # If the namespace is / just return the root ActionContainer
 236
 237     return ( $self->tree->getNodeValue )
 238       if ( !$namespace || ( $namespace eq '/' ) );
 239
 240     # Use a visitor to recurse down the tree finding the ActionContainers
 241     # for each namespace in the chain.
 242
 243     my $visitor = Tree::Simple::Visitor::FindByPath->new;
 244     my @path = split( '/', $namespace );
 245     $visitor->setSearchPath(@path);
 246     $self->tree->accept($visitor);
 247
 248     my @match = $visitor->getResults;
 249     @match = ( $self->tree ) unless @match;
 250
 251     if ( !defined $visitor->getResult ) {
 252
 253         # If we don't manage to match, the visitor doesn't return the last
 254         # node is matched, so foo/bar/baz would only find the 'foo' node,
 255         # not the foo and foo/bar nodes as it should. This does another
 256         # single-level search to see if that's the case, and the 'last unless'
 257         # should catch any failures - or short-circuit this if this *is* a
 258         # bug in the visitor and gets fixed.
 259
 260         my $extra = $path[ ( scalar @match ) - 1 ];
 261         last unless $extra;
 262         $visitor->setSearchPath($extra);
 263         $match[-1]->accept($visitor);
 264         push( @match, $visitor->getResult ) if defined $visitor->getResult;
 265     }
 266
 267     return map { $_->getNodeValue } @match;
 268 }
 269
 270 sub register {
 271     my ( $self, $c, $action ) = @_;
 272
 273     my $namespace = $action->namespace;
 274     my $parent    = $self->tree;
 275     my $visitor   = Tree::Simple::Visitor::FindByPath->new;
 276
 277     if ($namespace) {
 278         for my $part ( split '/', $namespace ) {
 279             $visitor->setSearchPath($part);
 280             $parent->accept($visitor);
 281             my $child = $visitor->getResult;
 282
 283             unless ($child) {
 284
 285                 # Create a new tree node and an ActionContainer to form
 286                 # its value.
 287
 288                 my $container =
 289                   Catalyst::ActionContainer->new(
 290                     { part => $part, actions => {} } );
 291                 $child = $parent->addChild( Tree::Simple->new($container) );
 292                 $visitor->setSearchPath($part);
 293                 $parent->accept($visitor);
 294                 $child = $visitor->getResult;
 295             }
 296
 297             $parent = $child;
 298         }
 299     }
 300
 301     # Set the method value
 302     $parent->getNodeValue->actions->{$action->name} = $action;
 303
 304     my $registered = $self->registered_dispatch_types;
 305
 306     foreach my $key (keys %{$action->attributes}) {
 307             my $class = "Catalyst::DispatchType::$key";
 308             unless ( $registered->{$class} ) {
 309                 eval "require $class";
 310                 push( @{ $self->dispatch_types }, $class->new ) unless $@;
 311                 $registered->{$class} = 1;
 312             }
 313     }
 314
 315     # Pass the action to our dispatch types so they can register it if reqd.
 316     foreach my $type ( @{ $self->dispatch_types } ) {
 317         $type->register( $c, $action );
 318     }
 319 }
 320
 321 =item $self->setup_actions( $class, $component )
 322
 323 =cut
 324
 325 sub setup_actions {
 326     my ( $self, $c ) = @_;
 327
 328     $self->dispatch_types( [] );
 329     $self->registered_dispatch_types( {} );
 330     $self->method_action_class( 'Catalyst::Action' );
 331     $self->action_container_class( 'Catalyst::ActionContainer' );
 332
 333     # Preload action types
 334     for my $type (@PRELOAD) {
 335         my $class = "Catalyst::DispatchType::$type";
 336         eval "require $class";
 337         Catalyst::Exception->throw( message => qq/Couldn't load "$class"/ )
 338           if $@;
 339         push @{ $self->dispatch_types }, $class->new;
 340         $self->registered_dispatch_types->{$class} = 1;
 341     }
 342
 343     # We use a tree
 344     my $container =
 345       Catalyst::ActionContainer->new( { part => '/', actions => {} } );
 346     $self->tree( Tree::Simple->new( $container, Tree::Simple->ROOT ) );
 347
 348     $c->register_actions( $c );
 349
 350     foreach my $comp ( values %{$c->components} ) {
 351         $comp->register_actions( $c ) if $comp->can('register_actions');
 352     }
 353
 354     # Postload action types
 355     for my $type (@POSTLOAD) {
 356         my $class = "Catalyst::DispatchType::$type";
 357         eval "require $class";
 358         Catalyst::Exception->throw( message => qq/Couldn't load "$class"/ )
 359           if $@;
 360         push @{ $self->dispatch_types }, $class->new;
 361     }
 362
 363     return unless $c->debug;
 364
 365     my $privates
 366         = Text::SimpleTable->new( [ 36, 'Private' ], [ 37, 'Class' ] );
 367
 368     my $has_private = 0;
 369     my $walker = sub {
 370         my ( $walker, $parent, $prefix ) = @_;
 371         $prefix .= $parent->getNodeValue || '';
 372         $prefix .= '/' unless $prefix =~ /\/$/;
 373         my $node = $parent->getNodeValue->actions;
 374
 375         for my $action ( keys %{$node} ) {
 376             my $action_obj = $node->{$action};
 377             next
 378               if ( ( $action =~ /^_.*/ )
 379                 && ( !$c->config->{show_internal_actions} ) );
 380             $privates->row( "$prefix$action", $action_obj->class );
 381             $has_private = 1;
 382         }
 383
 384         $walker->( $walker, $_, $prefix ) for $parent->getAllChildren;
 385     };
 386
 387     $walker->( $walker, $self->tree, '' );
 388     $c->log->debug( "Loaded Private actions:\n" . $privates->draw )
 389       if ( $has_private );
 390
 391     # List all public actions
 392     $_->list($c) for @{ $self->dispatch_types };
 393 }
 394
 395 =back
 396
 397 =head1 AUTHOR
 398
 399 Sebastian Riedel, C<sri@cpan.org>
 400 Matt S Trout, C<mst@shadowcatsystems.co.uk>
 401
 402 =head1 COPYRIGHT
 403
 404 This program is free software, you can redistribute it and/or modify it under
 405 the same terms as Perl itself.
 406
 407 =cut
 408
 409 1;