lib/Catalyst/Dispatcher.pm

   1 package Catalyst::Dispatcher;
   2
   3 use strict;
   4 use base 'Class::Data::Inheritable';
   5 use Catalyst::Exception;
   6 use Catalyst::Utils;
   7 use Text::ASCIITable;
   8 use Tree::Simple;
   9 use Tree::Simple::Visitor::FindByPath;
  10
  11 __PACKAGE__->mk_classdata($_) for qw/actions tree/;
  12
  13 =head1 NAME
  14
  15 Catalyst::Dispatcher - The Catalyst Dispatcher
  16
  17 =head1 SYNOPSIS
  18
  19 See L<Catalyst>.
  20
  21 =head1 DESCRIPTION
  22
  23 =head1 METHODS
  24
  25 =over 4
  26
  27 =item $c->detach( $command [, \@arguments ] )
  28
  29 Like C<forward> but doesn't return.
  30
  31 =cut
  32
  33 sub detach {
  34     my ( $c, $command, @args ) = @_;
  35     $c->forward( $command, @args ) if $command;
  36     # die with DETACH signal, which will be caught in dispatching.
  37     die $Catalyst::Engine::DETACH;
  38 }
  39
  40 =item $c->dispatch
  41
  42 Dispatch request to actions.
  43
  44 =cut
  45
  46 sub dispatch {
  47     my $c         = shift;
  48     my $action    = $c->req->action;
  49     my $namespace = '';
  50     $namespace = ( join( '/', @{ $c->req->args } ) || '/' )
  51       if $action eq 'default';
  52
  53     unless ($namespace) {
  54         if ( my $result = $c->get_action($action) ) {
  55             $namespace = Catalyst::Utils::class2prefix( $result->[0]->[0]->[0],
  56                 $c->config->{case_sensitive} );
  57         }
  58     }
  59
  60     my $default = $action eq 'default' ? $namespace : undef;
  61     my $results = $c->get_action( $action, $default, $default ? 1 : 0 );
  62     $namespace ||= '/';
  63
  64     if ( @{$results} ) {
  65
  66         # Execute last begin
  67         $c->state(1);
  68         if ( my $begin = @{ $c->get_action( 'begin', $namespace, 1 ) }[-1] ) {
  69             $c->execute( @{ $begin->[0] } );
  70             return if scalar @{ $c->error };
  71         }
  72
  73         # Execute the auto chain
  74         my $autorun = 0;
  75         for my $auto ( @{ $c->get_action( 'auto', $namespace, 1 ) } ) {
  76             $autorun++;
  77             $c->execute( @{ $auto->[0] } );
  78             return if scalar @{ $c->error };
  79             last unless $c->state;
  80         }
  81
  82         # Execute the action or last default
  83         my $mkay = $autorun ? $c->state ? 1 : 0 : 1;
  84         if ( ( my $action = $c->req->action ) && $mkay ) {
  85             if ( my $result = @{ $c->get_action( $action, $default, 1 ) }[-1] )
  86             {
  87                 $c->execute( @{ $result->[0] } );
  88             }
  89         }
  90
  91         # Execute last end
  92         if ( my $end = @{ $c->get_action( 'end', $namespace, 1 ) }[-1] ) {
  93             $c->execute( @{ $end->[0] } );
  94             return if scalar @{ $c->error };
  95         }
  96     } else {
  97         my $path  = $c->req->path;
  98         my $error = $path
  99           ? qq/Unknown resource "$path"/
 100           : "No default action defined";
 101         $c->log->error($error) if $c->debug;
 102         $c->error($error);
 103     }
 104 }
 105
 106 =item $c->forward( $command [, \@arguments ] )
 107
 108 Forward processing to a private action or a method from a class.
 109 If you define a class without method it will default to process().
 110 also takes an optional arrayref containing arguments to be passed
 111 to the new function. $c->req->args will be reset upon returning
 112 from the function.
 113
 114     $c->forward('/foo');
 115     $c->forward('index');
 116     $c->forward(qw/MyApp::Model::CDBI::Foo do_stuff/);
 117     $c->forward('MyApp::View::TT');
 118
 119 =cut
 120
 121 sub forward {
 122     my $c       = shift;
 123     my $command = shift;
 124
 125     unless ($command) {
 126         $c->log->debug('Nothing to forward to') if $c->debug;
 127         return 0;
 128     }
 129
 130     # Relative forwards from detach
 131     my $caller = ( caller(0) )[0]->isa('Catalyst::Dispatcher')
 132       && ( ( caller(1) )[3] =~ /::detach$/ ) ? caller(1) : caller(0);
 133
 134     my $namespace = '/';
 135     my $arguments = ( ref( $_[-1] ) eq 'ARRAY' ) ? pop(@_) : $c->req->args;
 136
 137     if ( $command =~ /^\// ) {
 138         $command =~ /^\/(.*)\/(\w+)$/;
 139         $namespace = $1 || '/';
 140         $command   = $2 || $command;
 141         $command =~ s/^\///;
 142     }
 143
 144     else {
 145         $namespace =
 146           Catalyst::Utils::class2prefix( $caller, $c->config->{case_sensitive} )
 147           || '/';
 148     }
 149
 150     my $results = $c->get_action( $command, $namespace );
 151
 152     unless ( @{$results} ) {
 153
 154         unless ( defined( $c->components->{$command} ) ) {
 155             my $error =
 156 qq/Couldn't forward to command "$command". Invalid action or component./;
 157             $c->error($error);
 158             $c->log->debug($error) if $c->debug;
 159             return 0;
 160         }
 161
 162         my $class  = $command;
 163         my $method = shift || 'process';
 164
 165         if ( my $code = $c->components->{$class}->can($method) ) {
 166             $c->actions->{reverse}->{"$code"} = "$class->$method";
 167             $results = [ [ [ $class, $code ] ] ];
 168         } else {
 169             my $error =
 170               qq/Couldn't forward to "$class". Does not implement "$method"/;
 171             $c->error($error);
 172             $c->log->debug($error)
 173               if $c->debug;
 174             return 0;
 175         }
 176
 177     }
 178
 179     local $c->request->{arguments} = [ @{$arguments} ];
 180
 181     for my $result ( @{$results} ) {
 182         $c->execute( @{ $result->[0] } );
 183         return if scalar @{ $c->error };
 184         last unless $c->state;
 185     }
 186
 187     return $c->state;
 188 }
 189
 190 =item $c->get_action( $action, $namespace, $inherit )
 191
 192 Get an action in a given namespace.
 193
 194 =cut
 195
 196 sub get_action {
 197     my ( $c, $action, $namespace, $inherit ) = @_;
 198     return [] unless $action;
 199     $namespace ||= '';
 200     $inherit   ||= 0;
 201
 202     if ($namespace) {
 203         $namespace = '' if $namespace eq '/';
 204         my $parent = $c->tree;
 205         my @results;
 206
 207         if ($inherit) {
 208             my $result = $c->actions->{private}->{ $parent->getUID }->{$action};
 209             push @results, [$result] if $result;
 210             my $visitor = Tree::Simple::Visitor::FindByPath->new;
 211
 212             for my $part ( split '/', $namespace ) {
 213                 $visitor->setSearchPath($part);
 214                 $parent->accept($visitor);
 215                 my $child = $visitor->getResult;
 216                 my $uid   = $child->getUID if $child;
 217                 my $match = $c->actions->{private}->{$uid}->{$action} if $uid;
 218                 push @results, [$match] if $match;
 219                 $parent = $child if $child;
 220             }
 221
 222         }
 223
 224         else {
 225
 226             if ($namespace) {
 227                 my $visitor = Tree::Simple::Visitor::FindByPath->new;
 228                 $visitor->setSearchPath( split '/', $namespace );
 229                 $parent->accept($visitor);
 230                 my $child = $visitor->getResult;
 231                 my $uid   = $child->getUID if $child;
 232                 my $match = $c->actions->{private}->{$uid}->{$action}
 233                   if $uid;
 234                 push @results, [$match] if $match;
 235             }
 236
 237             else {
 238                 my $result =
 239                   $c->actions->{private}->{ $parent->getUID }->{$action};
 240                 push @results, [$result] if $result;
 241             }
 242
 243         }
 244         return \@results;
 245     }
 246
 247     elsif ( my $p = $c->actions->{plain}->{$action} ) { return [ [$p] ] }
 248     elsif ( my $r = $c->actions->{regex}->{$action} ) { return [ [$r] ] }
 249
 250     else {
 251
 252         for my $i ( 0 .. $#{ $c->actions->{compiled} } ) {
 253             my $name  = $c->actions->{compiled}->[$i]->[0];
 254             my $regex = $c->actions->{compiled}->[$i]->[1];
 255
 256             if ( my @snippets = ( $action =~ $regex ) ) {
 257                 return [ [ $c->actions->{regex}->{$name}, $name, \@snippets ] ];
 258             }
 259
 260         }
 261     }
 262     return [];
 263 }
 264
 265 =item $c->set_action( $action, $code, $namespace, $attrs )
 266
 267 Set an action in a given namespace.
 268
 269 =cut
 270
 271 sub set_action {
 272     my ( $c, $method, $code, $namespace, $attrs ) = @_;
 273
 274     my $prefix =
 275       Catalyst::Utils::class2prefix( $namespace, $c->config->{case_sensitive} )
 276       || '';
 277     my %flags;
 278
 279     for my $attr ( @{$attrs} ) {
 280         if    ( $attr =~ /^(Local|Relative)$/ )    { $flags{local}++ }
 281         elsif ( $attr =~ /^(Global|Absolute)$/ )   { $flags{global}++ }
 282         elsif ( $attr =~ /^Path\(\s*(.+)\s*\)$/i ) { $flags{path} = $1 }
 283         elsif ( $attr =~ /^Private$/i )            { $flags{private}++ }
 284         elsif ( $attr =~ /^(Regex|Regexp)\(\s*(.+)\s*\)$/i ) {
 285             $flags{regex} = $2;
 286         }
 287     }
 288
 289     if ( $flags{private} && ( keys %flags > 1 ) ) {
 290         $c->log->debug( 'Bad action definition "'
 291               . join( ' ', @{$attrs} )
 292               . qq/" for "$namespace->$method"/ )
 293           if $c->debug;
 294         return;
 295     }
 296     return unless keys %flags;
 297
 298     my $parent  = $c->tree;
 299     my $visitor = Tree::Simple::Visitor::FindByPath->new;
 300
 301     for my $part ( split '/', $prefix ) {
 302         $visitor->setSearchPath($part);
 303         $parent->accept($visitor);
 304         my $child = $visitor->getResult;
 305
 306         unless ($child) {
 307             $child = $parent->addChild( Tree::Simple->new($part) );
 308             $visitor->setSearchPath($part);
 309             $parent->accept($visitor);
 310             $child = $visitor->getResult;
 311         }
 312
 313         $parent = $child;
 314     }
 315
 316     my $uid = $parent->getUID;
 317     $c->actions->{private}->{$uid}->{$method} = [ $namespace, $code ];
 318     my $forward = $prefix ? "$prefix/$method" : $method;
 319
 320     if ( $flags{path} ) {
 321         $flags{path} =~ s/^\w+//;
 322         $flags{path} =~ s/\w+$//;
 323         if ( $flags{path} =~ /^\s*'(.*)'\s*$/ ) { $flags{path} = $1 }
 324         if ( $flags{path} =~ /^\s*"(.*)"\s*$/ ) { $flags{path} = $1 }
 325     }
 326
 327     if ( $flags{regex} ) {
 328         $flags{regex} =~ s/^\w+//;
 329         $flags{regex} =~ s/\w+$//;
 330         if ( $flags{regex} =~ /^\s*'(.*)'\s*$/ ) { $flags{regex} = $1 }
 331         if ( $flags{regex} =~ /^\s*"(.*)"\s*$/ ) { $flags{regex} = $1 }
 332     }
 333
 334     my $reverse = $prefix ? "$prefix/$method" : $method;
 335
 336     if ( $flags{local} || $flags{global} || $flags{path} ) {
 337         my $path     = $flags{path} || $method;
 338         my $absolute = 0;
 339
 340         if ( $path =~ /^\/(.+)/ ) {
 341             $path     = $1;
 342             $absolute = 1;
 343         }
 344
 345         $absolute = 1 if $flags{global};
 346         my $name = $absolute ? $path : $prefix ? "$prefix/$path" : $path;
 347         $c->actions->{plain}->{$name} = [ $namespace, $code ];
 348     }
 349
 350     if ( my $regex = $flags{regex} ) {
 351         push @{ $c->actions->{compiled} }, [ $regex, qr#$regex# ];
 352         $c->actions->{regex}->{$regex} = [ $namespace, $code ];
 353     }
 354
 355     $c->actions->{reverse}->{"$code"} = $reverse;
 356 }
 357
 358 =item $class->setup_actions($component)
 359
 360 Setup actions for a component.
 361
 362 =cut
 363
 364 sub setup_actions {
 365     my $self = shift;
 366
 367     # These are the core structures
 368     $self->actions(
 369         {
 370             plain    => {},
 371             private  => {},
 372             regex    => {},
 373             compiled => [],
 374             reverse  => {}
 375         }
 376     );
 377
 378     # We use a tree
 379     $self->tree( Tree::Simple->new( 0, Tree::Simple->ROOT ) );
 380
 381     for my $comp ( keys %{ $self->components } ) {
 382
 383         # We only setup components that inherit from Catalyst::Base
 384         next unless $comp->isa('Catalyst::Base');
 385
 386         for my $action ( @{ Catalyst::Utils::reflect_actions($comp) } ) {
 387             my ( $code, $attrs ) = @{$action};
 388             my $name = '';
 389             no strict 'refs';
 390             my @cache = ( $comp, @{"$comp\::ISA"} );
 391             my %namespaces;
 392
 393             while ( my $namespace = shift @cache ) {
 394                 $namespaces{$namespace}++;
 395                 for my $isa ( @{"$comp\::ISA"} ) {
 396                     next if $namespaces{$isa};
 397                     push @cache, $isa;
 398                     $namespaces{$isa}++;
 399                 }
 400             }
 401
 402             for my $namespace ( keys %namespaces ) {
 403
 404                 for my $sym ( values %{ $namespace . '::' } ) {
 405
 406                     if ( *{$sym}{CODE} && *{$sym}{CODE} == $code ) {
 407
 408                         $name = *{$sym}{NAME};
 409                         $self->set_action( $name, $code, $comp, $attrs );
 410                         last;
 411                     }
 412
 413                 }
 414
 415             }
 416
 417         }
 418
 419     }
 420
 421     return unless $self->debug;
 422
 423     my $actions  = $self->actions;
 424     my $privates = Text::ASCIITable->new;
 425     $privates->setCols( 'Private', 'Class' );
 426     $privates->setColWidth( 'Private', 36, 1 );
 427     $privates->setColWidth( 'Class',   37, 1 );
 428
 429     my $walker = sub {
 430         my ( $walker, $parent, $prefix ) = @_;
 431         $prefix .= $parent->getNodeValue || '';
 432         $prefix .= '/' unless $prefix =~ /\/$/;
 433         my $uid = $parent->getUID;
 434
 435         for my $action ( keys %{ $actions->{private}->{$uid} } ) {
 436             my ( $class, $code ) = @{ $actions->{private}->{$uid}->{$action} };
 437             $privates->addRow( "$prefix$action", $class );
 438         }
 439
 440         $walker->( $walker, $_, $prefix ) for $parent->getAllChildren;
 441     };
 442
 443     $walker->( $walker, $self->tree, '' );
 444     $self->log->debug( "Loaded private actions:\n" . $privates->draw )
 445       if ( @{ $privates->{tbl_rows} } );
 446
 447     my $publics = Text::ASCIITable->new;
 448     $publics->setCols( 'Public', 'Private' );
 449     $publics->setColWidth( 'Public',  36, 1 );
 450     $publics->setColWidth( 'Private', 37, 1 );
 451
 452     for my $plain ( sort keys %{ $actions->{plain} } ) {
 453         my ( $class, $code ) = @{ $actions->{plain}->{$plain} };
 454         my $reverse = $self->actions->{reverse}->{$code};
 455         $reverse = $reverse ? "/$reverse" : $code;
 456         $publics->addRow( "/$plain", $reverse );
 457     }
 458
 459     $self->log->debug( "Loaded public actions:\n" . $publics->draw )
 460       if ( @{ $publics->{tbl_rows} } );
 461
 462     my $regexes = Text::ASCIITable->new;
 463     $regexes->setCols( 'Regex', 'Private' );
 464     $regexes->setColWidth( 'Regex',   36, 1 );
 465     $regexes->setColWidth( 'Private', 37, 1 );
 466
 467     for my $regex ( sort keys %{ $actions->{regex} } ) {
 468         my ( $class, $code ) = @{ $actions->{regex}->{$regex} };
 469         my $reverse = $self->actions->{reverse}->{$code};
 470         $reverse = $reverse ? "/$reverse" : $code;
 471         $regexes->addRow( $regex, $reverse );
 472     }
 473
 474     $self->log->debug( "Loaded regex actions:\n" . $regexes->draw )
 475       if ( @{ $regexes->{tbl_rows} } );
 476 }
 477
 478 =back
 479
 480 =head1 AUTHOR
 481
 482 Sebastian Riedel, C<sri@cpan.org>
 483
 484 =head1 COPYRIGHT
 485
 486 This program is free software, you can redistribute it and/or modify it under
 487 the same terms as Perl itself.
 488
 489 =cut
 490
 491 1;