lib/Catalyst/Dispatcher.pm

   1 package Catalyst::Dispatcher;
   2
   3 use strict;
   4 use base 'Class::Accessor::Fast';
   5 use Catalyst::Exception;
   6 use Catalyst::Utils;
   7 use Catalyst::Action;
   8 use Catalyst::ActionContainer;
   9 use Catalyst::DispatchType::Default;
  10 use Catalyst::DispatchType::Index;
  11 use Text::SimpleTable;
  12 use Tree::Simple;
  13 use Tree::Simple::Visitor::FindByPath;
  14
  15 # Stringify to class
  16 use overload '""' => sub { return ref shift }, fallback => 1;
  17
  18 __PACKAGE__->mk_accessors(
  19     qw/tree dispatch_types registered_dispatch_types
  20       method_action_class action_container_class/
  21 );
  22
  23 # Preload these action types
  24 our @PRELOAD = qw/Path Regex/;
  25
  26 # Postload these action types
  27 our @POSTLOAD = qw/Index Default/;
  28
  29 =head1 NAME
  30
  31 Catalyst::Dispatcher - The Catalyst Dispatcher
  32
  33 =head1 SYNOPSIS
  34
  35 See L<Catalyst>.
  36
  37 =head1 DESCRIPTION
  38
  39 =head1 METHODS
  40
  41 =over 4
  42
  43 =item $self->detach( $c, $command [, \@arguments ] )
  44
  45 =cut
  46
  47 sub detach {
  48     my ( $self, $c, $command, @args ) = @_;
  49     $c->forward( $command, @args ) if $command;
  50     die $Catalyst::DETACH;
  51 }
  52
  53 =item $self->dispatch($c)
  54
  55 =cut
  56
  57 sub dispatch {
  58     my ( $self, $c ) = @_;
  59
  60     if ( $c->action ) {
  61         $c->forward( join( '/', '', $c->action->namespace, '_DISPATCH' ) );
  62     }
  63
  64     else {
  65         my $path  = $c->req->path;
  66         my $error = $path
  67           ? qq/Unknown resource "$path"/
  68           : "No default action defined";
  69         $c->log->error($error) if $c->debug;
  70         $c->error($error);
  71     }
  72 }
  73
  74 =item $self->forward( $c, $command [, \@arguments ] )
  75
  76 =cut
  77
  78 sub forward {
  79     my $self    = shift;
  80     my $c       = shift;
  81     my $command = shift;
  82
  83     unless ($command) {
  84         $c->log->debug('Nothing to forward to') if $c->debug;
  85         return 0;
  86     }
  87
  88     my $local_args = 0;
  89     my $arguments  = [];
  90     if ( ref( $_[-1] ) eq 'ARRAY' ) {
  91         $arguments = pop(@_);
  92         $local_args++;
  93     }
  94
  95     my $result;
  96
  97     unless ( ref $command ) {
  98         my $command_copy = $command;
  99
 100         unless ( $command_copy =~ s/^\/// ) {
 101             my $namespace = $c->stack->[-1]->namespace;
 102             $command_copy = "${namespace}/${command}";
 103         }
 104
 105         unless ( $command_copy =~ /\// ) {
 106             $result = $c->get_action( $command_copy, '/' );
 107         }
 108         else {
 109             my @extra_args;
 110           DESCEND: while ( $command_copy =~ s/^(.*)\/(\w+)$/$1/ ) {
 111                 my $tail = $2;
 112                 $result = $c->get_action( $tail, $1 );
 113                 if ($result) {
 114                     $command = $tail;
 115                     if ($local_args) { unshift( @{$arguments}, @extra_args ) }
 116                     else {
 117                         $local_args++;
 118                         $arguments = \@extra_args;
 119                     }
 120                     last DESCEND;
 121                 }
 122                 unshift( @extra_args, $tail );
 123             }
 124         }
 125     }
 126
 127     unless ($result) {
 128
 129         my $class  = ref($command) || ref( $c->component($command) );
 130         my $method = shift         || 'process';
 131
 132         unless ($class) {
 133             my $error =
 134 qq/Couldn't forward to command "$command". Invalid action or component./;
 135             $c->error($error);
 136             $c->log->debug($error) if $c->debug;
 137             return 0;
 138         }
 139
 140         if ( my $code = $class->can($method) ) {
 141             my $action = $self->method_action_class->new(
 142                 {
 143                     name      => $method,
 144                     code      => $code,
 145                     reverse   => "$class->$method",
 146                     class     => $class,
 147                     namespace => Catalyst::Utils::class2prefix(
 148                         $class, $c->config->{case_sensitive}
 149                     ),
 150                 }
 151             );
 152             $result = $action;
 153         }
 154
 155         else {
 156             my $error =
 157               qq/Couldn't forward to "$class". Does not implement "$method"/;
 158             $c->error($error);
 159             $c->log->debug($error)
 160               if $c->debug;
 161             return 0;
 162         }
 163
 164     }
 165
 166     if ($local_args) { local $c->request->{arguments} = [ @{$arguments} ] }
 167
 168     $result->execute($c);
 169
 170     return $c->state;
 171 }
 172
 173 =item $self->prepare_action($c)
 174
 175 =cut
 176
 177 sub prepare_action {
 178     my ( $self, $c ) = @_;
 179     my $path = $c->req->path;
 180     my @path = split /\//, $c->req->path;
 181     $c->req->args( \my @args );
 182
 183     push( @path, '/' ) unless @path;    # Root action
 184
 185   DESCEND: while (@path) {
 186         $path = join '/', @path;
 187
 188         $path = '' if $path eq '/';     # Root action
 189
 190         # Check out dispatch types to see if any will handle the path at
 191         # this level
 192
 193         foreach my $type ( @{ $self->dispatch_types } ) {
 194             last DESCEND if $type->match( $c, $path );
 195         }
 196
 197         # If not, move the last part path to args
 198
 199         unshift @args, pop @path;
 200     }
 201
 202     $c->log->debug( 'Arguments are "' . join( '/', @args ) . '"' )
 203       if ( $c->debug && @args );
 204 }
 205
 206 =item $self->get_action( $action, $namespace )
 207
 208 =cut
 209
 210 sub get_action {
 211     my ( $self, $name, $namespace ) = @_;
 212     return unless $name;
 213     $namespace ||= '';
 214     $namespace = '' if $namespace eq '/';
 215
 216     my @match = $self->get_containers($namespace);
 217
 218     return unless @match;
 219
 220     if ( my $action = $match[-1]->get_action($name) ) {
 221         return $action if $action->namespace eq $namespace;
 222     }
 223 }
 224
 225 =item $self->get_actions( $c, $action, $namespace )
 226
 227 =cut
 228
 229 sub get_actions {
 230     my ( $self, $c, $action, $namespace ) = @_;
 231     return [] unless $action;
 232     $namespace ||= '';
 233     $namespace = '' if $namespace eq '/';
 234
 235     my @match = $self->get_containers($namespace);
 236
 237     return map { $_->get_action($action) } @match;
 238 }
 239
 240 =item $self->get_containers( $namespace )
 241
 242 =cut
 243
 244 sub get_containers {
 245     my ( $self, $namespace ) = @_;
 246
 247     # If the namespace is / just return the root ActionContainer
 248
 249     return ( $self->tree->getNodeValue )
 250       if ( !$namespace || ( $namespace eq '/' ) );
 251
 252     # Use a visitor to recurse down the tree finding the ActionContainers
 253     # for each namespace in the chain.
 254
 255     my $visitor = Tree::Simple::Visitor::FindByPath->new;
 256     my @path = split( '/', $namespace );
 257     $visitor->setSearchPath(@path);
 258     $self->tree->accept($visitor);
 259
 260     my @match = $visitor->getResults;
 261     @match = ( $self->tree ) unless @match;
 262
 263     if ( !defined $visitor->getResult ) {
 264
 265         # If we don't manage to match, the visitor doesn't return the last
 266         # node is matched, so foo/bar/baz would only find the 'foo' node,
 267         # not the foo and foo/bar nodes as it should. This does another
 268         # single-level search to see if that's the case, and the 'last unless'
 269         # should catch any failures - or short-circuit this if this *is* a
 270         # bug in the visitor and gets fixed.
 271
 272         if ( my $extra = $path[ ( scalar @match ) - 1 ] ) {
 273             $visitor->setSearchPath($extra);
 274             $match[-1]->accept($visitor);
 275             push( @match, $visitor->getResult ) if defined $visitor->getResult;
 276         }
 277     }
 278
 279     return map { $_->getNodeValue } @match;
 280 }
 281
 282 =item $self->register( $c, $action )
 283
 284 =cut
 285
 286 sub register {
 287     my ( $self, $c, $action ) = @_;
 288
 289     my $registered = $self->registered_dispatch_types;
 290
 291     my $priv = 0;
 292     foreach my $key ( keys %{ $action->attributes } ) {
 293         $priv++ if $key eq 'Private';
 294         my $class = "Catalyst::DispatchType::$key";
 295         unless ( $registered->{$class} ) {
 296             eval "require $class";
 297             push( @{ $self->dispatch_types }, $class->new ) unless $@;
 298             $registered->{$class} = 1;
 299         }
 300     }
 301
 302     # Pass the action to our dispatch types so they can register it if reqd.
 303     my $reg = 0;
 304     foreach my $type ( @{ $self->dispatch_types } ) {
 305         $reg++ if $type->register( $c, $action );
 306     }
 307
 308     return unless $reg + $priv;
 309
 310     my $namespace = $action->namespace;
 311     my $parent    = $self->tree;
 312     my $visitor   = Tree::Simple::Visitor::FindByPath->new;
 313
 314     if ($namespace) {
 315         for my $part ( split '/', $namespace ) {
 316             $visitor->setSearchPath($part);
 317             $parent->accept($visitor);
 318             my $child = $visitor->getResult;
 319
 320             unless ($child) {
 321
 322                 # Create a new tree node and an ActionContainer to form
 323                 # its value.
 324
 325                 my $container =
 326                   Catalyst::ActionContainer->new(
 327                     { part => $part, actions => {} } );
 328                 $child = $parent->addChild( Tree::Simple->new($container) );
 329                 $visitor->setSearchPath($part);
 330                 $parent->accept($visitor);
 331                 $child = $visitor->getResult;
 332             }
 333
 334             $parent = $child;
 335         }
 336     }
 337
 338     # Set the method value
 339     $parent->getNodeValue->actions->{ $action->name } = $action;
 340 }
 341
 342 =item $self->setup_actions( $class, $component )
 343
 344 =cut
 345
 346 sub setup_actions {
 347     my ( $self, $c ) = @_;
 348
 349     $self->dispatch_types( [] );
 350     $self->registered_dispatch_types( {} );
 351     $self->method_action_class('Catalyst::Action');
 352     $self->action_container_class('Catalyst::ActionContainer');
 353
 354     # Preload action types
 355     for my $type (@PRELOAD) {
 356         my $class = "Catalyst::DispatchType::$type";
 357         eval "require $class";
 358         Catalyst::Exception->throw( message => qq/Couldn't load "$class"/ )
 359           if $@;
 360         push @{ $self->dispatch_types }, $class->new;
 361         $self->registered_dispatch_types->{$class} = 1;
 362     }
 363
 364     # We use a tree
 365     my $container =
 366       Catalyst::ActionContainer->new( { part => '/', actions => {} } );
 367     $self->tree( Tree::Simple->new( $container, Tree::Simple->ROOT ) );
 368
 369     foreach my $comp ( values %{ $c->components } ) {
 370         $comp->register_actions($c) if $comp->can('register_actions');
 371     }
 372
 373     # Postload action types
 374     for my $type (@POSTLOAD) {
 375         my $class = "Catalyst::DispatchType::$type";
 376         eval "require $class";
 377         Catalyst::Exception->throw( message => qq/Couldn't load "$class"/ )
 378           if $@;
 379         push @{ $self->dispatch_types }, $class->new;
 380     }
 381
 382     return unless $c->debug;
 383
 384     my $privates = Text::SimpleTable->new(
 385         [ 20, 'Private' ],
 386         [ 38, 'Class' ],
 387         [ 12, 'Method' ]
 388     );
 389
 390     my $has_private = 0;
 391     my $walker = sub {
 392         my ( $walker, $parent, $prefix ) = @_;
 393         $prefix .= $parent->getNodeValue || '';
 394         $prefix .= '/' unless $prefix =~ /\/$/;
 395         my $node = $parent->getNodeValue->actions;
 396
 397         for my $action ( keys %{$node} ) {
 398             my $action_obj = $node->{$action};
 399             next
 400               if ( ( $action =~ /^_.*/ )
 401                 && ( !$c->config->{show_internal_actions} ) );
 402             $privates->row( "$prefix$action", $action_obj->class, $action );
 403             $has_private = 1;
 404         }
 405
 406         $walker->( $walker, $_, $prefix ) for $parent->getAllChildren;
 407     };
 408
 409     $walker->( $walker, $self->tree, '' );
 410     $c->log->debug( "Loaded Private actions:\n" . $privates->draw )
 411       if ($has_private);
 412
 413     # List all public actions
 414     $_->list($c) for @{ $self->dispatch_types };
 415 }
 416
 417 =back
 418
 419 =head1 AUTHOR
 420
 421 Sebastian Riedel, C<sri@cpan.org>
 422 Matt S Trout, C<mst@shadowcatsystems.co.uk>
 423
 424 =head1 COPYRIGHT
 425
 426 This program is free software, you can redistribute it and/or modify it under
 427 the same terms as Perl itself.
 428
 429 =cut
 430
 431 1;