lib/Catalyst/DispatchType/Chained.pm

   1 package Catalyst::DispatchType::Chained;
   2
   3 use strict;
   4 use base qw/Catalyst::DispatchType/;
   5 use Text::SimpleTable;
   6 use Catalyst::ActionChain;
   7 use URI;
   8
   9 # please don't perltidy this. hairy code within.
  10
  11 =head1 NAME
  12
  13 Catalyst::DispatchType::Chained - Path Part DispatchType
  14
  15 =head1 SYNOPSIS
  16
  17   #   root action - captures one argument after it
  18   sub foo_setup : Chained('/') PathPart('foo') CaptureArgs(1) {
  19       my ( $self, $c, $foo_arg ) = @_;
  20       ...
  21   }
  22
  23   #   child action endpoint - takes one argument
  24   sub bar : Chained('foo_setup') Args(1) {
  25       my ( $self, $c, $bar_arg ) = @_;
  26       ...
  27   }
  28
  29 =head1 DESCRIPTION
  30
  31 See L</USAGE>.
  32
  33 =head1 METHODS
  34
  35 =head2 $self->list($c)
  36
  37 Debug output for Path Part dispatch points
  38
  39 =cut
  40
  41 sub list {
  42     my ( $self, $c ) = @_;
  43
  44     return unless $self->{endpoints};
  45
  46     my $paths = Text::SimpleTable->new(
  47                     [ 35, 'Path Spec' ], [ 36, 'Private' ]
  48                 );
  49
  50     ENDPOINT: foreach my $endpoint (
  51                   sort { $a->reverse cmp $b->reverse }
  52                            @{ $self->{endpoints} }
  53                   ) {
  54         my $args = $endpoint->attributes->{Args}->[0];
  55         my @parts = (defined($args) ? (("*") x $args) : '...');
  56         my @parents = ();
  57         my $parent = "DUMMY";
  58         my $curr = $endpoint;
  59         while ($curr) {
  60             if (my $cap = $curr->attributes->{CaptureArgs}) {
  61                 unshift(@parts, (("*") x $cap->[0]));
  62             }
  63             if (my $pp = $curr->attributes->{PartPath}) {
  64                 unshift(@parts, $pp->[0])
  65                     if (defined $pp->[0] && length $pp->[0]);
  66             }
  67             $parent = $curr->attributes->{Chained}->[0];
  68             $curr = $self->{actions}{$parent};
  69             unshift(@parents, $curr) if $curr;
  70         }
  71         next ENDPOINT unless $parent eq '/'; # skip dangling action
  72         my @rows;
  73         foreach my $p (@parents) {
  74             my $name = "/${p}";
  75             if (my $cap = $p->attributes->{CaptureArgs}) {
  76                 $name .= ' ('.$cap->[0].')';
  77             }
  78             unless ($p eq $parents[0]) {
  79                 $name = "-> ${name}";
  80             }
  81             push(@rows, [ '', $name ]);
  82         }
  83         push(@rows, [ '', (@rows ? "=> " : '')."/${endpoint}" ]);
  84         $rows[0][0] = join('/', '', @parts);
  85         $paths->row(@$_) for @rows;
  86     }
  87
  88     $c->log->debug( "Loaded Path Part actions:\n" . $paths->draw );
  89 }
  90
  91 =head2 $self->match( $c, $path )
  92
  93 Calls C<recurse_match> to see if a chain matches the C<$path>.
  94
  95 =cut
  96
  97 sub match {
  98     my ( $self, $c, $path ) = @_;
  99
 100     return 0 if @{$c->req->args};
 101
 102     my @parts = split('/', $path);
 103
 104     my ($chain, $captures) = $self->recurse_match($c, '/', \@parts);
 105
 106     return 0 unless $chain;
 107
 108     my $action = Catalyst::ActionChain->from_chain($chain);
 109
 110     $c->req->action("/${action}");
 111     $c->req->match("/${action}");
 112     $c->req->captures($captures);
 113     $c->action($action);
 114     $c->namespace( $action->namespace );
 115
 116     return 1;
 117 }
 118
 119 =head2 $self->recurse_match( $c, $parent, \@path_parts )
 120
 121 Recursive search for a matching chain.
 122
 123 =cut
 124
 125 sub recurse_match {
 126     my ( $self, $c, $parent, $path_parts ) = @_;
 127     my $children = $self->{children_of}{$parent};
 128     return () unless $children;
 129     my @captures;
 130     TRY: foreach my $try_part (sort { length($b) <=> length($a) }
 131                                    keys %$children) {
 132                                # $b then $a to try longest part first
 133         my @parts = @$path_parts;
 134         if (length $try_part) { # test and strip PathPart
 135             next TRY unless
 136               ($try_part eq join('/', # assemble equal number of parts
 137                               splice( # and strip them off @parts as well
 138                                 @parts, 0, scalar(@{[split('/', $try_part)]})
 139                               ))); # @{[]} to avoid split to @_
 140         }
 141         my @try_actions = @{$children->{$try_part}};
 142         TRY_ACTION: foreach my $action (@try_actions) {
 143             if (my $capture_attr = $action->attributes->{CaptureArgs}) {
 144                 my @captures;
 145                 my @parts = @parts; # localise
 146
 147                 # strip CaptureArgs into list
 148                 push(@captures, splice(@parts, 0, $capture_attr->[0]));
 149
 150                 # try the remaining parts against children of this action
 151                 my ($actions, $captures) = $self->recurse_match(
 152                                              $c, '/'.$action->reverse, \@parts
 153                                            );
 154                 if ($actions) {
 155                     return [ $action, @$actions ], [ @captures, @$captures ];
 156                 }
 157             } else {
 158                 {
 159                     local $c->req->{arguments} = [ @{$c->req->args}, @parts ];
 160                     next TRY_ACTION unless $action->match($c);
 161                 }
 162                 push(@{$c->req->args}, @parts);
 163                 return [ $action ], [ ];
 164             }
 165         }
 166     }
 167     return ();
 168 }
 169
 170 =head2 $self->register( $c, $action )
 171
 172 Calls register_path for every Path attribute for the given $action.
 173
 174 =cut
 175
 176 sub register {
 177     my ( $self, $c, $action ) = @_;
 178
 179     my @chained_attr = @{ $action->attributes->{Chained} || [] };
 180
 181     return 0 unless @chained_attr;
 182
 183     if (@chained_attr > 2) {
 184         Catalyst::Exception->throw(
 185           "Multiple Chained attributes not supported registering ${action}"
 186         );
 187     }
 188
 189     my $parent = $chained_attr[0];
 190
 191     if (defined($parent) && length($parent)) {
 192         if ($parent eq '.') {
 193             $parent = '/'.$action->namespace;
 194         } elsif ($parent !~ m/^\//) {
 195             if ($action->namespace) {
 196                 $parent = '/'.join('/', $action->namespace, $parent);
 197             } else {
 198                 $parent = '/'.$parent; # special case namespace '' (root)
 199             }
 200         }
 201     } else {
 202         $parent = '/'
 203     }
 204
 205     $action->attributes->{Chained} = [ $parent ];
 206
 207     my $children = ($self->{children_of}{$parent} ||= {});
 208
 209     my @path_part = @{ $action->attributes->{PathPart} || [] };
 210
 211     my $part = $action->name;
 212
 213     if (@path_part == 1 && defined $path_part[0]) {
 214         $part = $path_part[0];
 215     } elsif (@path_part > 1) {
 216         Catalyst::Exception->throw(
 217           "Multiple PathPart attributes not supported registering ${action}"
 218         );
 219     }
 220
 221     if ($part =~ m(^/)) {
 222         Catalyst::Exception->throw(
 223           "Absolute parameters to PathPart not allowed registering ${action}"
 224         );
 225     }
 226
 227     $action->attributes->{PartPath} = [ $part ];
 228
 229     unshift(@{ $children->{$part} ||= [] }, $action);
 230
 231     ($self->{actions} ||= {})->{'/'.$action->reverse} = $action;
 232
 233     unless ($action->attributes->{CaptureArgs}) {
 234         unshift(@{ $self->{endpoints} ||= [] }, $action);
 235     }
 236
 237     return 1;
 238 }
 239
 240 =head2 $self->uri_for_action($action, $captures)
 241
 242 Get the URI part for the action, using C<$captures> to fill
 243 the capturing parts.
 244
 245 =cut
 246
 247 sub uri_for_action {
 248     my ( $self, $action, $captures ) = @_;
 249
 250     return undef unless ($action->attributes->{Chained}
 251                            && !$action->attributes->{CaptureArgs});
 252
 253     my @parts = ();
 254     my @captures = @$captures;
 255     my $parent = "DUMMY";
 256     my $curr = $action;
 257     while ($curr) {
 258         if (my $cap = $curr->attributes->{CaptureArgs}) {
 259             return undef unless @captures >= $cap->[0]; # not enough captures
 260             if ($cap->[0]) {
 261                 unshift(@parts, splice(@captures, -$cap->[0]));
 262             }
 263         }
 264         if (my $pp = $curr->attributes->{PartPath}) {
 265             unshift(@parts, $pp->[0])
 266                 if (defined($pp->[0]) && length($pp->[0]));
 267         }
 268         $parent = $curr->attributes->{Chained}->[0];
 269         $curr = $self->{actions}{$parent};
 270     }
 271
 272     return undef unless $parent eq '/'; # fail for dangling action
 273
 274     return undef if @captures; # fail for too many captures
 275
 276     return join('/', '', @parts);
 277
 278 }
 279
 280 =head1 USAGE
 281
 282 =head2 Introduction
 283
 284 The C<Chained> attribute allows you to chain public path parts together
 285 by their private names. A chain part's path can be specified with
 286 C<PathPart> and can be declared to expect an arbitrary number of
 287 arguments. The endpoint of the chain specifies how many arguments it
 288 gets through the C<Args> attribute. C<:Args(0)> would be none at all,
 289 C<:Args> without an integer would be unlimited. The path parts that
 290 aren't endpoints are using C<CaptureArgs> to specify how many parameters
 291 they expect to receive. As an example setup:
 292
 293   package MyApp::Controller::Greeting;
 294   use base qw/ Catalyst::Controller /;
 295
 296   #   this is the beginning of our chain
 297   sub hello : PathPart('hello') Chained('/') CaptureArgs(1) {
 298       my ( $self, $c, $integer ) = @_;
 299       $c->stash->{ message } = "Hello ";
 300       $c->stash->{ arg_sum } = $integer;
 301   }
 302
 303   #   this is our endpoint, because it has no :CaptureArgs
 304   sub world : PathPart('world') Chained('hello') Args(1) {
 305       my ( $self, $c, $integer ) = @_;
 306       $c->stash->{ message } .= "World!";
 307       $c->stash->{ arg_sum } += $integer;
 308
 309       $c->response->body( join "<br/>\n" =>
 310           $c->stash->{ message }, $c->stash->{ arg_sum } );
 311   }
 312
 313 The debug output provides a separate table for chained actions, showing
 314 the whole chain as it would match and the actions it contains. Here's an
 315 example of the startup output with our actions above:
 316
 317   ...
 318   [debug] Loaded Path Part actions:
 319   .-----------------------+------------------------------.
 320   | Path Spec             | Private                      |
 321   +-----------------------+------------------------------+
 322   | /hello/*/world/*      | /greeting/hello (1)          |
 323   |                       | => /greeting/world           |
 324   '-----------------------+------------------------------'
 325   ...
 326
 327 As you can see, Catalyst only deals with chains as whole paths and
 328 builds one for each endpoint, which are the actions with C<:Chained> but
 329 without C<:CaptureArgs>.
 330
 331 Let's assume this application gets a request at the path
 332 C</hello/23/world/12>. What happens then? First, Catalyst will dispatch
 333 to the C<hello> action and pass the value C<23> as an argument to it
 334 after the context. It does so because we have previously used
 335 C<:CaptureArgs(1)> to declare that it has one path part after itself as
 336 its argument. We told Catalyst that this is the beginning of the chain
 337 by specifying C<:Chained('/')>. Also note that instead of saying
 338 C<:PathPart('hello')> we could also just have said C<:PathPart>, as it
 339 defaults to the name of the action.
 340
 341 After C<hello> has run, Catalyst goes on to dispatch to the C<world>
 342 action. This is the last action to be called: Catalyst knows this is an
 343 endpoint because we did not specify a C<:CaptureArgs>
 344 attribute. Nevertheless we specify that this action expects an argument,
 345 but at this point we're using C<:Args(1)> to do that. We could also have
 346 said C<:Args> or left it out altogether, which would mean this action
 347 would get all arguments that are there. This action's C<:Chained>
 348 attribute says C<hello> and tells Catalyst that the C<hello> action in
 349 the current controller is its parent.
 350
 351 With this we have built a chain consisting of two public path parts.
 352 C<hello> captures one part of the path as its argument, and also
 353 specifies the path root as its parent. So this part is
 354 C</hello/$arg>. The next part is the endpoint C<world>, expecting one
 355 argument. It sums up to the path part C<world/$arg>. This leads to a
 356 complete chain of C</hello/$arg/world/$arg> which is matched against the
 357 requested paths.
 358
 359 This example application would, if run and called by e.g.
 360 C</hello/23/world/12>, set the stash value C<message> to "Hello" and the
 361 value C<arg_sum> to "23". The C<world> action would then append "World!"
 362 to C<message> and add C<12> to the stash's C<arg_sum> value.  For the
 363 sake of simplicity no view is shown. Instead we just put the values of
 364 the stash into our body. So the output would look like:
 365
 366   Hello World!
 367   35
 368
 369 And our test server would have given us this debugging output for the
 370 request:
 371
 372   ...
 373   [debug] "GET" request for "hello/23/world/12" from "127.0.0.1"
 374   [debug] Path is "/greeting/world"
 375   [debug] Arguments are "12"
 376   [info] Request took 0.164113s (6.093/s)
 377   .------------------------------------------+-----------.
 378   | Action                                   | Time      |
 379   +------------------------------------------+-----------+
 380   | /greeting/hello                          | 0.000029s |
 381   | /greeting/world                          | 0.000024s |
 382   '------------------------------------------+-----------'
 383   ...
 384
 385 What would be common uses of this dispatch technique? It gives the
 386 possibility to split up logic that contains steps that each depend on
 387 each other. An example would be, for example, a wiki path like
 388 C</wiki/FooBarPage/rev/23/view>. This chain can be easily built with
 389 these actions:
 390
 391   sub wiki : PathPart('wiki') Chained('/') CaptureArgs(1) {
 392       my ( $self, $c, $page_name ) = @_;
 393       #  load the page named $page_name and put the object
 394       #  into the stash
 395   }
 396
 397   sub rev : PathPart('rev') Chained('wiki') CaptureArgs(1) {
 398       my ( $self, $c, $revision_id ) = @_;
 399       #  use the page object in the stash to get at its
 400       #  revision with number $revision_id
 401   }
 402
 403   sub view : PathPart Chained('rev') Args(0) {
 404       my ( $self, $c ) = @_;
 405       #  display the revision in our stash. Another option
 406       #  would be to forward a compatible object to the action
 407       #  that displays the default wiki pages, unless we want
 408       #  a different interface here, for example restore
 409       #  functionality.
 410   }
 411
 412 It would now be possible to add other endpoints, for example C<restore>
 413 to restore this specific revision as the current state.
 414
 415 You don't have to put all the chained actions in one controller. The
 416 specification of the parent through C<:Chained> also takes an absolute
 417 action path as its argument. Just specify it with a leading C</>.
 418
 419 If you want, for example, to have actions for the public paths
 420 C</foo/12/edit> and C</foo/12>, just specify two actions with
 421 C<:PathPart('foo')> and C<:Chained('/')>. The handler for the former
 422 path needs a C<:CaptureArgs(1)> attribute and a endpoint with
 423 C<:PathPart('edit')> and C<:Chained('foo')>. For the latter path give
 424 the action just a C<:Args(1)> to mark it as endpoint. This sums up to
 425 this debugging output:
 426
 427   ...
 428   [debug] Loaded Path Part actions:
 429   .-----------------------+------------------------------.
 430   | Path Spec             | Private                      |
 431   +-----------------------+------------------------------+
 432   | /foo/*                | /controller/foo_view         |
 433   | /foo/*/edit           | /controller/foo_load (1)     |
 434   |                       | => /controller/edit          |
 435   '-----------------------+------------------------------'
 436   ...
 437
 438 Here's a more detailed specification of the attributes belonging to
 439 C<:Chained>:
 440
 441 =head2 Attributes
 442
 443 =over 8
 444
 445 =item PathPart
 446
 447 Sets the name of this part of the chain. If it is specified without
 448 arguments, it takes the name of the action as default. So basically
 449 C<sub foo :PathPart> and C<sub foo :PathPart('foo')> are identical.
 450 This can also contain slashes to bind to a deeper level. An action
 451 with C<sub bar :PathPart('foo/bar') :Chained('/')> would bind to
 452 C</foo/bar/...>. If you don't specify C<:PathPart> it has the same
 453 effect as using C<:PathPart>, it would default to the action name.
 454
 455 =item Chained
 456
 457 Has to be specified for every child in the chain. Possible values are
 458 absolute and relative private action paths, with the relatives pointing
 459 to the current controller, or a single slash C</> to tell Catalyst that
 460 this is the root of a chain. The attribute C<:Chained> without aguments
 461 also defaults to the C</> behavior.
 462
 463 Because you can specify an absolute path to the parent action, it
 464 doesn't matter to Catalyst where that parent is located. So, if your
 465 design requests it, you can redispatch a chain through any controller or
 466 namespace you want.
 467
 468 Another interesting possibility gives C<:Chained('.')>, which chains
 469 itself to an action with the path of the current controller's namespace.
 470 For example:
 471
 472   #   in MyApp::Controller::Foo
 473   sub bar : Chained CaptureArgs(1) { ... }
 474
 475   #   in MyApp::Controller::Foo::Bar
 476   sub baz : Chained('.') Args(1) { ... }
 477
 478 This builds up a chain like C</bar/*/baz/*>. The specification of C<.>
 479 as the argument to Chained here chains the C<baz> action to an action
 480 with the path of the current controller namespace, namely
 481 C</foo/bar>. That action chains directly to C</>, so the C</bar/*/baz/*>
 482 chain comes out as the end product.
 483
 484 =item CaptureArgs
 485
 486 Must be specified for every part of the chain that is not an
 487 endpoint. With this attribute Catalyst knows how many of the following
 488 parts of the path (separated by C</>) this action wants to capture as
 489 its arguments. If it doesn't expect any, just specify
 490 C<:CaptureArgs(0)>.  The captures get passed to the action's C<@_> right
 491 after the context, but you can also find them as array references in
 492 C<$c-E<gt>request-E<gt>captures-E<gt>[$level]>. The C<$level> is the
 493 level of the action in the chain that captured the parts of the path.
 494
 495 An action that is part of a chain (that is, one that has a C<:Chained>
 496 attribute) but has no C<:CaptureArgs> attribute is treated by Catalyst
 497 as a chain end.
 498
 499 =item Args
 500
 501 By default, endpoints receive the rest of the arguments in the path. You
 502 can tell Catalyst through C<:Args> explicitly how many arguments your
 503 endpoint expects, just like you can with C<:CaptureArgs>. Note that this
 504 also affects whether this chain is invoked on a request. A chain with an
 505 endpoint specifying one argument will only match if exactly one argument
 506 exists in the path.
 507
 508 You can specify an exact number of arguments like C<:Args(3)>, including
 509 C<0>. If you just say C<:Args> without any arguments, it is the same as
 510 leaving it out altogether: The chain is matched regardless of the number
 511 of path parts after the endpoint.
 512
 513 Just as with C<:CaptureArgs>, the arguments get passed to the action in
 514 C<@_> after the context object. They can also be reached through
 515 C<$c-E<gt>request-E<gt>arguments>.
 516
 517 =back
 518
 519 =head2 Auto actions, dispatching and forwarding
 520
 521 Note that the list of C<auto> actions called depends on the private path
 522 of the endpoint of the chain, not on the chained actions way. The
 523 C<auto> actions will be run before the chain dispatching begins. In
 524 every other aspect, C<auto> actions behave as documented.
 525
 526 The C<forward>ing to other actions does just what you would expect. But if
 527 you C<detach> out of a chain, the rest of the chain will not get called
 528 after the C<detach>.
 529
 530 =head1 AUTHOR
 531
 532 Matt S Trout <mst@shadowcatsystems.co.uk>
 533
 534 =head1 COPYRIGHT
 535
 536 This program is free software, you can redistribute it and/or modify it under
 537 the same terms as Perl itself.
 538
 539 =cut
 540
 541 1;