lib/Catalyst/DispatchType/Regex.pm

   1 package Catalyst::DispatchType::Regex;
   2
   3 use strict;
   4 use base qw/Catalyst::DispatchType::Path/;
   5 use Text::SimpleTable;
   6 use Text::Balanced ();
   7
   8 =head1 NAME
   9
  10 Catalyst::DispatchType::Regex - Regex DispatchType
  11
  12 =head1 SYNOPSIS
  13
  14 See L<Catalyst>.
  15
  16 =head1 DESCRIPTION
  17
  18 =head1 METHODS
  19
  20 =head2 $self->list($c)
  21
  22 Output a table of all regex actions, and their private equivalent.
  23
  24 =cut
  25
  26 sub list {
  27     my ( $self, $c ) = @_;
  28     my $re = Text::SimpleTable->new( [ 35, 'Regex' ], [ 36, 'Private' ] );
  29     for my $regex ( @{ $self->{compiled} } ) {
  30         my $action = $regex->{action};
  31         $re->row( $regex->{path}, "/$action" );
  32     }
  33     $c->log->debug( "Loaded Regex actions:\n" . $re->draw . "\n" )
  34       if ( @{ $self->{compiled} } );
  35 }
  36
  37 =head2 $self->match( $c, $path )
  38
  39 Checks path against every compiled regex, and offers the action for any regex
  40 which matches a chance to match the request. If it succeeds, sets action,
  41 match and captures on $c->req and returns 1. If not, returns 0 without
  42 altering $c.
  43
  44 =cut
  45
  46 sub match {
  47     my ( $self, $c, $path ) = @_;
  48
  49     return if $self->SUPER::match( $c, $path );
  50
  51     # Check path against plain text first
  52
  53     foreach my $compiled ( @{ $self->{compiled} || [] } ) {
  54         if ( my @captures = ( $path =~ $compiled->{re} ) ) {
  55             next unless $compiled->{action}->match($c);
  56             $c->req->action( $compiled->{path} );
  57             $c->req->match($path);
  58             $c->req->captures( \@captures );
  59             $c->action( $compiled->{action} );
  60             $c->namespace( $compiled->{action}->namespace );
  61             return 1;
  62         }
  63     }
  64
  65     return 0;
  66 }
  67
  68 =head2 $self->register( $c, $action )
  69
  70 Registers one or more regex actions for an action object.
  71 Also registers them as literal paths.
  72
  73 Returns 1 if any regexps were registered.
  74
  75 =cut
  76
  77 sub register {
  78     my ( $self, $c, $action ) = @_;
  79     my $attrs    = $action->attributes;
  80     my @register = @{ $attrs->{'Regex'} || [] };
  81
  82     foreach my $r (@register) {
  83         $self->register_path( $c, $r, $action );
  84         $self->register_regex( $c, $r, $action );
  85     }
  86
  87     return 1 if @register;
  88     return 0;
  89 }
  90
  91 =head2 $self->register_regex($c, $re, $action)
  92
  93 Register an individual regex on the action. Usually called from the
  94 register method.
  95
  96 =cut
  97
  98 sub register_regex {
  99     my ( $self, $c, $re, $action ) = @_;
 100     push(
 101         @{ $self->{compiled} },    # and compiled regex for us
 102         {
 103             re     => qr#$re#,
 104             action => $action,
 105             path   => $re,
 106         }
 107     );
 108 }
 109
 110 =head2 $self->uri_for_action($action, $captures)
 111
 112 returns a URI for this action if it can find a regex attributes that contains
 113 the correct number of () captures. Note that this may function incorrectly
 114 in the case of nested captures - if your regex does (...(..))..(..) you'll
 115 need to pass the first and third captures only.
 116
 117 =cut
 118
 119 sub uri_for_action {
 120     my ( $self, $action, $captures ) = @_;
 121
 122     if (my $regexes = $action->attributes->{Regex}) {
 123         REGEX: foreach my $orig (@$regexes) {
 124             my $re = "$orig";
 125             $re =~ s/^\^//;
 126             $re =~ s/\$$//;
 127             my $final = '/';
 128             my @captures = @$captures;
 129             while (my ($front, $rest) = split(/\(/, $re, 2)) {
 130                 ($rest, $re) =
 131                     Text::Balanced::extract_bracketed("(${rest}", '(');
 132                 next REGEX unless @captures;
 133                 $final .= $front.shift(@captures);
 134             }
 135             next REGEX if @captures;
 136             return $final;
 137          }
 138     }
 139     return undef;
 140 }
 141
 142 =head1 AUTHORS
 143
 144 Catalyst Contributors, see Catalyst.pm
 145
 146 =head1 COPYRIGHT
 147
 148 This program is free software, you can redistribute it and/or modify it under
 149 the same terms as Perl itself.
 150
 151 =cut
 152
 153 1;