lib/Catalyst/Dispatcher.pm

   1 package Catalyst::Dispatcher;
   2
   3 use strict;
   4 use base 'Class::Accessor::Fast';
   5 use Catalyst::Exception;
   6 use Catalyst::Utils;
   7 use Catalyst::Action;
   8 use Catalyst::ActionContainer;
   9 use Catalyst::DispatchType::Default;
  10 use Catalyst::DispatchType::Index;
  11 use Text::ASCIITable;
  12 use Tree::Simple;
  13 use Tree::Simple::Visitor::FindByPath;
  14
  15 # Stringify to class
  16 use overload '""' => sub { return ref shift }, fallback => 1;
  17
  18 __PACKAGE__->mk_accessors(qw/tree dispatch_types/);
  19
  20 # Preload these action types
  21 our @PRELOAD = qw/Path Regex/;
  22
  23 # Postload these action types
  24 our @POSTLOAD = qw/Index Default/;
  25
  26 =head1 NAME
  27
  28 Catalyst::Dispatcher - The Catalyst Dispatcher
  29
  30 =head1 SYNOPSIS
  31
  32 See L<Catalyst>.
  33
  34 =head1 DESCRIPTION
  35
  36 =head1 METHODS
  37
  38 =over 4
  39
  40 =item $self->detach( $c, $command [, \@arguments ] )
  41
  42 =cut
  43
  44 sub detach {
  45     my ( $self, $c, $command, @args ) = @_;
  46     $c->forward( $command, @args ) if $command;
  47     die $Catalyst::DETACH;
  48 }
  49
  50 =item $self->dispatch($c)
  51
  52 =cut
  53
  54 sub dispatch {
  55     my ( $self, $c ) = @_;
  56
  57     if ( $c->action ) {
  58
  59         my @containers = $self->get_containers( $c->namespace );
  60         my %actions;
  61         foreach my $name (qw/begin auto end/) {
  62
  63             # Go down the container list representing each part of the
  64             # current namespace inheritance tree, grabbing the actions hash
  65             # of the ActionContainer object and looking for actions of the
  66             # appropriate name registered to the namespace
  67
  68             $actions{$name} = [
  69                 map    { $_->{$name} }
  70                   grep { exists $_->{$name} }
  71                   map  { $_->actions } @containers
  72             ];
  73         }
  74
  75         # Errors break the normal flow and the end action is instantly run
  76         my $error = 0;
  77
  78         # Execute last begin
  79         $c->state(1);
  80         if ( my $begin = @{ $actions{begin} }[-1] ) {
  81             $begin->execute($c);
  82             $error++ if scalar @{ $c->error };
  83         }
  84
  85         # Execute the auto chain
  86         my $autorun = 0;
  87         for my $auto ( @{ $actions{auto} } ) {
  88             last if $error;
  89             $autorun++;
  90             $auto->execute($c);
  91             $error++ if scalar @{ $c->error };
  92             last unless $c->state;
  93         }
  94
  95         # Execute the action or last default
  96         my $mkay = $autorun ? $c->state ? 1 : 0 : 1;
  97         if ($mkay) {
  98             unless ($error) {
  99                 $c->action->execute($c);
 100                 $error++ if scalar @{ $c->error };
 101             }
 102         }
 103
 104         # Execute last end
 105         if ( my $end = @{ $actions{end} }[-1] ) {
 106             $end->execute($c);
 107         }
 108     }
 109
 110     else {
 111         my $path  = $c->req->path;
 112         my $error = $path
 113           ? qq/Unknown resource "$path"/
 114           : "No default action defined";
 115         $c->log->error($error) if $c->debug;
 116         $c->error($error);
 117     }
 118 }
 119
 120 =item $self->forward( $c, $command [, \@arguments ] )
 121
 122 =cut
 123
 124 sub forward {
 125     my $self    = shift;
 126     my $c       = shift;
 127     my $command = shift;
 128
 129     unless ($command) {
 130         $c->log->debug('Nothing to forward to') if $c->debug;
 131         return 0;
 132     }
 133
 134     # Relative forwards from detach
 135     my $caller = ( caller(1) )[0]->isa('Catalyst::Dispatcher')
 136       && ( ( caller(2) )[3] =~ /::detach$/ ) ? caller(3) : caller(1);
 137
 138     my $arguments = ( ref( $_[-1] ) eq 'ARRAY' ) ? pop(@_) : $c->req->args;
 139
 140     my $results = [];
 141
 142     my $command_copy = $command;
 143
 144     unless ( $command_copy =~ s/^\/// ) {
 145         my $namespace =
 146           Catalyst::Utils::class2prefix( $caller, $c->config->{case_sensitive} )
 147           || '';
 148         $command_copy = "${namespace}/${command}";
 149     }
 150
 151     unless ( $command_copy =~ /\// ) {
 152         $results = $c->get_action( $command_copy, '/' );
 153     }
 154     else {
 155         my @extra_args;
 156       DESCEND: while ( $command_copy =~ s/^(.*)\/(\w+)$/$1/ ) {
 157             my $tail = $2;
 158             $results = $c->get_action( $tail, $1 );
 159             if ( @{$results} ) {
 160                 $command = $tail;
 161                 push( @{$arguments}, @extra_args );
 162                 last DESCEND;
 163             }
 164             unshift( @extra_args, $tail );
 165         }
 166     }
 167
 168     unless ( @{$results} ) {
 169
 170         unless ( $c->components->{$command} ) {
 171             my $error =
 172 qq/Couldn't forward to command "$command". Invalid action or component./;
 173             $c->error($error);
 174             $c->log->debug($error) if $c->debug;
 175             return 0;
 176         }
 177
 178         my $class  = $command;
 179         my $method = shift || 'process';
 180
 181         if ( my $code = $c->components->{$class}->can($method) ) {
 182             my $action = Catalyst::Action->new(
 183                 {
 184                     name      => $method,
 185                     code      => $code,
 186                     reverse   => "$class->$method",
 187                     namespace => $class,
 188                     prefix    => $class,
 189                 }
 190             );
 191             $results = [ [$action] ];
 192         }
 193
 194         else {
 195             my $error =
 196               qq/Couldn't forward to "$class". Does not implement "$method"/;
 197             $c->error($error);
 198             $c->log->debug($error)
 199               if $c->debug;
 200             return 0;
 201         }
 202
 203     }
 204
 205     local $c->request->{arguments} = [ @{$arguments} ];
 206
 207     for my $result ( @{$results} ) {
 208         $result->[0]->execute($c);
 209         return if scalar @{ $c->error };
 210         last unless $c->state;
 211     }
 212
 213     return $c->state;
 214 }
 215
 216 =item $self->prepare_action($c)
 217
 218 =cut
 219
 220 sub prepare_action {
 221     my ( $self, $c ) = @_;
 222     my $path = $c->req->path;
 223     my @path = split /\//, $c->req->path;
 224     $c->req->args( \my @args );
 225
 226     push( @path, '/' ) unless @path;    # Root action
 227
 228   DESCEND: while (@path) {
 229         $path = join '/', @path;
 230
 231         $path = '' if $path eq '/';     # Root action
 232
 233         # Check out dispatch types to see if any will handle the path at
 234         # this level
 235
 236         foreach my $type ( @{ $self->dispatch_types } ) {
 237             last DESCEND if $type->match( $c, $path );
 238         }
 239
 240         # If not, move the last part path to args
 241
 242         unshift @args, pop @path;
 243     }
 244
 245     $c->log->debug( 'Arguments are "' . join( '/', @args ) . '"' )
 246       if ( $c->debug && @args );
 247 }
 248
 249 =item $self->get_action( $c, $action, $namespace, $inherit )
 250
 251 =cut
 252
 253 sub get_action {
 254     my ( $self, $c, $action, $namespace, $inherit ) = @_;
 255     return [] unless $action;
 256     $namespace ||= '';
 257     $inherit   ||= 0;
 258
 259     my @match = $self->get_containers($namespace);
 260
 261     my @results;
 262
 263     foreach my $child ( $inherit ? @match : $match[-1] ) {
 264         my $node = $child->actions;
 265         if ( defined $node->{$action} ) {
 266             unless ($inherit) {
 267                 $namespace = '' if $namespace eq '/';
 268                 my $reverse = $node->{$action}->reverse;
 269                 my $name    = $namespace
 270                   ? $namespace =~ /\/$/
 271                   ? "$namespace$action"
 272                   : "$namespace/$action"
 273                   : $action;
 274                 last unless $name eq $reverse;
 275             }
 276             push( @results, [ $node->{$action} ] );
 277         }
 278     }
 279     return \@results;
 280 }
 281
 282 =item $self->get_containers( $namespace )
 283
 284 =cut
 285
 286 sub get_containers {
 287     my ( $self, $namespace ) = @_;
 288
 289     # If the namespace is / just return the root ActionContainer
 290
 291     return ( $self->tree->getNodeValue )
 292       if ( !$namespace || ( $namespace eq '/' ) );
 293
 294     # Use a visitor to recurse down the tree finding the ActionContainers
 295     # for each namespace in the chain.
 296
 297     my $visitor = Tree::Simple::Visitor::FindByPath->new;
 298     my @path = split( '/', $namespace );
 299     $visitor->setSearchPath(@path);
 300     $self->tree->accept($visitor);
 301
 302     my @match = $visitor->getResults;
 303     @match = ( $self->tree ) unless @match;
 304
 305     if ( !defined $visitor->getResult ) {
 306
 307         # If we don't manage to match, the visitor doesn't return the last
 308         # node is matched, so foo/bar/baz would only find the 'foo' node,
 309         # not the foo and foo/bar nodes as it should. This does another
 310         # single-level search to see if that's the case, and the 'last unless'
 311         # should catch any failures - or short-circuit this if this *is* a
 312         # bug in the visitor and gets fixed.
 313
 314         my $extra = $path[ ( scalar @match ) - 1 ];
 315         last unless $extra;
 316         $visitor->setSearchPath($extra);
 317         $match[-1]->accept($visitor);
 318         push( @match, $visitor->getResult ) if defined $visitor->getResult;
 319     }
 320
 321     return map { $_->getNodeValue } @match;
 322 }
 323
 324 =item $self->set_action( $c, $action, $code, $namespace, $attrs )
 325
 326 =cut
 327
 328 sub set_action {
 329     my ( $self, $c, $method, $code, $namespace, $attrs ) = @_;
 330
 331     my $prefix =
 332       Catalyst::Utils::class2prefix( $namespace, $c->config->{case_sensitive} )
 333       || '';
 334     my %attributes;
 335
 336     for my $attr ( @{$attrs} ) {
 337
 338         # Parse out :Foo(bar) into Foo => bar etc (and arrayify)
 339
 340         my %initialized;
 341         $initialized{ ref $_ }++ for @{ $self->dispatch_types };
 342
 343         if ( my ( $key, $value ) = ( $attr =~ /^(.*?)(?:\(\s*(.+)\s*\))?$/ ) ) {
 344
 345             # Initialize types
 346             my $class = "Catalyst::DispatchType::$key";
 347             unless ( $initialized{$class} ) {
 348                 eval "require $class";
 349                 push( @{ $self->dispatch_types }, $class->new ) unless $@;
 350                 $initialized{$class}++;
 351             }
 352
 353             if ( defined $value ) {
 354                 ( $value =~ s/^'(.*)'$/$1/ ) || ( $value =~ s/^"(.*)"/$1/ );
 355             }
 356             push( @{ $attributes{$key} }, $value );
 357         }
 358     }
 359
 360     if ( $attributes{Private} && ( keys %attributes > 1 ) ) {
 361         $c->log->debug( 'Bad action definition "'
 362               . join( ' ', @{$attrs} )
 363               . qq/" for "$namespace->$method"/ )
 364           if $c->debug;
 365         return;
 366     }
 367     return unless keys %attributes;
 368
 369     my $parent  = $self->tree;
 370     my $visitor = Tree::Simple::Visitor::FindByPath->new;
 371
 372     if ($prefix) {
 373         for my $part ( split '/', $prefix ) {
 374             $visitor->setSearchPath($part);
 375             $parent->accept($visitor);
 376             my $child = $visitor->getResult;
 377
 378             unless ($child) {
 379
 380                 # Create a new tree node and an ActionContainer to form
 381                 # its value.
 382
 383                 my $container =
 384                   Catalyst::ActionContainer->new(
 385                     { part => $part, actions => {} } );
 386                 $child = $parent->addChild( Tree::Simple->new($container) );
 387                 $visitor->setSearchPath($part);
 388                 $parent->accept($visitor);
 389                 $child = $visitor->getResult;
 390             }
 391
 392             $parent = $child;
 393         }
 394     }
 395
 396     my $reverse = $prefix ? "$prefix/$method" : $method;
 397
 398     my $action = Catalyst::Action->new(
 399         {
 400             name       => $method,
 401             code       => $code,
 402             reverse    => $reverse,
 403             namespace  => $namespace,
 404             prefix     => $prefix,
 405             attributes => \%attributes,
 406         }
 407     );
 408
 409     # Set the method value
 410     $parent->getNodeValue->actions->{$method} = $action;
 411
 412     # Pass the action to our dispatch types so they can register it if reqd.
 413     foreach my $type ( @{ $self->dispatch_types } ) {
 414         $type->register( $c, $action );
 415     }
 416 }
 417
 418 =item $self->setup_actions( $class, $component )
 419
 420 =cut
 421
 422 sub setup_actions {
 423     my ( $self, $class ) = @_;
 424
 425     $self->dispatch_types( [] );
 426
 427     # Preload action types
 428     for my $type (@PRELOAD) {
 429         my $class = "Catalyst::DispatchType::$type";
 430         eval "require $class";
 431         Catalyst::Exception->throw( message => qq/Couldn't load "$class"/ )
 432           if $@;
 433         push @{ $self->dispatch_types }, $class->new;
 434     }
 435
 436     # We use a tree
 437     my $container =
 438       Catalyst::ActionContainer->new( { part => '/', actions => {} } );
 439     $self->tree( Tree::Simple->new( $container, Tree::Simple->ROOT ) );
 440
 441     for my $comp ( keys %{ $class->components } ) {
 442
 443         # We only setup components that inherit from Catalyst::Base
 444         next unless $comp->isa('Catalyst::Base');
 445
 446         for my $action ( @{ Catalyst::Utils::reflect_actions($comp) } ) {
 447             my ( $code, $attrs ) = @{$action};
 448             my $name = '';
 449             no strict 'refs';
 450             my @cache = ( $comp, @{"$comp\::ISA"} );
 451             my %namespaces;
 452
 453             while ( my $namespace = shift @cache ) {
 454                 $namespaces{$namespace}++;
 455                 for my $isa ( @{"$comp\::ISA"} ) {
 456                     next if $namespaces{$isa};
 457                     push @cache, $isa;
 458                     $namespaces{$isa}++;
 459                 }
 460             }
 461
 462             for my $namespace ( keys %namespaces ) {
 463                 for my $sym ( values %{ $namespace . '::' } ) {
 464                     if ( *{$sym}{CODE} && *{$sym}{CODE} == $code ) {
 465                         $name = *{$sym}{NAME};
 466                         $class->set_action( $name, $code, $comp, $attrs );
 467                         last;
 468                     }
 469                 }
 470             }
 471         }
 472     }
 473
 474     # Postload action types
 475     for my $type (@POSTLOAD) {
 476         my $class = "Catalyst::DispatchType::$type";
 477         eval "require $class";
 478         Catalyst::Exception->throw( message => qq/Couldn't load "$class"/ )
 479           if $@;
 480         push @{ $self->dispatch_types }, $class->new;
 481     }
 482
 483     return unless $class->debug;
 484
 485     my $privates = Text::ASCIITable->new;
 486     $privates->setCols( 'Private', 'Class' );
 487     $privates->setColWidth( 'Private', 36, 1 );
 488     $privates->setColWidth( 'Class',   37, 1 );
 489
 490     my $walker = sub {
 491         my ( $walker, $parent, $prefix ) = @_;
 492         $prefix .= $parent->getNodeValue || '';
 493         $prefix .= '/' unless $prefix =~ /\/$/;
 494         my $node = $parent->getNodeValue->actions;
 495
 496         for my $action ( keys %{$node} ) {
 497             my $action_obj = $node->{$action};
 498             $privates->addRow( "$prefix$action", $action_obj->namespace );
 499         }
 500
 501         $walker->( $walker, $_, $prefix ) for $parent->getAllChildren;
 502     };
 503
 504     $walker->( $walker, $self->tree, '' );
 505     $class->log->debug( "Loaded Private actions:\n" . $privates->draw )
 506       if ( @{ $privates->{tbl_rows} } );
 507
 508     # List all public actions
 509     $_->list($class) for @{ $self->dispatch_types };
 510 }
 511
 512 =back
 513
 514 =head1 AUTHOR
 515
 516 Sebastian Riedel, C<sri@cpan.org>
 517
 518 =head1 COPYRIGHT
 519
 520 This program is free software, you can redistribute it and/or modify it under
 521 the same terms as Perl itself.
 522
 523 =cut
 524
 525 1;