lib/Catalyst/DispatchType/Chained.pm

   1 package Catalyst::DispatchType::Chained;
   2
   3 use Moose;
   4 extends 'Catalyst::DispatchType';
   5
   6 use Text::SimpleTable;
   7 use Catalyst::ActionChain;
   8 use Catalyst::Utils;
   9 use URI;
  10 use Scalar::Util ();
  11
  12 has _endpoints => (
  13                    is => 'rw',
  14                    isa => 'ArrayRef',
  15                    required => 1,
  16                    default => sub{ [] },
  17                   );
  18
  19 has _actions => (
  20                  is => 'rw',
  21                  isa => 'HashRef',
  22                  required => 1,
  23                  default => sub{ {} },
  24                 );
  25
  26 has _children_of => (
  27                      is => 'rw',
  28                      isa => 'HashRef',
  29                      required => 1,
  30                      default => sub{ {} },
  31                     );
  32
  33 no Moose;
  34
  35 # please don't perltidy this. hairy code within.
  36
  37 =head1 NAME
  38
  39 Catalyst::DispatchType::Chained - Path Part DispatchType
  40
  41 =head1 SYNOPSIS
  42
  43 Path part matching, allowing several actions to sequentially take care of processing a request:
  44
  45   #   root action - captures one argument after it
  46   sub foo_setup : Chained('/') PathPart('foo') CaptureArgs(1) {
  47       my ( $self, $c, $foo_arg ) = @_;
  48       ...
  49   }
  50
  51   #   child action endpoint - takes one argument
  52   sub bar : Chained('foo_setup') Args(1) {
  53       my ( $self, $c, $bar_arg ) = @_;
  54       ...
  55   }
  56
  57 =head1 DESCRIPTION
  58
  59 Dispatch type managing default behaviour.  For more information on
  60 dispatch types, see:
  61
  62 =over 4
  63
  64 =item * L<Catalyst::Manual::Intro> for how they affect application authors
  65
  66 =item * L<Catalyst::DispatchType> for implementation information.
  67
  68 =back
  69
  70 =head1 METHODS
  71
  72 =head2 $self->list($c)
  73
  74 Debug output for Path Part dispatch points
  75
  76 =cut
  77
  78 sub list {
  79     my ( $self, $c ) = @_;
  80
  81     return unless $self->_endpoints;
  82
  83     my $avail_width = Catalyst::Utils::term_width() - 9;
  84     my $col1_width = ($avail_width * .50) < 35 ? 35 : int($avail_width * .50);
  85     my $col2_width = $avail_width - $col1_width;
  86     my $paths = Text::SimpleTable->new(
  87         [ $col1_width, 'Path Spec' ], [ $col2_width, 'Private' ],
  88     );
  89
  90     my $has_unattached_actions;
  91     my $unattached_actions = Text::SimpleTable->new(
  92         [ $col1_width, 'Private' ], [ $col2_width, 'Missing parent' ],
  93     );
  94
  95     ENDPOINT: foreach my $endpoint (
  96                   sort { $a->reverse cmp $b->reverse }
  97                            @{ $self->_endpoints }
  98                   ) {
  99         my $args = $endpoint->list_extra_info->{Args};
 100         my @parts = (defined($args) ? (("*") x $args) : '...');
 101         my @parents = ();
 102         my $parent = "DUMMY";
 103         my $extra  = $self->_list_extra_http_methods($endpoint);
 104         my $curr = $endpoint;
 105         while ($curr) {
 106             if (my $cap = $curr->list_extra_info->{CaptureArgs}) {
 107                 unshift(@parts, (("*") x $cap));
 108             }
 109             if (my $pp = $curr->attributes->{PathPart}) {
 110                 unshift(@parts, $pp->[0])
 111                     if (defined $pp->[0] && length $pp->[0]);
 112             }
 113             $parent = $curr->attributes->{Chained}->[0];
 114             $curr = $self->_actions->{$parent};
 115             unshift(@parents, $curr) if $curr;
 116         }
 117         if ($parent ne '/') {
 118             $has_unattached_actions = 1;
 119             $unattached_actions->row('/' . ($parents[0] || $endpoint)->reverse, $parent);
 120             next ENDPOINT;
 121         }
 122         my @rows;
 123         foreach my $p (@parents) {
 124             my $name = "/${p}";
 125
 126             if (defined(my $extra = $self->_list_extra_http_methods($p))) {
 127                 $name = "${extra} ${name}";
 128             }
 129             if (defined(my $cap = $p->list_extra_info->{CaptureArgs})) {
 130                 $name .= ' ('.$cap.')';
 131             }
 132             unless ($p eq $parents[0]) {
 133                 $name = "-> ${name}";
 134             }
 135             push(@rows, [ '', $name ]);
 136         }
 137         push(@rows, [ '', (@rows ? "=> " : '').($extra ? "$extra " : '')."/${endpoint}" ]);
 138         $rows[0][0] = join('/', '', @parts) || '/';
 139         $paths->row(@$_) for @rows;
 140     }
 141
 142     $c->log->debug( "Loaded Chained actions:\n" . $paths->draw . "\n" );
 143     $c->log->debug( "Unattached Chained actions:\n", $unattached_actions->draw . "\n" )
 144         if $has_unattached_actions;
 145 }
 146
 147 sub _list_extra_http_methods {
 148     my ( $self, $action ) = @_;
 149     return unless defined $action->list_extra_info->{HTTP_METHODS};
 150     return join(', ', @{$action->list_extra_info->{HTTP_METHODS}});
 151 }
 152
 153 =head2 $self->match( $c, $path )
 154
 155 Calls C<recurse_match> to see if a chain matches the C<$path>.
 156
 157 =cut
 158
 159 sub match {
 160     my ( $self, $c, $path ) = @_;
 161
 162     my $request = $c->request;
 163     return 0 if @{$request->args};
 164
 165     my @parts = split('/', $path);
 166
 167     my ($chain, $captures, $parts) = $self->recurse_match($c, '/', \@parts);
 168
 169     if ($parts && @$parts) {
 170         for my $arg (@$parts) {
 171             $arg =~ s/%([0-9A-Fa-f]{2})/chr(hex($1))/eg;
 172             push @{$request->args}, $arg;
 173         }
 174     }
 175
 176     return 0 unless $chain;
 177
 178     my $action = Catalyst::ActionChain->from_chain($chain);
 179
 180     $request->action("/${action}");
 181     $request->match("/${action}");
 182     $request->captures($captures);
 183     $c->action($action);
 184     $c->namespace( $action->namespace );
 185
 186     return 1;
 187 }
 188
 189 =head2 $self->recurse_match( $c, $parent, \@path_parts )
 190
 191 Recursive search for a matching chain.
 192
 193 =cut
 194
 195 sub recurse_match {
 196     my ( $self, $c, $parent, $path_parts ) = @_;
 197     my $children = $self->_children_of->{$parent};
 198     return () unless $children;
 199     my $best_action;
 200     my @captures;
 201     TRY: foreach my $try_part (sort { length($b) <=> length($a) }
 202                                    keys %$children) {
 203                                # $b then $a to try longest part first
 204         my @parts = @$path_parts;
 205         if (length $try_part) { # test and strip PathPart
 206             next TRY unless
 207               ($try_part eq join('/', # assemble equal number of parts
 208                               splice( # and strip them off @parts as well
 209                                 @parts, 0, scalar(@{[split('/', $try_part)]})
 210                               ))); # @{[]} to avoid split to @_
 211         }
 212         my @try_actions = @{$children->{$try_part}};
 213         TRY_ACTION: foreach my $action (@try_actions) {
 214             if (my $capture_attr = $action->attributes->{CaptureArgs}) {
 215                 my $capture_count = $capture_attr->[0] || 0;
 216
 217                 # Short-circuit if not enough remaining parts
 218                 next TRY_ACTION unless @parts >= $capture_count;
 219
 220                 my @captures;
 221                 my @parts = @parts; # localise
 222
 223                 # strip CaptureArgs into list
 224                 push(@captures, splice(@parts, 0, $capture_count));
 225
 226                 # check if the action may fit, depending on a given test by the app
 227                 if ($action->can('match_captures')) { next TRY_ACTION unless $action->match_captures($c, \@captures) }
 228
 229                 # try the remaining parts against children of this action
 230                 my ($actions, $captures, $action_parts, $n_pathparts) = $self->recurse_match(
 231                                              $c, '/'.$action->reverse, \@parts
 232                                            );
 233                 #    No best action currently
 234                 # OR The action has less parts
 235                 # OR The action has equal parts but less captured data (ergo more defined)
 236                 if ($actions    &&
 237                     (!$best_action                                 ||
 238                      $#$action_parts < $#{$best_action->{parts}}   ||
 239                      ($#$action_parts == $#{$best_action->{parts}} &&
 240                       $#$captures < $#{$best_action->{captures}} &&
 241                       $n_pathparts > $best_action->{n_pathparts}))) {
 242                     my @pathparts = split /\//, $action->attributes->{PathPart}->[0];
 243                     $best_action = {
 244                         actions => [ $action, @$actions ],
 245                         captures=> [ @captures, @$captures ],
 246                         parts   => $action_parts,
 247                         n_pathparts => scalar(@pathparts) + $n_pathparts,
 248                     };
 249                 }
 250             }
 251             else {
 252                 {
 253                     local $c->req->{arguments} = [ @{$c->req->args}, @parts ];
 254                     next TRY_ACTION unless $action->match($c);
 255                 }
 256                 my $args_attr = $action->attributes->{Args}->[0];
 257                 my @pathparts = split /\//, $action->attributes->{PathPart}->[0];
 258                 #    No best action currently
 259                 # OR This one matches with fewer parts left than the current best action,
 260                 #    And therefore is a better match
 261                 # OR No parts and this expects 0
 262                 #    The current best action might also be Args(0),
 263                 #    but we couldn't chose between then anyway so we'll take the last seen
 264
 265                 if (!$best_action                       ||
 266                     @parts < @{$best_action->{parts}}   ||
 267                     (!@parts && defined($args_attr) && $args_attr eq "0")){
 268                     $best_action = {
 269                         actions => [ $action ],
 270                         captures=> [],
 271                         parts   => \@parts,
 272                         n_pathparts => scalar(@pathparts),
 273                     };
 274                 }
 275             }
 276         }
 277     }
 278     return @$best_action{qw/actions captures parts n_pathparts/} if $best_action;
 279     return ();
 280 }
 281
 282 =head2 $self->register( $c, $action )
 283
 284 Calls register_path for every Path attribute for the given $action.
 285
 286 =cut
 287
 288 sub _check_args_attr {
 289     my ( $self, $action, $name ) = @_;
 290
 291     return unless exists $action->attributes->{$name};
 292
 293     if (@{$action->attributes->{$name}} > 1) {
 294         Catalyst::Exception->throw(
 295           "Multiple $name attributes not supported registering " . $action->reverse()
 296         );
 297     }
 298     my $args = $action->attributes->{$name}->[0];
 299     if (defined($args) and not (
 300         Scalar::Util::looks_like_number($args) and
 301         int($args) == $args
 302     )) {
 303         require Data::Dumper;
 304         local $Data::Dumper::Terse = 1;
 305         local $Data::Dumper::Indent = 0;
 306         $args = Data::Dumper::Dumper($args);
 307         Catalyst::Exception->throw(
 308           "Invalid $name($args) for action " . $action->reverse() .
 309           " (use '$name' or '$name(<number>)')"
 310         );
 311     }
 312 }
 313
 314 sub register {
 315     my ( $self, $c, $action ) = @_;
 316
 317     my @chained_attr = @{ $action->attributes->{Chained} || [] };
 318
 319     return 0 unless @chained_attr;
 320
 321     if (@chained_attr > 1) {
 322         Catalyst::Exception->throw(
 323           "Multiple Chained attributes not supported registering ${action}"
 324         );
 325     }
 326     my $chained_to = $chained_attr[0];
 327
 328     Catalyst::Exception->throw(
 329       "Actions cannot chain to themselves registering /${action}"
 330     ) if ($chained_to eq '/' . $action);
 331
 332     my $children = ($self->_children_of->{ $chained_to } ||= {});
 333
 334     my @path_part = @{ $action->attributes->{PathPart} || [] };
 335
 336     my $part = $action->name;
 337
 338     if (@path_part == 1 && defined $path_part[0]) {
 339         $part = $path_part[0];
 340     } elsif (@path_part > 1) {
 341         Catalyst::Exception->throw(
 342           "Multiple PathPart attributes not supported registering " . $action->reverse()
 343         );
 344     }
 345
 346     if ($part =~ m(^/)) {
 347         Catalyst::Exception->throw(
 348           "Absolute parameters to PathPart not allowed registering " . $action->reverse()
 349         );
 350     }
 351
 352     $action->attributes->{PathPart} = [ $part ];
 353
 354     unshift(@{ $children->{$part} ||= [] }, $action);
 355
 356     $self->_actions->{'/'.$action->reverse} = $action;
 357
 358     foreach my $name (qw(Args CaptureArgs)) {
 359         $self->_check_args_attr($action, $name);
 360     }
 361
 362     if (exists $action->attributes->{Args} and exists $action->attributes->{CaptureArgs}) {
 363         Catalyst::Exception->throw(
 364           "Combining Args and CaptureArgs not allowed registering " . $action->reverse()
 365         );
 366     }
 367
 368     unless ($action->attributes->{CaptureArgs}) {
 369         unshift(@{ $self->_endpoints }, $action);
 370     }
 371
 372     return 1;
 373 }
 374
 375 =head2 $self->uri_for_action($action, $captures)
 376
 377 Get the URI part for the action, using C<$captures> to fill
 378 the capturing parts.
 379
 380 =cut
 381
 382 sub uri_for_action {
 383     my ( $self, $action, $captures ) = @_;
 384
 385     return undef unless ($action->attributes->{Chained}
 386                            && !$action->attributes->{CaptureArgs});
 387
 388     my @parts = ();
 389     my @captures = @$captures;
 390     my $parent = "DUMMY";
 391     my $curr = $action;
 392     while ($curr) {
 393         if (my $cap = $curr->attributes->{CaptureArgs}) {
 394             return undef unless @captures >= ($cap->[0]||0); # not enough captures
 395             if ($cap->[0]) {
 396                 unshift(@parts, splice(@captures, -$cap->[0]));
 397             }
 398         }
 399         if (my $pp = $curr->attributes->{PathPart}) {
 400             unshift(@parts, $pp->[0])
 401                 if (defined($pp->[0]) && length($pp->[0]));
 402         }
 403         $parent = $curr->attributes->{Chained}->[0];
 404         $curr = $self->_actions->{$parent};
 405     }
 406
 407     return undef unless $parent eq '/'; # fail for dangling action
 408
 409     return undef if @captures; # fail for too many captures
 410
 411     return join('/', '', @parts);
 412
 413 }
 414
 415 =head2 $c->expand_action($action)
 416
 417 Return a list of actions that represents a chained action. See
 418 L<Catalyst::Dispatcher> for more info. You probably want to
 419 use the expand_action it provides rather than this directly.
 420
 421 =cut
 422
 423 sub expand_action {
 424     my ($self, $action) = @_;
 425
 426     return unless $action->attributes && $action->attributes->{Chained};
 427
 428     my @chain;
 429     my $curr = $action;
 430
 431     while ($curr) {
 432         push @chain, $curr;
 433         my $parent = $curr->attributes->{Chained}->[0];
 434         $curr = $self->_actions->{$parent};
 435     }
 436
 437     return Catalyst::ActionChain->from_chain([reverse @chain]);
 438 }
 439
 440 __PACKAGE__->meta->make_immutable;
 441 1;
 442
 443 =head1 USAGE
 444
 445 =head2 Introduction
 446
 447 The C<Chained> attribute allows you to chain public path parts together
 448 by their private names. A chain part's path can be specified with
 449 C<PathPart> and can be declared to expect an arbitrary number of
 450 arguments. The endpoint of the chain specifies how many arguments it
 451 gets through the C<Args> attribute. C<:Args(0)> would be none at all,
 452 C<:Args> without an integer would be unlimited. The path parts that
 453 aren't endpoints are using C<CaptureArgs> to specify how many parameters
 454 they expect to receive. As an example setup:
 455
 456   package MyApp::Controller::Greeting;
 457   use base qw/ Catalyst::Controller /;
 458
 459   #   this is the beginning of our chain
 460   sub hello : PathPart('hello') Chained('/') CaptureArgs(1) {
 461       my ( $self, $c, $integer ) = @_;
 462       $c->stash->{ message } = "Hello ";
 463       $c->stash->{ arg_sum } = $integer;
 464   }
 465
 466   #   this is our endpoint, because it has no :CaptureArgs
 467   sub world : PathPart('world') Chained('hello') Args(1) {
 468       my ( $self, $c, $integer ) = @_;
 469       $c->stash->{ message } .= "World!";
 470       $c->stash->{ arg_sum } += $integer;
 471
 472       $c->response->body( join "<br/>\n" =>
 473           $c->stash->{ message }, $c->stash->{ arg_sum } );
 474   }
 475
 476 The debug output provides a separate table for chained actions, showing
 477 the whole chain as it would match and the actions it contains. Here's an
 478 example of the startup output with our actions above:
 479
 480   ...
 481   [debug] Loaded Path Part actions:
 482   .-----------------------+------------------------------.
 483   | Path Spec             | Private                      |
 484   +-----------------------+------------------------------+
 485   | /hello/*/world/*      | /greeting/hello (1)          |
 486   |                       | => /greeting/world           |
 487   '-----------------------+------------------------------'
 488   ...
 489
 490 As you can see, Catalyst only deals with chains as whole paths and
 491 builds one for each endpoint, which are the actions with C<:Chained> but
 492 without C<:CaptureArgs>.
 493
 494 Let's assume this application gets a request at the path
 495 C</hello/23/world/12>. What happens then? First, Catalyst will dispatch
 496 to the C<hello> action and pass the value C<23> as an argument to it
 497 after the context. It does so because we have previously used
 498 C<:CaptureArgs(1)> to declare that it has one path part after itself as
 499 its argument. We told Catalyst that this is the beginning of the chain
 500 by specifying C<:Chained('/')>. Also note that instead of saying
 501 C<:PathPart('hello')> we could also just have said C<:PathPart>, as it
 502 defaults to the name of the action.
 503
 504 After C<hello> has run, Catalyst goes on to dispatch to the C<world>
 505 action. This is the last action to be called: Catalyst knows this is an
 506 endpoint because we did not specify a C<:CaptureArgs>
 507 attribute. Nevertheless we specify that this action expects an argument,
 508 but at this point we're using C<:Args(1)> to do that. We could also have
 509 said C<:Args> or left it out altogether, which would mean this action
 510 would get all arguments that are there. This action's C<:Chained>
 511 attribute says C<hello> and tells Catalyst that the C<hello> action in
 512 the current controller is its parent.
 513
 514 With this we have built a chain consisting of two public path parts.
 515 C<hello> captures one part of the path as its argument, and also
 516 specifies the path root as its parent. So this part is
 517 C</hello/$arg>. The next part is the endpoint C<world>, expecting one
 518 argument. It sums up to the path part C<world/$arg>. This leads to a
 519 complete chain of C</hello/$arg/world/$arg> which is matched against the
 520 requested paths.
 521
 522 This example application would, if run and called by e.g.
 523 C</hello/23/world/12>, set the stash value C<message> to "Hello" and the
 524 value C<arg_sum> to "23". The C<world> action would then append "World!"
 525 to C<message> and add C<12> to the stash's C<arg_sum> value.  For the
 526 sake of simplicity no view is shown. Instead we just put the values of
 527 the stash into our body. So the output would look like:
 528
 529   Hello World!
 530   35
 531
 532 And our test server would have given us this debugging output for the
 533 request:
 534
 535   ...
 536   [debug] "GET" request for "hello/23/world/12" from "127.0.0.1"
 537   [debug] Path is "/greeting/world"
 538   [debug] Arguments are "12"
 539   [info] Request took 0.164113s (6.093/s)
 540   .------------------------------------------+-----------.
 541   | Action                                   | Time      |
 542   +------------------------------------------+-----------+
 543   | /greeting/hello                          | 0.000029s |
 544   | /greeting/world                          | 0.000024s |
 545   '------------------------------------------+-----------'
 546   ...
 547
 548 What would be common uses of this dispatch technique? It gives the
 549 possibility to split up logic that contains steps that each depend on
 550 each other. An example would be, for example, a wiki path like
 551 C</wiki/FooBarPage/rev/23/view>. This chain can be easily built with
 552 these actions:
 553
 554   sub wiki : PathPart('wiki') Chained('/') CaptureArgs(1) {
 555       my ( $self, $c, $page_name ) = @_;
 556       #  load the page named $page_name and put the object
 557       #  into the stash
 558   }
 559
 560   sub rev : PathPart('rev') Chained('wiki') CaptureArgs(1) {
 561       my ( $self, $c, $revision_id ) = @_;
 562       #  use the page object in the stash to get at its
 563       #  revision with number $revision_id
 564   }
 565
 566   sub view : PathPart Chained('rev') Args(0) {
 567       my ( $self, $c ) = @_;
 568       #  display the revision in our stash. Another option
 569       #  would be to forward a compatible object to the action
 570       #  that displays the default wiki pages, unless we want
 571       #  a different interface here, for example restore
 572       #  functionality.
 573   }
 574
 575 It would now be possible to add other endpoints, for example C<restore>
 576 to restore this specific revision as the current state.
 577
 578 You don't have to put all the chained actions in one controller. The
 579 specification of the parent through C<:Chained> also takes an absolute
 580 action path as its argument. Just specify it with a leading C</>.
 581
 582 If you want, for example, to have actions for the public paths
 583 C</foo/12/edit> and C</foo/12>, just specify two actions with
 584 C<:PathPart('foo')> and C<:Chained('/')>. The handler for the former
 585 path needs a C<:CaptureArgs(1)> attribute and a endpoint with
 586 C<:PathPart('edit')> and C<:Chained('foo')>. For the latter path give
 587 the action just a C<:Args(1)> to mark it as endpoint. This sums up to
 588 this debugging output:
 589
 590   ...
 591   [debug] Loaded Path Part actions:
 592   .-----------------------+------------------------------.
 593   | Path Spec             | Private                      |
 594   +-----------------------+------------------------------+
 595   | /foo/*                | /controller/foo_view         |
 596   | /foo/*/edit           | /controller/foo_load (1)     |
 597   |                       | => /controller/edit          |
 598   '-----------------------+------------------------------'
 599   ...
 600
 601 Here's a more detailed specification of the attributes belonging to
 602 C<:Chained>:
 603
 604 =head2 Attributes
 605
 606 =over 8
 607
 608 =item PathPart
 609
 610 Sets the name of this part of the chain. If it is specified without
 611 arguments, it takes the name of the action as default. So basically
 612 C<sub foo :PathPart> and C<sub foo :PathPart('foo')> are identical.
 613 This can also contain slashes to bind to a deeper level. An action
 614 with C<sub bar :PathPart('foo/bar') :Chained('/')> would bind to
 615 C</foo/bar/...>. If you don't specify C<:PathPart> it has the same
 616 effect as using C<:PathPart>, it would default to the action name.
 617
 618 =item PathPrefix
 619
 620 Sets PathPart to the path_prefix of the current controller.
 621
 622 =item Chained
 623
 624 Has to be specified for every child in the chain. Possible values are
 625 absolute and relative private action paths or a single slash C</> to
 626 tell Catalyst that this is the root of a chain. The attribute
 627 C<:Chained> without arguments also defaults to the C</> behavior.
 628 Relative action paths may use C<../> to refer to actions in parent
 629 controllers.
 630
 631 Because you can specify an absolute path to the parent action, it
 632 doesn't matter to Catalyst where that parent is located. So, if your
 633 design requests it, you can redispatch a chain through any controller or
 634 namespace you want.
 635
 636 Another interesting possibility gives C<:Chained('.')>, which chains
 637 itself to an action with the path of the current controller's namespace.
 638 For example:
 639
 640   #   in MyApp::Controller::Foo
 641   sub bar : Chained CaptureArgs(1) { ... }
 642
 643   #   in MyApp::Controller::Foo::Bar
 644   sub baz : Chained('.') Args(1) { ... }
 645
 646 This builds up a chain like C</bar/*/baz/*>. The specification of C<.>
 647 as the argument to Chained here chains the C<baz> action to an action
 648 with the path of the current controller namespace, namely
 649 C</foo/bar>. That action chains directly to C</>, so the C</bar/*/baz/*>
 650 chain comes out as the end product.
 651
 652 =item ChainedParent
 653
 654 Chains an action to another action with the same name in the parent
 655 controller. For Example:
 656
 657   # in MyApp::Controller::Foo
 658   sub bar : Chained CaptureArgs(1) { ... }
 659
 660   # in MyApp::Controller::Foo::Moo
 661   sub bar : ChainedParent Args(1) { ... }
 662
 663 This builds a chain like C</bar/*/bar/*>.
 664
 665 =item CaptureArgs
 666
 667 Must be specified for every part of the chain that is not an
 668 endpoint. With this attribute Catalyst knows how many of the following
 669 parts of the path (separated by C</>) this action wants to capture as
 670 its arguments. If it doesn't expect any, just specify
 671 C<:CaptureArgs(0)>.  The captures get passed to the action's C<@_> right
 672 after the context, but you can also find them as array references in
 673 C<$c-E<gt>request-E<gt>captures-E<gt>[$level]>. The C<$level> is the
 674 level of the action in the chain that captured the parts of the path.
 675
 676 An action that is part of a chain (that is, one that has a C<:Chained>
 677 attribute) but has no C<:CaptureArgs> attribute is treated by Catalyst
 678 as a chain end.
 679
 680 =item Args
 681
 682 By default, endpoints receive the rest of the arguments in the path. You
 683 can tell Catalyst through C<:Args> explicitly how many arguments your
 684 endpoint expects, just like you can with C<:CaptureArgs>. Note that this
 685 also affects whether this chain is invoked on a request. A chain with an
 686 endpoint specifying one argument will only match if exactly one argument
 687 exists in the path.
 688
 689 You can specify an exact number of arguments like C<:Args(3)>, including
 690 C<0>. If you just say C<:Args> without any arguments, it is the same as
 691 leaving it out altogether: The chain is matched regardless of the number
 692 of path parts after the endpoint.
 693
 694 Just as with C<:CaptureArgs>, the arguments get passed to the action in
 695 C<@_> after the context object. They can also be reached through
 696 C<$c-E<gt>request-E<gt>arguments>.
 697
 698 =back
 699
 700 =head2 Auto actions, dispatching and forwarding
 701
 702 Note that the list of C<auto> actions called depends on the private path
 703 of the endpoint of the chain, not on the chained actions way. The
 704 C<auto> actions will be run before the chain dispatching begins. In
 705 every other aspect, C<auto> actions behave as documented.
 706
 707 The C<forward>ing to other actions does just what you would expect. i.e.
 708 only the target action is run. The actions that that action is chained
 709 to are not run.
 710 If you C<detach> out of a chain, the rest of the chain will not get
 711 called after the C<detach>.
 712
 713 =head2 match_captures
 714
 715 A method which can optionally be implemented by actions to
 716 stop chain matching.
 717
 718 See L<Catalyst::Action> for further details.
 719
 720 =head1 AUTHORS
 721
 722 Catalyst Contributors, see Catalyst.pm
 723
 724 =head1 COPYRIGHT
 725
 726 This library is free software. You can redistribute it and/or modify it under
 727 the same terms as Perl itself.
 728
 729 =cut
 730
 731 1;