lib/Catalyst/DispatchType/Chained.pm

   1 package Catalyst::DispatchType::Chained;
   2
   3 use strict;
   4 use base qw/Catalyst::DispatchType/;
   5 use Text::SimpleTable;
   6 use Catalyst::ActionChain;
   7 use URI;
   8
   9 # please don't perltidy this. hairy code within.
  10
  11 =head1 NAME
  12
  13 Catalyst::DispatchType::Chained - Path Part DispatchType
  14
  15 =head1 SYNOPSIS
  16
  17   #   root action - captures one argument after it
  18   sub foo_setup : Chained('/') PathPart('foo') CaptureArgs(1) {
  19       my ( $self, $c, $foo_arg ) = @_;
  20       ...
  21   }
  22
  23   #   child action endpoint - takes one argument
  24   sub bar : Chained('foo_setup') Args(1) {
  25       my ( $self, $c, $bar_arg ) = @_;
  26       ...
  27   }
  28
  29 =head1 DESCRIPTION
  30
  31 See L</USAGE>.
  32
  33 =head1 METHODS
  34
  35 =head2 $self->list($c)
  36
  37 Debug output for Path Part dispatch points
  38
  39 =cut
  40
  41 sub list {
  42     my ( $self, $c ) = @_;
  43
  44     return unless $self->{endpoints};
  45
  46     my $paths = Text::SimpleTable->new(
  47                     [ 35, 'Path Spec' ], [ 36, 'Private' ]
  48                 );
  49
  50     ENDPOINT: foreach my $endpoint (
  51                   sort { $a->reverse cmp $b->reverse }
  52                            @{ $self->{endpoints} }
  53                   ) {
  54         my $args = $endpoint->attributes->{Args}->[0];
  55         my @parts = (defined($args) ? (("*") x $args) : '...');
  56         my @parents = ();
  57         my $parent = "DUMMY";
  58         my $curr = $endpoint;
  59         while ($curr) {
  60             if (my $cap = $curr->attributes->{CaptureArgs}) {
  61                 unshift(@parts, (("*") x $cap->[0]));
  62             }
  63             if (my $pp = $curr->attributes->{PartPath}) {
  64                 unshift(@parts, $pp->[0])
  65                     if (defined $pp->[0] && length $pp->[0]);
  66             }
  67             $parent = $curr->attributes->{Chained}->[0];
  68             $curr = $self->{actions}{$parent};
  69             unshift(@parents, $curr) if $curr;
  70         }
  71         next ENDPOINT unless $parent eq '/'; # skip dangling action
  72         my @rows;
  73         foreach my $p (@parents) {
  74             my $name = "/${p}";
  75             if (my $cap = $p->attributes->{CaptureArgs}) {
  76                 $name .= ' ('.$cap->[0].')';
  77             }
  78             unless ($p eq $parents[0]) {
  79                 $name = "-> ${name}";
  80             }
  81             push(@rows, [ '', $name ]);
  82         }
  83         push(@rows, [ '', (@rows ? "=> " : '')."/${endpoint}" ]);
  84         $rows[0][0] = join('/', '', @parts);
  85         $paths->row(@$_) for @rows;
  86     }
  87
  88     $c->log->debug( "Loaded Chained actions:\n" . $paths->draw . "\n" );
  89 }
  90
  91 =head2 $self->match( $c, $path )
  92
  93 Calls C<recurse_match> to see if a chain matches the C<$path>.
  94
  95 =cut
  96
  97 sub match {
  98     my ( $self, $c, $path ) = @_;
  99
 100     return 0 if @{$c->req->args};
 101
 102     my @parts = split('/', $path);
 103
 104     my ($chain, $captures, $parts) = $self->recurse_match($c, '/', \@parts);
 105         push @{$c->req->args}, @$parts;
 106
 107     return 0 unless $chain;
 108
 109     my $action = Catalyst::ActionChain->from_chain($chain);
 110
 111     $c->req->action("/${action}");
 112     $c->req->match("/${action}");
 113     $c->req->captures($captures);
 114     $c->action($action);
 115     $c->namespace( $action->namespace );
 116
 117     return 1;
 118 }
 119
 120 =head2 $self->recurse_match( $c, $parent, \@path_parts )
 121
 122 Recursive search for a matching chain.
 123
 124 =cut
 125
 126 sub recurse_match {
 127     my ( $self, $c, $parent, $path_parts ) = @_;
 128     my $children = $self->{children_of}{$parent};
 129     return () unless $children;
 130         my $best_action;
 131     my @captures;
 132     TRY: foreach my $try_part (sort { length($b) <=> length($a) }
 133                                    keys %$children) {
 134                                # $b then $a to try longest part first
 135         my @parts = @$path_parts;
 136         if (length $try_part) { # test and strip PathPart
 137             next TRY unless
 138               ($try_part eq join('/', # assemble equal number of parts
 139                               splice( # and strip them off @parts as well
 140                                 @parts, 0, scalar(@{[split('/', $try_part)]})
 141                               ))); # @{[]} to avoid split to @_
 142         }
 143         my @try_actions = @{$children->{$try_part}};
 144         TRY_ACTION: foreach my $action (@try_actions) {
 145             if (my $capture_attr = $action->attributes->{CaptureArgs}) {
 146
 147                 # Short-circuit if not enough remaining parts
 148                 next TRY_ACTION unless @parts >= $capture_attr->[0];
 149
 150                 my @captures;
 151                 my @parts = @parts; # localise
 152
 153                 # strip CaptureArgs into list
 154                 push(@captures, splice(@parts, 0, $capture_attr->[0]));
 155
 156                 # try the remaining parts against children of this action
 157                 my ($actions, $captures, $action_parts) = $self->recurse_match(
 158                                              $c, '/'.$action->reverse, \@parts
 159                                            );
 160                                 if ($actions && (!$best_action || $#$action_parts < $#{$best_action->{parts}})){
 161                                         $best_action = {
 162                                                 actions => [ $action, @$actions ],
 163                                                 captures=> [ @captures, @$captures ],
 164                                                 parts   => $action_parts
 165                                                 };
 166                                 }
 167                 }
 168                         else {
 169                 {
 170                     local $c->req->{arguments} = [ @{$c->req->args}, @parts ];
 171                     next TRY_ACTION unless $action->match($c);
 172                 }
 173                                 if (!$best_action || $#parts < $#{$best_action->{parts}}){
 174                         $best_action = {
 175                                                 actions => [ $action ],
 176                                                 captures=> [],
 177                                                 parts   => \@parts
 178                                                 }
 179                                         }
 180             }
 181         }
 182     }
 183         return @$best_action{qw/actions captures parts /} if $best_action;
 184     return ();
 185 }
 186
 187 =head2 $self->register( $c, $action )
 188
 189 Calls register_path for every Path attribute for the given $action.
 190
 191 =cut
 192
 193 sub register {
 194     my ( $self, $c, $action ) = @_;
 195
 196     my @chained_attr = @{ $action->attributes->{Chained} || [] };
 197
 198     return 0 unless @chained_attr;
 199
 200     if (@chained_attr > 2) {
 201         Catalyst::Exception->throw(
 202           "Multiple Chained attributes not supported registering ${action}"
 203         );
 204     }
 205
 206     my $parent = $chained_attr[0];
 207
 208     if (defined($parent) && length($parent)) {
 209         if ($parent eq '.') {
 210             $parent = '/'.$action->namespace;
 211         } elsif ($parent !~ m/^\//) {
 212             if ($action->namespace) {
 213                 $parent = '/'.join('/', $action->namespace, $parent);
 214             } else {
 215                 $parent = '/'.$parent; # special case namespace '' (root)
 216             }
 217         }
 218     } else {
 219         $parent = '/'
 220     }
 221
 222     $action->attributes->{Chained} = [ $parent ];
 223
 224     my $children = ($self->{children_of}{$parent} ||= {});
 225
 226     my @path_part = @{ $action->attributes->{PathPart} || [] };
 227
 228     my $part = $action->name;
 229
 230     if (@path_part == 1 && defined $path_part[0]) {
 231         $part = $path_part[0];
 232     } elsif (@path_part > 1) {
 233         Catalyst::Exception->throw(
 234           "Multiple PathPart attributes not supported registering ${action}"
 235         );
 236     }
 237
 238     if ($part =~ m(^/)) {
 239         Catalyst::Exception->throw(
 240           "Absolute parameters to PathPart not allowed registering ${action}"
 241         );
 242     }
 243
 244     $action->attributes->{PartPath} = [ $part ];
 245
 246     unshift(@{ $children->{$part} ||= [] }, $action);
 247
 248     ($self->{actions} ||= {})->{'/'.$action->reverse} = $action;
 249
 250     unless ($action->attributes->{CaptureArgs}) {
 251         unshift(@{ $self->{endpoints} ||= [] }, $action);
 252     }
 253
 254     return 1;
 255 }
 256
 257 =head2 $self->uri_for_action($action, $captures)
 258
 259 Get the URI part for the action, using C<$captures> to fill
 260 the capturing parts.
 261
 262 =cut
 263
 264 sub uri_for_action {
 265     my ( $self, $action, $captures ) = @_;
 266
 267     return undef unless ($action->attributes->{Chained}
 268                            && !$action->attributes->{CaptureArgs});
 269
 270     my @parts = ();
 271     my @captures = @$captures;
 272     my $parent = "DUMMY";
 273     my $curr = $action;
 274     while ($curr) {
 275         if (my $cap = $curr->attributes->{CaptureArgs}) {
 276             return undef unless @captures >= $cap->[0]; # not enough captures
 277             if ($cap->[0]) {
 278                 unshift(@parts, splice(@captures, -$cap->[0]));
 279             }
 280         }
 281         if (my $pp = $curr->attributes->{PartPath}) {
 282             unshift(@parts, $pp->[0])
 283                 if (defined($pp->[0]) && length($pp->[0]));
 284         }
 285         $parent = $curr->attributes->{Chained}->[0];
 286         $curr = $self->{actions}{$parent};
 287     }
 288
 289     return undef unless $parent eq '/'; # fail for dangling action
 290
 291     return undef if @captures; # fail for too many captures
 292
 293     return join('/', '', @parts);
 294
 295 }
 296
 297 =head1 USAGE
 298
 299 =head2 Introduction
 300
 301 The C<Chained> attribute allows you to chain public path parts together
 302 by their private names. A chain part's path can be specified with
 303 C<PathPart> and can be declared to expect an arbitrary number of
 304 arguments. The endpoint of the chain specifies how many arguments it
 305 gets through the C<Args> attribute. C<:Args(0)> would be none at all,
 306 C<:Args> without an integer would be unlimited. The path parts that
 307 aren't endpoints are using C<CaptureArgs> to specify how many parameters
 308 they expect to receive. As an example setup:
 309
 310   package MyApp::Controller::Greeting;
 311   use base qw/ Catalyst::Controller /;
 312
 313   #   this is the beginning of our chain
 314   sub hello : PathPart('hello') Chained('/') CaptureArgs(1) {
 315       my ( $self, $c, $integer ) = @_;
 316       $c->stash->{ message } = "Hello ";
 317       $c->stash->{ arg_sum } = $integer;
 318   }
 319
 320   #   this is our endpoint, because it has no :CaptureArgs
 321   sub world : PathPart('world') Chained('hello') Args(1) {
 322       my ( $self, $c, $integer ) = @_;
 323       $c->stash->{ message } .= "World!";
 324       $c->stash->{ arg_sum } += $integer;
 325
 326       $c->response->body( join "<br/>\n" =>
 327           $c->stash->{ message }, $c->stash->{ arg_sum } );
 328   }
 329
 330 The debug output provides a separate table for chained actions, showing
 331 the whole chain as it would match and the actions it contains. Here's an
 332 example of the startup output with our actions above:
 333
 334   ...
 335   [debug] Loaded Path Part actions:
 336   .-----------------------+------------------------------.
 337   | Path Spec             | Private                      |
 338   +-----------------------+------------------------------+
 339   | /hello/*/world/*      | /greeting/hello (1)          |
 340   |                       | => /greeting/world           |
 341   '-----------------------+------------------------------'
 342   ...
 343
 344 As you can see, Catalyst only deals with chains as whole paths and
 345 builds one for each endpoint, which are the actions with C<:Chained> but
 346 without C<:CaptureArgs>.
 347
 348 Let's assume this application gets a request at the path
 349 C</hello/23/world/12>. What happens then? First, Catalyst will dispatch
 350 to the C<hello> action and pass the value C<23> as an argument to it
 351 after the context. It does so because we have previously used
 352 C<:CaptureArgs(1)> to declare that it has one path part after itself as
 353 its argument. We told Catalyst that this is the beginning of the chain
 354 by specifying C<:Chained('/')>. Also note that instead of saying
 355 C<:PathPart('hello')> we could also just have said C<:PathPart>, as it
 356 defaults to the name of the action.
 357
 358 After C<hello> has run, Catalyst goes on to dispatch to the C<world>
 359 action. This is the last action to be called: Catalyst knows this is an
 360 endpoint because we did not specify a C<:CaptureArgs>
 361 attribute. Nevertheless we specify that this action expects an argument,
 362 but at this point we're using C<:Args(1)> to do that. We could also have
 363 said C<:Args> or left it out altogether, which would mean this action
 364 would get all arguments that are there. This action's C<:Chained>
 365 attribute says C<hello> and tells Catalyst that the C<hello> action in
 366 the current controller is its parent.
 367
 368 With this we have built a chain consisting of two public path parts.
 369 C<hello> captures one part of the path as its argument, and also
 370 specifies the path root as its parent. So this part is
 371 C</hello/$arg>. The next part is the endpoint C<world>, expecting one
 372 argument. It sums up to the path part C<world/$arg>. This leads to a
 373 complete chain of C</hello/$arg/world/$arg> which is matched against the
 374 requested paths.
 375
 376 This example application would, if run and called by e.g.
 377 C</hello/23/world/12>, set the stash value C<message> to "Hello" and the
 378 value C<arg_sum> to "23". The C<world> action would then append "World!"
 379 to C<message> and add C<12> to the stash's C<arg_sum> value.  For the
 380 sake of simplicity no view is shown. Instead we just put the values of
 381 the stash into our body. So the output would look like:
 382
 383   Hello World!
 384   35
 385
 386 And our test server would have given us this debugging output for the
 387 request:
 388
 389   ...
 390   [debug] "GET" request for "hello/23/world/12" from "127.0.0.1"
 391   [debug] Path is "/greeting/world"
 392   [debug] Arguments are "12"
 393   [info] Request took 0.164113s (6.093/s)
 394   .------------------------------------------+-----------.
 395   | Action                                   | Time      |
 396   +------------------------------------------+-----------+
 397   | /greeting/hello                          | 0.000029s |
 398   | /greeting/world                          | 0.000024s |
 399   '------------------------------------------+-----------'
 400   ...
 401
 402 What would be common uses of this dispatch technique? It gives the
 403 possibility to split up logic that contains steps that each depend on
 404 each other. An example would be, for example, a wiki path like
 405 C</wiki/FooBarPage/rev/23/view>. This chain can be easily built with
 406 these actions:
 407
 408   sub wiki : PathPart('wiki') Chained('/') CaptureArgs(1) {
 409       my ( $self, $c, $page_name ) = @_;
 410       #  load the page named $page_name and put the object
 411       #  into the stash
 412   }
 413
 414   sub rev : PathPart('rev') Chained('wiki') CaptureArgs(1) {
 415       my ( $self, $c, $revision_id ) = @_;
 416       #  use the page object in the stash to get at its
 417       #  revision with number $revision_id
 418   }
 419
 420   sub view : PathPart Chained('rev') Args(0) {
 421       my ( $self, $c ) = @_;
 422       #  display the revision in our stash. Another option
 423       #  would be to forward a compatible object to the action
 424       #  that displays the default wiki pages, unless we want
 425       #  a different interface here, for example restore
 426       #  functionality.
 427   }
 428
 429 It would now be possible to add other endpoints, for example C<restore>
 430 to restore this specific revision as the current state.
 431
 432 You don't have to put all the chained actions in one controller. The
 433 specification of the parent through C<:Chained> also takes an absolute
 434 action path as its argument. Just specify it with a leading C</>.
 435
 436 If you want, for example, to have actions for the public paths
 437 C</foo/12/edit> and C</foo/12>, just specify two actions with
 438 C<:PathPart('foo')> and C<:Chained('/')>. The handler for the former
 439 path needs a C<:CaptureArgs(1)> attribute and a endpoint with
 440 C<:PathPart('edit')> and C<:Chained('foo')>. For the latter path give
 441 the action just a C<:Args(1)> to mark it as endpoint. This sums up to
 442 this debugging output:
 443
 444   ...
 445   [debug] Loaded Path Part actions:
 446   .-----------------------+------------------------------.
 447   | Path Spec             | Private                      |
 448   +-----------------------+------------------------------+
 449   | /foo/*                | /controller/foo_view         |
 450   | /foo/*/edit           | /controller/foo_load (1)     |
 451   |                       | => /controller/edit          |
 452   '-----------------------+------------------------------'
 453   ...
 454
 455 Here's a more detailed specification of the attributes belonging to
 456 C<:Chained>:
 457
 458 =head2 Attributes
 459
 460 =over 8
 461
 462 =item PathPart
 463
 464 Sets the name of this part of the chain. If it is specified without
 465 arguments, it takes the name of the action as default. So basically
 466 C<sub foo :PathPart> and C<sub foo :PathPart('foo')> are identical.
 467 This can also contain slashes to bind to a deeper level. An action
 468 with C<sub bar :PathPart('foo/bar') :Chained('/')> would bind to
 469 C</foo/bar/...>. If you don't specify C<:PathPart> it has the same
 470 effect as using C<:PathPart>, it would default to the action name.
 471
 472 =item Chained
 473
 474 Has to be specified for every child in the chain. Possible values are
 475 absolute and relative private action paths, with the relatives pointing
 476 to the current controller, or a single slash C</> to tell Catalyst that
 477 this is the root of a chain. The attribute C<:Chained> without arguments
 478 also defaults to the C</> behavior.
 479
 480 Because you can specify an absolute path to the parent action, it
 481 doesn't matter to Catalyst where that parent is located. So, if your
 482 design requests it, you can redispatch a chain through any controller or
 483 namespace you want.
 484
 485 Another interesting possibility gives C<:Chained('.')>, which chains
 486 itself to an action with the path of the current controller's namespace.
 487 For example:
 488
 489   #   in MyApp::Controller::Foo
 490   sub bar : Chained CaptureArgs(1) { ... }
 491
 492   #   in MyApp::Controller::Foo::Bar
 493   sub baz : Chained('.') Args(1) { ... }
 494
 495 This builds up a chain like C</bar/*/baz/*>. The specification of C<.>
 496 as the argument to Chained here chains the C<baz> action to an action
 497 with the path of the current controller namespace, namely
 498 C</foo/bar>. That action chains directly to C</>, so the C</bar/*/baz/*>
 499 chain comes out as the end product.
 500
 501 =item CaptureArgs
 502
 503 Must be specified for every part of the chain that is not an
 504 endpoint. With this attribute Catalyst knows how many of the following
 505 parts of the path (separated by C</>) this action wants to capture as
 506 its arguments. If it doesn't expect any, just specify
 507 C<:CaptureArgs(0)>.  The captures get passed to the action's C<@_> right
 508 after the context, but you can also find them as array references in
 509 C<$c-E<gt>request-E<gt>captures-E<gt>[$level]>. The C<$level> is the
 510 level of the action in the chain that captured the parts of the path.
 511
 512 An action that is part of a chain (that is, one that has a C<:Chained>
 513 attribute) but has no C<:CaptureArgs> attribute is treated by Catalyst
 514 as a chain end.
 515
 516 =item Args
 517
 518 By default, endpoints receive the rest of the arguments in the path. You
 519 can tell Catalyst through C<:Args> explicitly how many arguments your
 520 endpoint expects, just like you can with C<:CaptureArgs>. Note that this
 521 also affects whether this chain is invoked on a request. A chain with an
 522 endpoint specifying one argument will only match if exactly one argument
 523 exists in the path.
 524
 525 You can specify an exact number of arguments like C<:Args(3)>, including
 526 C<0>. If you just say C<:Args> without any arguments, it is the same as
 527 leaving it out altogether: The chain is matched regardless of the number
 528 of path parts after the endpoint.
 529
 530 Just as with C<:CaptureArgs>, the arguments get passed to the action in
 531 C<@_> after the context object. They can also be reached through
 532 C<$c-E<gt>request-E<gt>arguments>.
 533
 534 =back
 535
 536 =head2 Auto actions, dispatching and forwarding
 537
 538 Note that the list of C<auto> actions called depends on the private path
 539 of the endpoint of the chain, not on the chained actions way. The
 540 C<auto> actions will be run before the chain dispatching begins. In
 541 every other aspect, C<auto> actions behave as documented.
 542
 543 The C<forward>ing to other actions does just what you would expect. But if
 544 you C<detach> out of a chain, the rest of the chain will not get called
 545 after the C<detach>.
 546
 547 =head1 AUTHOR
 548
 549 Matt S Trout <mst@shadowcatsystems.co.uk>
 550
 551 =head1 COPYRIGHT
 552
 553 This program is free software, you can redistribute it and/or modify it under
 554 the same terms as Perl itself.
 555
 556 =cut
 557
 558 1;