lib/Catalyst/Dispatcher.pm

   1 package Catalyst::Dispatcher;
   2
   3 use strict;
   4 use base 'Class::Accessor::Fast';
   5 use Catalyst::Exception;
   6 use Catalyst::Utils;
   7 use Catalyst::Action;
   8 use Catalyst::ActionContainer;
   9 use Catalyst::DispatchType::Default;
  10 use Catalyst::DispatchType::Index;
  11 use Text::SimpleTable;
  12 use Tree::Simple;
  13 use Tree::Simple::Visitor::FindByPath;
  14
  15 # Stringify to class
  16 use overload '""' => sub { return ref shift }, fallback => 1;
  17
  18 __PACKAGE__->mk_accessors(
  19     qw/tree dispatch_types registered_dispatch_types
  20       method_action_class action_container_class/
  21 );
  22
  23 # Preload these action types
  24 our @PRELOAD = qw/Path Regex/;
  25
  26 # Postload these action types
  27 our @POSTLOAD = qw/Index Default/;
  28
  29 =head1 NAME
  30
  31 Catalyst::Dispatcher - The Catalyst Dispatcher
  32
  33 =head1 SYNOPSIS
  34
  35 See L<Catalyst>.
  36
  37 =head1 DESCRIPTION
  38
  39 =head1 METHODS
  40
  41 =over 4
  42
  43 =item $self->detach( $c, $command [, \@arguments ] )
  44
  45 =cut
  46
  47 sub detach {
  48     my ( $self, $c, $command, @args ) = @_;
  49     $c->forward( $command, @args ) if $command;
  50     die $Catalyst::DETACH;
  51 }
  52
  53 =item $self->dispatch($c)
  54
  55 =cut
  56
  57 sub dispatch {
  58     my ( $self, $c ) = @_;
  59
  60     if ( $c->action ) {
  61         $c->forward( join( '/', '', $c->action->namespace, '_DISPATCH' ) );
  62     }
  63
  64     else {
  65         my $path  = $c->req->path;
  66         my $error = $path
  67           ? qq/Unknown resource "$path"/
  68           : "No default action defined";
  69         $c->log->error($error) if $c->debug;
  70         $c->error($error);
  71     }
  72 }
  73
  74 =item $self->forward( $c, $command [, \@arguments ] )
  75
  76 =cut
  77
  78 sub forward {
  79     my $self    = shift;
  80     my $c       = shift;
  81     my $command = shift;
  82
  83     # Get the calling class
  84     my $caller = ( caller(0) )[0];
  85     if ( $caller->isa('Catalyst') ) {
  86         if    ( ( caller(2) )[3] =~ /detach$/ )  { $caller = caller(3) }
  87         elsif ( ( caller(0) )[3] =~ /forward$/ ) { $caller = caller(1) }
  88     }
  89
  90     unless ($command) {
  91         $c->log->debug('Nothing to forward to') if $c->debug;
  92         return 0;
  93     }
  94
  95     my $arguments = ( ref( $_[-1] ) eq 'ARRAY' ) ? pop(@_) : $c->req->args;
  96
  97     my $result;
  98
  99     unless ( ref $command ) {
 100         my $command_copy = $command;
 101
 102         unless ( $command_copy =~ s/^\/// ) {
 103             my $prefix =
 104               Catalyst::Utils::class2prefix( $caller,
 105                 $c->config->{case_sensitive} )
 106               || '';
 107             $command_copy = "${prefix}/${command}";
 108         }
 109
 110         unless ( $command_copy =~ /\// ) {
 111             $result = $c->get_action( $command_copy, '/' );
 112         }
 113         else {
 114             my @extra_args;
 115           DESCEND: while ( $command_copy =~ s/^(.*)\/(\w+)$/$1/ ) {
 116                 my $tail = $2;
 117                 $result = $c->get_action( $tail, $1 );
 118                 if ($result) {
 119                     $command = $tail;
 120                     push( @{$arguments}, @extra_args );
 121                     last DESCEND;
 122                 }
 123                 unshift( @extra_args, $tail );
 124             }
 125         }
 126     }
 127
 128     unless ($result) {
 129
 130         my $class  = ref($command) || ref( $c->component($command) );
 131         my $method = shift         || 'process';
 132
 133         unless ($class) {
 134             my $error =
 135 qq/Couldn't forward to command "$command". Invalid action or component./;
 136             $c->error($error);
 137             $c->log->debug($error) if $c->debug;
 138             return 0;
 139         }
 140
 141         if ( my $code = $class->can($method) ) {
 142             my $action = $self->method_action_class->new(
 143                 {
 144                     name      => $method,
 145                     code      => $code,
 146                     reverse   => "$class->$method",
 147                     class     => $class,
 148                     namespace => $class,
 149                 }
 150             );
 151             $result = $action;
 152         }
 153
 154         else {
 155             my $error =
 156               qq/Couldn't forward to "$class". Does not implement "$method"/;
 157             $c->error($error);
 158             $c->log->debug($error)
 159               if $c->debug;
 160             return 0;
 161         }
 162
 163     }
 164
 165     local $c->request->{arguments} = [ @{$arguments} ];
 166
 167     $result->execute($c);
 168
 169     return $c->state;
 170 }
 171
 172 =item $self->prepare_action($c)
 173
 174 =cut
 175
 176 sub prepare_action {
 177     my ( $self, $c ) = @_;
 178     my $path = $c->req->path;
 179     my @path = split /\//, $c->req->path;
 180     $c->req->args( \my @args );
 181
 182     push( @path, '/' ) unless @path;    # Root action
 183
 184   DESCEND: while (@path) {
 185         $path = join '/', @path;
 186
 187         $path = '' if $path eq '/';     # Root action
 188
 189         # Check out dispatch types to see if any will handle the path at
 190         # this level
 191
 192         foreach my $type ( @{ $self->dispatch_types } ) {
 193             last DESCEND if $type->match( $c, $path );
 194         }
 195
 196         # If not, move the last part path to args
 197
 198         unshift @args, pop @path;
 199     }
 200
 201     $c->log->debug( 'Arguments are "' . join( '/', @args ) . '"' )
 202       if ( $c->debug && @args );
 203 }
 204
 205 =item $self->get_action( $action, $namespace )
 206
 207 =cut
 208
 209 sub get_action {
 210     my ( $self, $name, $namespace ) = @_;
 211     return unless $name;
 212     $namespace ||= '';
 213     $namespace = '' if $namespace eq '/';
 214
 215     my @match = $self->get_containers($namespace);
 216
 217     return unless @match;
 218
 219     if ( my $action = $match[-1]->get_action($name) ) {
 220         return $action if $action->namespace eq $namespace;
 221     }
 222 }
 223
 224 =item $self->get_actions( $c, $action, $namespace )
 225
 226 =cut
 227
 228 sub get_actions {
 229     my ( $self, $c, $action, $namespace ) = @_;
 230     return [] unless $action;
 231     $namespace ||= '';
 232     $namespace = '' if $namespace eq '/';
 233
 234     my @match = $self->get_containers($namespace);
 235
 236     return map { $_->get_action($action) } @match;
 237 }
 238
 239 =item $self->get_containers( $namespace )
 240
 241 =cut
 242
 243 sub get_containers {
 244     my ( $self, $namespace ) = @_;
 245
 246     # If the namespace is / just return the root ActionContainer
 247
 248     return ( $self->tree->getNodeValue )
 249       if ( !$namespace || ( $namespace eq '/' ) );
 250
 251     # Use a visitor to recurse down the tree finding the ActionContainers
 252     # for each namespace in the chain.
 253
 254     my $visitor = Tree::Simple::Visitor::FindByPath->new;
 255     my @path = split( '/', $namespace );
 256     $visitor->setSearchPath(@path);
 257     $self->tree->accept($visitor);
 258
 259     my @match = $visitor->getResults;
 260     @match = ( $self->tree ) unless @match;
 261
 262     if ( !defined $visitor->getResult ) {
 263
 264         # If we don't manage to match, the visitor doesn't return the last
 265         # node is matched, so foo/bar/baz would only find the 'foo' node,
 266         # not the foo and foo/bar nodes as it should. This does another
 267         # single-level search to see if that's the case, and the 'last unless'
 268         # should catch any failures - or short-circuit this if this *is* a
 269         # bug in the visitor and gets fixed.
 270
 271         if ( my $extra = $path[ ( scalar @match ) - 1 ] ) {
 272             $visitor->setSearchPath($extra);
 273             $match[-1]->accept($visitor);
 274             push( @match, $visitor->getResult ) if defined $visitor->getResult;
 275         }
 276     }
 277
 278     return map { $_->getNodeValue } @match;
 279 }
 280
 281 =item $self->register( $c, $action )
 282
 283 =cut
 284
 285 sub register {
 286     my ( $self, $c, $action ) = @_;
 287
 288     my $registered = $self->registered_dispatch_types;
 289
 290     my $priv = 0;
 291     foreach my $key ( keys %{ $action->attributes } ) {
 292         $priv++ if $key eq 'Private';
 293         my $class = "Catalyst::DispatchType::$key";
 294         unless ( $registered->{$class} ) {
 295             eval "require $class";
 296             push( @{ $self->dispatch_types }, $class->new ) unless $@;
 297             $registered->{$class} = 1;
 298         }
 299     }
 300
 301     # Pass the action to our dispatch types so they can register it if reqd.
 302     my $reg = 0;
 303     foreach my $type ( @{ $self->dispatch_types } ) {
 304         $reg++ if $type->register( $c, $action );
 305     }
 306
 307     return unless $reg + $priv;
 308
 309     my $namespace = $action->namespace;
 310     my $parent    = $self->tree;
 311     my $visitor   = Tree::Simple::Visitor::FindByPath->new;
 312
 313     if ($namespace) {
 314         for my $part ( split '/', $namespace ) {
 315             $visitor->setSearchPath($part);
 316             $parent->accept($visitor);
 317             my $child = $visitor->getResult;
 318
 319             unless ($child) {
 320
 321                 # Create a new tree node and an ActionContainer to form
 322                 # its value.
 323
 324                 my $container =
 325                   Catalyst::ActionContainer->new(
 326                     { part => $part, actions => {} } );
 327                 $child = $parent->addChild( Tree::Simple->new($container) );
 328                 $visitor->setSearchPath($part);
 329                 $parent->accept($visitor);
 330                 $child = $visitor->getResult;
 331             }
 332
 333             $parent = $child;
 334         }
 335     }
 336
 337     # Set the method value
 338     $parent->getNodeValue->actions->{ $action->name } = $action;
 339 }
 340
 341 =item $self->setup_actions( $class, $component )
 342
 343 =cut
 344
 345 sub setup_actions {
 346     my ( $self, $c ) = @_;
 347
 348     $self->dispatch_types( [] );
 349     $self->registered_dispatch_types( {} );
 350     $self->method_action_class('Catalyst::Action');
 351     $self->action_container_class('Catalyst::ActionContainer');
 352
 353     # Preload action types
 354     for my $type (@PRELOAD) {
 355         my $class = "Catalyst::DispatchType::$type";
 356         eval "require $class";
 357         Catalyst::Exception->throw( message => qq/Couldn't load "$class"/ )
 358           if $@;
 359         push @{ $self->dispatch_types }, $class->new;
 360         $self->registered_dispatch_types->{$class} = 1;
 361     }
 362
 363     # We use a tree
 364     my $container =
 365       Catalyst::ActionContainer->new( { part => '/', actions => {} } );
 366     $self->tree( Tree::Simple->new( $container, Tree::Simple->ROOT ) );
 367
 368     foreach my $comp ( values %{ $c->components } ) {
 369         $comp->register_actions($c) if $comp->can('register_actions');
 370     }
 371
 372     # Postload action types
 373     for my $type (@POSTLOAD) {
 374         my $class = "Catalyst::DispatchType::$type";
 375         eval "require $class";
 376         Catalyst::Exception->throw( message => qq/Couldn't load "$class"/ )
 377           if $@;
 378         push @{ $self->dispatch_types }, $class->new;
 379     }
 380
 381     return unless $c->debug;
 382
 383     my $privates = Text::SimpleTable->new(
 384         [ 24, 'Private' ],
 385         [ 23, 'Class' ],
 386         [ 23, 'Method' ]
 387     );
 388
 389     my $has_private = 0;
 390     my $walker = sub {
 391         my ( $walker, $parent, $prefix ) = @_;
 392         $prefix .= $parent->getNodeValue || '';
 393         $prefix .= '/' unless $prefix =~ /\/$/;
 394         my $node = $parent->getNodeValue->actions;
 395
 396         for my $action ( keys %{$node} ) {
 397             my $action_obj = $node->{$action};
 398             next
 399               if ( ( $action =~ /^_.*/ )
 400                 && ( !$c->config->{show_internal_actions} ) );
 401             $privates->row( "$prefix$action", $action_obj->class, $action );
 402             $has_private = 1;
 403         }
 404
 405         $walker->( $walker, $_, $prefix ) for $parent->getAllChildren;
 406     };
 407
 408     $walker->( $walker, $self->tree, '' );
 409     $c->log->debug( "Loaded Private actions:\n" . $privates->draw )
 410       if ($has_private);
 411
 412     # List all public actions
 413     $_->list($c) for @{ $self->dispatch_types };
 414 }
 415
 416 =back
 417
 418 =head1 AUTHOR
 419
 420 Sebastian Riedel, C<sri@cpan.org>
 421 Matt S Trout, C<mst@shadowcatsystems.co.uk>
 422
 423 =head1 COPYRIGHT
 424
 425 This program is free software, you can redistribute it and/or modify it under
 426 the same terms as Perl itself.
 427
 428 =cut
 429
 430 1;