lib/Catalyst/Dispatcher.pm

   1 package Catalyst::Dispatcher;
   2
   3 use strict;
   4 use base 'Class::Accessor::Fast';
   5 use Catalyst::Exception;
   6 use Catalyst::Utils;
   7 use Catalyst::Action;
   8 use Catalyst::ActionContainer;
   9 use Catalyst::DispatchType::Path;
  10 use Catalyst::DispatchType::Regex;
  11 use Catalyst::DispatchType::Default;
  12 use Text::ASCIITable;
  13 use Tree::Simple;
  14 use Tree::Simple::Visitor::FindByPath;
  15
  16 # Stringify to class
  17 use overload '""' => sub { return ref shift }, fallback => 1;
  18
  19 __PACKAGE__->mk_accessors(qw/actions tree dispatch_types/);
  20
  21 =head1 NAME
  22
  23 Catalyst::Dispatcher - The Catalyst Dispatcher
  24
  25 =head1 SYNOPSIS
  26
  27 See L<Catalyst>.
  28
  29 =head1 DESCRIPTION
  30
  31 =head1 METHODS
  32
  33 =over 4
  34
  35 =item $self->detach( $c, $command [, \@arguments ] )
  36
  37 =cut
  38
  39 sub detach {
  40     my ( $self, $c, $command, @args ) = @_;
  41     $c->forward( $command, @args ) if $command;
  42     die $Catalyst::DETACH;
  43 }
  44
  45 =item $self->dispatch($c)
  46
  47 =cut
  48
  49 sub dispatch {
  50     my ( $self, $c ) = @_;
  51
  52     if ( $c->action ) {
  53
  54         my @containers = $self->get_containers( $c->namespace );
  55         my %actions;
  56         foreach my $name (qw/begin auto end/) {
  57
  58             # Go down the container list representing each part of the
  59             # current namespace inheritance tree, grabbing the actions hash
  60             # of the ActionContainer object and looking for actions of the
  61             # appropriate name registered to the namespace
  62
  63             $actions{$name} = [
  64                 map { $_->{$name} }
  65                 grep { exists $_->{$name} }
  66                 map { $_->actions }
  67                 @containers
  68             ];
  69         }
  70
  71         # Errors break the normal flow and the end action is instantly run
  72         my $error = 0;
  73
  74         # Execute last begin
  75         $c->state(1);
  76         if ( my $begin = @{ $actions{begin} }[-1] ) {
  77             $begin->execute($c);
  78             $error++ if scalar @{ $c->error };
  79         }
  80
  81         # Execute the auto chain
  82         my $autorun = 0;
  83         for my $auto ( @{ $actions{auto} } ) {
  84             last if $error;
  85             $autorun++;
  86             $auto->execute($c);
  87             $error++ if scalar @{ $c->error };
  88             last unless $c->state;
  89         }
  90
  91         # Execute the action or last default
  92         my $mkay = $autorun ? $c->state ? 1 : 0 : 1;
  93         if ( $mkay ) {
  94             unless ($error) {
  95                 $c->action->execute($c);
  96                 $error++ if scalar @{ $c->error };
  97             }
  98         }
  99
 100         # Execute last end
 101         if ( my $end = @{ $actions{end} }[-1] ) {
 102             $end->execute($c);
 103         }
 104     }
 105
 106     else {
 107         my $path  = $c->req->path;
 108         my $error = $path
 109           ? qq/Unknown resource "$path"/
 110           : "No default action defined";
 111         $c->log->error($error) if $c->debug;
 112         $c->error($error);
 113     }
 114 }
 115
 116 =item $self->forward( $c, $command [, \@arguments ] )
 117
 118 =cut
 119
 120 sub forward {
 121     my $self    = shift;
 122     my $c       = shift;
 123     my $command = shift;
 124
 125     unless ($command) {
 126         $c->log->debug('Nothing to forward to') if $c->debug;
 127         return 0;
 128     }
 129
 130     # Relative forwards from detach
 131     my $caller = ( caller(1) )[0]->isa('Catalyst::Dispatcher')
 132       && ( ( caller(2) )[3] =~ /::detach$/ ) ? caller(3) : caller(1);
 133
 134     my $arguments = ( ref( $_[-1] ) eq 'ARRAY' ) ? pop(@_) : $c->req->args;
 135
 136     my $results = [];
 137
 138     my $command_copy = $command;
 139
 140     unless ( $command_copy =~ s/^\/// ) {
 141         my $namespace =
 142           Catalyst::Utils::class2prefix( $caller, $c->config->{case_sensitive} ) || '';
 143         $command_copy = "${namespace}/${command}";
 144     }
 145
 146     unless ( $command_copy =~ /\// ) {
 147         $results = $c->get_action( $command_copy, '/' );
 148     }
 149     else {
 150         my @extra_args;
 151       DESCEND: while ( $command_copy =~ s/^(.*)\/(\w+)$/$1/ ) {
 152             my $tail = $2;
 153             $results = $c->get_action( $tail, $1 );
 154             if ( @{$results} ) {
 155                 $command = $tail;
 156                 push( @{$arguments}, @extra_args );
 157                 last DESCEND;
 158             }
 159             unshift( @extra_args, $tail );
 160         }
 161     }
 162
 163     unless ( @{$results} ) {
 164
 165         unless ( $c->components->{$command} ) {
 166             my $error =
 167 qq/Couldn't forward to command "$command". Invalid action or component./;
 168             $c->error($error);
 169             $c->log->debug($error) if $c->debug;
 170             return 0;
 171         }
 172
 173         my $class  = $command;
 174         my $method = shift || 'process';
 175
 176         if ( my $code = $c->components->{$class}->can($method) ) {
 177             my $action = Catalyst::Action->new(
 178                 {
 179                     name      => $method,
 180                     code      => $code,
 181                     reverse   => "$class->$method",
 182                     namespace => $class,
 183                     prefix    => $class,
 184                 }
 185             );
 186             $results = [ [$action] ];
 187         }
 188
 189         else {
 190             my $error =
 191               qq/Couldn't forward to "$class". Does not implement "$method"/;
 192             $c->error($error);
 193             $c->log->debug($error)
 194               if $c->debug;
 195             return 0;
 196         }
 197
 198     }
 199
 200     local $c->request->{arguments} = [ @{$arguments} ];
 201
 202     for my $result ( @{$results} ) {
 203         $result->[0]->execute($c);
 204         return if scalar @{ $c->error };
 205         last unless $c->state;
 206     }
 207
 208     return $c->state;
 209 }
 210
 211 =item $self->prepare_action($c)
 212
 213 =cut
 214
 215 sub prepare_action {
 216     my ( $self, $c ) = @_;
 217     my $path = $c->req->path;
 218     my @path = split /\//, $c->req->path;
 219     $c->req->args( \my @args );
 220
 221   DESCEND: while (@path) {
 222         $path = join '/', @path;
 223
 224         # Check out dispatch types to see if any will handle the path at
 225         # this level
 226
 227         foreach my $type (@{$self->dispatch_types}) {
 228             last DESCEND if $type->prepare_action($c, $path);
 229         }
 230
 231         # If not, move the last part path to args
 232
 233         unshift @args, pop @path;
 234     }
 235
 236     $c->log->debug( 'Arguments are "' . join( '/', @args ) . '"' )
 237       if ( $c->debug && @args );
 238 }
 239
 240 =item $self->get_action( $c, $action, $namespace, $inherit )
 241
 242 =cut
 243
 244 sub get_action {
 245     my ( $self, $c, $action, $namespace, $inherit ) = @_;
 246     return [] unless $action;
 247     $namespace ||= '';
 248     $inherit   ||= 0;
 249
 250     if ($namespace) {
 251
 252         my @match = $self->get_containers( $namespace );
 253
 254         my @results;
 255
 256         foreach my $child ($inherit ? @match: $match[-1]) {
 257             my $node = $child->actions;
 258             push(@results, [ $node->{$action} ]) if defined $node->{$action};
 259         }
 260         return \@results;
 261     }
 262
 263     return [];
 264 }
 265
 266 =item $self->get_containers( $namespace )
 267
 268 =cut
 269
 270 sub get_containers {
 271     my ( $self, $namespace ) = @_;
 272
 273     # If the namespace is / just return the root ActionContainer
 274
 275     return ($self->tree->getNodeValue) if $namespace eq '/';
 276
 277     # Use a visitor to recurse down the tree finding the ActionContainers
 278     # for each namespace in the chain.
 279
 280     my $visitor = Tree::Simple::Visitor::FindByPath->new;
 281     my @path = split('/', $namespace);
 282     $visitor->setSearchPath( @path );
 283     $self->tree->accept($visitor);
 284
 285     my @match = $visitor->getResults;
 286     @match = ($self->tree) unless @match;
 287
 288     if (!defined $visitor->getResult) {
 289
 290         # If we don't manage to match, the visitor doesn't return the last
 291         # node is matched, so foo/bar/baz would only find the 'foo' node,
 292         # not the foo and foo/bar nodes as it should. This does another
 293         # single-level search to see if that's the case, and the 'last unless'
 294         # should catch any failures - or short-circuit this if this *is* a
 295         # bug in the visitor and gets fixed.
 296
 297         my $extra = $path[(scalar @match) - 1];
 298         last unless $extra;
 299         $visitor->setSearchPath($extra);
 300         $match[-1]->accept($visitor);
 301         push(@match, $visitor->getResult) if defined $visitor->getResult;
 302     }
 303
 304     return map { $_->getNodeValue } @match;
 305 }
 306
 307 =item $self->set_action( $c, $action, $code, $namespace, $attrs )
 308
 309 =cut
 310
 311 sub set_action {
 312     my ( $self, $c, $method, $code, $namespace, $attrs ) = @_;
 313
 314     my $prefix =
 315       Catalyst::Utils::class2prefix( $namespace, $c->config->{case_sensitive} )
 316       || '';
 317     my %attributes;
 318
 319     for my $attr ( @{$attrs} ) {
 320
 321         # Parse out :Foo(bar) into Foo => bar etc (and arrayify)
 322
 323         if ( my ($key, $value) = ($attr =~ /^(.*?)(?:\(\s*(.+)\s*\))?$/) ) {
 324             if ( defined $value ) {
 325                 ($value =~ s/^'(.*)'$/$1/) || ($value =~ s/^"(.*)"/$1/);
 326             }
 327             push(@{$attributes{$key}}, $value);
 328         }
 329     }
 330
 331     if ( $attributes{Private} && ( keys %attributes > 1 ) ) {
 332         $c->log->debug( 'Bad action definition "'
 333               . join( ' ', @{$attrs} )
 334               . qq/" for "$namespace->$method"/ )
 335           if $c->debug;
 336         return;
 337     }
 338     return unless keys %attributes;
 339
 340     my $parent  = $self->tree;
 341     my $visitor = Tree::Simple::Visitor::FindByPath->new;
 342
 343     if ($prefix) {
 344         for my $part ( split '/', $prefix ) {
 345             $visitor->setSearchPath($part);
 346             $parent->accept($visitor);
 347             my $child = $visitor->getResult;
 348
 349             unless ($child) {
 350
 351                 # Create a new tree node and an ActionContainer to form
 352                 # its value.
 353
 354                 my $container = Catalyst::ActionContainer->new(
 355                                     { part => $part, actions => {} });
 356                 $child = $parent->addChild( Tree::Simple->new($container) );
 357                 $visitor->setSearchPath($part);
 358                 $parent->accept($visitor);
 359                 $child = $visitor->getResult;
 360             }
 361
 362             $parent = $child;
 363         }
 364     }
 365
 366     my $reverse = $prefix ? "$prefix/$method" : $method;
 367
 368     my $action = Catalyst::Action->new(
 369         {
 370             name       => $method,
 371             code       => $code,
 372             reverse    => $reverse,
 373             namespace  => $namespace,
 374             prefix     => $prefix,
 375             attributes => \%attributes,
 376         }
 377     );
 378
 379     # Set the method value
 380     $parent->getNodeValue->actions->{$method} = $action;
 381
 382     # Pass the action to our dispatch types so they can register it if reqd.
 383     foreach my $type ( @{ $self->dispatch_types } ) {
 384         $type->register_action($c, $action);
 385     }
 386 }
 387
 388 =item $self->setup_actions( $class, $component )
 389
 390 =cut
 391
 392 sub setup_actions {
 393     my ( $self, $class ) = @_;
 394
 395     # These are the core structures
 396     $self->actions(
 397         {
 398             plain    => {},
 399             private  => {},
 400             regex    => {},
 401             compiled => []
 402         }
 403     );
 404
 405     $self->dispatch_types([
 406         map { "Catalyst::DispatchType::$_"->new }
 407             qw/Path Regex Default/ ]);
 408
 409     # We use a tree
 410     my $container = Catalyst::ActionContainer->new(
 411                         { part => '/', actions => {} } );
 412     $self->tree( Tree::Simple->new( $container, Tree::Simple->ROOT ) );
 413
 414     for my $comp ( keys %{ $class->components } ) {
 415
 416         # We only setup components that inherit from Catalyst::Base
 417         next unless $comp->isa('Catalyst::Base');
 418
 419         for my $action ( @{ Catalyst::Utils::reflect_actions($comp) } ) {
 420             my ( $code, $attrs ) = @{$action};
 421             my $name = '';
 422             no strict 'refs';
 423             my @cache = ( $comp, @{"$comp\::ISA"} );
 424             my %namespaces;
 425
 426             while ( my $namespace = shift @cache ) {
 427                 $namespaces{$namespace}++;
 428                 for my $isa ( @{"$comp\::ISA"} ) {
 429                     next if $namespaces{$isa};
 430                     push @cache, $isa;
 431                     $namespaces{$isa}++;
 432                 }
 433             }
 434
 435             for my $namespace ( keys %namespaces ) {
 436
 437                 for my $sym ( values %{ $namespace . '::' } ) {
 438
 439                     if ( *{$sym}{CODE} && *{$sym}{CODE} == $code ) {
 440
 441                         $name = *{$sym}{NAME};
 442                         $class->set_action( $name, $code, $comp, $attrs );
 443                         last;
 444                     }
 445
 446                 }
 447
 448             }
 449
 450         }
 451
 452     }
 453
 454     return unless $class->debug;
 455
 456     my $actions  = $self->actions;
 457     my $privates = Text::ASCIITable->new;
 458     $privates->setCols( 'Private', 'Class' );
 459     $privates->setColWidth( 'Private', 36, 1 );
 460     $privates->setColWidth( 'Class',   37, 1 );
 461
 462     my $walker = sub {
 463         my ( $walker, $parent, $prefix ) = @_;
 464         $prefix .= $parent->getNodeValue || '';
 465         $prefix .= '/' unless $prefix =~ /\/$/;
 466         my $node = $parent->getNodeValue->actions;
 467
 468         for my $action ( keys %{ $node } ) {
 469             my $action_obj = $node->{$action};
 470             $privates->addRow( "$prefix$action", $action_obj->namespace );
 471         }
 472
 473         $walker->( $walker, $_, $prefix ) for $parent->getAllChildren;
 474     };
 475
 476     $walker->( $walker, $self->tree, '' );
 477     $class->log->debug( "Loaded private actions:\n" . $privates->draw )
 478       if ( @{ $privates->{tbl_rows} } );
 479
 480     my $publics = Text::ASCIITable->new;
 481     $publics->setCols( 'Public', 'Private' );
 482     $publics->setColWidth( 'Public',  36, 1 );
 483     $publics->setColWidth( 'Private', 37, 1 );
 484
 485     for my $plain ( sort keys %{ $actions->{plain} } ) {
 486         my $action = $actions->{plain}->{$plain};
 487         $publics->addRow( "/$plain", "/$action" );
 488     }
 489
 490     $class->log->debug( "Loaded public actions:\n" . $publics->draw )
 491       if ( @{ $publics->{tbl_rows} } );
 492
 493     my $regexes = Text::ASCIITable->new;
 494     $regexes->setCols( 'Regex', 'Private' );
 495     $regexes->setColWidth( 'Regex',   36, 1 );
 496     $regexes->setColWidth( 'Private', 37, 1 );
 497
 498     for my $regex ( sort keys %{ $actions->{regex} } ) {
 499         my $action = $actions->{regex}->{$regex};
 500         $regexes->addRow( $regex, "/$action" );
 501     }
 502
 503     $class->log->debug( "Loaded regex actions:\n" . $regexes->draw )
 504       if ( @{ $regexes->{tbl_rows} } );
 505 }
 506
 507 =back
 508
 509 =head1 AUTHOR
 510
 511 Sebastian Riedel, C<sri@cpan.org>
 512
 513 =head1 COPYRIGHT
 514
 515 This program is free software, you can redistribute it and/or modify it under
 516 the same terms as Perl itself.
 517
 518 =cut
 519
 520 1;