lib/Catalyst/DispatchType/Regex.pm

   1 package Catalyst::DispatchType::Regex;
   2
   3 use strict;
   4 use base qw/Catalyst::DispatchType::Path/;
   5 use Text::SimpleTable;
   6 use Text::Balanced ();
   7
   8 =head1 NAME
   9
  10 Catalyst::DispatchType::Regex - Regex DispatchType
  11
  12 =head1 SYNOPSIS
  13
  14 See L<Catalyst>.
  15
  16 =head1 DESCRIPTION
  17
  18 =head1 METHODS
  19
  20 =head2 $self->list($c)
  21
  22 Output a table of all regex actions, and their private equivalent.
  23
  24 =cut
  25
  26 sub list {
  27     my ( $self, $c ) = @_;
  28     my $re = Text::SimpleTable->new( [ 35, 'Regex' ], [ 36, 'Private' ] );
  29     for my $regex ( @{ $self->{compiled} } ) {
  30         my $action = $regex->{action};
  31         $re->row( $regex->{path}, "/$action" );
  32     }
  33     $c->log->debug( "Loaded Regex actions:\n" . $re->draw )
  34       if ( @{ $self->{compiled} } );
  35 }
  36
  37 =head2 $self->match( $c, $path )
  38
  39 Check path against compiled regexes, and set action to any matching
  40 action. Returns 1 on success and 0 on failure.
  41
  42 =cut
  43
  44 sub match {
  45     my ( $self, $c, $path ) = @_;
  46
  47     return if $self->SUPER::match( $c, $path );
  48
  49     # Check path against plain text first
  50
  51     foreach my $compiled ( @{ $self->{compiled} || [] } ) {
  52         if ( my @captures = ( $path =~ $compiled->{re} ) ) {
  53             next unless $compiled->{action}->match($c);
  54             $c->req->action( $compiled->{path} );
  55             $c->req->match($path);
  56             $c->req->captures( \@captures );
  57             $c->action( $compiled->{action} );
  58             $c->namespace( $compiled->{action}->namespace );
  59             return 1;
  60         }
  61     }
  62
  63     return 0;
  64 }
  65
  66 =head2 $self->register( $c, $action )
  67
  68 Registers one or more regex actions for an action object.\
  69 Also registers them as literal paths.
  70
  71 Returns 1 on if any regexps were registered.
  72
  73 =cut
  74
  75 sub register {
  76     my ( $self, $c, $action ) = @_;
  77     my $attrs    = $action->attributes;
  78     my @register = @{ $attrs->{'Regex'} || [] };
  79
  80     foreach my $r (@register) {
  81         $self->register_path( $c, $r, $action );
  82         $self->register_regex( $c, $r, $action );
  83     }
  84
  85     return 1 if @register;
  86     return 0;
  87 }
  88
  89 =head2 $self->register_regex($c, $re, $action)
  90
  91 Register an individual regex on the action. Usually called from the
  92 register action.
  93
  94 =cut
  95
  96 sub register_regex {
  97     my ( $self, $c, $re, $action ) = @_;
  98     push(
  99         @{ $self->{compiled} },    # and compiled regex for us
 100         {
 101             re     => qr#$re#,
 102             action => $action,
 103             path   => $re,
 104         }
 105     );
 106 }
 107
 108 =head2 $self->uri_for_action($action, $captures)
 109
 110 returns a URI for this action if it can find a regex attributes that contains
 111 the correct number of () captures. Note that this may function incorrectly
 112 in the case of nested captures - if your regex does (...(..))..(..) you'll
 113 need to pass the first and third captures only.
 114
 115 =cut
 116
 117 sub uri_for_action {
 118     my ( $self, $action, $captures ) = @_;
 119
 120     if (my $regexes = $action->attributes->{Regex}) {
 121         REGEX: foreach my $orig (@$regexes) {
 122             my $re = "$orig";
 123             $re =~ s/^\^//;
 124             $re =~ s/\$$//;
 125             my $final = '/';
 126             my @captures = @$captures;
 127             while (my ($front, $rest) = split(/\(/, $re, 2)) {
 128                 ($rest, $re) =
 129                     Text::Balanced::extract_bracketed("(${rest}", '(');
 130                 next REGEX unless @captures;
 131                 $final .= $front.shift(@captures);
 132             }
 133             next REGEX if @captures;
 134             return $final;
 135          }
 136     }
 137     return undef;
 138 }
 139
 140 =head1 AUTHOR
 141
 142 Matt S Trout
 143 Sebastian Riedel, C<sri@cpan.org>
 144
 145 =head1 COPYRIGHT
 146
 147 This program is free software, you can redistribute it and/or modify it under
 148 the same terms as Perl itself.
 149
 150 =cut
 151
 152 1;