lib/Catalyst/DispatchType/Chained.pm

   1 package Catalyst::DispatchType::Chained;
   2
   3 use Moose;
   4 extends 'Catalyst::DispatchType';
   5
   6 use Text::SimpleTable;
   7 use Catalyst::ActionChain;
   8 use Catalyst::Utils;
   9 use URI;
  10 use Scalar::Util ();
  11 use Encode 2.21 'decode_utf8';
  12
  13 has _endpoints => (
  14                    is => 'rw',
  15                    isa => 'ArrayRef',
  16                    required => 1,
  17                    default => sub{ [] },
  18                   );
  19
  20 has _actions => (
  21                  is => 'rw',
  22                  isa => 'HashRef',
  23                  required => 1,
  24                  default => sub{ {} },
  25                 );
  26
  27 has _children_of => (
  28                      is => 'rw',
  29                      isa => 'HashRef',
  30                      required => 1,
  31                      default => sub{ {} },
  32                     );
  33
  34 no Moose;
  35
  36 # please don't perltidy this. hairy code within.
  37
  38 =head1 NAME
  39
  40 Catalyst::DispatchType::Chained - Path Part DispatchType
  41
  42 =head1 SYNOPSIS
  43
  44 Path part matching, allowing several actions to sequentially take care of processing a request:
  45
  46   #   root action - captures one argument after it
  47   sub foo_setup : Chained('/') PathPart('foo') CaptureArgs(1) {
  48       my ( $self, $c, $foo_arg ) = @_;
  49       ...
  50   }
  51
  52   #   child action endpoint - takes one argument
  53   sub bar : Chained('foo_setup') Args(1) {
  54       my ( $self, $c, $bar_arg ) = @_;
  55       ...
  56   }
  57
  58 =head1 DESCRIPTION
  59
  60 Dispatch type managing default behaviour.  For more information on
  61 dispatch types, see:
  62
  63 =over 4
  64
  65 =item * L<Catalyst::Manual::Intro> for how they affect application authors
  66
  67 =item * L<Catalyst::DispatchType> for implementation information.
  68
  69 =back
  70
  71 =head1 METHODS
  72
  73 =head2 $self->list($c)
  74
  75 Debug output for Path Part dispatch points
  76
  77 =cut
  78
  79 sub list {
  80     my ( $self, $c ) = @_;
  81
  82     return unless $self->_endpoints;
  83
  84     my $avail_width = Catalyst::Utils::term_width() - 9;
  85     my $col1_width = ($avail_width * .50) < 35 ? 35 : int($avail_width * .50);
  86     my $col2_width = $avail_width - $col1_width;
  87     my $paths = Text::SimpleTable->new(
  88         [ $col1_width, 'Path Spec' ], [ $col2_width, 'Private' ],
  89     );
  90
  91     my $has_unattached_actions;
  92     my $unattached_actions = Text::SimpleTable->new(
  93         [ $col1_width, 'Private' ], [ $col2_width, 'Missing parent' ],
  94     );
  95
  96     ENDPOINT: foreach my $endpoint (
  97                   sort { $a->reverse cmp $b->reverse }
  98                            @{ $self->_endpoints }
  99                   ) {
 100         my $args = $endpoint->list_extra_info->{Args};
 101         my @parts = (defined($args) ? (("*") x $args) : '...');
 102         my @parents = ();
 103         my $parent = "DUMMY";
 104         my $extra  = $self->_list_extra_http_methods($endpoint);
 105         my $consumes = $self->_list_extra_consumes($endpoint);
 106         my $scheme = $self->_list_extra_scheme($endpoint);
 107         my $curr = $endpoint;
 108         while ($curr) {
 109             if (my $cap = $curr->list_extra_info->{CaptureArgs}) {
 110                 unshift(@parts, (("*") x $cap));
 111             }
 112             if (my $pp = $curr->attributes->{PathPart}) {
 113                 unshift(@parts, $pp->[0])
 114                     if (defined $pp->[0] && length $pp->[0]);
 115             }
 116             $parent = $curr->attributes->{Chained}->[0];
 117             $curr = $self->_actions->{$parent};
 118             unshift(@parents, $curr) if $curr;
 119         }
 120         if ($parent ne '/') {
 121             $has_unattached_actions = 1;
 122             $unattached_actions->row('/' . ($parents[0] || $endpoint)->reverse, $parent);
 123             next ENDPOINT;
 124         }
 125         my @rows;
 126         foreach my $p (@parents) {
 127             my $name = "/${p}";
 128
 129             if (defined(my $extra = $self->_list_extra_http_methods($p))) {
 130                 $name = "${extra} ${name}";
 131             }
 132             if (defined(my $cap = $p->list_extra_info->{CaptureArgs})) {
 133                 $name .= ' ('.$cap.')';
 134             }
 135             if (defined(my $ct = $p->list_extra_info->{Consumes})) {
 136                 $name .= ' :'.$ct;
 137             }
 138             if (defined(my $s = $p->list_extra_info->{Scheme})) {
 139                 $scheme = uc $s;
 140             }
 141
 142             unless ($p eq $parents[0]) {
 143                 $name = "-> ${name}";
 144             }
 145             push(@rows, [ '', $name ]);
 146         }
 147         push(@rows, [ '', (@rows ? "=> " : '').($extra ? "$extra " : ''). ($scheme ? "$scheme: ":'')."/${endpoint}". ($consumes ? " :$consumes":"" ) ]);
 148         my @display_parts = map { $_ =~s/%([0-9A-Fa-f]{2})/chr(hex($1))/eg; decode_utf8 $_ } @parts;
 149         $rows[0][0] = join('/', '', @display_parts) || '/';
 150         $paths->row(@$_) for @rows;
 151     }
 152
 153     $c->log->debug( "Loaded Chained actions:\n" . $paths->draw . "\n" );
 154     $c->log->debug( "Unattached Chained actions:\n", $unattached_actions->draw . "\n" )
 155         if $has_unattached_actions;
 156 }
 157
 158 sub _list_extra_http_methods {
 159     my ( $self, $action ) = @_;
 160     return unless defined $action->list_extra_info->{HTTP_METHODS};
 161     return join(', ', @{$action->list_extra_info->{HTTP_METHODS}});
 162
 163 }
 164
 165 sub _list_extra_consumes {
 166     my ( $self, $action ) = @_;
 167     return unless defined $action->list_extra_info->{CONSUMES};
 168     return join(', ', @{$action->list_extra_info->{CONSUMES}});
 169 }
 170
 171 sub _list_extra_scheme {
 172     my ( $self, $action ) = @_;
 173     return unless defined $action->list_extra_info->{Scheme};
 174     return uc $action->list_extra_info->{Scheme};
 175 }
 176
 177 =head2 $self->match( $c, $path )
 178
 179 Calls C<recurse_match> to see if a chain matches the C<$path>.
 180
 181 =cut
 182
 183 sub match {
 184     my ( $self, $c, $path ) = @_;
 185
 186     my $request = $c->request;
 187     return 0 if @{$request->args};
 188
 189     my @parts = split('/', $path);
 190
 191     my ($chain, $captures, $parts) = $self->recurse_match($c, '/', \@parts);
 192
 193     if ($parts && @$parts) {
 194         for my $arg (@$parts) {
 195             $arg =~ s/%([0-9A-Fa-f]{2})/chr(hex($1))/eg;
 196             push @{$request->args}, $arg;
 197         }
 198     }
 199
 200     return 0 unless $chain;
 201
 202     my $action = Catalyst::ActionChain->from_chain($chain);
 203
 204     $request->action("/${action}");
 205     $request->match("/${action}");
 206     $request->captures($captures);
 207     $c->action($action);
 208     $c->namespace( $action->namespace );
 209
 210     return 1;
 211 }
 212
 213 =head2 $self->recurse_match( $c, $parent, \@path_parts )
 214
 215 Recursive search for a matching chain.
 216
 217 =cut
 218
 219 sub recurse_match {
 220     my ( $self, $c, $parent, $path_parts ) = @_;
 221     my $children = $self->_children_of->{$parent};
 222     return () unless $children;
 223     my $best_action;
 224     my @captures;
 225     TRY: foreach my $try_part (sort { length($b) <=> length($a) }
 226                                    keys %$children) {
 227                                # $b then $a to try longest part first
 228         my @parts = @$path_parts;
 229         if (length $try_part) { # test and strip PathPart
 230             next TRY unless
 231               ($try_part eq join('/', # assemble equal number of parts
 232                               splice( # and strip them off @parts as well
 233                                 @parts, 0, scalar(@{[split('/', $try_part)]})
 234                               ))); # @{[]} to avoid split to @_
 235         }
 236         my @try_actions = @{$children->{$try_part}};
 237         TRY_ACTION: foreach my $action (@try_actions) {
 238             if (my $capture_attr = $action->attributes->{CaptureArgs}) {
 239                 my $capture_count = $action->number_of_captures|| 0;
 240
 241                 # Short-circuit if not enough remaining parts
 242                 next TRY_ACTION unless @parts >= $capture_count;
 243
 244                 my @captures;
 245                 my @parts = @parts; # localise
 246
 247                 # strip CaptureArgs into list
 248                 push(@captures, splice(@parts, 0, $capture_count));
 249
 250                 # check if the action may fit, depending on a given test by the app
 251                 next TRY_ACTION unless $action->match_captures($c, \@captures);
 252
 253                 # try the remaining parts against children of this action
 254                 my ($actions, $captures, $action_parts, $n_pathparts) = $self->recurse_match(
 255                                              $c, '/'.$action->reverse, \@parts
 256                                            );
 257                 #    No best action currently
 258                 # OR The action has less parts
 259                 # OR The action has equal parts but less captured data (ergo more defined)
 260                 if ($actions    &&
 261                     (!$best_action                                 ||
 262                      $#$action_parts < $#{$best_action->{parts}}   ||
 263                      ($#$action_parts == $#{$best_action->{parts}} &&
 264                       $#$captures < $#{$best_action->{captures}} &&
 265                       $n_pathparts > $best_action->{n_pathparts}))) {
 266                     my @pathparts = split /\//, $action->attributes->{PathPart}->[0];
 267                     $best_action = {
 268                         actions => [ $action, @$actions ],
 269                         captures=> [ @captures, @$captures ],
 270                         parts   => $action_parts,
 271                         n_pathparts => scalar(@pathparts) + $n_pathparts,
 272                     };
 273                 }
 274             }
 275             else {
 276                 {
 277                     local $c->req->{arguments} = [ @{$c->req->args}, @parts ];
 278                     next TRY_ACTION unless $action->match($c);
 279                 }
 280                 my $args_attr = $action->attributes->{Args}->[0];
 281                 my @pathparts = split /\//, $action->attributes->{PathPart}->[0];
 282                 #    No best action currently
 283                 # OR This one matches with fewer parts left than the current best action,
 284                 #    And therefore is a better match
 285                 # OR No parts and this expects 0
 286                 #    The current best action might also be Args(0),
 287                 #    but we couldn't chose between then anyway so we'll take the last seen
 288
 289                 if (!$best_action                       ||
 290                     @parts < @{$best_action->{parts}}   ||
 291                     (!@parts && defined($args_attr) && $args_attr eq "0")){
 292                     $best_action = {
 293                         actions => [ $action ],
 294                         captures=> [],
 295                         parts   => \@parts,
 296                         n_pathparts => scalar(@pathparts),
 297                     };
 298                 }
 299             }
 300         }
 301     }
 302     return @$best_action{qw/actions captures parts n_pathparts/} if $best_action;
 303     return ();
 304 }
 305
 306 =head2 $self->register( $c, $action )
 307
 308 Calls register_path for every Path attribute for the given $action.
 309
 310 =cut
 311
 312 sub register {
 313     my ( $self, $c, $action ) = @_;
 314
 315     my @chained_attr = @{ $action->attributes->{Chained} || [] };
 316
 317     return 0 unless @chained_attr;
 318
 319     if (@chained_attr > 1) {
 320         Catalyst::Exception->throw(
 321           "Multiple Chained attributes not supported registering ${action}"
 322         );
 323     }
 324     my $chained_to = $chained_attr[0];
 325
 326     Catalyst::Exception->throw(
 327       "Actions cannot chain to themselves registering /${action}"
 328     ) if ($chained_to eq '/' . $action);
 329
 330     my $children = ($self->_children_of->{ $chained_to } ||= {});
 331
 332     my @path_part = @{ $action->attributes->{PathPart} || [] };
 333
 334     my $part = $action->name;
 335
 336     if (@path_part == 1 && defined $path_part[0]) {
 337         $part = $path_part[0];
 338     } elsif (@path_part > 1) {
 339         Catalyst::Exception->throw(
 340           "Multiple PathPart attributes not supported registering " . $action->reverse()
 341         );
 342     }
 343
 344     if ($part =~ m(^/)) {
 345         Catalyst::Exception->throw(
 346           "Absolute parameters to PathPart not allowed registering " . $action->reverse()
 347         );
 348     }
 349
 350     my $encoded_part = URI->new($part)->canonical;
 351     $encoded_part =~ s{(?<=[^/])/+\z}{};
 352
 353     $action->attributes->{PathPart} = [ $encoded_part ];
 354
 355     unshift(@{ $children->{$encoded_part} ||= [] }, $action);
 356
 357     $self->_actions->{'/'.$action->reverse} = $action;
 358
 359     if (exists $action->attributes->{Args} and exists $action->attributes->{CaptureArgs}) {
 360         Catalyst::Exception->throw(
 361           "Combining Args and CaptureArgs attributes not supported registering " .
 362           $action->reverse()
 363         );
 364     }
 365
 366     unless ($action->attributes->{CaptureArgs}) {
 367         unshift(@{ $self->_endpoints }, $action);
 368     }
 369
 370     return 1;
 371 }
 372
 373 =head2 $self->uri_for_action($action, $captures)
 374
 375 Get the URI part for the action, using C<$captures> to fill
 376 the capturing parts.
 377
 378 =cut
 379
 380 sub uri_for_action {
 381     my ( $self, $action, $captures ) = @_;
 382
 383     return undef unless ($action->attributes->{Chained}
 384                            && !$action->attributes->{CaptureArgs});
 385
 386     my @parts = ();
 387     my @captures = @$captures;
 388     my $parent = "DUMMY";
 389     my $curr = $action;
 390     # If this is an action chain get the last action in the chain
 391     if($curr->can('chain') ) {
 392       $curr = ${$curr->chain}[-1];
 393     }
 394     while ($curr) {
 395         if (my $cap = $curr->number_of_captures) {
 396             return undef unless @captures >= $cap; # not enough captures
 397             if ($cap) {
 398                 unshift(@parts, splice(@captures, -$cap));
 399             }
 400         }
 401         if (my $pp = $curr->attributes->{PathPart}) {
 402             unshift(@parts, $pp->[0])
 403                 if (defined($pp->[0]) && length($pp->[0]));
 404         }
 405         $parent = $curr->attributes->{Chained}->[0];
 406         $curr = $self->_actions->{$parent};
 407     }
 408
 409     return undef unless $parent eq '/'; # fail for dangling action
 410
 411     return undef if @captures; # fail for too many captures
 412
 413     return join('/', '', @parts);
 414
 415 }
 416
 417 =head2 $c->expand_action($action)
 418
 419 Return a list of actions that represents a chained action. See
 420 L<Catalyst::Dispatcher> for more info. You probably want to
 421 use the expand_action it provides rather than this directly.
 422
 423 =cut
 424
 425 sub expand_action {
 426     my ($self, $action) = @_;
 427
 428     return unless $action->attributes && $action->attributes->{Chained};
 429
 430     my @chain;
 431     my $curr = $action;
 432
 433     while ($curr) {
 434         push @chain, $curr;
 435         my $parent = $curr->attributes->{Chained}->[0];
 436         $curr = $self->_actions->{$parent};
 437     }
 438
 439     return Catalyst::ActionChain->from_chain([reverse @chain]);
 440 }
 441
 442 __PACKAGE__->meta->make_immutable;
 443 1;
 444
 445 =head1 USAGE
 446
 447 =head2 Introduction
 448
 449 The C<Chained> attribute allows you to chain public path parts together
 450 by their private names. A chain part's path can be specified with
 451 C<PathPart> and can be declared to expect an arbitrary number of
 452 arguments. The endpoint of the chain specifies how many arguments it
 453 gets through the C<Args> attribute. C<:Args(0)> would be none at all,
 454 C<:Args> without an integer would be unlimited. The path parts that
 455 aren't endpoints are using C<CaptureArgs> to specify how many parameters
 456 they expect to receive. As an example setup:
 457
 458   package MyApp::Controller::Greeting;
 459   use base qw/ Catalyst::Controller /;
 460
 461   #   this is the beginning of our chain
 462   sub hello : PathPart('hello') Chained('/') CaptureArgs(1) {
 463       my ( $self, $c, $integer ) = @_;
 464       $c->stash->{ message } = "Hello ";
 465       $c->stash->{ arg_sum } = $integer;
 466   }
 467
 468   #   this is our endpoint, because it has no :CaptureArgs
 469   sub world : PathPart('world') Chained('hello') Args(1) {
 470       my ( $self, $c, $integer ) = @_;
 471       $c->stash->{ message } .= "World!";
 472       $c->stash->{ arg_sum } += $integer;
 473
 474       $c->response->body( join "<br/>\n" =>
 475           $c->stash->{ message }, $c->stash->{ arg_sum } );
 476   }
 477
 478 The debug output provides a separate table for chained actions, showing
 479 the whole chain as it would match and the actions it contains. Here's an
 480 example of the startup output with our actions above:
 481
 482   ...
 483   [debug] Loaded Path Part actions:
 484   .-----------------------+------------------------------.
 485   | Path Spec             | Private                      |
 486   +-----------------------+------------------------------+
 487   | /hello/*/world/*      | /greeting/hello (1)          |
 488   |                       | => /greeting/world           |
 489   '-----------------------+------------------------------'
 490   ...
 491
 492 As you can see, Catalyst only deals with chains as whole paths and
 493 builds one for each endpoint, which are the actions with C<:Chained> but
 494 without C<:CaptureArgs>.
 495
 496 Let's assume this application gets a request at the path
 497 C</hello/23/world/12>. What happens then? First, Catalyst will dispatch
 498 to the C<hello> action and pass the value C<23> as an argument to it
 499 after the context. It does so because we have previously used
 500 C<:CaptureArgs(1)> to declare that it has one path part after itself as
 501 its argument. We told Catalyst that this is the beginning of the chain
 502 by specifying C<:Chained('/')>. Also note that instead of saying
 503 C<:PathPart('hello')> we could also just have said C<:PathPart>, as it
 504 defaults to the name of the action.
 505
 506 After C<hello> has run, Catalyst goes on to dispatch to the C<world>
 507 action. This is the last action to be called: Catalyst knows this is an
 508 endpoint because we did not specify a C<:CaptureArgs>
 509 attribute. Nevertheless we specify that this action expects an argument,
 510 but at this point we're using C<:Args(1)> to do that. We could also have
 511 said C<:Args> or left it out altogether, which would mean this action
 512 would get all arguments that are there. This action's C<:Chained>
 513 attribute says C<hello> and tells Catalyst that the C<hello> action in
 514 the current controller is its parent.
 515
 516 With this we have built a chain consisting of two public path parts.
 517 C<hello> captures one part of the path as its argument, and also
 518 specifies the path root as its parent. So this part is
 519 C</hello/$arg>. The next part is the endpoint C<world>, expecting one
 520 argument. It sums up to the path part C<world/$arg>. This leads to a
 521 complete chain of C</hello/$arg/world/$arg> which is matched against the
 522 requested paths.
 523
 524 This example application would, if run and called by e.g.
 525 C</hello/23/world/12>, set the stash value C<message> to "Hello" and the
 526 value C<arg_sum> to "23". The C<world> action would then append "World!"
 527 to C<message> and add C<12> to the stash's C<arg_sum> value.  For the
 528 sake of simplicity no view is shown. Instead we just put the values of
 529 the stash into our body. So the output would look like:
 530
 531   Hello World!
 532   35
 533
 534 And our test server would have given us this debugging output for the
 535 request:
 536
 537   ...
 538   [debug] "GET" request for "hello/23/world/12" from "127.0.0.1"
 539   [debug] Path is "/greeting/world"
 540   [debug] Arguments are "12"
 541   [info] Request took 0.164113s (6.093/s)
 542   .------------------------------------------+-----------.
 543   | Action                                   | Time      |
 544   +------------------------------------------+-----------+
 545   | /greeting/hello                          | 0.000029s |
 546   | /greeting/world                          | 0.000024s |
 547   '------------------------------------------+-----------'
 548   ...
 549
 550 What would be common uses of this dispatch technique? It gives the
 551 possibility to split up logic that contains steps that each depend on
 552 each other. An example would be, for example, a wiki path like
 553 C</wiki/FooBarPage/rev/23/view>. This chain can be easily built with
 554 these actions:
 555
 556   sub wiki : PathPart('wiki') Chained('/') CaptureArgs(1) {
 557       my ( $self, $c, $page_name ) = @_;
 558       #  load the page named $page_name and put the object
 559       #  into the stash
 560   }
 561
 562   sub rev : PathPart('rev') Chained('wiki') CaptureArgs(1) {
 563       my ( $self, $c, $revision_id ) = @_;
 564       #  use the page object in the stash to get at its
 565       #  revision with number $revision_id
 566   }
 567
 568   sub view : PathPart Chained('rev') Args(0) {
 569       my ( $self, $c ) = @_;
 570       #  display the revision in our stash. Another option
 571       #  would be to forward a compatible object to the action
 572       #  that displays the default wiki pages, unless we want
 573       #  a different interface here, for example restore
 574       #  functionality.
 575   }
 576
 577 It would now be possible to add other endpoints, for example C<restore>
 578 to restore this specific revision as the current state.
 579
 580 You don't have to put all the chained actions in one controller. The
 581 specification of the parent through C<:Chained> also takes an absolute
 582 action path as its argument. Just specify it with a leading C</>.
 583
 584 If you want, for example, to have actions for the public paths
 585 C</foo/12/edit> and C</foo/12>, just specify two actions with
 586 C<:PathPart('foo')> and C<:Chained('/')>. The handler for the former
 587 path needs a C<:CaptureArgs(1)> attribute and a endpoint with
 588 C<:PathPart('edit')> and C<:Chained('foo')>. For the latter path give
 589 the action just a C<:Args(1)> to mark it as endpoint. This sums up to
 590 this debugging output:
 591
 592   ...
 593   [debug] Loaded Path Part actions:
 594   .-----------------------+------------------------------.
 595   | Path Spec             | Private                      |
 596   +-----------------------+------------------------------+
 597   | /foo/*                | /controller/foo_view         |
 598   | /foo/*/edit           | /controller/foo_load (1)     |
 599   |                       | => /controller/edit          |
 600   '-----------------------+------------------------------'
 601   ...
 602
 603 Here's a more detailed specification of the attributes belonging to
 604 C<:Chained>:
 605
 606 =head2 Attributes
 607
 608 =over 8
 609
 610 =item PathPart
 611
 612 Sets the name of this part of the chain. If it is specified without
 613 arguments, it takes the name of the action as default. So basically
 614 C<sub foo :PathPart> and C<sub foo :PathPart('foo')> are identical.
 615 This can also contain slashes to bind to a deeper level. An action
 616 with C<sub bar :PathPart('foo/bar') :Chained('/')> would bind to
 617 C</foo/bar/...>. If you don't specify C<:PathPart> it has the same
 618 effect as using C<:PathPart>, it would default to the action name.
 619
 620 =item PathPrefix
 621
 622 Sets PathPart to the path_prefix of the current controller.
 623
 624 =item Chained
 625
 626 Has to be specified for every child in the chain. Possible values are
 627 absolute and relative private action paths or a single slash C</> to
 628 tell Catalyst that this is the root of a chain. The attribute
 629 C<:Chained> without arguments also defaults to the C</> behavior.
 630 Relative action paths may use C<../> to refer to actions in parent
 631 controllers.
 632
 633 Because you can specify an absolute path to the parent action, it
 634 doesn't matter to Catalyst where that parent is located. So, if your
 635 design requests it, you can redispatch a chain through any controller or
 636 namespace you want.
 637
 638 Another interesting possibility gives C<:Chained('.')>, which chains
 639 itself to an action with the path of the current controller's namespace.
 640 For example:
 641
 642   #   in MyApp::Controller::Foo
 643   sub bar : Chained CaptureArgs(1) { ... }
 644
 645   #   in MyApp::Controller::Foo::Bar
 646   sub baz : Chained('.') Args(1) { ... }
 647
 648 This builds up a chain like C</bar/*/baz/*>. The specification of C<.>
 649 as the argument to Chained here chains the C<baz> action to an action
 650 with the path of the current controller namespace, namely
 651 C</foo/bar>. That action chains directly to C</>, so the C</bar/*/baz/*>
 652 chain comes out as the end product.
 653
 654 =item ChainedParent
 655
 656 Chains an action to another action with the same name in the parent
 657 controller. For Example:
 658
 659   # in MyApp::Controller::Foo
 660   sub bar : Chained CaptureArgs(1) { ... }
 661
 662   # in MyApp::Controller::Foo::Moo
 663   sub bar : ChainedParent Args(1) { ... }
 664
 665 This builds a chain like C</bar/*/bar/*>.
 666
 667 =item CaptureArgs
 668
 669 Must be specified for every part of the chain that is not an
 670 endpoint. With this attribute Catalyst knows how many of the following
 671 parts of the path (separated by C</>) this action wants to capture as
 672 its arguments. If it doesn't expect any, just specify
 673 C<:CaptureArgs(0)>.  The captures get passed to the action's C<@_> right
 674 after the context, but you can also find them as array references in
 675 C<$c-E<gt>request-E<gt>captures-E<gt>[$level]>. The C<$level> is the
 676 level of the action in the chain that captured the parts of the path.
 677
 678 An action that is part of a chain (that is, one that has a C<:Chained>
 679 attribute) but has no C<:CaptureArgs> attribute is treated by Catalyst
 680 as a chain end.
 681
 682 Allowed values for CaptureArgs is a single integer (CaptureArgs(2), meaning two
 683 allowed) or you can declare a L<Moose>, L<MooseX::Types> or L<Type::Tiny>
 684 named constraint such as CaptureArgs(Int,Str) would require two args with
 685 the first being a Integer and the second a string.  You may declare your own
 686 custom type constraints and import them into the controller namespace:
 687
 688     package MyApp::Controller::Root;
 689
 690     use Moose;
 691     use MooseX::MethodAttributes;
 692     use MyApp::Types qw/Int/;
 693
 694     extends 'Catalyst::Controller';
 695
 696     sub chain_base :Chained(/) CaptureArgs(1) { }
 697
 698       sub any_priority_chain :Chained(chain_base) PathPart('') Args(1) { }
 699
 700       sub int_priority_chain :Chained(chain_base) PathPart('') Args(Int) { }
 701
 702 See L<Catalyst::RouteMatching> for more.
 703
 704 =item Args
 705
 706 By default, endpoints receive the rest of the arguments in the path. You
 707 can tell Catalyst through C<:Args> explicitly how many arguments your
 708 endpoint expects, just like you can with C<:CaptureArgs>. Note that this
 709 also affects whether this chain is invoked on a request. A chain with an
 710 endpoint specifying one argument will only match if exactly one argument
 711 exists in the path.
 712
 713 You can specify an exact number of arguments like C<:Args(3)>, including
 714 C<0>. If you just say C<:Args> without any arguments, it is the same as
 715 leaving it out altogether: The chain is matched regardless of the number
 716 of path parts after the endpoint.
 717
 718 Just as with C<:CaptureArgs>, the arguments get passed to the action in
 719 C<@_> after the context object. They can also be reached through
 720 C<$c-E<gt>request-E<gt>arguments>.
 721
 722 =back
 723
 724 =head2 Auto actions, dispatching and forwarding
 725
 726 Note that the list of C<auto> actions called depends on the private path
 727 of the endpoint of the chain, not on the chained actions way. The
 728 C<auto> actions will be run before the chain dispatching begins. In
 729 every other aspect, C<auto> actions behave as documented.
 730
 731 The C<forward>ing to other actions does just what you would expect. i.e.
 732 only the target action is run. The actions that that action is chained
 733 to are not run.
 734 If you C<detach> out of a chain, the rest of the chain will not get
 735 called after the C<detach>.
 736
 737 =head2 match_captures
 738
 739 A method which can optionally be implemented by actions to
 740 stop chain matching.
 741
 742 See L<Catalyst::Action> for further details.
 743
 744 =head1 AUTHORS
 745
 746 Catalyst Contributors, see Catalyst.pm
 747
 748 =head1 COPYRIGHT
 749
 750 This library is free software. You can redistribute it and/or modify it under
 751 the same terms as Perl itself.
 752
 753 =cut
 754
 755 1;