lib/Catalyst/DispatchType/Chained.pm

   1 package Catalyst::DispatchType::Chained;
   2
   3 use Moose;
   4 extends 'Catalyst::DispatchType';
   5
   6 use Text::SimpleTable;
   7 use Catalyst::ActionChain;
   8 use Catalyst::Utils;
   9 use URI;
  10 use Scalar::Util ();
  11 use Encode 2.21 'decode_utf8';
  12
  13 has _endpoints => (
  14                    is => 'rw',
  15                    isa => 'ArrayRef',
  16                    required => 1,
  17                    default => sub{ [] },
  18                   );
  19
  20 has _actions => (
  21                  is => 'rw',
  22                  isa => 'HashRef',
  23                  required => 1,
  24                  default => sub{ {} },
  25                 );
  26
  27 has _children_of => (
  28                      is => 'rw',
  29                      isa => 'HashRef',
  30                      required => 1,
  31                      default => sub{ {} },
  32                     );
  33
  34 no Moose;
  35
  36 # please don't perltidy this. hairy code within.
  37
  38 =head1 NAME
  39
  40 Catalyst::DispatchType::Chained - Path Part DispatchType
  41
  42 =head1 SYNOPSIS
  43
  44 Path part matching, allowing several actions to sequentially take care of processing a request:
  45
  46   #   root action - captures one argument after it
  47   sub foo_setup : Chained('/') PathPart('foo') CaptureArgs(1) {
  48       my ( $self, $c, $foo_arg ) = @_;
  49       ...
  50   }
  51
  52   #   child action endpoint - takes one argument
  53   sub bar : Chained('foo_setup') Args(1) {
  54       my ( $self, $c, $bar_arg ) = @_;
  55       ...
  56   }
  57
  58 =head1 DESCRIPTION
  59
  60 Dispatch type managing default behaviour.  For more information on
  61 dispatch types, see:
  62
  63 =over 4
  64
  65 =item * L<Catalyst::Manual::Intro> for how they affect application authors
  66
  67 =item * L<Catalyst::DispatchType> for implementation information.
  68
  69 =back
  70
  71 =head1 METHODS
  72
  73 =head2 $self->list($c)
  74
  75 Debug output for Path Part dispatch points
  76
  77 =cut
  78
  79 sub list {
  80     my ( $self, $c ) = @_;
  81
  82     return unless $self->_endpoints;
  83
  84     my $avail_width = Catalyst::Utils::term_width() - 9;
  85     my $col1_width = ($avail_width * .50) < 35 ? 35 : int($avail_width * .50);
  86     my $col2_width = $avail_width - $col1_width;
  87     my $paths = Text::SimpleTable->new(
  88         [ $col1_width, 'Path Spec' ], [ $col2_width, 'Private' ],
  89     );
  90
  91     my $has_unattached_actions;
  92     my $unattached_actions = Text::SimpleTable->new(
  93         [ $col1_width, 'Private' ], [ $col2_width, 'Missing parent' ],
  94     );
  95
  96     ENDPOINT: foreach my $endpoint (
  97                   sort { $a->reverse cmp $b->reverse }
  98                            @{ $self->_endpoints }
  99                   ) {
 100         my $args = $endpoint->list_extra_info->{Args};
 101         my @parts = (defined($args) ? (("*") x $args) : '...');
 102         my @parents = ();
 103         my $parent = "DUMMY";
 104         my $extra  = $self->_list_extra_http_methods($endpoint);
 105         my $consumes = $self->_list_extra_consumes($endpoint);
 106         my $scheme = $self->_list_extra_scheme($endpoint);
 107         my $curr = $endpoint;
 108         while ($curr) {
 109             if (my $cap = $curr->list_extra_info->{CaptureArgs}) {
 110                 unshift(@parts, (("*") x $cap));
 111             }
 112             if (my $pp = $curr->attributes->{PathPart}) {
 113                 unshift(@parts, $pp->[0])
 114                     if (defined $pp->[0] && length $pp->[0]);
 115             }
 116             $parent = $curr->attributes->{Chained}->[0];
 117             $curr = $self->_actions->{$parent};
 118             unshift(@parents, $curr) if $curr;
 119         }
 120         if ($parent ne '/') {
 121             $has_unattached_actions = 1;
 122             $unattached_actions->row('/' . ($parents[0] || $endpoint)->reverse, $parent);
 123             next ENDPOINT;
 124         }
 125         my @rows;
 126         foreach my $p (@parents) {
 127             my $name = "/${p}";
 128
 129             if (defined(my $extra = $self->_list_extra_http_methods($p))) {
 130                 $name = "${extra} ${name}";
 131             }
 132             if (defined(my $cap = $p->list_extra_info->{CaptureArgs})) {
 133                 $name .= ' ('.$cap.')';
 134             }
 135             if (defined(my $ct = $p->list_extra_info->{Consumes})) {
 136                 $name .= ' :'.$ct;
 137             }
 138             if (defined(my $s = $p->list_extra_info->{Scheme})) {
 139                 $scheme = uc $s;
 140             }
 141
 142             unless ($p eq $parents[0]) {
 143                 $name = "-> ${name}";
 144             }
 145             push(@rows, [ '', $name ]);
 146         }
 147         push(@rows, [ '', (@rows ? "=> " : '').($extra ? "$extra " : ''). ($scheme ? "$scheme: ":'')."/${endpoint}". ($consumes ? " :$consumes":"" ) ]);
 148         my @display_parts = map { $_ =~s/%([0-9A-Fa-f]{2})/chr(hex($1))/eg; decode_utf8 $_ } @parts;
 149         $rows[0][0] = join('/', '', @display_parts) || '/';
 150         $paths->row(@$_) for @rows;
 151     }
 152
 153     $c->log->debug( "Loaded Chained actions:\n" . $paths->draw . "\n" );
 154     $c->log->debug( "Unattached Chained actions:\n", $unattached_actions->draw . "\n" )
 155         if $has_unattached_actions;
 156 }
 157
 158 sub _list_extra_http_methods {
 159     my ( $self, $action ) = @_;
 160     return unless defined $action->list_extra_info->{HTTP_METHODS};
 161     return join(', ', @{$action->list_extra_info->{HTTP_METHODS}});
 162
 163 }
 164
 165 sub _list_extra_consumes {
 166     my ( $self, $action ) = @_;
 167     return unless defined $action->list_extra_info->{CONSUMES};
 168     return join(', ', @{$action->list_extra_info->{CONSUMES}});
 169 }
 170
 171 sub _list_extra_scheme {
 172     my ( $self, $action ) = @_;
 173     return unless defined $action->list_extra_info->{Scheme};
 174     return uc $action->list_extra_info->{Scheme};
 175 }
 176
 177 =head2 $self->match( $c, $path )
 178
 179 Calls C<recurse_match> to see if a chain matches the C<$path>.
 180
 181 =cut
 182
 183 sub match {
 184     my ( $self, $c, $path ) = @_;
 185
 186     my $request = $c->request;
 187     return 0 if @{$request->args};
 188
 189     my @parts = split('/', $path);
 190
 191     my ($chain, $captures, $parts) = $self->recurse_match($c, '/', \@parts);
 192
 193     if ($parts && @$parts) {
 194         for my $arg (@$parts) {
 195             $arg =~ s/%([0-9A-Fa-f]{2})/chr(hex($1))/eg;
 196             push @{$request->args}, $arg;
 197         }
 198     }
 199
 200     return 0 unless $chain;
 201
 202     my $action = Catalyst::ActionChain->from_chain($chain);
 203
 204     $request->action("/${action}");
 205     $request->match("/${action}");
 206     $request->captures($captures);
 207     $c->action($action);
 208     $c->namespace( $action->namespace );
 209
 210     return 1;
 211 }
 212
 213 =head2 $self->recurse_match( $c, $parent, \@path_parts )
 214
 215 Recursive search for a matching chain.
 216
 217 =cut
 218
 219 sub recurse_match {
 220     my ( $self, $c, $parent, $path_parts ) = @_;
 221     my $children = $self->_children_of->{$parent};
 222     return () unless $children;
 223     my $best_action;
 224     my @captures;
 225     TRY: foreach my $try_part (sort { length($b) <=> length($a) }
 226                                    keys %$children) {
 227                                # $b then $a to try longest part first
 228         my @parts = @$path_parts;
 229         if (length $try_part) { # test and strip PathPart
 230             next TRY unless
 231               ($try_part eq join('/', # assemble equal number of parts
 232                               splice( # and strip them off @parts as well
 233                                 @parts, 0, scalar(@{[split('/', $try_part)]})
 234                               ))); # @{[]} to avoid split to @_
 235         }
 236         my @try_actions = @{$children->{$try_part}};
 237         TRY_ACTION: foreach my $action (@try_actions) {
 238             if (my $capture_attr = $action->attributes->{CaptureArgs}) {
 239                 my $capture_count = $capture_attr->[0] || 0;
 240
 241                 # Short-circuit if not enough remaining parts
 242                 next TRY_ACTION unless @parts >= $capture_count;
 243
 244                 my @captures;
 245                 my @parts = @parts; # localise
 246
 247                 # strip CaptureArgs into list
 248                 push(@captures, splice(@parts, 0, $capture_count));
 249
 250                 # check if the action may fit, depending on a given test by the app
 251                 if ($action->can('match_captures')) { next TRY_ACTION unless $action->match_captures($c, \@captures) }
 252
 253                 # try the remaining parts against children of this action
 254                 my ($actions, $captures, $action_parts, $n_pathparts) = $self->recurse_match(
 255                                              $c, '/'.$action->reverse, \@parts
 256                                            );
 257                 #    No best action currently
 258                 # OR The action has less parts
 259                 # OR The action has equal parts but less captured data (ergo more defined)
 260                 if ($actions    &&
 261                     (!$best_action                                 ||
 262                      $#$action_parts < $#{$best_action->{parts}}   ||
 263                      ($#$action_parts == $#{$best_action->{parts}} &&
 264                       $#$captures < $#{$best_action->{captures}} &&
 265                       $n_pathparts > $best_action->{n_pathparts}))) {
 266                     my @pathparts = split /\//, $action->attributes->{PathPart}->[0];
 267                     $best_action = {
 268                         actions => [ $action, @$actions ],
 269                         captures=> [ @captures, @$captures ],
 270                         parts   => $action_parts,
 271                         n_pathparts => scalar(@pathparts) + $n_pathparts,
 272                     };
 273                 }
 274             }
 275             else {
 276                 {
 277                     local $c->req->{arguments} = [ @{$c->req->args}, @parts ];
 278                     next TRY_ACTION unless $action->match($c);
 279                 }
 280                 my $args_attr = $action->attributes->{Args}->[0];
 281                 my @pathparts = split /\//, $action->attributes->{PathPart}->[0];
 282                 #    No best action currently
 283                 # OR This one matches with fewer parts left than the current best action,
 284                 #    And therefore is a better match
 285                 # OR No parts and this expects 0
 286                 #    The current best action might also be Args(0),
 287                 #    but we couldn't chose between then anyway so we'll take the last seen
 288
 289                 if (
 290                     !$best_action                       ||
 291                     @parts < @{$best_action->{parts}}   ||
 292                     (
 293                         !@parts &&
 294                         defined($args_attr) &&
 295                         (
 296                             $args_attr eq "0" &&
 297                             (
 298                               ($c->config->{use_chained_args_0_special_case}||0) ||
 299                                 (
 300                                   exists($best_action->{args_attr}) && defined($best_action->{args_attr}) ?
 301                                   ($best_action->{args_attr} ne 0) : 1
 302                                 )
 303                             )
 304                         )
 305                     )
 306                 ){
 307                     $best_action = {
 308                         actions => [ $action ],
 309                         captures=> [],
 310                         parts   => \@parts,
 311                         args_attr => $args_attr,
 312                         n_pathparts => scalar(@pathparts),
 313                     };
 314                 }
 315             }
 316         }
 317     }
 318     return @$best_action{qw/actions captures parts n_pathparts/} if $best_action;
 319     return ();
 320 }
 321
 322 =head2 $self->register( $c, $action )
 323
 324 Calls register_path for every Path attribute for the given $action.
 325
 326 =cut
 327
 328 sub _check_args_attr {
 329     my ( $self, $action, $name ) = @_;
 330
 331     return unless exists $action->attributes->{$name};
 332
 333     if (@{$action->attributes->{$name}} > 1) {
 334         Catalyst::Exception->throw(
 335           "Multiple $name attributes not supported registering " . $action->reverse()
 336         );
 337     }
 338     my $args = $action->attributes->{$name}->[0];
 339     if (defined($args) and not (
 340         Scalar::Util::looks_like_number($args) and
 341         int($args) == $args and $args >= 0
 342     )) {
 343         require Data::Dumper;
 344         local $Data::Dumper::Terse = 1;
 345         local $Data::Dumper::Indent = 0;
 346         $args = Data::Dumper::Dumper($args);
 347         Catalyst::Exception->throw(
 348           "Invalid $name($args) for action " . $action->reverse() .
 349           " (use '$name' or '$name(<number>)')"
 350         );
 351     }
 352 }
 353
 354 sub register {
 355     my ( $self, $c, $action ) = @_;
 356
 357     my @chained_attr = @{ $action->attributes->{Chained} || [] };
 358
 359     return 0 unless @chained_attr;
 360
 361     if (@chained_attr > 1) {
 362         Catalyst::Exception->throw(
 363           "Multiple Chained attributes not supported registering ${action}"
 364         );
 365     }
 366     my $chained_to = $chained_attr[0];
 367
 368     Catalyst::Exception->throw(
 369       "Actions cannot chain to themselves registering /${action}"
 370     ) if ($chained_to eq '/' . $action);
 371
 372     my $children = ($self->_children_of->{ $chained_to } ||= {});
 373
 374     my @path_part = @{ $action->attributes->{PathPart} || [] };
 375
 376     my $part = $action->name;
 377
 378     if (@path_part == 1 && defined $path_part[0]) {
 379         $part = $path_part[0];
 380     } elsif (@path_part > 1) {
 381         Catalyst::Exception->throw(
 382           "Multiple PathPart attributes not supported registering " . $action->reverse()
 383         );
 384     }
 385
 386     if ($part =~ m(^/)) {
 387         Catalyst::Exception->throw(
 388           "Absolute parameters to PathPart not allowed registering " . $action->reverse()
 389         );
 390     }
 391
 392     my $encoded_part = URI->new($part)->canonical;
 393     $encoded_part =~ s{(?<=[^/])/+\z}{};
 394
 395     $action->attributes->{PathPart} = [ $encoded_part ];
 396
 397     unshift(@{ $children->{$encoded_part} ||= [] }, $action);
 398
 399     $self->_actions->{'/'.$action->reverse} = $action;
 400
 401     foreach my $name (qw(Args CaptureArgs)) {
 402         $self->_check_args_attr($action, $name);
 403     }
 404
 405     if (exists $action->attributes->{Args} and exists $action->attributes->{CaptureArgs}) {
 406         Catalyst::Exception->throw(
 407           "Combining Args and CaptureArgs attributes not supported registering " .
 408           $action->reverse()
 409         );
 410     }
 411
 412     unless ($action->attributes->{CaptureArgs}) {
 413         unshift(@{ $self->_endpoints }, $action);
 414     }
 415
 416     return 1;
 417 }
 418
 419 =head2 $self->uri_for_action($action, $captures)
 420
 421 Get the URI part for the action, using C<$captures> to fill
 422 the capturing parts.
 423
 424 =cut
 425
 426 sub uri_for_action {
 427     my ( $self, $action, $captures ) = @_;
 428
 429     return undef unless ($action->attributes->{Chained}
 430                            && !$action->attributes->{CaptureArgs});
 431
 432     my @parts = ();
 433     my @captures = @$captures;
 434     my $parent = "DUMMY";
 435     my $curr = $action;
 436     while ($curr) {
 437         if (my $cap = $curr->attributes->{CaptureArgs}) {
 438             return undef unless @captures >= ($cap->[0]||0); # not enough captures
 439             if ($cap->[0]) {
 440                 unshift(@parts, splice(@captures, -$cap->[0]));
 441             }
 442         }
 443         if (my $pp = $curr->attributes->{PathPart}) {
 444             unshift(@parts, $pp->[0])
 445                 if (defined($pp->[0]) && length($pp->[0]));
 446         }
 447         $parent = $curr->attributes->{Chained}->[0];
 448         $curr = $self->_actions->{$parent};
 449     }
 450
 451     return undef unless $parent eq '/'; # fail for dangling action
 452
 453     return undef if @captures; # fail for too many captures
 454
 455     return join('/', '', @parts);
 456
 457 }
 458
 459 =head2 $c->expand_action($action)
 460
 461 Return a list of actions that represents a chained action. See
 462 L<Catalyst::Dispatcher> for more info. You probably want to
 463 use the expand_action it provides rather than this directly.
 464
 465 =cut
 466
 467 sub expand_action {
 468     my ($self, $action) = @_;
 469
 470     return unless $action->attributes && $action->attributes->{Chained};
 471
 472     my @chain;
 473     my $curr = $action;
 474
 475     while ($curr) {
 476         push @chain, $curr;
 477         my $parent = $curr->attributes->{Chained}->[0];
 478         $curr = $self->_actions->{$parent};
 479     }
 480
 481     return Catalyst::ActionChain->from_chain([reverse @chain]);
 482 }
 483
 484 __PACKAGE__->meta->make_immutable;
 485 1;
 486
 487 =head1 USAGE
 488
 489 =head2 Introduction
 490
 491 The C<Chained> attribute allows you to chain public path parts together
 492 by their private names. A chain part's path can be specified with
 493 C<PathPart> and can be declared to expect an arbitrary number of
 494 arguments. The endpoint of the chain specifies how many arguments it
 495 gets through the C<Args> attribute. C<:Args(0)> would be none at all,
 496 C<:Args> without an integer would be unlimited. The path parts that
 497 aren't endpoints are using C<CaptureArgs> to specify how many parameters
 498 they expect to receive. As an example setup:
 499
 500   package MyApp::Controller::Greeting;
 501   use base qw/ Catalyst::Controller /;
 502
 503   #   this is the beginning of our chain
 504   sub hello : PathPart('hello') Chained('/') CaptureArgs(1) {
 505       my ( $self, $c, $integer ) = @_;
 506       $c->stash->{ message } = "Hello ";
 507       $c->stash->{ arg_sum } = $integer;
 508   }
 509
 510   #   this is our endpoint, because it has no :CaptureArgs
 511   sub world : PathPart('world') Chained('hello') Args(1) {
 512       my ( $self, $c, $integer ) = @_;
 513       $c->stash->{ message } .= "World!";
 514       $c->stash->{ arg_sum } += $integer;
 515
 516       $c->response->body( join "<br/>\n" =>
 517           $c->stash->{ message }, $c->stash->{ arg_sum } );
 518   }
 519
 520 The debug output provides a separate table for chained actions, showing
 521 the whole chain as it would match and the actions it contains. Here's an
 522 example of the startup output with our actions above:
 523
 524   ...
 525   [debug] Loaded Path Part actions:
 526   .-----------------------+------------------------------.
 527   | Path Spec             | Private                      |
 528   +-----------------------+------------------------------+
 529   | /hello/*/world/*      | /greeting/hello (1)          |
 530   |                       | => /greeting/world           |
 531   '-----------------------+------------------------------'
 532   ...
 533
 534 As you can see, Catalyst only deals with chains as whole paths and
 535 builds one for each endpoint, which are the actions with C<:Chained> but
 536 without C<:CaptureArgs>.
 537
 538 Let's assume this application gets a request at the path
 539 C</hello/23/world/12>. What happens then? First, Catalyst will dispatch
 540 to the C<hello> action and pass the value C<23> as an argument to it
 541 after the context. It does so because we have previously used
 542 C<:CaptureArgs(1)> to declare that it has one path part after itself as
 543 its argument. We told Catalyst that this is the beginning of the chain
 544 by specifying C<:Chained('/')>. Also note that instead of saying
 545 C<:PathPart('hello')> we could also just have said C<:PathPart>, as it
 546 defaults to the name of the action.
 547
 548 After C<hello> has run, Catalyst goes on to dispatch to the C<world>
 549 action. This is the last action to be called: Catalyst knows this is an
 550 endpoint because we did not specify a C<:CaptureArgs>
 551 attribute. Nevertheless we specify that this action expects an argument,
 552 but at this point we're using C<:Args(1)> to do that. We could also have
 553 said C<:Args> or left it out altogether, which would mean this action
 554 would get all arguments that are there. This action's C<:Chained>
 555 attribute says C<hello> and tells Catalyst that the C<hello> action in
 556 the current controller is its parent.
 557
 558 With this we have built a chain consisting of two public path parts.
 559 C<hello> captures one part of the path as its argument, and also
 560 specifies the path root as its parent. So this part is
 561 C</hello/$arg>. The next part is the endpoint C<world>, expecting one
 562 argument. It sums up to the path part C<world/$arg>. This leads to a
 563 complete chain of C</hello/$arg/world/$arg> which is matched against the
 564 requested paths.
 565
 566 This example application would, if run and called by e.g.
 567 C</hello/23/world/12>, set the stash value C<message> to "Hello" and the
 568 value C<arg_sum> to "23". The C<world> action would then append "World!"
 569 to C<message> and add C<12> to the stash's C<arg_sum> value.  For the
 570 sake of simplicity no view is shown. Instead we just put the values of
 571 the stash into our body. So the output would look like:
 572
 573   Hello World!
 574   35
 575
 576 And our test server would have given us this debugging output for the
 577 request:
 578
 579   ...
 580   [debug] "GET" request for "hello/23/world/12" from "127.0.0.1"
 581   [debug] Path is "/greeting/world"
 582   [debug] Arguments are "12"
 583   [info] Request took 0.164113s (6.093/s)
 584   .------------------------------------------+-----------.
 585   | Action                                   | Time      |
 586   +------------------------------------------+-----------+
 587   | /greeting/hello                          | 0.000029s |
 588   | /greeting/world                          | 0.000024s |
 589   '------------------------------------------+-----------'
 590   ...
 591
 592 What would be common uses of this dispatch technique? It gives the
 593 possibility to split up logic that contains steps that each depend on
 594 each other. An example would be, for example, a wiki path like
 595 C</wiki/FooBarPage/rev/23/view>. This chain can be easily built with
 596 these actions:
 597
 598   sub wiki : PathPart('wiki') Chained('/') CaptureArgs(1) {
 599       my ( $self, $c, $page_name ) = @_;
 600       #  load the page named $page_name and put the object
 601       #  into the stash
 602   }
 603
 604   sub rev : PathPart('rev') Chained('wiki') CaptureArgs(1) {
 605       my ( $self, $c, $revision_id ) = @_;
 606       #  use the page object in the stash to get at its
 607       #  revision with number $revision_id
 608   }
 609
 610   sub view : PathPart Chained('rev') Args(0) {
 611       my ( $self, $c ) = @_;
 612       #  display the revision in our stash. Another option
 613       #  would be to forward a compatible object to the action
 614       #  that displays the default wiki pages, unless we want
 615       #  a different interface here, for example restore
 616       #  functionality.
 617   }
 618
 619 It would now be possible to add other endpoints, for example C<restore>
 620 to restore this specific revision as the current state.
 621
 622 You don't have to put all the chained actions in one controller. The
 623 specification of the parent through C<:Chained> also takes an absolute
 624 action path as its argument. Just specify it with a leading C</>.
 625
 626 If you want, for example, to have actions for the public paths
 627 C</foo/12/edit> and C</foo/12>, just specify two actions with
 628 C<:PathPart('foo')> and C<:Chained('/')>. The handler for the former
 629 path needs a C<:CaptureArgs(1)> attribute and a endpoint with
 630 C<:PathPart('edit')> and C<:Chained('foo')>. For the latter path give
 631 the action just a C<:Args(1)> to mark it as endpoint. This sums up to
 632 this debugging output:
 633
 634   ...
 635   [debug] Loaded Path Part actions:
 636   .-----------------------+------------------------------.
 637   | Path Spec             | Private                      |
 638   +-----------------------+------------------------------+
 639   | /foo/*                | /controller/foo_view         |
 640   | /foo/*/edit           | /controller/foo_load (1)     |
 641   |                       | => /controller/edit          |
 642   '-----------------------+------------------------------'
 643   ...
 644
 645 Here's a more detailed specification of the attributes belonging to
 646 C<:Chained>:
 647
 648 =head2 Attributes
 649
 650 =over 8
 651
 652 =item PathPart
 653
 654 Sets the name of this part of the chain. If it is specified without
 655 arguments, it takes the name of the action as default. So basically
 656 C<sub foo :PathPart> and C<sub foo :PathPart('foo')> are identical.
 657 This can also contain slashes to bind to a deeper level. An action
 658 with C<sub bar :PathPart('foo/bar') :Chained('/')> would bind to
 659 C</foo/bar/...>. If you don't specify C<:PathPart> it has the same
 660 effect as using C<:PathPart>, it would default to the action name.
 661
 662 =item PathPrefix
 663
 664 Sets PathPart to the path_prefix of the current controller.
 665
 666 =item Chained
 667
 668 Has to be specified for every child in the chain. Possible values are
 669 absolute and relative private action paths or a single slash C</> to
 670 tell Catalyst that this is the root of a chain. The attribute
 671 C<:Chained> without arguments also defaults to the C</> behavior.
 672 Relative action paths may use C<../> to refer to actions in parent
 673 controllers.
 674
 675 Because you can specify an absolute path to the parent action, it
 676 doesn't matter to Catalyst where that parent is located. So, if your
 677 design requests it, you can redispatch a chain through any controller or
 678 namespace you want.
 679
 680 Another interesting possibility gives C<:Chained('.')>, which chains
 681 itself to an action with the path of the current controller's namespace.
 682 For example:
 683
 684   #   in MyApp::Controller::Foo
 685   sub bar : Chained CaptureArgs(1) { ... }
 686
 687   #   in MyApp::Controller::Foo::Bar
 688   sub baz : Chained('.') Args(1) { ... }
 689
 690 This builds up a chain like C</bar/*/baz/*>. The specification of C<.>
 691 as the argument to Chained here chains the C<baz> action to an action
 692 with the path of the current controller namespace, namely
 693 C</foo/bar>. That action chains directly to C</>, so the C</bar/*/baz/*>
 694 chain comes out as the end product.
 695
 696 =item ChainedParent
 697
 698 Chains an action to another action with the same name in the parent
 699 controller. For Example:
 700
 701   # in MyApp::Controller::Foo
 702   sub bar : Chained CaptureArgs(1) { ... }
 703
 704   # in MyApp::Controller::Foo::Moo
 705   sub bar : ChainedParent Args(1) { ... }
 706
 707 This builds a chain like C</bar/*/bar/*>.
 708
 709 =item CaptureArgs
 710
 711 Must be specified for every part of the chain that is not an
 712 endpoint. With this attribute Catalyst knows how many of the following
 713 parts of the path (separated by C</>) this action wants to capture as
 714 its arguments. If it doesn't expect any, just specify
 715 C<:CaptureArgs(0)>.  The captures get passed to the action's C<@_> right
 716 after the context, but you can also find them as array references in
 717 C<$c-E<gt>request-E<gt>captures-E<gt>[$level]>. The C<$level> is the
 718 level of the action in the chain that captured the parts of the path.
 719
 720 An action that is part of a chain (that is, one that has a C<:Chained>
 721 attribute) but has no C<:CaptureArgs> attribute is treated by Catalyst
 722 as a chain end.
 723
 724 =item Args
 725
 726 By default, endpoints receive the rest of the arguments in the path. You
 727 can tell Catalyst through C<:Args> explicitly how many arguments your
 728 endpoint expects, just like you can with C<:CaptureArgs>. Note that this
 729 also affects whether this chain is invoked on a request. A chain with an
 730 endpoint specifying one argument will only match if exactly one argument
 731 exists in the path.
 732
 733 You can specify an exact number of arguments like C<:Args(3)>, including
 734 C<0>. If you just say C<:Args> without any arguments, it is the same as
 735 leaving it out altogether: The chain is matched regardless of the number
 736 of path parts after the endpoint.
 737
 738 Just as with C<:CaptureArgs>, the arguments get passed to the action in
 739 C<@_> after the context object. They can also be reached through
 740 C<$c-E<gt>request-E<gt>arguments>.
 741
 742 =back
 743
 744 =head2 Auto actions, dispatching and forwarding
 745
 746 Note that the list of C<auto> actions called depends on the private path
 747 of the endpoint of the chain, not on the chained actions way. The
 748 C<auto> actions will be run before the chain dispatching begins. In
 749 every other aspect, C<auto> actions behave as documented.
 750
 751 The C<forward>ing to other actions does just what you would expect. i.e.
 752 only the target action is run. The actions that that action is chained
 753 to are not run.
 754 If you C<detach> out of a chain, the rest of the chain will not get
 755 called after the C<detach>.
 756
 757 =head2 match_captures
 758
 759 A method which can optionally be implemented by actions to
 760 stop chain matching.
 761
 762 See L<Catalyst::Action> for further details.
 763
 764 =head1 AUTHORS
 765
 766 Catalyst Contributors, see Catalyst.pm
 767
 768 =head1 COPYRIGHT
 769
 770 This library is free software. You can redistribute it and/or modify it under
 771 the same terms as Perl itself.
 772
 773 =cut
 774
 775 1;