lib/Catalyst/DispatchType/Chained.pm

   1 package Catalyst::DispatchType::Chained;
   2
   3 use Moose;
   4 extends 'Catalyst::DispatchType';
   5
   6 use Text::SimpleTable;
   7 use Catalyst::ActionChain;
   8 use Catalyst::Utils;
   9 use URI;
  10 use Scalar::Util ();
  11 use Encode 2.21 'decode_utf8';
  12
  13 has _endpoints => (
  14                    is => 'rw',
  15                    isa => 'ArrayRef',
  16                    required => 1,
  17                    default => sub{ [] },
  18                   );
  19
  20 has _actions => (
  21                  is => 'rw',
  22                  isa => 'HashRef',
  23                  required => 1,
  24                  default => sub{ {} },
  25                 );
  26
  27 has _children_of => (
  28                      is => 'rw',
  29                      isa => 'HashRef',
  30                      required => 1,
  31                      default => sub{ {} },
  32                     );
  33
  34 no Moose;
  35
  36 # please don't perltidy this. hairy code within.
  37
  38 =head1 NAME
  39
  40 Catalyst::DispatchType::Chained - Path Part DispatchType
  41
  42 =head1 SYNOPSIS
  43
  44 Path part matching, allowing several actions to sequentially take care of processing a request:
  45
  46   #   root action - captures one argument after it
  47   sub foo_setup : Chained('/') PathPart('foo') CaptureArgs(1) {
  48       my ( $self, $c, $foo_arg ) = @_;
  49       ...
  50   }
  51
  52   #   child action endpoint - takes one argument
  53   sub bar : Chained('foo_setup') Args(1) {
  54       my ( $self, $c, $bar_arg ) = @_;
  55       ...
  56   }
  57
  58 =head1 DESCRIPTION
  59
  60 Dispatch type managing default behaviour.  For more information on
  61 dispatch types, see:
  62
  63 =over 4
  64
  65 =item * L<Catalyst::Manual::Intro> for how they affect application authors
  66
  67 =item * L<Catalyst::DispatchType> for implementation information.
  68
  69 =back
  70
  71 =head1 METHODS
  72
  73 =head2 $self->list($c)
  74
  75 Debug output for Path Part dispatch points
  76
  77 =cut
  78
  79 sub list {
  80     my ( $self, $c ) = @_;
  81
  82     return unless $self->_endpoints;
  83
  84     my $avail_width = Catalyst::Utils::term_width() - 9;
  85     my $col1_width = ($avail_width * .50) < 35 ? 35 : int($avail_width * .50);
  86     my $col2_width = $avail_width - $col1_width;
  87     my $paths = Text::SimpleTable->new(
  88         [ $col1_width, 'Path Spec' ], [ $col2_width, 'Private' ],
  89     );
  90
  91     my $has_unattached_actions;
  92     my $unattached_actions = Text::SimpleTable->new(
  93         [ $col1_width, 'Private' ], [ $col2_width, 'Missing parent' ],
  94     );
  95
  96     ENDPOINT: foreach my $endpoint (
  97                   sort { $a->reverse cmp $b->reverse }
  98                            @{ $self->_endpoints }
  99                   ) {
 100         my $args = $endpoint->list_extra_info->{Args};
 101         my @parts = (defined($args) ? (("*") x $args) : '...');
 102         my @parents = ();
 103         my $parent = "DUMMY";
 104         my $extra  = $self->_list_extra_http_methods($endpoint);
 105         my $consumes = $self->_list_extra_consumes($endpoint);
 106         my $scheme = $self->_list_extra_scheme($endpoint);
 107         my $curr = $endpoint;
 108         while ($curr) {
 109             if (my $cap = $curr->list_extra_info->{CaptureArgs}) {
 110                 unshift(@parts, (("*") x $cap));
 111             }
 112             if (my $pp = $curr->attributes->{PathPart}) {
 113                 unshift(@parts, $pp->[0])
 114                     if (defined $pp->[0] && length $pp->[0]);
 115             }
 116             $parent = $curr->attributes->{Chained}->[0];
 117             $curr = $self->_actions->{$parent};
 118             unshift(@parents, $curr) if $curr;
 119         }
 120         if ($parent ne '/') {
 121             $has_unattached_actions = 1;
 122             $unattached_actions->row('/' . ($parents[0] || $endpoint)->reverse, $parent);
 123             next ENDPOINT;
 124         }
 125         my @rows;
 126         foreach my $p (@parents) {
 127             my $name = "/${p}";
 128
 129             if (defined(my $extra = $self->_list_extra_http_methods($p))) {
 130                 $name = "${extra} ${name}";
 131             }
 132             if (defined(my $cap = $p->list_extra_info->{CaptureArgs})) {
 133                 $name .= ' ('.$cap.')';
 134             }
 135             if (defined(my $ct = $p->list_extra_info->{Consumes})) {
 136                 $name .= ' :'.$ct;
 137             }
 138             if (defined(my $s = $p->list_extra_info->{Scheme})) {
 139                 $scheme = uc $s;
 140             }
 141
 142             unless ($p eq $parents[0]) {
 143                 $name = "-> ${name}";
 144             }
 145             push(@rows, [ '', $name ]);
 146         }
 147         push(@rows, [ '', (@rows ? "=> " : '').($extra ? "$extra " : ''). ($scheme ? "$scheme: ":'')."/${endpoint}". ($consumes ? " :$consumes":"" ) ]);
 148         my @display_parts = map { $_ =~s/%([0-9A-Fa-f]{2})/chr(hex($1))/eg; decode_utf8 $_ } @parts;
 149         $rows[0][0] = join('/', '', @display_parts) || '/';
 150         $paths->row(@$_) for @rows;
 151     }
 152
 153     $c->log->debug( "Loaded Chained actions:\n" . $paths->draw . "\n" );
 154     $c->log->debug( "Unattached Chained actions:\n", $unattached_actions->draw . "\n" )
 155         if $has_unattached_actions;
 156 }
 157
 158 sub _list_extra_http_methods {
 159     my ( $self, $action ) = @_;
 160     return unless defined $action->list_extra_info->{HTTP_METHODS};
 161     return join(', ', @{$action->list_extra_info->{HTTP_METHODS}});
 162
 163 }
 164
 165 sub _list_extra_consumes {
 166     my ( $self, $action ) = @_;
 167     return unless defined $action->list_extra_info->{CONSUMES};
 168     return join(', ', @{$action->list_extra_info->{CONSUMES}});
 169 }
 170
 171 sub _list_extra_scheme {
 172     my ( $self, $action ) = @_;
 173     return unless defined $action->list_extra_info->{Scheme};
 174     return uc $action->list_extra_info->{Scheme};
 175 }
 176
 177 =head2 $self->match( $c, $path )
 178
 179 Calls C<recurse_match> to see if a chain matches the C<$path>.
 180
 181 =cut
 182
 183 sub match {
 184     my ( $self, $c, $path ) = @_;
 185
 186     my $request = $c->request;
 187     return 0 if @{$request->args};
 188
 189     my @parts = split('/', $path);
 190
 191     my ($chain, $captures, $parts) = $self->recurse_match($c, '/', \@parts);
 192
 193     if ($parts && @$parts) {
 194         for my $arg (@$parts) {
 195             $arg =~ s/%([0-9A-Fa-f]{2})/chr(hex($1))/eg;
 196             push @{$request->args}, $arg;
 197         }
 198     }
 199
 200     return 0 unless $chain;
 201
 202     my $action = Catalyst::ActionChain->from_chain($chain);
 203
 204     $request->action("/${action}");
 205     $request->match("/${action}");
 206     $request->captures($captures);
 207     $c->action($action);
 208     $c->namespace( $action->namespace );
 209
 210     return 1;
 211 }
 212
 213 =head2 $self->recurse_match( $c, $parent, \@path_parts )
 214
 215 Recursive search for a matching chain.
 216
 217 =cut
 218
 219 sub recurse_match {
 220     my ( $self, $c, $parent, $path_parts ) = @_;
 221     my $children = $self->_children_of->{$parent};
 222     return () unless $children;
 223     my $best_action;
 224     my @captures;
 225     TRY: foreach my $try_part (sort { length($b) <=> length($a) }
 226                                    keys %$children) {
 227                                # $b then $a to try longest part first
 228         my @parts = @$path_parts;
 229         if (length $try_part) { # test and strip PathPart
 230             next TRY unless
 231               ($try_part eq join('/', # assemble equal number of parts
 232                               splice( # and strip them off @parts as well
 233                                 @parts, 0, scalar(@{[split('/', $try_part)]})
 234                               ))); # @{[]} to avoid split to @_
 235         }
 236         my @try_actions = @{$children->{$try_part}};
 237         TRY_ACTION: foreach my $action (@try_actions) {
 238             if (my $capture_attr = $action->attributes->{CaptureArgs}) {
 239                 my $capture_count = $capture_attr->[0] || 0;
 240
 241                 # Short-circuit if not enough remaining parts
 242                 next TRY_ACTION unless @parts >= $capture_count;
 243
 244                 my @captures;
 245                 my @parts = @parts; # localise
 246
 247                 # strip CaptureArgs into list
 248                 push(@captures, splice(@parts, 0, $capture_count));
 249
 250                 # check if the action may fit, depending on a given test by the app
 251                 if ($action->can('match_captures')) { next TRY_ACTION unless $action->match_captures($c, \@captures) }
 252
 253                 # try the remaining parts against children of this action
 254                 my ($actions, $captures, $action_parts, $n_pathparts) = $self->recurse_match(
 255                                              $c, '/'.$action->reverse, \@parts
 256                                            );
 257                 #    No best action currently
 258                 # OR The action has less parts
 259                 # OR The action has equal parts but less captured data (ergo more defined)
 260                 if ($actions    &&
 261                     (!$best_action                                 ||
 262                      $#$action_parts < $#{$best_action->{parts}}   ||
 263                      ($#$action_parts == $#{$best_action->{parts}} &&
 264                       $#$captures < $#{$best_action->{captures}} &&
 265                       $n_pathparts > $best_action->{n_pathparts}))) {
 266                     my @pathparts = split /\//, $action->attributes->{PathPart}->[0];
 267                     $best_action = {
 268                         actions => [ $action, @$actions ],
 269                         captures=> [ @captures, @$captures ],
 270                         parts   => $action_parts,
 271                         n_pathparts => scalar(@pathparts) + $n_pathparts,
 272                     };
 273                 }
 274             }
 275             else {
 276                 {
 277                     local $c->req->{arguments} = [ @{$c->req->args}, @parts ];
 278                     next TRY_ACTION unless $action->match($c);
 279                 }
 280                 my $args_attr = $action->attributes->{Args}->[0];
 281                 my @pathparts = split /\//, $action->attributes->{PathPart}->[0];
 282                 #    No best action currently
 283                 # OR This one matches with fewer parts left than the current best action,
 284                 #    And therefore is a better match
 285                 # OR No parts and this expects 0
 286                 #    The current best action might also be Args(0),
 287                 #    but we couldn't chose between then anyway so we'll take the last seen
 288
 289                 if (
 290                     !$best_action                       ||
 291                     @parts < @{$best_action->{parts}}   ||
 292                     (
 293                         !@parts &&
 294                         defined($args_attr) &&
 295                         (
 296                             $args_attr eq "0" &&
 297                             ( exists($best_action->{args_attr}) && defined($best_action->{args_attr}) ?  ($best_action->{args_attr} ne 0) : 1 )
 298                         )
 299                     )
 300                 ){
 301                     $best_action = {
 302                         actions => [ $action ],
 303                         captures=> [],
 304                         parts   => \@parts,
 305                         args_attr => $args_attr,
 306                         n_pathparts => scalar(@pathparts),
 307                     };
 308                 }
 309             }
 310         }
 311     }
 312     return @$best_action{qw/actions captures parts n_pathparts/} if $best_action;
 313     return ();
 314 }
 315
 316 =head2 $self->register( $c, $action )
 317
 318 Calls register_path for every Path attribute for the given $action.
 319
 320 =cut
 321
 322 sub _check_args_attr {
 323     my ( $self, $action, $name ) = @_;
 324
 325     return unless exists $action->attributes->{$name};
 326
 327     if (@{$action->attributes->{$name}} > 1) {
 328         Catalyst::Exception->throw(
 329           "Multiple $name attributes not supported registering " . $action->reverse()
 330         );
 331     }
 332     my $args = $action->attributes->{$name}->[0];
 333     if (defined($args) and not (
 334         Scalar::Util::looks_like_number($args) and
 335         int($args) == $args and $args >= 0
 336     )) {
 337         require Data::Dumper;
 338         local $Data::Dumper::Terse = 1;
 339         local $Data::Dumper::Indent = 0;
 340         $args = Data::Dumper::Dumper($args);
 341         Catalyst::Exception->throw(
 342           "Invalid $name($args) for action " . $action->reverse() .
 343           " (use '$name' or '$name(<number>)')"
 344         );
 345     }
 346 }
 347
 348 sub register {
 349     my ( $self, $c, $action ) = @_;
 350
 351     my @chained_attr = @{ $action->attributes->{Chained} || [] };
 352
 353     return 0 unless @chained_attr;
 354
 355     if (@chained_attr > 1) {
 356         Catalyst::Exception->throw(
 357           "Multiple Chained attributes not supported registering ${action}"
 358         );
 359     }
 360     my $chained_to = $chained_attr[0];
 361
 362     Catalyst::Exception->throw(
 363       "Actions cannot chain to themselves registering /${action}"
 364     ) if ($chained_to eq '/' . $action);
 365
 366     my $children = ($self->_children_of->{ $chained_to } ||= {});
 367
 368     my @path_part = @{ $action->attributes->{PathPart} || [] };
 369
 370     my $part = $action->name;
 371
 372     if (@path_part == 1 && defined $path_part[0]) {
 373         $part = $path_part[0];
 374     } elsif (@path_part > 1) {
 375         Catalyst::Exception->throw(
 376           "Multiple PathPart attributes not supported registering " . $action->reverse()
 377         );
 378     }
 379
 380     if ($part =~ m(^/)) {
 381         Catalyst::Exception->throw(
 382           "Absolute parameters to PathPart not allowed registering " . $action->reverse()
 383         );
 384     }
 385
 386     my $encoded_part = URI->new($part)->canonical;
 387     $encoded_part =~ s{(?<=[^/])/+\z}{};
 388
 389     $action->attributes->{PathPart} = [ $encoded_part ];
 390
 391     unshift(@{ $children->{$encoded_part} ||= [] }, $action);
 392
 393     $self->_actions->{'/'.$action->reverse} = $action;
 394
 395     foreach my $name (qw(Args CaptureArgs)) {
 396         $self->_check_args_attr($action, $name);
 397     }
 398
 399     if (exists $action->attributes->{Args} and exists $action->attributes->{CaptureArgs}) {
 400         Catalyst::Exception->throw(
 401           "Combining Args and CaptureArgs attributes not supported registering " .
 402           $action->reverse()
 403         );
 404     }
 405
 406     unless ($action->attributes->{CaptureArgs}) {
 407         unshift(@{ $self->_endpoints }, $action);
 408     }
 409
 410     return 1;
 411 }
 412
 413 =head2 $self->uri_for_action($action, $captures)
 414
 415 Get the URI part for the action, using C<$captures> to fill
 416 the capturing parts.
 417
 418 =cut
 419
 420 sub uri_for_action {
 421     my ( $self, $action, $captures ) = @_;
 422
 423     return undef unless ($action->attributes->{Chained}
 424                            && !$action->attributes->{CaptureArgs});
 425
 426     my @parts = ();
 427     my @captures = @$captures;
 428     my $parent = "DUMMY";
 429     my $curr = $action;
 430     while ($curr) {
 431         if (my $cap = $curr->attributes->{CaptureArgs}) {
 432             return undef unless @captures >= ($cap->[0]||0); # not enough captures
 433             if ($cap->[0]) {
 434                 unshift(@parts, splice(@captures, -$cap->[0]));
 435             }
 436         }
 437         if (my $pp = $curr->attributes->{PathPart}) {
 438             unshift(@parts, $pp->[0])
 439                 if (defined($pp->[0]) && length($pp->[0]));
 440         }
 441         $parent = $curr->attributes->{Chained}->[0];
 442         $curr = $self->_actions->{$parent};
 443     }
 444
 445     return undef unless $parent eq '/'; # fail for dangling action
 446
 447     return undef if @captures; # fail for too many captures
 448
 449     return join('/', '', @parts);
 450
 451 }
 452
 453 =head2 $c->expand_action($action)
 454
 455 Return a list of actions that represents a chained action. See
 456 L<Catalyst::Dispatcher> for more info. You probably want to
 457 use the expand_action it provides rather than this directly.
 458
 459 =cut
 460
 461 sub expand_action {
 462     my ($self, $action) = @_;
 463
 464     return unless $action->attributes && $action->attributes->{Chained};
 465
 466     my @chain;
 467     my $curr = $action;
 468
 469     while ($curr) {
 470         push @chain, $curr;
 471         my $parent = $curr->attributes->{Chained}->[0];
 472         $curr = $self->_actions->{$parent};
 473     }
 474
 475     return Catalyst::ActionChain->from_chain([reverse @chain]);
 476 }
 477
 478 __PACKAGE__->meta->make_immutable;
 479 1;
 480
 481 =head1 USAGE
 482
 483 =head2 Introduction
 484
 485 The C<Chained> attribute allows you to chain public path parts together
 486 by their private names. A chain part's path can be specified with
 487 C<PathPart> and can be declared to expect an arbitrary number of
 488 arguments. The endpoint of the chain specifies how many arguments it
 489 gets through the C<Args> attribute. C<:Args(0)> would be none at all,
 490 C<:Args> without an integer would be unlimited. The path parts that
 491 aren't endpoints are using C<CaptureArgs> to specify how many parameters
 492 they expect to receive. As an example setup:
 493
 494   package MyApp::Controller::Greeting;
 495   use base qw/ Catalyst::Controller /;
 496
 497   #   this is the beginning of our chain
 498   sub hello : PathPart('hello') Chained('/') CaptureArgs(1) {
 499       my ( $self, $c, $integer ) = @_;
 500       $c->stash->{ message } = "Hello ";
 501       $c->stash->{ arg_sum } = $integer;
 502   }
 503
 504   #   this is our endpoint, because it has no :CaptureArgs
 505   sub world : PathPart('world') Chained('hello') Args(1) {
 506       my ( $self, $c, $integer ) = @_;
 507       $c->stash->{ message } .= "World!";
 508       $c->stash->{ arg_sum } += $integer;
 509
 510       $c->response->body( join "<br/>\n" =>
 511           $c->stash->{ message }, $c->stash->{ arg_sum } );
 512   }
 513
 514 The debug output provides a separate table for chained actions, showing
 515 the whole chain as it would match and the actions it contains. Here's an
 516 example of the startup output with our actions above:
 517
 518   ...
 519   [debug] Loaded Path Part actions:
 520   .-----------------------+------------------------------.
 521   | Path Spec             | Private                      |
 522   +-----------------------+------------------------------+
 523   | /hello/*/world/*      | /greeting/hello (1)          |
 524   |                       | => /greeting/world           |
 525   '-----------------------+------------------------------'
 526   ...
 527
 528 As you can see, Catalyst only deals with chains as whole paths and
 529 builds one for each endpoint, which are the actions with C<:Chained> but
 530 without C<:CaptureArgs>.
 531
 532 Let's assume this application gets a request at the path
 533 C</hello/23/world/12>. What happens then? First, Catalyst will dispatch
 534 to the C<hello> action and pass the value C<23> as an argument to it
 535 after the context. It does so because we have previously used
 536 C<:CaptureArgs(1)> to declare that it has one path part after itself as
 537 its argument. We told Catalyst that this is the beginning of the chain
 538 by specifying C<:Chained('/')>. Also note that instead of saying
 539 C<:PathPart('hello')> we could also just have said C<:PathPart>, as it
 540 defaults to the name of the action.
 541
 542 After C<hello> has run, Catalyst goes on to dispatch to the C<world>
 543 action. This is the last action to be called: Catalyst knows this is an
 544 endpoint because we did not specify a C<:CaptureArgs>
 545 attribute. Nevertheless we specify that this action expects an argument,
 546 but at this point we're using C<:Args(1)> to do that. We could also have
 547 said C<:Args> or left it out altogether, which would mean this action
 548 would get all arguments that are there. This action's C<:Chained>
 549 attribute says C<hello> and tells Catalyst that the C<hello> action in
 550 the current controller is its parent.
 551
 552 With this we have built a chain consisting of two public path parts.
 553 C<hello> captures one part of the path as its argument, and also
 554 specifies the path root as its parent. So this part is
 555 C</hello/$arg>. The next part is the endpoint C<world>, expecting one
 556 argument. It sums up to the path part C<world/$arg>. This leads to a
 557 complete chain of C</hello/$arg/world/$arg> which is matched against the
 558 requested paths.
 559
 560 This example application would, if run and called by e.g.
 561 C</hello/23/world/12>, set the stash value C<message> to "Hello" and the
 562 value C<arg_sum> to "23". The C<world> action would then append "World!"
 563 to C<message> and add C<12> to the stash's C<arg_sum> value.  For the
 564 sake of simplicity no view is shown. Instead we just put the values of
 565 the stash into our body. So the output would look like:
 566
 567   Hello World!
 568   35
 569
 570 And our test server would have given us this debugging output for the
 571 request:
 572
 573   ...
 574   [debug] "GET" request for "hello/23/world/12" from "127.0.0.1"
 575   [debug] Path is "/greeting/world"
 576   [debug] Arguments are "12"
 577   [info] Request took 0.164113s (6.093/s)
 578   .------------------------------------------+-----------.
 579   | Action                                   | Time      |
 580   +------------------------------------------+-----------+
 581   | /greeting/hello                          | 0.000029s |
 582   | /greeting/world                          | 0.000024s |
 583   '------------------------------------------+-----------'
 584   ...
 585
 586 What would be common uses of this dispatch technique? It gives the
 587 possibility to split up logic that contains steps that each depend on
 588 each other. An example would be, for example, a wiki path like
 589 C</wiki/FooBarPage/rev/23/view>. This chain can be easily built with
 590 these actions:
 591
 592   sub wiki : PathPart('wiki') Chained('/') CaptureArgs(1) {
 593       my ( $self, $c, $page_name ) = @_;
 594       #  load the page named $page_name and put the object
 595       #  into the stash
 596   }
 597
 598   sub rev : PathPart('rev') Chained('wiki') CaptureArgs(1) {
 599       my ( $self, $c, $revision_id ) = @_;
 600       #  use the page object in the stash to get at its
 601       #  revision with number $revision_id
 602   }
 603
 604   sub view : PathPart Chained('rev') Args(0) {
 605       my ( $self, $c ) = @_;
 606       #  display the revision in our stash. Another option
 607       #  would be to forward a compatible object to the action
 608       #  that displays the default wiki pages, unless we want
 609       #  a different interface here, for example restore
 610       #  functionality.
 611   }
 612
 613 It would now be possible to add other endpoints, for example C<restore>
 614 to restore this specific revision as the current state.
 615
 616 You don't have to put all the chained actions in one controller. The
 617 specification of the parent through C<:Chained> also takes an absolute
 618 action path as its argument. Just specify it with a leading C</>.
 619
 620 If you want, for example, to have actions for the public paths
 621 C</foo/12/edit> and C</foo/12>, just specify two actions with
 622 C<:PathPart('foo')> and C<:Chained('/')>. The handler for the former
 623 path needs a C<:CaptureArgs(1)> attribute and a endpoint with
 624 C<:PathPart('edit')> and C<:Chained('foo')>. For the latter path give
 625 the action just a C<:Args(1)> to mark it as endpoint. This sums up to
 626 this debugging output:
 627
 628   ...
 629   [debug] Loaded Path Part actions:
 630   .-----------------------+------------------------------.
 631   | Path Spec             | Private                      |
 632   +-----------------------+------------------------------+
 633   | /foo/*                | /controller/foo_view         |
 634   | /foo/*/edit           | /controller/foo_load (1)     |
 635   |                       | => /controller/edit          |
 636   '-----------------------+------------------------------'
 637   ...
 638
 639 Here's a more detailed specification of the attributes belonging to
 640 C<:Chained>:
 641
 642 =head2 Attributes
 643
 644 =over 8
 645
 646 =item PathPart
 647
 648 Sets the name of this part of the chain. If it is specified without
 649 arguments, it takes the name of the action as default. So basically
 650 C<sub foo :PathPart> and C<sub foo :PathPart('foo')> are identical.
 651 This can also contain slashes to bind to a deeper level. An action
 652 with C<sub bar :PathPart('foo/bar') :Chained('/')> would bind to
 653 C</foo/bar/...>. If you don't specify C<:PathPart> it has the same
 654 effect as using C<:PathPart>, it would default to the action name.
 655
 656 =item PathPrefix
 657
 658 Sets PathPart to the path_prefix of the current controller.
 659
 660 =item Chained
 661
 662 Has to be specified for every child in the chain. Possible values are
 663 absolute and relative private action paths or a single slash C</> to
 664 tell Catalyst that this is the root of a chain. The attribute
 665 C<:Chained> without arguments also defaults to the C</> behavior.
 666 Relative action paths may use C<../> to refer to actions in parent
 667 controllers.
 668
 669 Because you can specify an absolute path to the parent action, it
 670 doesn't matter to Catalyst where that parent is located. So, if your
 671 design requests it, you can redispatch a chain through any controller or
 672 namespace you want.
 673
 674 Another interesting possibility gives C<:Chained('.')>, which chains
 675 itself to an action with the path of the current controller's namespace.
 676 For example:
 677
 678   #   in MyApp::Controller::Foo
 679   sub bar : Chained CaptureArgs(1) { ... }
 680
 681   #   in MyApp::Controller::Foo::Bar
 682   sub baz : Chained('.') Args(1) { ... }
 683
 684 This builds up a chain like C</bar/*/baz/*>. The specification of C<.>
 685 as the argument to Chained here chains the C<baz> action to an action
 686 with the path of the current controller namespace, namely
 687 C</foo/bar>. That action chains directly to C</>, so the C</bar/*/baz/*>
 688 chain comes out as the end product.
 689
 690 =item ChainedParent
 691
 692 Chains an action to another action with the same name in the parent
 693 controller. For Example:
 694
 695   # in MyApp::Controller::Foo
 696   sub bar : Chained CaptureArgs(1) { ... }
 697
 698   # in MyApp::Controller::Foo::Moo
 699   sub bar : ChainedParent Args(1) { ... }
 700
 701 This builds a chain like C</bar/*/bar/*>.
 702
 703 =item CaptureArgs
 704
 705 Must be specified for every part of the chain that is not an
 706 endpoint. With this attribute Catalyst knows how many of the following
 707 parts of the path (separated by C</>) this action wants to capture as
 708 its arguments. If it doesn't expect any, just specify
 709 C<:CaptureArgs(0)>.  The captures get passed to the action's C<@_> right
 710 after the context, but you can also find them as array references in
 711 C<$c-E<gt>request-E<gt>captures-E<gt>[$level]>. The C<$level> is the
 712 level of the action in the chain that captured the parts of the path.
 713
 714 An action that is part of a chain (that is, one that has a C<:Chained>
 715 attribute) but has no C<:CaptureArgs> attribute is treated by Catalyst
 716 as a chain end.
 717
 718 =item Args
 719
 720 By default, endpoints receive the rest of the arguments in the path. You
 721 can tell Catalyst through C<:Args> explicitly how many arguments your
 722 endpoint expects, just like you can with C<:CaptureArgs>. Note that this
 723 also affects whether this chain is invoked on a request. A chain with an
 724 endpoint specifying one argument will only match if exactly one argument
 725 exists in the path.
 726
 727 You can specify an exact number of arguments like C<:Args(3)>, including
 728 C<0>. If you just say C<:Args> without any arguments, it is the same as
 729 leaving it out altogether: The chain is matched regardless of the number
 730 of path parts after the endpoint.
 731
 732 Just as with C<:CaptureArgs>, the arguments get passed to the action in
 733 C<@_> after the context object. They can also be reached through
 734 C<$c-E<gt>request-E<gt>arguments>.
 735
 736 =back
 737
 738 =head2 Auto actions, dispatching and forwarding
 739
 740 Note that the list of C<auto> actions called depends on the private path
 741 of the endpoint of the chain, not on the chained actions way. The
 742 C<auto> actions will be run before the chain dispatching begins. In
 743 every other aspect, C<auto> actions behave as documented.
 744
 745 The C<forward>ing to other actions does just what you would expect. i.e.
 746 only the target action is run. The actions that that action is chained
 747 to are not run.
 748 If you C<detach> out of a chain, the rest of the chain will not get
 749 called after the C<detach>.
 750
 751 =head2 match_captures
 752
 753 A method which can optionally be implemented by actions to
 754 stop chain matching.
 755
 756 See L<Catalyst::Action> for further details.
 757
 758 =head1 AUTHORS
 759
 760 Catalyst Contributors, see Catalyst.pm
 761
 762 =head1 COPYRIGHT
 763
 764 This library is free software. You can redistribute it and/or modify it under
 765 the same terms as Perl itself.
 766
 767 =cut
 768
 769 1;