lib/Catalyst/Dispatcher.pm

   1 package Catalyst::Dispatcher;
   2
   3 use strict;
   4 use base 'Class::Accessor::Fast';
   5 use Catalyst::Exception;
   6 use Catalyst::Utils;
   7 use Catalyst::Action;
   8 use Catalyst::ActionContainer;
   9 use Catalyst::DispatchType::Default;
  10 use Catalyst::DispatchType::Index;
  11 use Text::SimpleTable;
  12 use Tree::Simple;
  13 use Tree::Simple::Visitor::FindByPath;
  14
  15 # Stringify to class
  16 use overload '""' => sub { return ref shift }, fallback => 1;
  17
  18 __PACKAGE__->mk_accessors(
  19     qw/tree dispatch_types registered_dispatch_types
  20       method_action_class action_container_class/
  21 );
  22
  23 # Preload these action types
  24 our @PRELOAD = qw/Path Regex/;
  25
  26 # Postload these action types
  27 our @POSTLOAD = qw/Index Default/;
  28
  29 =head1 NAME
  30
  31 Catalyst::Dispatcher - The Catalyst Dispatcher
  32
  33 =head1 SYNOPSIS
  34
  35 See L<Catalyst>.
  36
  37 =head1 DESCRIPTION
  38
  39 =head1 METHODS
  40
  41 =head2 $self->detach( $c, $command [, \@arguments ] )
  42
  43 =cut
  44
  45 sub detach {
  46     my ( $self, $c, $command, @args ) = @_;
  47     $c->forward( $command, @args ) if $command;
  48     die $Catalyst::DETACH;
  49 }
  50
  51 =head2 $self->dispatch($c)
  52
  53 =cut
  54
  55 sub dispatch {
  56     my ( $self, $c ) = @_;
  57     if ( $c->action ) {
  58         $c->forward( join( '/', '', $c->action->namespace, '_DISPATCH' ) );
  59     }
  60
  61     else {
  62         my $path  = $c->req->path;
  63         my $error = $path
  64           ? qq/Unknown resource "$path"/
  65           : "No default action defined";
  66         $c->log->error($error) if $c->debug;
  67         $c->error($error);
  68     }
  69 }
  70
  71 =head2 $self->forward( $c, $command [, \@arguments ] )
  72
  73 =cut
  74
  75 sub forward {
  76     my $self    = shift;
  77     my $c       = shift;
  78     my $command = shift;
  79
  80     unless ($command) {
  81         $c->log->debug('Nothing to forward to') if $c->debug;
  82         return 0;
  83     }
  84
  85     my $local_args = 0;
  86     my $arguments  = $c->req->args;
  87     if ( ref( $_[-1] ) eq 'ARRAY' ) {
  88         $arguments  = pop(@_);
  89         $local_args = 1;
  90     }
  91
  92     my $result;
  93
  94     unless ( ref $command ) {
  95         my $command_copy = $command;
  96
  97         unless ( $command_copy =~ s/^\/// ) {
  98             my $namespace = $c->stack->[-1]->namespace;
  99             $command_copy = "${namespace}/${command}";
 100         }
 101
 102         unless ( $command_copy =~ /\// ) {
 103             $result = $c->get_action( $command_copy, '/' );
 104         }
 105         else {
 106             my @extra_args;
 107           DESCEND: while ( $command_copy =~ s/^(.*)\/(\w+)$/$1/ ) {
 108                 my $tail = $2;
 109                 $result = $c->get_action( $tail, $1 );
 110                 if ($result) {
 111                     $local_args = 1;
 112                     $command    = $tail;
 113                     unshift( @{$arguments}, @extra_args );
 114                     last DESCEND;
 115                 }
 116                 unshift( @extra_args, $tail );
 117             }
 118         }
 119     }
 120
 121     unless ($result) {
 122
 123         my $class = ref($command)
 124           || ref( $c->component($command) )
 125           || $c->component($command);
 126         my $method = shift || 'process';
 127
 128         unless ($class) {
 129             my $error =
 130 qq/Couldn't forward to command "$command". Invalid action or component./;
 131             $c->error($error);
 132             $c->log->debug($error) if $c->debug;
 133             return 0;
 134         }
 135
 136         if ( my $code = $class->can($method) ) {
 137             my $action = $self->method_action_class->new(
 138                 {
 139                     name      => $method,
 140                     code      => $code,
 141                     reverse   => "$class->$method",
 142                     class     => $class,
 143                     namespace => Catalyst::Utils::class2prefix(
 144                         $class, $c->config->{case_sensitive}
 145                     ),
 146                 }
 147             );
 148             $result = $action;
 149         }
 150
 151         else {
 152             my $error =
 153               qq/Couldn't forward to "$class". Does not implement "$method"/;
 154             $c->error($error);
 155             $c->log->debug($error)
 156               if $c->debug;
 157             return 0;
 158         }
 159
 160     }
 161
 162     if ($local_args) {
 163         local $c->request->{arguments} = [ @{$arguments} ];
 164         $result->execute($c);
 165     }
 166     else { $result->execute($c) }
 167
 168     return $c->state;
 169 }
 170
 171 =head2 $self->prepare_action($c)
 172
 173 =cut
 174
 175 sub prepare_action {
 176     my ( $self, $c ) = @_;
 177     my $path = $c->req->path;
 178     my @path = split /\//, $c->req->path;
 179     $c->req->args( \my @args );
 180
 181     push( @path, '/' ) unless @path;    # Root action
 182
 183   DESCEND: while (@path) {
 184         $path = join '/', @path;
 185
 186         $path = '' if $path eq '/';     # Root action
 187
 188         # Check out dispatch types to see if any will handle the path at
 189         # this level
 190
 191         foreach my $type ( @{ $self->dispatch_types } ) {
 192             last DESCEND if $type->match( $c, $path );
 193         }
 194
 195         # If not, move the last part path to args
 196         unshift @args, pop @path;
 197     }
 198
 199     $c->log->debug( 'Path is "' . $c->req->match . '"' )
 200       if ( $c->debug && $c->req->match );
 201
 202     $c->log->debug( 'Arguments are "' . join( '/', @args ) . '"' )
 203       if ( $c->debug && @args );
 204 }
 205
 206 =head2 $self->get_action( $action, $namespace )
 207
 208 =cut
 209
 210 sub get_action {
 211     my ( $self, $name, $namespace ) = @_;
 212     return unless $name;
 213     $namespace ||= '';
 214     $namespace = '' if $namespace eq '/';
 215
 216     my @match = $self->get_containers($namespace);
 217
 218     return unless @match;
 219
 220     if ( my $action = $match[-1]->get_action($name) ) {
 221         return $action if $action->namespace eq $namespace;
 222     }
 223 }
 224
 225 =head2 $self->get_actions( $c, $action, $namespace )
 226
 227 =cut
 228
 229 sub get_actions {
 230     my ( $self, $c, $action, $namespace ) = @_;
 231     return [] unless $action;
 232     $namespace ||= '';
 233     $namespace = '' if $namespace eq '/';
 234
 235     my @match = $self->get_containers($namespace);
 236
 237     return map { $_->get_action($action) } @match;
 238 }
 239
 240 =head2 $self->get_containers( $namespace )
 241
 242 =cut
 243
 244 sub get_containers {
 245     my ( $self, $namespace ) = @_;
 246
 247     # If the namespace is / just return the root ActionContainer
 248
 249     return ( $self->tree->getNodeValue )
 250       if ( !$namespace || ( $namespace eq '/' ) );
 251
 252     # Use a visitor to recurse down the tree finding the ActionContainers
 253     # for each namespace in the chain.
 254
 255     my $visitor = Tree::Simple::Visitor::FindByPath->new;
 256     my @path = split( '/', $namespace );
 257     $visitor->setSearchPath(@path);
 258     $self->tree->accept($visitor);
 259
 260     my @match = $visitor->getResults;
 261     @match = ( $self->tree ) unless @match;
 262
 263     if ( !defined $visitor->getResult ) {
 264
 265         # If we don't manage to match, the visitor doesn't return the last
 266         # node is matched, so foo/bar/baz would only find the 'foo' node,
 267         # not the foo and foo/bar nodes as it should. This does another
 268         # single-level search to see if that's the case, and the 'last unless'
 269         # should catch any failures - or short-circuit this if this *is* a
 270         # bug in the visitor and gets fixed.
 271
 272         if ( my $extra = $path[ ( scalar @match ) - 1 ] ) {
 273             $visitor->setSearchPath($extra);
 274             $match[-1]->accept($visitor);
 275             push( @match, $visitor->getResult ) if defined $visitor->getResult;
 276         }
 277     }
 278
 279     return map { $_->getNodeValue } @match;
 280 }
 281
 282 =head2 $self->register( $c, $action )
 283
 284 =cut
 285
 286 sub register {
 287     my ( $self, $c, $action ) = @_;
 288
 289     my $registered = $self->registered_dispatch_types;
 290
 291     my $priv = 0;
 292     foreach my $key ( keys %{ $action->attributes } ) {
 293         $priv++ if $key eq 'Private';
 294         my $class = "Catalyst::DispatchType::$key";
 295         unless ( $registered->{$class} ) {
 296             eval "require $class";
 297             push( @{ $self->dispatch_types }, $class->new ) unless $@;
 298             $registered->{$class} = 1;
 299         }
 300     }
 301
 302     # Pass the action to our dispatch types so they can register it if reqd.
 303     my $reg = 0;
 304     foreach my $type ( @{ $self->dispatch_types } ) {
 305         $reg++ if $type->register( $c, $action );
 306     }
 307
 308     return unless $reg + $priv;
 309
 310     my $namespace = $action->namespace;
 311     my $parent    = $self->tree;
 312     my $visitor   = Tree::Simple::Visitor::FindByPath->new;
 313
 314     if ($namespace) {
 315         for my $part ( split '/', $namespace ) {
 316             $visitor->setSearchPath($part);
 317             $parent->accept($visitor);
 318             my $child = $visitor->getResult;
 319
 320             unless ($child) {
 321
 322                 # Create a new tree node and an ActionContainer to form
 323                 # its value.
 324
 325                 my $container =
 326                   Catalyst::ActionContainer->new(
 327                     { part => $part, actions => {} } );
 328                 $child = $parent->addChild( Tree::Simple->new($container) );
 329                 $visitor->setSearchPath($part);
 330                 $parent->accept($visitor);
 331                 $child = $visitor->getResult;
 332             }
 333
 334             $parent = $child;
 335         }
 336     }
 337
 338     # Set the method value
 339     $parent->getNodeValue->actions->{ $action->name } = $action;
 340 }
 341
 342 =head2 $self->setup_actions( $class, $component )
 343
 344 =cut
 345
 346 sub setup_actions {
 347     my ( $self, $c ) = @_;
 348
 349     $self->dispatch_types( [] );
 350     $self->registered_dispatch_types( {} );
 351     $self->method_action_class('Catalyst::Action');
 352     $self->action_container_class('Catalyst::ActionContainer');
 353
 354     # Preload action types
 355     for my $type (@PRELOAD) {
 356         my $class = "Catalyst::DispatchType::$type";
 357         eval "require $class";
 358         Catalyst::Exception->throw( message => qq/Couldn't load "$class"/ )
 359           if $@;
 360         push @{ $self->dispatch_types }, $class->new;
 361         $self->registered_dispatch_types->{$class} = 1;
 362     }
 363
 364     # We use a tree
 365     my $container =
 366       Catalyst::ActionContainer->new( { part => '/', actions => {} } );
 367     $self->tree( Tree::Simple->new( $container, Tree::Simple->ROOT ) );
 368
 369     foreach my $comp ( values %{ $c->components } ) {
 370         $comp->register_actions($c) if $comp->can('register_actions');
 371     }
 372
 373     # Postload action types
 374     for my $type (@POSTLOAD) {
 375         my $class = "Catalyst::DispatchType::$type";
 376         eval "require $class";
 377         Catalyst::Exception->throw( message => qq/Couldn't load "$class"/ )
 378           if $@;
 379         push @{ $self->dispatch_types }, $class->new;
 380     }
 381
 382     return unless $c->debug;
 383
 384     my $privates = Text::SimpleTable->new(
 385         [ 20, 'Private' ],
 386         [ 38, 'Class' ],
 387         [ 12, 'Method' ]
 388     );
 389
 390     my $has_private = 0;
 391     my $walker = sub {
 392         my ( $walker, $parent, $prefix ) = @_;
 393         $prefix .= $parent->getNodeValue || '';
 394         $prefix .= '/' unless $prefix =~ /\/$/;
 395         my $node = $parent->getNodeValue->actions;
 396
 397         for my $action ( keys %{$node} ) {
 398             my $action_obj = $node->{$action};
 399             next
 400               if ( ( $action =~ /^_.*/ )
 401                 && ( !$c->config->{show_internal_actions} ) );
 402             $privates->row( "$prefix$action", $action_obj->class, $action );
 403             $has_private = 1;
 404         }
 405
 406         $walker->( $walker, $_, $prefix ) for $parent->getAllChildren;
 407     };
 408
 409     $walker->( $walker, $self->tree, '' );
 410     $c->log->debug( "Loaded Private actions:\n" . $privates->draw )
 411       if ($has_private);
 412
 413     # List all public actions
 414     $_->list($c) for @{ $self->dispatch_types };
 415 }
 416
 417 =head1 AUTHOR
 418
 419 Sebastian Riedel, C<sri@cpan.org>
 420 Matt S Trout, C<mst@shadowcatsystems.co.uk>
 421
 422 =head1 COPYRIGHT
 423
 424 This program is free software, you can redistribute it and/or modify it under
 425 the same terms as Perl itself.
 426
 427 =cut
 428
 429 1;