lib/Catalyst/DispatchType/Chained.pm

   1 package Catalyst::DispatchType::Chained;
   2
   3 use Moose;
   4 extends 'Catalyst::DispatchType';
   5
   6 use Text::SimpleTable;
   7 use Catalyst::ActionChain;
   8 use Catalyst::Utils;
   9 use URI;
  10 use Scalar::Util ();
  11 use Encode 2.21 'decode_utf8';
  12
  13 has _endpoints => (
  14                    is => 'rw',
  15                    isa => 'ArrayRef',
  16                    required => 1,
  17                    default => sub{ [] },
  18                   );
  19
  20 has _actions => (
  21                  is => 'rw',
  22                  isa => 'HashRef',
  23                  required => 1,
  24                  default => sub{ {} },
  25                 );
  26
  27 has _children_of => (
  28                      is => 'rw',
  29                      isa => 'HashRef',
  30                      required => 1,
  31                      default => sub{ {} },
  32                     );
  33
  34 no Moose;
  35
  36 # please don't perltidy this. hairy code within.
  37
  38 =head1 NAME
  39
  40 Catalyst::DispatchType::Chained - Path Part DispatchType
  41
  42 =head1 SYNOPSIS
  43
  44 Path part matching, allowing several actions to sequentially take care of processing a request:
  45
  46   #   root action - captures one argument after it
  47   sub foo_setup : Chained('/') PathPart('foo') CaptureArgs(1) {
  48       my ( $self, $c, $foo_arg ) = @_;
  49       ...
  50   }
  51
  52   #   child action endpoint - takes one argument
  53   sub bar : Chained('foo_setup') Args(1) {
  54       my ( $self, $c, $bar_arg ) = @_;
  55       ...
  56   }
  57
  58 =head1 DESCRIPTION
  59
  60 Dispatch type managing default behaviour.  For more information on
  61 dispatch types, see:
  62
  63 =over 4
  64
  65 =item * L<Catalyst::Manual::Intro> for how they affect application authors
  66
  67 =item * L<Catalyst::DispatchType> for implementation information.
  68
  69 =back
  70
  71 =head1 METHODS
  72
  73 =head2 $self->list($c)
  74
  75 Debug output for Path Part dispatch points
  76
  77 =cut
  78
  79 sub list {
  80     my ( $self, $c ) = @_;
  81
  82     return unless $self->_endpoints;
  83
  84     my $avail_width = Catalyst::Utils::term_width() - 9;
  85     my $col1_width = ($avail_width * .50) < 35 ? 35 : int($avail_width * .50);
  86     my $col2_width = $avail_width - $col1_width;
  87     my $paths = Text::SimpleTable->new(
  88         [ $col1_width, 'Path Spec' ], [ $col2_width, 'Private' ],
  89     );
  90
  91     my $has_unattached_actions;
  92     my $unattached_actions = Text::SimpleTable->new(
  93         [ $col1_width, 'Private' ], [ $col2_width, 'Missing parent' ],
  94     );
  95
  96     ENDPOINT: foreach my $endpoint (
  97                   sort { $a->reverse cmp $b->reverse }
  98                            @{ $self->_endpoints }
  99                   ) {
 100         my $args = $endpoint->list_extra_info->{Args};
 101         my @parts = (defined($endpoint->attributes->{Args}[0]) ? (("*") x $args) : '...');
 102         my @parents = ();
 103         my $parent = "DUMMY";
 104         my $extra  = $self->_list_extra_http_methods($endpoint);
 105         my $consumes = $self->_list_extra_consumes($endpoint);
 106         my $scheme = $self->_list_extra_scheme($endpoint);
 107         my $curr = $endpoint;
 108         while ($curr) {
 109             if (my $cap = $curr->list_extra_info->{CaptureArgs}) {
 110                 unshift(@parts, (("*") x $cap));
 111             }
 112             if (my $pp = $curr->attributes->{PathPart}) {
 113                 unshift(@parts, $pp->[0])
 114                     if (defined $pp->[0] && length $pp->[0]);
 115             }
 116             $parent = $curr->attributes->{Chained}->[0];
 117             $curr = $self->_actions->{$parent};
 118             unshift(@parents, $curr) if $curr;
 119         }
 120         if ($parent ne '/') {
 121             $has_unattached_actions = 1;
 122             $unattached_actions->row('/' . ($parents[0] || $endpoint)->reverse, $parent);
 123             next ENDPOINT;
 124         }
 125         my @rows;
 126         foreach my $p (@parents) {
 127             my $name = "/${p}";
 128
 129             if (defined(my $extra = $self->_list_extra_http_methods($p))) {
 130                 $name = "${extra} ${name}";
 131             }
 132             if (defined(my $cap = $p->list_extra_info->{CaptureArgs})) {
 133                 if($p->has_captures_constraints) {
 134                   my $tc = join ',', @{$p->captures_constraints};
 135                   $name .= " ($tc)";
 136                 } else {
 137                   $name .= " ($cap)";
 138                 }
 139             }
 140             if (defined(my $ct = $p->list_extra_info->{Consumes})) {
 141                 $name .= ' :'.$ct;
 142             }
 143             if (defined(my $s = $p->list_extra_info->{Scheme})) {
 144                 $scheme = uc $s;
 145             }
 146
 147             unless ($p eq $parents[0]) {
 148                 $name = "-> ${name}";
 149             }
 150             push(@rows, [ '', $name ]);
 151         }
 152
 153         if($endpoint->has_args_constraints) {
 154           my $tc = join ',', @{$endpoint->args_constraints};
 155           $endpoint .= " ($tc)";
 156         } else {
 157           $endpoint .= defined($endpoint->attributes->{Args}[0]) ? " ($args)" : " (...)";
 158         }
 159         push(@rows, [ '', (@rows ? "=> " : '').($extra ? "$extra " : ''). ($scheme ? "$scheme: ":'')."/${endpoint}". ($consumes ? " :$consumes":"" ) ]);
 160         my @display_parts = map { $_ =~s/%([0-9A-Fa-f]{2})/chr(hex($1))/eg; decode_utf8 $_ } @parts;
 161         $rows[0][0] = join('/', '', @display_parts) || '/';
 162         $paths->row(@$_) for @rows;
 163     }
 164
 165     $c->log->debug( "Loaded Chained actions:\n" . $paths->draw . "\n" );
 166     $c->log->debug( "Unattached Chained actions:\n", $unattached_actions->draw . "\n" )
 167         if $has_unattached_actions;
 168 }
 169
 170 sub _list_extra_http_methods {
 171     my ( $self, $action ) = @_;
 172     return unless defined $action->list_extra_info->{HTTP_METHODS};
 173     return join(', ', @{$action->list_extra_info->{HTTP_METHODS}});
 174
 175 }
 176
 177 sub _list_extra_consumes {
 178     my ( $self, $action ) = @_;
 179     return unless defined $action->list_extra_info->{CONSUMES};
 180     return join(', ', @{$action->list_extra_info->{CONSUMES}});
 181 }
 182
 183 sub _list_extra_scheme {
 184     my ( $self, $action ) = @_;
 185     return unless defined $action->list_extra_info->{Scheme};
 186     return uc $action->list_extra_info->{Scheme};
 187 }
 188
 189 =head2 $self->match( $c, $path )
 190
 191 Calls C<recurse_match> to see if a chain matches the C<$path>.
 192
 193 =cut
 194
 195 sub match {
 196     my ( $self, $c, $path ) = @_;
 197
 198     my $request = $c->request;
 199     return 0 if @{$request->args};
 200
 201     my @parts = split('/', $path);
 202
 203     my ($chain, $captures, $parts) = $self->recurse_match($c, '/', \@parts);
 204
 205     if ($parts && @$parts) {
 206         for my $arg (@$parts) {
 207             $arg =~ s/%([0-9A-Fa-f]{2})/chr(hex($1))/eg;
 208             push @{$request->args}, $arg;
 209         }
 210     }
 211
 212     return 0 unless $chain;
 213
 214     my $action = Catalyst::ActionChain->from_chain($chain);
 215
 216     $request->action("/${action}");
 217     $request->match("/${action}");
 218     $request->captures($captures);
 219     $c->action($action);
 220     $c->namespace( $action->namespace );
 221
 222     return 1;
 223 }
 224
 225 =head2 $self->recurse_match( $c, $parent, \@path_parts )
 226
 227 Recursive search for a matching chain.
 228
 229 =cut
 230
 231 sub recurse_match {
 232     my ( $self, $c, $parent, $path_parts ) = @_;
 233     my $children = $self->_children_of->{$parent};
 234     return () unless $children;
 235     my $best_action;
 236     my @captures;
 237     TRY: foreach my $try_part (sort { length($b) <=> length($a) }
 238                                    keys %$children) {
 239                                # $b then $a to try longest part first
 240         my @parts = @$path_parts;
 241         if (length $try_part) { # test and strip PathPart
 242             next TRY unless
 243               ($try_part eq join('/', # assemble equal number of parts
 244                               splice( # and strip them off @parts as well
 245                                 @parts, 0, scalar(@{[split('/', $try_part)]})
 246                               ))); # @{[]} to avoid split to @_
 247         }
 248         my @try_actions = @{$children->{$try_part}};
 249         TRY_ACTION: foreach my $action (@try_actions) {
 250             if (my $capture_attr = $action->attributes->{CaptureArgs}) {
 251                 my $capture_count = $action->number_of_captures|| 0;
 252
 253                 # Short-circuit if not enough remaining parts
 254                 next TRY_ACTION unless @parts >= $capture_count;
 255
 256                 my @captures;
 257                 my @parts = @parts; # localise
 258
 259                 # strip CaptureArgs into list
 260                 push(@captures, splice(@parts, 0, $capture_count));
 261
 262                 # check if the action may fit, depending on a given test by the app
 263                 next TRY_ACTION unless $action->match_captures($c, \@captures);
 264
 265                 # try the remaining parts against children of this action
 266                 my ($actions, $captures, $action_parts, $n_pathparts) = $self->recurse_match(
 267                                              $c, '/'.$action->reverse, \@parts
 268                                            );
 269                 #    No best action currently
 270                 # OR The action has less parts
 271                 # OR The action has equal parts but less captured data (ergo more defined)
 272                 if ($actions    &&
 273                     (!$best_action                                 ||
 274                      $#$action_parts < $#{$best_action->{parts}}   ||
 275                      ($#$action_parts == $#{$best_action->{parts}} &&
 276                       $#$captures < $#{$best_action->{captures}} &&
 277                       $n_pathparts > $best_action->{n_pathparts}))) {
 278                     my @pathparts = split /\//, $action->attributes->{PathPart}->[0];
 279                     $best_action = {
 280                         actions => [ $action, @$actions ],
 281                         captures=> [ @captures, @$captures ],
 282                         parts   => $action_parts,
 283                         n_pathparts => scalar(@pathparts) + $n_pathparts,
 284                     };
 285                 }
 286             }
 287             else {
 288                 {
 289                     local $c->req->{arguments} = [ @{$c->req->args}, @parts ];
 290                     next TRY_ACTION unless $action->match($c);
 291                 }
 292                 my $args_attr = $action->attributes->{Args}->[0];
 293                 my @pathparts = split /\//, $action->attributes->{PathPart}->[0];
 294                 #    No best action currently
 295                 # OR This one matches with fewer parts left than the current best action,
 296                 #    And therefore is a better match
 297                 # OR No parts and this expects 0
 298                 #    The current best action might also be Args(0),
 299                 #    but we couldn't chose between then anyway so we'll take the last seen
 300
 301                 if (!$best_action                       ||
 302                     @parts < @{$best_action->{parts}}   ||
 303                     (!@parts && defined($args_attr) && $args_attr eq "0")){
 304                     $best_action = {
 305                         actions => [ $action ],
 306                         captures=> [],
 307                         parts   => \@parts,
 308                         n_pathparts => scalar(@pathparts),
 309                     };
 310                 }
 311             }
 312         }
 313     }
 314     return @$best_action{qw/actions captures parts n_pathparts/} if $best_action;
 315     return ();
 316 }
 317
 318 =head2 $self->register( $c, $action )
 319
 320 Calls register_path for every Path attribute for the given $action.
 321
 322 =cut
 323
 324 sub register {
 325     my ( $self, $c, $action ) = @_;
 326
 327     my @chained_attr = @{ $action->attributes->{Chained} || [] };
 328
 329     return 0 unless @chained_attr;
 330
 331     if (@chained_attr > 1) {
 332         Catalyst::Exception->throw(
 333           "Multiple Chained attributes not supported registering ${action}"
 334         );
 335     }
 336     my $chained_to = $chained_attr[0];
 337
 338     Catalyst::Exception->throw(
 339       "Actions cannot chain to themselves registering /${action}"
 340     ) if ($chained_to eq '/' . $action);
 341
 342     my $children = ($self->_children_of->{ $chained_to } ||= {});
 343
 344     my @path_part = @{ $action->attributes->{PathPart} || [] };
 345
 346     my $part = $action->name;
 347
 348     if (@path_part == 1 && defined $path_part[0]) {
 349         $part = $path_part[0];
 350     } elsif (@path_part > 1) {
 351         Catalyst::Exception->throw(
 352           "Multiple PathPart attributes not supported registering " . $action->reverse()
 353         );
 354     }
 355
 356     if ($part =~ m(^/)) {
 357         Catalyst::Exception->throw(
 358           "Absolute parameters to PathPart not allowed registering " . $action->reverse()
 359         );
 360     }
 361
 362     my $encoded_part = URI->new($part)->canonical;
 363     $encoded_part =~ s{(?<=[^/])/+\z}{};
 364
 365     $action->attributes->{PathPart} = [ $encoded_part ];
 366
 367     unshift(@{ $children->{$encoded_part} ||= [] }, $action);
 368
 369     $self->_actions->{'/'.$action->reverse} = $action;
 370
 371     if (exists $action->attributes->{Args} and exists $action->attributes->{CaptureArgs}) {
 372         Catalyst::Exception->throw(
 373           "Combining Args and CaptureArgs attributes not supported registering " .
 374           $action->reverse()
 375         );
 376     }
 377
 378     unless ($action->attributes->{CaptureArgs}) {
 379         unshift(@{ $self->_endpoints }, $action);
 380     }
 381
 382     return 1;
 383 }
 384
 385 =head2 $self->uri_for_action($action, $captures)
 386
 387 Get the URI part for the action, using C<$captures> to fill
 388 the capturing parts.
 389
 390 =cut
 391
 392 sub uri_for_action {
 393     my ( $self, $action, $captures ) = @_;
 394
 395     return undef unless ($action->attributes->{Chained}
 396                            && !$action->attributes->{CaptureArgs});
 397
 398     my @parts = ();
 399     my @captures = @$captures;
 400     my $parent = "DUMMY";
 401     my $curr = $action;
 402     # If this is an action chain get the last action in the chain
 403     if($curr->can('chain') ) {
 404       $curr = ${$curr->chain}[-1];
 405     }
 406     while ($curr) {
 407         if (my $cap = $curr->number_of_captures) {
 408             return undef unless @captures >= $cap; # not enough captures
 409             if ($cap) {
 410                 unshift(@parts, splice(@captures, -$cap));
 411             }
 412         }
 413         if (my $pp = $curr->attributes->{PathPart}) {
 414             unshift(@parts, $pp->[0])
 415                 if (defined($pp->[0]) && length($pp->[0]));
 416         }
 417         $parent = $curr->attributes->{Chained}->[0];
 418         $curr = $self->_actions->{$parent};
 419     }
 420
 421     return undef unless $parent eq '/'; # fail for dangling action
 422
 423     return undef if @captures; # fail for too many captures
 424
 425     return join('/', '', @parts);
 426
 427 }
 428
 429 =head2 $c->expand_action($action)
 430
 431 Return a list of actions that represents a chained action. See
 432 L<Catalyst::Dispatcher> for more info. You probably want to
 433 use the expand_action it provides rather than this directly.
 434
 435 =cut
 436
 437 sub expand_action {
 438     my ($self, $action) = @_;
 439
 440     return unless $action->attributes && $action->attributes->{Chained};
 441
 442     my @chain;
 443     my $curr = $action;
 444
 445     while ($curr) {
 446         push @chain, $curr;
 447         my $parent = $curr->attributes->{Chained}->[0];
 448         $curr = $self->_actions->{$parent};
 449     }
 450
 451     return Catalyst::ActionChain->from_chain([reverse @chain]);
 452 }
 453
 454 __PACKAGE__->meta->make_immutable;
 455 1;
 456
 457 =head1 USAGE
 458
 459 =head2 Introduction
 460
 461 The C<Chained> attribute allows you to chain public path parts together
 462 by their private names. A chain part's path can be specified with
 463 C<PathPart> and can be declared to expect an arbitrary number of
 464 arguments. The endpoint of the chain specifies how many arguments it
 465 gets through the C<Args> attribute. C<:Args(0)> would be none at all,
 466 C<:Args> without an integer would be unlimited. The path parts that
 467 aren't endpoints are using C<CaptureArgs> to specify how many parameters
 468 they expect to receive. As an example setup:
 469
 470   package MyApp::Controller::Greeting;
 471   use base qw/ Catalyst::Controller /;
 472
 473   #   this is the beginning of our chain
 474   sub hello : PathPart('hello') Chained('/') CaptureArgs(1) {
 475       my ( $self, $c, $integer ) = @_;
 476       $c->stash->{ message } = "Hello ";
 477       $c->stash->{ arg_sum } = $integer;
 478   }
 479
 480   #   this is our endpoint, because it has no :CaptureArgs
 481   sub world : PathPart('world') Chained('hello') Args(1) {
 482       my ( $self, $c, $integer ) = @_;
 483       $c->stash->{ message } .= "World!";
 484       $c->stash->{ arg_sum } += $integer;
 485
 486       $c->response->body( join "<br/>\n" =>
 487           $c->stash->{ message }, $c->stash->{ arg_sum } );
 488   }
 489
 490 The debug output provides a separate table for chained actions, showing
 491 the whole chain as it would match and the actions it contains. Here's an
 492 example of the startup output with our actions above:
 493
 494   ...
 495   [debug] Loaded Path Part actions:
 496   .-----------------------+------------------------------.
 497   | Path Spec             | Private                      |
 498   +-----------------------+------------------------------+
 499   | /hello/*/world/*      | /greeting/hello (1)          |
 500   |                       | => /greeting/world           |
 501   '-----------------------+------------------------------'
 502   ...
 503
 504 As you can see, Catalyst only deals with chains as whole paths and
 505 builds one for each endpoint, which are the actions with C<:Chained> but
 506 without C<:CaptureArgs>.
 507
 508 Let's assume this application gets a request at the path
 509 C</hello/23/world/12>. What happens then? First, Catalyst will dispatch
 510 to the C<hello> action and pass the value C<23> as an argument to it
 511 after the context. It does so because we have previously used
 512 C<:CaptureArgs(1)> to declare that it has one path part after itself as
 513 its argument. We told Catalyst that this is the beginning of the chain
 514 by specifying C<:Chained('/')>. Also note that instead of saying
 515 C<:PathPart('hello')> we could also just have said C<:PathPart>, as it
 516 defaults to the name of the action.
 517
 518 After C<hello> has run, Catalyst goes on to dispatch to the C<world>
 519 action. This is the last action to be called: Catalyst knows this is an
 520 endpoint because we did not specify a C<:CaptureArgs>
 521 attribute. Nevertheless we specify that this action expects an argument,
 522 but at this point we're using C<:Args(1)> to do that. We could also have
 523 said C<:Args> or left it out altogether, which would mean this action
 524 would get all arguments that are there. This action's C<:Chained>
 525 attribute says C<hello> and tells Catalyst that the C<hello> action in
 526 the current controller is its parent.
 527
 528 With this we have built a chain consisting of two public path parts.
 529 C<hello> captures one part of the path as its argument, and also
 530 specifies the path root as its parent. So this part is
 531 C</hello/$arg>. The next part is the endpoint C<world>, expecting one
 532 argument. It sums up to the path part C<world/$arg>. This leads to a
 533 complete chain of C</hello/$arg/world/$arg> which is matched against the
 534 requested paths.
 535
 536 This example application would, if run and called by e.g.
 537 C</hello/23/world/12>, set the stash value C<message> to "Hello" and the
 538 value C<arg_sum> to "23". The C<world> action would then append "World!"
 539 to C<message> and add C<12> to the stash's C<arg_sum> value.  For the
 540 sake of simplicity no view is shown. Instead we just put the values of
 541 the stash into our body. So the output would look like:
 542
 543   Hello World!
 544   35
 545
 546 And our test server would have given us this debugging output for the
 547 request:
 548
 549   ...
 550   [debug] "GET" request for "hello/23/world/12" from "127.0.0.1"
 551   [debug] Path is "/greeting/world"
 552   [debug] Arguments are "12"
 553   [info] Request took 0.164113s (6.093/s)
 554   .------------------------------------------+-----------.
 555   | Action                                   | Time      |
 556   +------------------------------------------+-----------+
 557   | /greeting/hello                          | 0.000029s |
 558   | /greeting/world                          | 0.000024s |
 559   '------------------------------------------+-----------'
 560   ...
 561
 562 What would be common uses of this dispatch technique? It gives the
 563 possibility to split up logic that contains steps that each depend on
 564 each other. An example would be, for example, a wiki path like
 565 C</wiki/FooBarPage/rev/23/view>. This chain can be easily built with
 566 these actions:
 567
 568   sub wiki : PathPart('wiki') Chained('/') CaptureArgs(1) {
 569       my ( $self, $c, $page_name ) = @_;
 570       #  load the page named $page_name and put the object
 571       #  into the stash
 572   }
 573
 574   sub rev : PathPart('rev') Chained('wiki') CaptureArgs(1) {
 575       my ( $self, $c, $revision_id ) = @_;
 576       #  use the page object in the stash to get at its
 577       #  revision with number $revision_id
 578   }
 579
 580   sub view : PathPart Chained('rev') Args(0) {
 581       my ( $self, $c ) = @_;
 582       #  display the revision in our stash. Another option
 583       #  would be to forward a compatible object to the action
 584       #  that displays the default wiki pages, unless we want
 585       #  a different interface here, for example restore
 586       #  functionality.
 587   }
 588
 589 It would now be possible to add other endpoints, for example C<restore>
 590 to restore this specific revision as the current state.
 591
 592 You don't have to put all the chained actions in one controller. The
 593 specification of the parent through C<:Chained> also takes an absolute
 594 action path as its argument. Just specify it with a leading C</>.
 595
 596 If you want, for example, to have actions for the public paths
 597 C</foo/12/edit> and C</foo/12>, just specify two actions with
 598 C<:PathPart('foo')> and C<:Chained('/')>. The handler for the former
 599 path needs a C<:CaptureArgs(1)> attribute and a endpoint with
 600 C<:PathPart('edit')> and C<:Chained('foo')>. For the latter path give
 601 the action just a C<:Args(1)> to mark it as endpoint. This sums up to
 602 this debugging output:
 603
 604   ...
 605   [debug] Loaded Path Part actions:
 606   .-----------------------+------------------------------.
 607   | Path Spec             | Private                      |
 608   +-----------------------+------------------------------+
 609   | /foo/*                | /controller/foo_view         |
 610   | /foo/*/edit           | /controller/foo_load (1)     |
 611   |                       | => /controller/edit          |
 612   '-----------------------+------------------------------'
 613   ...
 614
 615 Here's a more detailed specification of the attributes belonging to
 616 C<:Chained>:
 617
 618 =head2 Attributes
 619
 620 =over 8
 621
 622 =item PathPart
 623
 624 Sets the name of this part of the chain. If it is specified without
 625 arguments, it takes the name of the action as default. So basically
 626 C<sub foo :PathPart> and C<sub foo :PathPart('foo')> are identical.
 627 This can also contain slashes to bind to a deeper level. An action
 628 with C<sub bar :PathPart('foo/bar') :Chained('/')> would bind to
 629 C</foo/bar/...>. If you don't specify C<:PathPart> it has the same
 630 effect as using C<:PathPart>, it would default to the action name.
 631
 632 =item PathPrefix
 633
 634 Sets PathPart to the path_prefix of the current controller.
 635
 636 =item Chained
 637
 638 Has to be specified for every child in the chain. Possible values are
 639 absolute and relative private action paths or a single slash C</> to
 640 tell Catalyst that this is the root of a chain. The attribute
 641 C<:Chained> without arguments also defaults to the C</> behavior.
 642 Relative action paths may use C<../> to refer to actions in parent
 643 controllers.
 644
 645 Because you can specify an absolute path to the parent action, it
 646 doesn't matter to Catalyst where that parent is located. So, if your
 647 design requests it, you can redispatch a chain through any controller or
 648 namespace you want.
 649
 650 Another interesting possibility gives C<:Chained('.')>, which chains
 651 itself to an action with the path of the current controller's namespace.
 652 For example:
 653
 654   #   in MyApp::Controller::Foo
 655   sub bar : Chained CaptureArgs(1) { ... }
 656
 657   #   in MyApp::Controller::Foo::Bar
 658   sub baz : Chained('.') Args(1) { ... }
 659
 660 This builds up a chain like C</bar/*/baz/*>. The specification of C<.>
 661 as the argument to Chained here chains the C<baz> action to an action
 662 with the path of the current controller namespace, namely
 663 C</foo/bar>. That action chains directly to C</>, so the C</bar/*/baz/*>
 664 chain comes out as the end product.
 665
 666 =item ChainedParent
 667
 668 Chains an action to another action with the same name in the parent
 669 controller. For Example:
 670
 671   # in MyApp::Controller::Foo
 672   sub bar : Chained CaptureArgs(1) { ... }
 673
 674   # in MyApp::Controller::Foo::Moo
 675   sub bar : ChainedParent Args(1) { ... }
 676
 677 This builds a chain like C</bar/*/bar/*>.
 678
 679 =item CaptureArgs
 680
 681 Must be specified for every part of the chain that is not an
 682 endpoint. With this attribute Catalyst knows how many of the following
 683 parts of the path (separated by C</>) this action wants to capture as
 684 its arguments. If it doesn't expect any, just specify
 685 C<:CaptureArgs(0)>.  The captures get passed to the action's C<@_> right
 686 after the context, but you can also find them as array references in
 687 C<$c-E<gt>request-E<gt>captures-E<gt>[$level]>. The C<$level> is the
 688 level of the action in the chain that captured the parts of the path.
 689
 690 An action that is part of a chain (that is, one that has a C<:Chained>
 691 attribute) but has no C<:CaptureArgs> attribute is treated by Catalyst
 692 as a chain end.
 693
 694 Allowed values for CaptureArgs is a single integer (CaptureArgs(2), meaning two
 695 allowed) or you can declare a L<Moose>, L<MooseX::Types> or L<Type::Tiny>
 696 named constraint such as CaptureArgs(Int,Str) would require two args with
 697 the first being a Integer and the second a string.  You may declare your own
 698 custom type constraints and import them into the controller namespace:
 699
 700     package MyApp::Controller::Root;
 701
 702     use Moose;
 703     use MooseX::MethodAttributes;
 704     use MyApp::Types qw/Int/;
 705
 706     extends 'Catalyst::Controller';
 707
 708     sub chain_base :Chained(/) CaptureArgs(1) { }
 709
 710       sub any_priority_chain :Chained(chain_base) PathPart('') Args(1) { }
 711
 712       sub int_priority_chain :Chained(chain_base) PathPart('') Args(Int) { }
 713
 714 See L<Catalyst::RouteMatching> for more.
 715
 716 =item Args
 717
 718 By default, endpoints receive the rest of the arguments in the path. You
 719 can tell Catalyst through C<:Args> explicitly how many arguments your
 720 endpoint expects, just like you can with C<:CaptureArgs>. Note that this
 721 also affects whether this chain is invoked on a request. A chain with an
 722 endpoint specifying one argument will only match if exactly one argument
 723 exists in the path.
 724
 725 You can specify an exact number of arguments like C<:Args(3)>, including
 726 C<0>. If you just say C<:Args> without any arguments, it is the same as
 727 leaving it out altogether: The chain is matched regardless of the number
 728 of path parts after the endpoint.
 729
 730 Just as with C<:CaptureArgs>, the arguments get passed to the action in
 731 C<@_> after the context object. They can also be reached through
 732 C<$c-E<gt>request-E<gt>arguments>.
 733
 734 =back
 735
 736 =head2 Auto actions, dispatching and forwarding
 737
 738 Note that the list of C<auto> actions called depends on the private path
 739 of the endpoint of the chain, not on the chained actions way. The
 740 C<auto> actions will be run before the chain dispatching begins. In
 741 every other aspect, C<auto> actions behave as documented.
 742
 743 The C<forward>ing to other actions does just what you would expect. i.e.
 744 only the target action is run. The actions that that action is chained
 745 to are not run.
 746 If you C<detach> out of a chain, the rest of the chain will not get
 747 called after the C<detach>.
 748
 749 =head2 match_captures
 750
 751 A method which can optionally be implemented by actions to
 752 stop chain matching.
 753
 754 See L<Catalyst::Action> for further details.
 755
 756 =head1 AUTHORS
 757
 758 Catalyst Contributors, see Catalyst.pm
 759
 760 =head1 COPYRIGHT
 761
 762 This library is free software. You can redistribute it and/or modify it under
 763 the same terms as Perl itself.
 764
 765 =cut
 766
 767 1;