lib/Catalyst/DispatchType/Chained.pm

   1 package Catalyst::DispatchType::Chained;
   2
   3 use Moose;
   4 extends 'Catalyst::DispatchType';
   5
   6 use Text::SimpleTable;
   7 use Catalyst::ActionChain;
   8 use Catalyst::Utils;
   9 use URI;
  10 use Scalar::Util ();
  11
  12 has _endpoints => (
  13                    is => 'rw',
  14                    isa => 'ArrayRef',
  15                    required => 1,
  16                    default => sub{ [] },
  17                   );
  18
  19 has _actions => (
  20                  is => 'rw',
  21                  isa => 'HashRef',
  22                  required => 1,
  23                  default => sub{ {} },
  24                 );
  25
  26 has _children_of => (
  27                      is => 'rw',
  28                      isa => 'HashRef',
  29                      required => 1,
  30                      default => sub{ {} },
  31                     );
  32
  33 no Moose;
  34
  35 # please don't perltidy this. hairy code within.
  36
  37 =head1 NAME
  38
  39 Catalyst::DispatchType::Chained - Path Part DispatchType
  40
  41 =head1 SYNOPSIS
  42
  43 Path part matching, allowing several actions to sequentially take care of processing a request:
  44
  45   #   root action - captures one argument after it
  46   sub foo_setup : Chained('/') PathPart('foo') CaptureArgs(1) {
  47       my ( $self, $c, $foo_arg ) = @_;
  48       ...
  49   }
  50
  51   #   child action endpoint - takes one argument
  52   sub bar : Chained('foo_setup') Args(1) {
  53       my ( $self, $c, $bar_arg ) = @_;
  54       ...
  55   }
  56
  57 =head1 DESCRIPTION
  58
  59 Dispatch type managing default behaviour.  For more information on
  60 dispatch types, see:
  61
  62 =over 4
  63
  64 =item * L<Catalyst::Manual::Intro> for how they affect application authors
  65
  66 =item * L<Catalyst::DispatchType> for implementation information.
  67
  68 =back
  69
  70 =head1 METHODS
  71
  72 =head2 $self->list($c)
  73
  74 Debug output for Path Part dispatch points
  75
  76 =cut
  77
  78 sub list {
  79     my ( $self, $c ) = @_;
  80
  81     return unless $self->_endpoints;
  82
  83     my $avail_width = Catalyst::Utils::term_width() - 9;
  84     my $col1_width = ($avail_width * .50) < 35 ? 35 : int($avail_width * .50);
  85     my $col2_width = $avail_width - $col1_width;
  86     my $paths = Text::SimpleTable->new(
  87         [ $col1_width, 'Path Spec' ], [ $col2_width, 'Private' ],
  88     );
  89
  90     my $has_unattached_actions;
  91     my $unattached_actions = Text::SimpleTable->new(
  92         [ $col1_width, 'Private' ], [ $col2_width, 'Missing parent' ],
  93     );
  94
  95     ENDPOINT: foreach my $endpoint (
  96                   sort { $a->reverse cmp $b->reverse }
  97                            @{ $self->_endpoints }
  98                   ) {
  99         my $args = $endpoint->attributes->{Args}->[0];
 100         my @parts = (defined($args) ? (("*") x $args) : '...');
 101         my @parents = ();
 102         my $parent = "DUMMY";
 103         my $curr = $endpoint;
 104         while ($curr) {
 105             if (my $cap = $curr->attributes->{CaptureArgs}) {
 106                 unshift(@parts, (("*") x $cap->[0]));
 107             }
 108             if (my $pp = $curr->attributes->{PathPart}) {
 109                 unshift(@parts, $pp->[0])
 110                     if (defined $pp->[0] && length $pp->[0]);
 111             }
 112             $parent = $curr->attributes->{Chained}->[0];
 113             $curr = $self->_actions->{$parent};
 114             unshift(@parents, $curr) if $curr;
 115         }
 116         if ($parent ne '/') {
 117             $has_unattached_actions = 1;
 118             $unattached_actions->row('/' . ($parents[0] || $endpoint)->reverse, $parent);
 119             next ENDPOINT;
 120         }
 121         my @rows;
 122         foreach my $p (@parents) {
 123             my $name = "/${p}";
 124             if (my $cap = $p->attributes->{CaptureArgs}) {
 125                 $name .= ' ('.$cap->[0].')';
 126             }
 127             unless ($p eq $parents[0]) {
 128                 $name = "-> ${name}";
 129             }
 130             push(@rows, [ '', $name ]);
 131         }
 132         push(@rows, [ '', (@rows ? "=> " : '')."/${endpoint}" ]);
 133         $rows[0][0] = join('/', '', @parts) || '/';
 134         $paths->row(@$_) for @rows;
 135     }
 136
 137     $c->log->debug( "Loaded Chained actions:\n" . $paths->draw . "\n" );
 138     $c->log->debug( "Unattached Chained actions:\n", $unattached_actions->draw . "\n" )
 139         if $has_unattached_actions;
 140 }
 141
 142 =head2 $self->match( $c, $path )
 143
 144 Calls C<recurse_match> to see if a chain matches the C<$path>.
 145
 146 =cut
 147
 148 sub match {
 149     my ( $self, $c, $path ) = @_;
 150
 151     my $request = $c->request;
 152     return 0 if @{$request->args};
 153
 154     my @parts = split('/', $path);
 155
 156     my ($chain, $captures, $parts) = $self->recurse_match($c, '/', \@parts);
 157
 158     if ($parts && @$parts) {
 159         for my $arg (@$parts) {
 160             $arg =~ s/%([0-9A-Fa-f]{2})/chr(hex($1))/eg;
 161             push @{$request->args}, $arg;
 162         }
 163     }
 164
 165     return 0 unless $chain;
 166
 167     my $action = Catalyst::ActionChain->from_chain($chain);
 168
 169     $request->action("/${action}");
 170     $request->match("/${action}");
 171     $request->captures($captures);
 172     $c->action($action);
 173     $c->namespace( $action->namespace );
 174
 175     return 1;
 176 }
 177
 178 =head2 $self->recurse_match( $c, $parent, \@path_parts )
 179
 180 Recursive search for a matching chain.
 181
 182 =cut
 183
 184 sub recurse_match {
 185     my ( $self, $c, $parent, $path_parts ) = @_;
 186     my $children = $self->_children_of->{$parent};
 187     return () unless $children;
 188     my $best_action;
 189     my @captures;
 190     my $found=0;
 191     TRY: foreach my $try_part (sort { length($b) <=> length($a) }
 192                                    keys %$children) {
 193                                # $b then $a to try longest part first
 194         my @parts = @$path_parts;
 195         if (length $try_part) { # test and strip PathPart
 196             next TRY unless
 197               ($try_part eq join('/', # assemble equal number of parts
 198                               splice( # and strip them off @parts as well
 199                                 @parts, 0, scalar(@{[split('/', $try_part)]})
 200                               ))); # @{[]} to avoid split to @_
 201             $found=1;
 202         }
 203         my @try_actions = @{$children->{$try_part}};
 204         TRY_ACTION: foreach my $action (@try_actions) {
 205             if (my $capture_attr = $action->attributes->{CaptureArgs}) {
 206
 207                 # Short-circuit if not enough remaining parts
 208                 next TRY_ACTION unless @parts >= $capture_attr->[0];
 209
 210                 my @captures;
 211                 my @parts = @parts; # localise
 212
 213                 # strip CaptureArgs into list
 214                 push(@captures, splice(@parts, 0, $capture_attr->[0]));
 215
 216                 # try the remaining parts against children of this action
 217                 my ($actions, $captures, $action_parts, $found) = $self->recurse_match(
 218                                              $c, '/'.$action->reverse, \@parts
 219                                            );
 220                 #    No best action currently
 221                 # OR The action has less parts
 222                 # OR The action has equal parts but less captured data (ergo more defined)
 223                 if ($actions    &&
 224                     (!$best_action                                 ||
 225                       $#$action_parts < $#{$best_action->{parts}}  ||
 226                      ($#$action_parts == $#{$best_action->{parts}} &&
 227                       $#$captures < $#{$best_action->{captures}} && ($found > $best_action->{found})
 228                   ))) {
 229                     $best_action = {
 230                         actions => [ $action, @$actions ],
 231                         captures=> [ @captures, @$captures ],
 232                         parts   => $action_parts,
 233                         found=>$found
 234                         };
 235                 }
 236             }
 237             else {
 238                 {
 239                     local $c->req->{arguments} = [ @{$c->req->args}, @parts ];
 240                     next TRY_ACTION unless $action->match($c);
 241                 }
 242                 my $args_attr = $action->attributes->{Args}->[0];
 243
 244                 #    No best action currently
 245                 # OR This one matches with fewer parts left than the current best action,
 246                 #    And therefore is a better match
 247                 # OR No parts and this expects 0
 248                 #    The current best action might also be Args(0),
 249                 #    but we couldn't chose between then anyway so we'll take the last seen
 250
 251                 if (!$best_action                       ||
 252                     @parts < @{$best_action->{parts}}   ||
 253                     (!@parts && $args_attr eq 0)){
 254                     $best_action = {
 255                         actions => [ $action ],
 256                         captures=> [],
 257                         parts   => \@parts,
 258                         found=>$found,
 259                     }
 260                 }
 261             }
 262         }
 263     }
 264     return @$best_action{qw/actions captures parts found/} if $best_action;
 265     return ();
 266 }
 267
 268 =head2 $self->register( $c, $action )
 269
 270 Calls register_path for every Path attribute for the given $action.
 271
 272 =cut
 273
 274 sub register {
 275     my ( $self, $c, $action ) = @_;
 276
 277     my @chained_attr = @{ $action->attributes->{Chained} || [] };
 278
 279     return 0 unless @chained_attr;
 280
 281     if (@chained_attr > 1) {
 282         Catalyst::Exception->throw(
 283           "Multiple Chained attributes not supported registering ${action}"
 284         );
 285     }
 286     my $chained_to = $chained_attr[0];
 287
 288     Catalyst::Exception->throw(
 289       "Actions cannot chain to themselves registering /${action}"
 290     ) if ($chained_to eq '/' . $action);
 291
 292     my $children = ($self->_children_of->{ $chained_to } ||= {});
 293
 294     my @path_part = @{ $action->attributes->{PathPart} || [] };
 295
 296     my $part = $action->name;
 297
 298     if (@path_part == 1 && defined $path_part[0]) {
 299         $part = $path_part[0];
 300     } elsif (@path_part > 1) {
 301         Catalyst::Exception->throw(
 302           "Multiple PathPart attributes not supported registering " . $action->reverse()
 303         );
 304     }
 305
 306     if ($part =~ m(^/)) {
 307         Catalyst::Exception->throw(
 308           "Absolute parameters to PathPart not allowed registering " . $action->reverse()
 309         );
 310     }
 311
 312     $action->attributes->{PathPart} = [ $part ];
 313
 314     unshift(@{ $children->{$part} ||= [] }, $action);
 315
 316     $self->_actions->{'/'.$action->reverse} = $action;
 317
 318     if (exists $action->attributes->{Args}) {
 319         my $args = $action->attributes->{Args}->[0];
 320         if (defined($args) and not (
 321             Scalar::Util::looks_like_number($args) and
 322             int($args) == $args
 323         )) {
 324             require Data::Dumper;
 325             local $Data::Dumper::Terse = 1;
 326             local $Data::Dumper::Indent = 0;
 327             $args = Data::Dumper::Dumper($args);
 328             Catalyst::Exception->throw(
 329               "Invalid Args($args) for action " . $action->reverse() .
 330               " (use 'Args' or 'Args(<number>)'"
 331             );
 332         }
 333     }
 334
 335     unless ($action->attributes->{CaptureArgs}) {
 336         unshift(@{ $self->_endpoints }, $action);
 337     }
 338
 339     return 1;
 340 }
 341
 342 =head2 $self->uri_for_action($action, $captures)
 343
 344 Get the URI part for the action, using C<$captures> to fill
 345 the capturing parts.
 346
 347 =cut
 348
 349 sub uri_for_action {
 350     my ( $self, $action, $captures ) = @_;
 351
 352     return undef unless ($action->attributes->{Chained}
 353                            && !$action->attributes->{CaptureArgs});
 354
 355     my @parts = ();
 356     my @captures = @$captures;
 357     my $parent = "DUMMY";
 358     my $curr = $action;
 359     while ($curr) {
 360         if (my $cap = $curr->attributes->{CaptureArgs}) {
 361             return undef unless @captures >= $cap->[0]; # not enough captures
 362             if ($cap->[0]) {
 363                 unshift(@parts, splice(@captures, -$cap->[0]));
 364             }
 365         }
 366         if (my $pp = $curr->attributes->{PathPart}) {
 367             unshift(@parts, $pp->[0])
 368                 if (defined($pp->[0]) && length($pp->[0]));
 369         }
 370         $parent = $curr->attributes->{Chained}->[0];
 371         $curr = $self->_actions->{$parent};
 372     }
 373
 374     return undef unless $parent eq '/'; # fail for dangling action
 375
 376     return undef if @captures; # fail for too many captures
 377
 378     return join('/', '', @parts);
 379
 380 }
 381
 382 =head2 $c->expand_action($action)
 383
 384 Return a list of actions that represents a chained action. See
 385 L<Catalyst::Dispatcher> for more info. You probably want to
 386 use the expand_action it provides rather than this directly.
 387
 388 =cut
 389
 390 sub expand_action {
 391     my ($self, $action) = @_;
 392
 393     return unless $action->attributes && $action->attributes->{Chained};
 394
 395     my @chain;
 396     my $curr = $action;
 397
 398     while ($curr) {
 399         push @chain, $curr;
 400         my $parent = $curr->attributes->{Chained}->[0];
 401         $curr = $self->_actions->{$parent};
 402     }
 403
 404     return Catalyst::ActionChain->from_chain([reverse @chain]);
 405 }
 406
 407 __PACKAGE__->meta->make_immutable;
 408
 409 =head1 USAGE
 410
 411 =head2 Introduction
 412
 413 The C<Chained> attribute allows you to chain public path parts together
 414 by their private names. A chain part's path can be specified with
 415 C<PathPart> and can be declared to expect an arbitrary number of
 416 arguments. The endpoint of the chain specifies how many arguments it
 417 gets through the C<Args> attribute. C<:Args(0)> would be none at all,
 418 C<:Args> without an integer would be unlimited. The path parts that
 419 aren't endpoints are using C<CaptureArgs> to specify how many parameters
 420 they expect to receive. As an example setup:
 421
 422   package MyApp::Controller::Greeting;
 423   use base qw/ Catalyst::Controller /;
 424
 425   #   this is the beginning of our chain
 426   sub hello : PathPart('hello') Chained('/') CaptureArgs(1) {
 427       my ( $self, $c, $integer ) = @_;
 428       $c->stash->{ message } = "Hello ";
 429       $c->stash->{ arg_sum } = $integer;
 430   }
 431
 432   #   this is our endpoint, because it has no :CaptureArgs
 433   sub world : PathPart('world') Chained('hello') Args(1) {
 434       my ( $self, $c, $integer ) = @_;
 435       $c->stash->{ message } .= "World!";
 436       $c->stash->{ arg_sum } += $integer;
 437
 438       $c->response->body( join "<br/>\n" =>
 439           $c->stash->{ message }, $c->stash->{ arg_sum } );
 440   }
 441
 442 The debug output provides a separate table for chained actions, showing
 443 the whole chain as it would match and the actions it contains. Here's an
 444 example of the startup output with our actions above:
 445
 446   ...
 447   [debug] Loaded Path Part actions:
 448   .-----------------------+------------------------------.
 449   | Path Spec             | Private                      |
 450   +-----------------------+------------------------------+
 451   | /hello/*/world/*      | /greeting/hello (1)          |
 452   |                       | => /greeting/world           |
 453   '-----------------------+------------------------------'
 454   ...
 455
 456 As you can see, Catalyst only deals with chains as whole paths and
 457 builds one for each endpoint, which are the actions with C<:Chained> but
 458 without C<:CaptureArgs>.
 459
 460 Let's assume this application gets a request at the path
 461 C</hello/23/world/12>. What happens then? First, Catalyst will dispatch
 462 to the C<hello> action and pass the value C<23> as an argument to it
 463 after the context. It does so because we have previously used
 464 C<:CaptureArgs(1)> to declare that it has one path part after itself as
 465 its argument. We told Catalyst that this is the beginning of the chain
 466 by specifying C<:Chained('/')>. Also note that instead of saying
 467 C<:PathPart('hello')> we could also just have said C<:PathPart>, as it
 468 defaults to the name of the action.
 469
 470 After C<hello> has run, Catalyst goes on to dispatch to the C<world>
 471 action. This is the last action to be called: Catalyst knows this is an
 472 endpoint because we did not specify a C<:CaptureArgs>
 473 attribute. Nevertheless we specify that this action expects an argument,
 474 but at this point we're using C<:Args(1)> to do that. We could also have
 475 said C<:Args> or left it out altogether, which would mean this action
 476 would get all arguments that are there. This action's C<:Chained>
 477 attribute says C<hello> and tells Catalyst that the C<hello> action in
 478 the current controller is its parent.
 479
 480 With this we have built a chain consisting of two public path parts.
 481 C<hello> captures one part of the path as its argument, and also
 482 specifies the path root as its parent. So this part is
 483 C</hello/$arg>. The next part is the endpoint C<world>, expecting one
 484 argument. It sums up to the path part C<world/$arg>. This leads to a
 485 complete chain of C</hello/$arg/world/$arg> which is matched against the
 486 requested paths.
 487
 488 This example application would, if run and called by e.g.
 489 C</hello/23/world/12>, set the stash value C<message> to "Hello" and the
 490 value C<arg_sum> to "23". The C<world> action would then append "World!"
 491 to C<message> and add C<12> to the stash's C<arg_sum> value.  For the
 492 sake of simplicity no view is shown. Instead we just put the values of
 493 the stash into our body. So the output would look like:
 494
 495   Hello World!
 496   35
 497
 498 And our test server would have given us this debugging output for the
 499 request:
 500
 501   ...
 502   [debug] "GET" request for "hello/23/world/12" from "127.0.0.1"
 503   [debug] Path is "/greeting/world"
 504   [debug] Arguments are "12"
 505   [info] Request took 0.164113s (6.093/s)
 506   .------------------------------------------+-----------.
 507   | Action                                   | Time      |
 508   +------------------------------------------+-----------+
 509   | /greeting/hello                          | 0.000029s |
 510   | /greeting/world                          | 0.000024s |
 511   '------------------------------------------+-----------'
 512   ...
 513
 514 What would be common uses of this dispatch technique? It gives the
 515 possibility to split up logic that contains steps that each depend on
 516 each other. An example would be, for example, a wiki path like
 517 C</wiki/FooBarPage/rev/23/view>. This chain can be easily built with
 518 these actions:
 519
 520   sub wiki : PathPart('wiki') Chained('/') CaptureArgs(1) {
 521       my ( $self, $c, $page_name ) = @_;
 522       #  load the page named $page_name and put the object
 523       #  into the stash
 524   }
 525
 526   sub rev : PathPart('rev') Chained('wiki') CaptureArgs(1) {
 527       my ( $self, $c, $revision_id ) = @_;
 528       #  use the page object in the stash to get at its
 529       #  revision with number $revision_id
 530   }
 531
 532   sub view : PathPart Chained('rev') Args(0) {
 533       my ( $self, $c ) = @_;
 534       #  display the revision in our stash. Another option
 535       #  would be to forward a compatible object to the action
 536       #  that displays the default wiki pages, unless we want
 537       #  a different interface here, for example restore
 538       #  functionality.
 539   }
 540
 541 It would now be possible to add other endpoints, for example C<restore>
 542 to restore this specific revision as the current state.
 543
 544 You don't have to put all the chained actions in one controller. The
 545 specification of the parent through C<:Chained> also takes an absolute
 546 action path as its argument. Just specify it with a leading C</>.
 547
 548 If you want, for example, to have actions for the public paths
 549 C</foo/12/edit> and C</foo/12>, just specify two actions with
 550 C<:PathPart('foo')> and C<:Chained('/')>. The handler for the former
 551 path needs a C<:CaptureArgs(1)> attribute and a endpoint with
 552 C<:PathPart('edit')> and C<:Chained('foo')>. For the latter path give
 553 the action just a C<:Args(1)> to mark it as endpoint. This sums up to
 554 this debugging output:
 555
 556   ...
 557   [debug] Loaded Path Part actions:
 558   .-----------------------+------------------------------.
 559   | Path Spec             | Private                      |
 560   +-----------------------+------------------------------+
 561   | /foo/*                | /controller/foo_view         |
 562   | /foo/*/edit           | /controller/foo_load (1)     |
 563   |                       | => /controller/edit          |
 564   '-----------------------+------------------------------'
 565   ...
 566
 567 Here's a more detailed specification of the attributes belonging to
 568 C<:Chained>:
 569
 570 =head2 Attributes
 571
 572 =over 8
 573
 574 =item PathPart
 575
 576 Sets the name of this part of the chain. If it is specified without
 577 arguments, it takes the name of the action as default. So basically
 578 C<sub foo :PathPart> and C<sub foo :PathPart('foo')> are identical.
 579 This can also contain slashes to bind to a deeper level. An action
 580 with C<sub bar :PathPart('foo/bar') :Chained('/')> would bind to
 581 C</foo/bar/...>. If you don't specify C<:PathPart> it has the same
 582 effect as using C<:PathPart>, it would default to the action name.
 583
 584 =item PathPrefix
 585
 586 Sets PathPart to the path_prefix of the current controller.
 587
 588 =item Chained
 589
 590 Has to be specified for every child in the chain. Possible values are
 591 absolute and relative private action paths or a single slash C</> to
 592 tell Catalyst that this is the root of a chain. The attribute
 593 C<:Chained> without arguments also defaults to the C</> behavior.
 594 Relative action paths may use C<../> to refer to actions in parent
 595 controllers.
 596
 597 Because you can specify an absolute path to the parent action, it
 598 doesn't matter to Catalyst where that parent is located. So, if your
 599 design requests it, you can redispatch a chain through any controller or
 600 namespace you want.
 601
 602 Another interesting possibility gives C<:Chained('.')>, which chains
 603 itself to an action with the path of the current controller's namespace.
 604 For example:
 605
 606   #   in MyApp::Controller::Foo
 607   sub bar : Chained CaptureArgs(1) { ... }
 608
 609   #   in MyApp::Controller::Foo::Bar
 610   sub baz : Chained('.') Args(1) { ... }
 611
 612 This builds up a chain like C</bar/*/baz/*>. The specification of C<.>
 613 as the argument to Chained here chains the C<baz> action to an action
 614 with the path of the current controller namespace, namely
 615 C</foo/bar>. That action chains directly to C</>, so the C</bar/*/baz/*>
 616 chain comes out as the end product.
 617
 618 =item ChainedParent
 619
 620 Chains an action to another action with the same name in the parent
 621 controller. For Example:
 622
 623   # in MyApp::Controller::Foo
 624   sub bar : Chained CaptureArgs(1) { ... }
 625
 626   # in MyApp::Controller::Foo::Moo
 627   sub bar : ChainedParent Args(1) { ... }
 628
 629 This builds a chain like C</bar/*/bar/*>.
 630
 631 =item CaptureArgs
 632
 633 Must be specified for every part of the chain that is not an
 634 endpoint. With this attribute Catalyst knows how many of the following
 635 parts of the path (separated by C</>) this action wants to capture as
 636 its arguments. If it doesn't expect any, just specify
 637 C<:CaptureArgs(0)>.  The captures get passed to the action's C<@_> right
 638 after the context, but you can also find them as array references in
 639 C<$c-E<gt>request-E<gt>captures-E<gt>[$level]>. The C<$level> is the
 640 level of the action in the chain that captured the parts of the path.
 641
 642 An action that is part of a chain (that is, one that has a C<:Chained>
 643 attribute) but has no C<:CaptureArgs> attribute is treated by Catalyst
 644 as a chain end.
 645
 646 =item Args
 647
 648 By default, endpoints receive the rest of the arguments in the path. You
 649 can tell Catalyst through C<:Args> explicitly how many arguments your
 650 endpoint expects, just like you can with C<:CaptureArgs>. Note that this
 651 also affects whether this chain is invoked on a request. A chain with an
 652 endpoint specifying one argument will only match if exactly one argument
 653 exists in the path.
 654
 655 You can specify an exact number of arguments like C<:Args(3)>, including
 656 C<0>. If you just say C<:Args> without any arguments, it is the same as
 657 leaving it out altogether: The chain is matched regardless of the number
 658 of path parts after the endpoint.
 659
 660 Just as with C<:CaptureArgs>, the arguments get passed to the action in
 661 C<@_> after the context object. They can also be reached through
 662 C<$c-E<gt>request-E<gt>arguments>.
 663
 664 =back
 665
 666 =head2 Auto actions, dispatching and forwarding
 667
 668 Note that the list of C<auto> actions called depends on the private path
 669 of the endpoint of the chain, not on the chained actions way. The
 670 C<auto> actions will be run before the chain dispatching begins. In
 671 every other aspect, C<auto> actions behave as documented.
 672
 673 The C<forward>ing to other actions does just what you would expect. But if
 674 you C<detach> out of a chain, the rest of the chain will not get called
 675 after the C<detach>.
 676
 677 =head1 AUTHORS
 678
 679 Catalyst Contributors, see Catalyst.pm
 680
 681 =head1 COPYRIGHT
 682
 683 This library is free software. You can redistribute it and/or modify it under
 684 the same terms as Perl itself.
 685
 686 =cut
 687
 688 1;