lib/Catalyst/DispatchType/Chained.pm

   1 package Catalyst::DispatchType::Chained;
   2
   3 use strict;
   4 use base qw/Catalyst::DispatchType/;
   5 use Text::SimpleTable;
   6 use Catalyst::ActionChain;
   7 use URI;
   8
   9 # please don't perltidy this. hairy code within.
  10
  11 =head1 NAME
  12
  13 Catalyst::DispatchType::Chained - Path Part DispatchType
  14
  15 =head1 SYNOPSIS
  16
  17   #   root action - captures one argument after it
  18   sub foo_setup : Chained('/') PathPart('foo') CaptureArgs(1) {
  19       my ( $self, $c, $foo_arg ) = @_;
  20       ...
  21   }
  22
  23   #   child action endpoint - takes one argument
  24   sub bar : Chained('foo_setup') Args(1) {
  25       my ( $self, $c, $bar_arg ) = @_;
  26       ...
  27   }
  28
  29 =head1 DESCRIPTION
  30
  31 See L</USAGE>.
  32
  33 =head1 METHODS
  34
  35 =head2 $self->list($c)
  36
  37 Debug output for Path Part dispatch points
  38
  39 =cut
  40
  41 sub list {
  42     my ( $self, $c ) = @_;
  43
  44     return unless $self->{endpoints};
  45
  46     my $paths = Text::SimpleTable->new(
  47                     [ 35, 'Path Spec' ], [ 36, 'Private' ]
  48                 );
  49
  50     ENDPOINT: foreach my $endpoint (
  51                   sort { $a->reverse cmp $b->reverse }
  52                            @{ $self->{endpoints} }
  53                   ) {
  54         my $args = $endpoint->attributes->{Args}->[0];
  55         my @parts = (defined($args) ? (("*") x $args) : '...');
  56         my @parents = ();
  57         my $parent = "DUMMY";
  58         my $curr = $endpoint;
  59         while ($curr) {
  60             if (my $cap = $curr->attributes->{CaptureArgs}) {
  61                 unshift(@parts, (("*") x $cap->[0]));
  62             }
  63             if (my $pp = $curr->attributes->{PartPath}) {
  64                 unshift(@parts, $pp->[0])
  65                     if (defined $pp->[0] && length $pp->[0]);
  66             }
  67             $parent = $curr->attributes->{Chained}->[0];
  68             $curr = $self->{actions}{$parent};
  69             unshift(@parents, $curr) if $curr;
  70         }
  71         next ENDPOINT unless $parent eq '/'; # skip dangling action
  72         my @rows;
  73         foreach my $p (@parents) {
  74             my $name = "/${p}";
  75             if (my $cap = $p->attributes->{CaptureArgs}) {
  76                 $name .= ' ('.$cap->[0].')';
  77             }
  78             unless ($p eq $parents[0]) {
  79                 $name = "-> ${name}";
  80             }
  81             push(@rows, [ '', $name ]);
  82         }
  83         push(@rows, [ '', (@rows ? "=> " : '')."/${endpoint}" ]);
  84         $rows[0][0] = join('/', '', @parts);
  85         $paths->row(@$_) for @rows;
  86     }
  87
  88     $c->log->debug( "Loaded Chained actions:\n" . $paths->draw . "\n" );
  89 }
  90
  91 =head2 $self->match( $c, $path )
  92
  93 Calls C<recurse_match> to see if a chain matches the C<$path>.
  94
  95 =cut
  96
  97 sub match {
  98     my ( $self, $c, $path ) = @_;
  99
 100     return 0 if @{$c->req->args};
 101
 102     my @parts = split('/', $path);
 103
 104     my ($chain, $captures, $parts) = $self->recurse_match($c, '/', \@parts);
 105     push @{$c->req->args}, @$parts if $parts && @$parts;
 106
 107     return 0 unless $chain;
 108
 109     my $action = Catalyst::ActionChain->from_chain($chain);
 110
 111     $c->req->action("/${action}");
 112     $c->req->match("/${action}");
 113     $c->req->captures($captures);
 114     $c->action($action);
 115     $c->namespace( $action->namespace );
 116
 117     return 1;
 118 }
 119
 120 =head2 $self->recurse_match( $c, $parent, \@path_parts )
 121
 122 Recursive search for a matching chain.
 123
 124 =cut
 125
 126 sub recurse_match {
 127     my ( $self, $c, $parent, $path_parts ) = @_;
 128     my $children = $self->{children_of}{$parent};
 129     return () unless $children;
 130     my $best_action;
 131     my @captures;
 132     TRY: foreach my $try_part (sort { length($b) <=> length($a) }
 133                                    keys %$children) {
 134                                # $b then $a to try longest part first
 135         my @parts = @$path_parts;
 136         if (length $try_part) { # test and strip PathPart
 137             next TRY unless
 138               ($try_part eq join('/', # assemble equal number of parts
 139                               splice( # and strip them off @parts as well
 140                                 @parts, 0, scalar(@{[split('/', $try_part)]})
 141                               ))); # @{[]} to avoid split to @_
 142         }
 143         my @try_actions = @{$children->{$try_part}};
 144         TRY_ACTION: foreach my $action (@try_actions) {
 145             if (my $capture_attr = $action->attributes->{CaptureArgs}) {
 146
 147                 # Short-circuit if not enough remaining parts
 148                 next TRY_ACTION unless @parts >= $capture_attr->[0];
 149
 150                 my @captures;
 151                 my @parts = @parts; # localise
 152
 153                 # strip CaptureArgs into list
 154                 push(@captures, splice(@parts, 0, $capture_attr->[0]));
 155
 156                 # try the remaining parts against children of this action
 157                 my ($actions, $captures, $action_parts) = $self->recurse_match(
 158                                              $c, '/'.$action->reverse, \@parts
 159                                            );
 160                 #    No best action currently
 161                 # OR The action has less parts
 162                 # OR The action has equal parts but less captured data (ergo more defined)
 163                 if ($actions    &&
 164                     (!$best_action                                 ||
 165                      $#$action_parts < $#{$best_action->{parts}}   ||
 166                      ($#$action_parts == $#{$best_action->{parts}} &&
 167                       $#$captures < $#{$best_action->{captures}}))){
 168                     $best_action = {
 169                         actions => [ $action, @$actions ],
 170                         captures=> [ @captures, @$captures ],
 171                         parts   => $action_parts
 172                         };
 173                 }
 174             }
 175             else {
 176                 {
 177                     local $c->req->{arguments} = [ @{$c->req->args}, @parts ];
 178                     next TRY_ACTION unless $action->match($c);
 179                 }
 180                 my $args_attr = $action->attributes->{Args}->[0];
 181
 182                 #    No best action currently
 183                 # OR This one matches with fewer parts left than the current best action,
 184                 #    And therefore is a better match
 185                 # OR No parts and this expects 0
 186                 #    The current best action might also be Args(0),
 187                 #    but we couldn't chose between then anyway so we'll take the last seen
 188
 189                 if (!$best_action                       ||
 190                     @parts < @{$best_action->{parts}}   ||
 191                     (!@parts && $args_attr eq 0)){
 192                     $best_action = {
 193                         actions => [ $action ],
 194                         captures=> [],
 195                         parts   => \@parts
 196                     }
 197                 }
 198             }
 199         }
 200     }
 201     return @$best_action{qw/actions captures parts/} if $best_action;
 202     return ();
 203 }
 204
 205 =head2 $self->register( $c, $action )
 206
 207 Calls register_path for every Path attribute for the given $action.
 208
 209 =cut
 210
 211 sub register {
 212     my ( $self, $c, $action ) = @_;
 213
 214     my @chained_attr = @{ $action->attributes->{Chained} || [] };
 215
 216     return 0 unless @chained_attr;
 217
 218     if (@chained_attr > 1) {
 219         Catalyst::Exception->throw(
 220           "Multiple Chained attributes not supported registering ${action}"
 221         );
 222     }
 223
 224     my $children = ($self->{children_of}{ $chained_attr[0] } ||= {});
 225
 226     my @path_part = @{ $action->attributes->{PathPart} || [] };
 227
 228     my $part = $action->name;
 229
 230     if (@path_part == 1 && defined $path_part[0]) {
 231         $part = $path_part[0];
 232     } elsif (@path_part > 1) {
 233         Catalyst::Exception->throw(
 234           "Multiple PathPart attributes not supported registering ${action}"
 235         );
 236     }
 237
 238     if ($part =~ m(^/)) {
 239         Catalyst::Exception->throw(
 240           "Absolute parameters to PathPart not allowed registering ${action}"
 241         );
 242     }
 243
 244     $action->attributes->{PartPath} = [ $part ];
 245
 246     unshift(@{ $children->{$part} ||= [] }, $action);
 247
 248     ($self->{actions} ||= {})->{'/'.$action->reverse} = $action;
 249
 250     unless ($action->attributes->{CaptureArgs}) {
 251         unshift(@{ $self->{endpoints} ||= [] }, $action);
 252     }
 253
 254     return 1;
 255 }
 256
 257 =head2 $self->uri_for_action($action, $captures)
 258
 259 Get the URI part for the action, using C<$captures> to fill
 260 the capturing parts.
 261
 262 =cut
 263
 264 sub uri_for_action {
 265     my ( $self, $action, $captures ) = @_;
 266
 267     return undef unless ($action->attributes->{Chained}
 268                            && !$action->attributes->{CaptureArgs});
 269
 270     my @parts = ();
 271     my @captures = @$captures;
 272     my $parent = "DUMMY";
 273     my $curr = $action;
 274     while ($curr) {
 275         if (my $cap = $curr->attributes->{CaptureArgs}) {
 276             return undef unless @captures >= $cap->[0]; # not enough captures
 277             if ($cap->[0]) {
 278                 unshift(@parts, splice(@captures, -$cap->[0]));
 279             }
 280         }
 281         if (my $pp = $curr->attributes->{PartPath}) {
 282             unshift(@parts, $pp->[0])
 283                 if (defined($pp->[0]) && length($pp->[0]));
 284         }
 285         $parent = $curr->attributes->{Chained}->[0];
 286         $curr = $self->{actions}{$parent};
 287     }
 288
 289     return undef unless $parent eq '/'; # fail for dangling action
 290
 291     return undef if @captures; # fail for too many captures
 292
 293     return join('/', '', @parts);
 294
 295 }
 296
 297 =head2 $c->expand_action($action)
 298
 299 Return a list of actions that represents a chained action. See
 300 L<Catalyst::Dispatcher> for more info. You probably want to
 301 use the expand_action it provides rather than this directly.
 302
 303 =cut
 304
 305 sub expand_action {
 306     my ($self, $action) = @_;
 307
 308     return unless $action->attributes && $action->attributes->{Chained};
 309
 310     my @chain;
 311     my $curr = $action;
 312
 313     while ($curr) {
 314         push @chain, $curr;
 315         my $parent = $curr->attributes->{Chained}->[0];
 316         $curr = $self->{'actions'}{$parent};
 317     }
 318
 319     return Catalyst::ActionChain->from_chain([reverse @chain]);
 320 }
 321
 322 =head1 USAGE
 323
 324 =head2 Introduction
 325
 326 The C<Chained> attribute allows you to chain public path parts together
 327 by their private names. A chain part's path can be specified with
 328 C<PathPart> and can be declared to expect an arbitrary number of
 329 arguments. The endpoint of the chain specifies how many arguments it
 330 gets through the C<Args> attribute. C<:Args(0)> would be none at all,
 331 C<:Args> without an integer would be unlimited. The path parts that
 332 aren't endpoints are using C<CaptureArgs> to specify how many parameters
 333 they expect to receive. As an example setup:
 334
 335   package MyApp::Controller::Greeting;
 336   use base qw/ Catalyst::Controller /;
 337
 338   #   this is the beginning of our chain
 339   sub hello : PathPart('hello') Chained('/') CaptureArgs(1) {
 340       my ( $self, $c, $integer ) = @_;
 341       $c->stash->{ message } = "Hello ";
 342       $c->stash->{ arg_sum } = $integer;
 343   }
 344
 345   #   this is our endpoint, because it has no :CaptureArgs
 346   sub world : PathPart('world') Chained('hello') Args(1) {
 347       my ( $self, $c, $integer ) = @_;
 348       $c->stash->{ message } .= "World!";
 349       $c->stash->{ arg_sum } += $integer;
 350
 351       $c->response->body( join "<br/>\n" =>
 352           $c->stash->{ message }, $c->stash->{ arg_sum } );
 353   }
 354
 355 The debug output provides a separate table for chained actions, showing
 356 the whole chain as it would match and the actions it contains. Here's an
 357 example of the startup output with our actions above:
 358
 359   ...
 360   [debug] Loaded Path Part actions:
 361   .-----------------------+------------------------------.
 362   | Path Spec             | Private                      |
 363   +-----------------------+------------------------------+
 364   | /hello/*/world/*      | /greeting/hello (1)          |
 365   |                       | => /greeting/world           |
 366   '-----------------------+------------------------------'
 367   ...
 368
 369 As you can see, Catalyst only deals with chains as whole paths and
 370 builds one for each endpoint, which are the actions with C<:Chained> but
 371 without C<:CaptureArgs>.
 372
 373 Let's assume this application gets a request at the path
 374 C</hello/23/world/12>. What happens then? First, Catalyst will dispatch
 375 to the C<hello> action and pass the value C<23> as an argument to it
 376 after the context. It does so because we have previously used
 377 C<:CaptureArgs(1)> to declare that it has one path part after itself as
 378 its argument. We told Catalyst that this is the beginning of the chain
 379 by specifying C<:Chained('/')>. Also note that instead of saying
 380 C<:PathPart('hello')> we could also just have said C<:PathPart>, as it
 381 defaults to the name of the action.
 382
 383 After C<hello> has run, Catalyst goes on to dispatch to the C<world>
 384 action. This is the last action to be called: Catalyst knows this is an
 385 endpoint because we did not specify a C<:CaptureArgs>
 386 attribute. Nevertheless we specify that this action expects an argument,
 387 but at this point we're using C<:Args(1)> to do that. We could also have
 388 said C<:Args> or left it out altogether, which would mean this action
 389 would get all arguments that are there. This action's C<:Chained>
 390 attribute says C<hello> and tells Catalyst that the C<hello> action in
 391 the current controller is its parent.
 392
 393 With this we have built a chain consisting of two public path parts.
 394 C<hello> captures one part of the path as its argument, and also
 395 specifies the path root as its parent. So this part is
 396 C</hello/$arg>. The next part is the endpoint C<world>, expecting one
 397 argument. It sums up to the path part C<world/$arg>. This leads to a
 398 complete chain of C</hello/$arg/world/$arg> which is matched against the
 399 requested paths.
 400
 401 This example application would, if run and called by e.g.
 402 C</hello/23/world/12>, set the stash value C<message> to "Hello" and the
 403 value C<arg_sum> to "23". The C<world> action would then append "World!"
 404 to C<message> and add C<12> to the stash's C<arg_sum> value.  For the
 405 sake of simplicity no view is shown. Instead we just put the values of
 406 the stash into our body. So the output would look like:
 407
 408   Hello World!
 409   35
 410
 411 And our test server would have given us this debugging output for the
 412 request:
 413
 414   ...
 415   [debug] "GET" request for "hello/23/world/12" from "127.0.0.1"
 416   [debug] Path is "/greeting/world"
 417   [debug] Arguments are "12"
 418   [info] Request took 0.164113s (6.093/s)
 419   .------------------------------------------+-----------.
 420   | Action                                   | Time      |
 421   +------------------------------------------+-----------+
 422   | /greeting/hello                          | 0.000029s |
 423   | /greeting/world                          | 0.000024s |
 424   '------------------------------------------+-----------'
 425   ...
 426
 427 What would be common uses of this dispatch technique? It gives the
 428 possibility to split up logic that contains steps that each depend on
 429 each other. An example would be, for example, a wiki path like
 430 C</wiki/FooBarPage/rev/23/view>. This chain can be easily built with
 431 these actions:
 432
 433   sub wiki : PathPart('wiki') Chained('/') CaptureArgs(1) {
 434       my ( $self, $c, $page_name ) = @_;
 435       #  load the page named $page_name and put the object
 436       #  into the stash
 437   }
 438
 439   sub rev : PathPart('rev') Chained('wiki') CaptureArgs(1) {
 440       my ( $self, $c, $revision_id ) = @_;
 441       #  use the page object in the stash to get at its
 442       #  revision with number $revision_id
 443   }
 444
 445   sub view : PathPart Chained('rev') Args(0) {
 446       my ( $self, $c ) = @_;
 447       #  display the revision in our stash. Another option
 448       #  would be to forward a compatible object to the action
 449       #  that displays the default wiki pages, unless we want
 450       #  a different interface here, for example restore
 451       #  functionality.
 452   }
 453
 454 It would now be possible to add other endpoints, for example C<restore>
 455 to restore this specific revision as the current state.
 456
 457 You don't have to put all the chained actions in one controller. The
 458 specification of the parent through C<:Chained> also takes an absolute
 459 action path as its argument. Just specify it with a leading C</>.
 460
 461 If you want, for example, to have actions for the public paths
 462 C</foo/12/edit> and C</foo/12>, just specify two actions with
 463 C<:PathPart('foo')> and C<:Chained('/')>. The handler for the former
 464 path needs a C<:CaptureArgs(1)> attribute and a endpoint with
 465 C<:PathPart('edit')> and C<:Chained('foo')>. For the latter path give
 466 the action just a C<:Args(1)> to mark it as endpoint. This sums up to
 467 this debugging output:
 468
 469   ...
 470   [debug] Loaded Path Part actions:
 471   .-----------------------+------------------------------.
 472   | Path Spec             | Private                      |
 473   +-----------------------+------------------------------+
 474   | /foo/*                | /controller/foo_view         |
 475   | /foo/*/edit           | /controller/foo_load (1)     |
 476   |                       | => /controller/edit          |
 477   '-----------------------+------------------------------'
 478   ...
 479
 480 Here's a more detailed specification of the attributes belonging to
 481 C<:Chained>:
 482
 483 =head2 Attributes
 484
 485 =over 8
 486
 487 =item PathPart
 488
 489 Sets the name of this part of the chain. If it is specified without
 490 arguments, it takes the name of the action as default. So basically
 491 C<sub foo :PathPart> and C<sub foo :PathPart('foo')> are identical.
 492 This can also contain slashes to bind to a deeper level. An action
 493 with C<sub bar :PathPart('foo/bar') :Chained('/')> would bind to
 494 C</foo/bar/...>. If you don't specify C<:PathPart> it has the same
 495 effect as using C<:PathPart>, it would default to the action name.
 496
 497 =item PathPrefix
 498
 499 Sets PathPart to the path_prefix of the current controller.
 500
 501 =item Chained
 502
 503 Has to be specified for every child in the chain. Possible values are
 504 absolute and relative private action paths or a single slash C</> to
 505 tell Catalyst that this is the root of a chain. The attribute
 506 C<:Chained> without arguments also defaults to the C</> behavior.
 507 Relative action paths may use C<../> to refer to actions in parent
 508 controllers.
 509
 510 Because you can specify an absolute path to the parent action, it
 511 doesn't matter to Catalyst where that parent is located. So, if your
 512 design requests it, you can redispatch a chain through any controller or
 513 namespace you want.
 514
 515 Another interesting possibility gives C<:Chained('.')>, which chains
 516 itself to an action with the path of the current controller's namespace.
 517 For example:
 518
 519   #   in MyApp::Controller::Foo
 520   sub bar : Chained CaptureArgs(1) { ... }
 521
 522   #   in MyApp::Controller::Foo::Bar
 523   sub baz : Chained('.') Args(1) { ... }
 524
 525 This builds up a chain like C</bar/*/baz/*>. The specification of C<.>
 526 as the argument to Chained here chains the C<baz> action to an action
 527 with the path of the current controller namespace, namely
 528 C</foo/bar>. That action chains directly to C</>, so the C</bar/*/baz/*>
 529 chain comes out as the end product.
 530
 531 =item ChainedParent
 532
 533 Chains an action to another action with the same name in the parent
 534 controller. For Example:
 535
 536   # in MyApp::Controller::Foo
 537   sub bar : Chained CaptureArgs(1) { ... }
 538
 539   # in MyApp::Controller::Foo::Moo
 540   sub bar : ChainedParent Args(1) { ... }
 541
 542 This builds a chain like C</bar/*/bar/*>.
 543
 544 =item CaptureArgs
 545
 546 Must be specified for every part of the chain that is not an
 547 endpoint. With this attribute Catalyst knows how many of the following
 548 parts of the path (separated by C</>) this action wants to capture as
 549 its arguments. If it doesn't expect any, just specify
 550 C<:CaptureArgs(0)>.  The captures get passed to the action's C<@_> right
 551 after the context, but you can also find them as array references in
 552 C<$c-E<gt>request-E<gt>captures-E<gt>[$level]>. The C<$level> is the
 553 level of the action in the chain that captured the parts of the path.
 554
 555 An action that is part of a chain (that is, one that has a C<:Chained>
 556 attribute) but has no C<:CaptureArgs> attribute is treated by Catalyst
 557 as a chain end.
 558
 559 =item Args
 560
 561 By default, endpoints receive the rest of the arguments in the path. You
 562 can tell Catalyst through C<:Args> explicitly how many arguments your
 563 endpoint expects, just like you can with C<:CaptureArgs>. Note that this
 564 also affects whether this chain is invoked on a request. A chain with an
 565 endpoint specifying one argument will only match if exactly one argument
 566 exists in the path.
 567
 568 You can specify an exact number of arguments like C<:Args(3)>, including
 569 C<0>. If you just say C<:Args> without any arguments, it is the same as
 570 leaving it out altogether: The chain is matched regardless of the number
 571 of path parts after the endpoint.
 572
 573 Just as with C<:CaptureArgs>, the arguments get passed to the action in
 574 C<@_> after the context object. They can also be reached through
 575 C<$c-E<gt>request-E<gt>arguments>.
 576
 577 =back
 578
 579 =head2 Auto actions, dispatching and forwarding
 580
 581 Note that the list of C<auto> actions called depends on the private path
 582 of the endpoint of the chain, not on the chained actions way. The
 583 C<auto> actions will be run before the chain dispatching begins. In
 584 every other aspect, C<auto> actions behave as documented.
 585
 586 The C<forward>ing to other actions does just what you would expect. But if
 587 you C<detach> out of a chain, the rest of the chain will not get called
 588 after the C<detach>.
 589
 590 =head1 AUTHORS
 591
 592 Catalyst Contributors, see Catalyst.pm
 593
 594 =head1 COPYRIGHT
 595
 596 This program is free software, you can redistribute it and/or modify it under
 597 the same terms as Perl itself.
 598
 599 =cut
 600
 601 1;