lib/Catalyst/Dispatcher.pm

   1 package Catalyst::Dispatcher;
   2
   3 use strict;
   4 use base 'Class::Data::Inheritable';
   5 use Memoize;
   6 use Text::ASCIITable;
   7 use Text::ASCIITable::Wrap 'wrap';
   8 use Tree::Simple;
   9 use Tree::Simple::Visitor::FindByPath;
  10
  11 __PACKAGE__->mk_classdata($_) for qw/actions tree/;
  12
  13 __PACKAGE__->actions(
  14     { plain => {}, private => {}, regex => {}, compiled => [], reverse => {} }
  15 );
  16 __PACKAGE__->tree( Tree::Simple->new( 0, Tree::Simple->ROOT ) );
  17
  18 memoize('_class2prefix');
  19
  20 =head1 NAME
  21
  22 Catalyst::Dispatch - The Catalyst Dispatcher
  23
  24 =head1 SYNOPSIS
  25
  26 See L<Catalyst>.
  27
  28 =head1 DESCRIPTION
  29
  30 =head1 METHODS
  31
  32 =over 4
  33
  34 =item $c->dispatch
  35
  36 Dispatch request to actions.
  37
  38 =cut
  39
  40 sub dispatch {
  41     my $c         = shift;
  42     my $action    = $c->req->action;
  43     my $namespace = '';
  44     $namespace = ( join( '/', @{ $c->req->args } ) || '/' )
  45       if $action eq 'default';
  46     unless ($namespace) {
  47         if ( my $result = $c->get_action($action) ) {
  48             $namespace = _class2prefix( $result->[0]->[0]->[0] );
  49         }
  50     }
  51     my $default = $action eq 'default' ? $namespace : undef;
  52     my $results = $c->get_action( $action, $default );
  53     $namespace ||= '/';
  54     if ( @{$results} ) {
  55
  56         # Execute last begin
  57         $c->state(1);
  58         if ( my $begin = @{ $c->get_action( 'begin', $namespace ) }[-1] ) {
  59             $c->execute( @{ $begin->[0] } );
  60             return if scalar @{ $c->error };
  61         }
  62
  63         # Execute the auto chain
  64         for my $auto ( @{ $c->get_action( 'auto', $namespace ) } ) {
  65             $c->execute( @{ $auto->[0] } );
  66             return if scalar @{ $c->error };
  67             last unless $c->state;
  68         }
  69
  70         # Execute the action or last default
  71         if ( ( my $action = $c->req->action ) && $c->state ) {
  72             if ( my $result = @{ $c->get_action( $action, $default ) }[-1] ) {
  73                 $c->execute( @{ $result->[0] } );
  74             }
  75         }
  76
  77         # Execute last end
  78         if ( my $end = @{ $c->get_action( 'end', $namespace ) }[-1] ) {
  79             $c->execute( @{ $end->[0] } );
  80             return if scalar @{ $c->error };
  81         }
  82     }
  83     else {
  84         my $path  = $c->req->path;
  85         my $error = $path
  86           ? qq/Unknown resource "$path"/
  87           : "No default action defined";
  88         $c->log->error($error) if $c->debug;
  89         $c->error($error);
  90     }
  91 }
  92
  93 =item $c->forward($command)
  94
  95 Forward processing to a private action or a method from a class.
  96 If you define a class without method it will default to process().
  97
  98     $c->forward('/foo');
  99     $c->forward('index');
 100     $c->forward(qw/MyApp::Model::CDBI::Foo do_stuff/);
 101     $c->forward('MyApp::View::TT');
 102
 103 =cut
 104
 105 sub forward {
 106     my $c       = shift;
 107     my $command = shift;
 108     unless ($command) {
 109         $c->log->debug('Nothing to forward to') if $c->debug;
 110         return 0;
 111     }
 112     my $caller    = caller(0);
 113     my $namespace = '/';
 114     if ( $command =~ /^\// ) {
 115         $command =~ /^(.*)\/(\w+)$/;
 116         $namespace = $1 || '/';
 117         $command = $2;
 118     }
 119     else { $namespace = _class2prefix($caller) || '/' }
 120     my $results = $c->get_action( $command, $namespace );
 121     unless ( @{$results} ) {
 122         my $class = $command;
 123         if ( $class =~ /[^\w\:]/ ) {
 124             my $error = qq/Couldn't forward to "$class"/;
 125             $c->error($error);
 126             $c->log->debug($error) if $c->debug;
 127             return 0;
 128         }
 129         my $method = shift || 'process';
 130         if ( my $code = $class->can($method) ) {
 131             $c->actions->{reverse}->{"$code"} = "$class->$method";
 132             $results = [ [ [ $class, $code ] ] ];
 133         }
 134         else {
 135             my $error = qq/Couldn't forward to "$class->$method"/;
 136             $c->error($error);
 137             $c->log->debug($error)
 138               if $c->debug;
 139             return 0;
 140         }
 141     }
 142     for my $result ( @{$results} ) {
 143         $c->execute( @{ $result->[0] } );
 144         return if scalar @{ $c->error };
 145         last unless $c->state;
 146     }
 147     return $c->state;
 148 }
 149
 150 =item $c->get_action( $action, $namespace )
 151
 152 Get an action in a given namespace.
 153
 154 =cut
 155
 156 sub get_action {
 157     my ( $c, $action, $namespace ) = @_;
 158     return [] unless $action;
 159     $namespace ||= '';
 160     if ($namespace) {
 161         $namespace = '' if $namespace eq '/';
 162         my $parent = $c->tree;
 163         my @results;
 164         my %allowed = ( begin => 1, auto => 1, default => 1, end => 1 );
 165         if ( $allowed{$action} ) {
 166             my $result = $c->actions->{private}->{ $parent->getUID }->{$action};
 167             push @results, [$result] if $result;
 168             my $visitor = Tree::Simple::Visitor::FindByPath->new;
 169             for my $part ( split '/', $namespace ) {
 170                 $visitor->setSearchPath($part);
 171                 $parent->accept($visitor);
 172                 my $child = $visitor->getResult;
 173                 my $uid   = $child->getUID if $child;
 174                 my $match = $c->actions->{private}->{$uid}->{$action} if $uid;
 175                 push @results, [$match] if $match;
 176                 $parent = $child if $child;
 177             }
 178         }
 179         else {
 180             if ($namespace) {
 181                 my $visitor = Tree::Simple::Visitor::FindByPath->new;
 182                 $visitor->setSearchPath( split '/', $namespace );
 183                 $parent->accept($visitor);
 184                 my $child = $visitor->getResult;
 185                 my $uid   = $child->getUID if $child;
 186                 my $match = $c->actions->{private}->{$uid}->{$action}
 187                   if $uid;
 188                 push @results, [$match] if $match;
 189             }
 190             else {
 191                 my $result =
 192                   $c->actions->{private}->{ $parent->getUID }->{$action};
 193                 push @results, [$result] if $result;
 194             }
 195         }
 196         return \@results;
 197     }
 198     elsif ( my $p = $c->actions->{plain}->{$action} ) { return [ [$p] ] }
 199     elsif ( my $r = $c->actions->{regex}->{$action} ) { return [ [$r] ] }
 200     else {
 201         for my $i ( 0 .. $#{ $c->actions->{compiled} } ) {
 202             my $name  = $c->actions->{compiled}->[$i]->[0];
 203             my $regex = $c->actions->{compiled}->[$i]->[1];
 204             if ( $action =~ $regex ) {
 205                 my @snippets;
 206                 for my $i ( 1 .. 9 ) {
 207                     no strict 'refs';
 208                     last unless ${$i};
 209                     push @snippets, ${$i};
 210                 }
 211                 return [ [ $c->actions->{regex}->{$name}, $name, \@snippets ] ];
 212             }
 213         }
 214     }
 215     return [];
 216 }
 217
 218 =item $c->set_action( $action, $code, $namespace, $attrs )
 219
 220 Set an action in a given namespace.
 221
 222 =cut
 223
 224 sub set_action {
 225     my ( $c, $method, $code, $namespace, $attrs ) = @_;
 226
 227     my $prefix = _class2prefix($namespace) || '';
 228     my %flags;
 229
 230     for my $attr ( @{$attrs} ) {
 231         if    ( $attr =~ /^(Local|Relative)$/ )        { $flags{local}++ }
 232         elsif ( $attr =~ /^(Global|Absolute)$/ )       { $flags{global}++ }
 233         elsif ( $attr =~ /^Path\((.+)\)$/i )           { $flags{path} = $1 }
 234         elsif ( $attr =~ /^Private$/i )                { $flags{private}++ }
 235         elsif ( $attr =~ /^(Regex|Regexp)\((.+)\)$/i ) { $flags{regex} = $2 }
 236     }
 237
 238     if ( $flags{private} && ( keys %flags > 1 ) ) {
 239         $c->log->error( 'Bad action definition "'
 240               . join( ' ', @{$attrs} )
 241               . qq/" for "$namespace->$method"/ );
 242         return;
 243     }
 244     return unless keys %flags;
 245
 246     my $parent  = $c->tree;
 247     my $visitor = Tree::Simple::Visitor::FindByPath->new;
 248     for my $part ( split '/', $prefix ) {
 249         $visitor->setSearchPath($part);
 250         $parent->accept($visitor);
 251         my $child = $visitor->getResult;
 252         unless ($child) {
 253             $child = $parent->addChild( Tree::Simple->new($part) );
 254             $visitor->setSearchPath($part);
 255             $parent->accept($visitor);
 256             $child = $visitor->getResult;
 257         }
 258         $parent = $child;
 259     }
 260     my $uid = $parent->getUID;
 261     $c->actions->{private}->{$uid}->{$method} = [ $namespace, $code ];
 262     my $forward = $prefix ? "$prefix/$method" : $method;
 263
 264     if ( $flags{path} ) {
 265         $flags{path} =~ s/^\w+//;
 266         $flags{path} =~ s/\w+$//;
 267         if ( $flags{path} =~ /^'(.*)'$/ ) { $flags{path} = $1 }
 268         if ( $flags{path} =~ /^"(.*)"$/ ) { $flags{path} = $1 }
 269     }
 270     if ( $flags{regex} ) {
 271         $flags{regex} =~ s/^\w+//;
 272         $flags{regex} =~ s/\w+$//;
 273         if ( $flags{regex} =~ /^'(.*)'$/ ) { $flags{regex} = $1 }
 274         if ( $flags{regex} =~ /^"(.*)"$/ ) { $flags{regex} = $1 }
 275     }
 276
 277     my $reverse = $prefix ? "$prefix/$method" : $method;
 278
 279     if ( $flags{local} || $flags{global} || $flags{path} ) {
 280         my $path = $flags{path} || $method;
 281         my $absolute = 0;
 282         if ( $path =~ /^\/(.+)/ ) {
 283             $path     = $1;
 284             $absolute = 1;
 285         }
 286         $absolute = 1 if $flags{global};
 287         my $name = $absolute ? $path : $prefix ? "$prefix/$path" : $path;
 288         $c->actions->{plain}->{$name} = [ $namespace, $code ];
 289     }
 290     if ( my $regex = $flags{regex} ) {
 291         push @{ $c->actions->{compiled} }, [ $regex, qr#$regex# ];
 292         $c->actions->{regex}->{$regex} = [ $namespace, $code ];
 293     }
 294
 295     $c->actions->{reverse}->{"$code"} = $reverse;
 296 }
 297
 298 =item $class->setup_actions($component)
 299
 300 Setup actions for a component.
 301
 302 =cut
 303
 304 sub setup_actions {
 305     my ( $self, $comps ) = @_;
 306     for my $comp (@$comps) {
 307         $comp = ref $comp || $comp;
 308         for my $action ( @{ $comp->_cache } ) {
 309             my ( $code, $attrs ) = @{$action};
 310             my $name = '';
 311             no strict 'refs';
 312             my @cache = ( $comp, @{"$comp\::ISA"} );
 313             my %namespaces;
 314             while ( my $namespace = shift @cache ) {
 315                 $namespaces{$namespace}++;
 316                 for my $isa ( @{"$comp\::ISA"} ) {
 317                     next if $namespaces{$isa};
 318                     push @cache, $isa;
 319                     $namespaces{$isa}++;
 320                 }
 321             }
 322             for my $namespace ( keys %namespaces ) {
 323                 for my $sym ( values %{ $namespace . '::' } ) {
 324                     if ( *{$sym}{CODE} && *{$sym}{CODE} == $code ) {
 325                         $name = *{$sym}{NAME};
 326                         $self->set_action( $name, $code, $comp, $attrs );
 327                         last;
 328                     }
 329                 }
 330             }
 331         }
 332     }
 333     my $actions  = $self->actions;
 334     my $privates = Text::ASCIITable->new;
 335     $privates->setCols( 'Private', 'Class' );
 336     $privates->setColWidth( 'Private', 36, 1 );
 337     $privates->setColWidth( 'Class',   37, 1 );
 338     my $walker = sub {
 339         my ( $walker, $parent, $prefix ) = @_;
 340         $prefix .= $parent->getNodeValue || '';
 341         $prefix .= '/' unless $prefix =~ /\/$/;
 342         my $uid = $parent->getUID;
 343         for my $action ( keys %{ $actions->{private}->{$uid} } ) {
 344             my ( $class, $code ) = @{ $actions->{private}->{$uid}->{$action} };
 345             $privates->addRow( wrap( "$prefix$action", 36 ),
 346                 wrap( $class, 37 ) );
 347         }
 348         $walker->( $walker, $_, $prefix ) for $parent->getAllChildren;
 349     };
 350     $walker->( $walker, $self->tree, '' );
 351     $self->log->debug( 'Loaded private actions', $privates->draw )
 352       if ( @{ $privates->{tbl_rows} } && $self->debug );
 353     my $publics = Text::ASCIITable->new;
 354     $publics->setCols( 'Public', 'Private' );
 355     $publics->setColWidth( 'Public',  36, 1 );
 356     $publics->setColWidth( 'Private', 37, 1 );
 357     for my $plain ( sort keys %{ $actions->{plain} } ) {
 358         my ( $class, $code ) = @{ $actions->{plain}->{$plain} };
 359         my $reverse = $self->actions->{reverse}->{$code};
 360         $reverse = $reverse ? "/$reverse" : $code;
 361         $publics->addRow( wrap( "/$plain", 36 ), wrap( $reverse, 37 ) );
 362     }
 363     $self->log->debug( 'Loaded public actions', $publics->draw )
 364       if ( @{ $publics->{tbl_rows} } && $self->debug );
 365     my $regexes = Text::ASCIITable->new;
 366     $regexes->setCols( 'Regex', 'Private' );
 367     $regexes->setColWidth( 'Regex',   36, 1 );
 368     $regexes->setColWidth( 'Private', 37, 1 );
 369     for my $regex ( sort keys %{ $actions->{regex} } ) {
 370         my ( $class, $code ) = @{ $actions->{regex}->{$regex} };
 371         my $reverse = $self->actions->{reverse}->{$code};
 372         $reverse = $reverse ? "/$reverse" : $code;
 373         $regexes->addRow( wrap( $regex, 36 ), wrap( $reverse, 37 ) );
 374     }
 375     $self->log->debug( 'Loaded regex actions', $regexes->draw )
 376       if ( @{ $regexes->{tbl_rows} } && $self->debug );
 377 }
 378
 379 sub _prefix {
 380     my ( $class, $name ) = @_;
 381     my $prefix = _class2prefix($class);
 382     $name = "$prefix/$name" if $prefix;
 383     return $name;
 384 }
 385
 386 sub _class2prefix {
 387     my $class = shift || '';
 388     my $prefix;
 389     if ( $class =~ /^.*::([MVC]|Model|View|Controller)?::(.*)$/ ) {
 390         $prefix = lc $2;
 391         $prefix =~ s/\:\:/\//g;
 392     }
 393     return $prefix;
 394 }
 395
 396 =back
 397
 398 =head1 AUTHOR
 399
 400 Sebastian Riedel, C<sri@cpan.org>
 401
 402 =head1 COPYRIGHT
 403
 404 This program is free software, you can redistribute it and/or modify it under
 405 the same terms as Perl itself.
 406
 407 =cut
 408
 409 1;