lib/Catalyst/DispatchType/Chained.pm

   1 package Catalyst::DispatchType::Chained;
   2
   3 use Moose;
   4 extends 'Catalyst::DispatchType';
   5
   6 use Text::SimpleTable;
   7 use Catalyst::ActionChain;
   8 use Catalyst::Utils;
   9 use URI;
  10 use Scalar::Util ();
  11 use Encode 2.21 'decode_utf8';
  12
  13 has _endpoints => (
  14                    is => 'rw',
  15                    isa => 'ArrayRef',
  16                    required => 1,
  17                    default => sub{ [] },
  18                   );
  19
  20 has _actions => (
  21                  is => 'rw',
  22                  isa => 'HashRef',
  23                  required => 1,
  24                  default => sub{ {} },
  25                 );
  26
  27 has _children_of => (
  28                      is => 'rw',
  29                      isa => 'HashRef',
  30                      required => 1,
  31                      default => sub{ {} },
  32                     );
  33
  34 no Moose;
  35
  36 # please don't perltidy this. hairy code within.
  37
  38 =head1 NAME
  39
  40 Catalyst::DispatchType::Chained - Path Part DispatchType
  41
  42 =head1 SYNOPSIS
  43
  44 Path part matching, allowing several actions to sequentially take care of processing a request:
  45
  46   #   root action - captures one argument after it
  47   sub foo_setup : Chained('/') PathPart('foo') CaptureArgs(1) {
  48       my ( $self, $c, $foo_arg ) = @_;
  49       ...
  50   }
  51
  52   #   child action endpoint - takes one argument
  53   sub bar : Chained('foo_setup') Args(1) {
  54       my ( $self, $c, $bar_arg ) = @_;
  55       ...
  56   }
  57
  58 =head1 DESCRIPTION
  59
  60 Dispatch type managing default behaviour.  For more information on
  61 dispatch types, see:
  62
  63 =over 4
  64
  65 =item * L<Catalyst::Manual::Intro> for how they affect application authors
  66
  67 =item * L<Catalyst::DispatchType> for implementation information.
  68
  69 =back
  70
  71 =head1 METHODS
  72
  73 =head2 $self->list($c)
  74
  75 Debug output for Path Part dispatch points
  76
  77 =cut
  78
  79 sub list {
  80     my ( $self, $c ) = @_;
  81
  82     return unless $self->_endpoints;
  83
  84     my $avail_width = Catalyst::Utils::term_width() - 9;
  85     my $col1_width = ($avail_width * .50) < 35 ? 35 : int($avail_width * .50);
  86     my $col2_width = $avail_width - $col1_width;
  87     my $paths = Text::SimpleTable->new(
  88         [ $col1_width, 'Path Spec' ], [ $col2_width, 'Private' ],
  89     );
  90
  91     my $has_unattached_actions;
  92     my $unattached_actions = Text::SimpleTable->new(
  93         [ $col1_width, 'Private' ], [ $col2_width, 'Missing parent' ],
  94     );
  95
  96     ENDPOINT: foreach my $endpoint (
  97                   sort { $a->reverse cmp $b->reverse }
  98                            @{ $self->_endpoints }
  99                   ) {
 100         my $args = $endpoint->list_extra_info->{Args};
 101         my @parts = (defined($args) ? (("*") x $args) : '...');
 102         my @parents = ();
 103         my $parent = "DUMMY";
 104         my $extra  = $self->_list_extra_http_methods($endpoint);
 105         my $consumes = $self->_list_extra_consumes($endpoint);
 106         my $scheme = $self->_list_extra_scheme($endpoint);
 107         my $curr = $endpoint;
 108         while ($curr) {
 109             if (my $cap = $curr->list_extra_info->{CaptureArgs}) {
 110                 unshift(@parts, (("*") x $cap));
 111             }
 112             if (my $pp = $curr->attributes->{PathPart}) {
 113                 unshift(@parts, $pp->[0])
 114                     if (defined $pp->[0] && length $pp->[0]);
 115             }
 116             $parent = $curr->attributes->{Chained}->[0];
 117             $curr = $self->_actions->{$parent};
 118             unshift(@parents, $curr) if $curr;
 119         }
 120         if ($parent ne '/') {
 121             $has_unattached_actions = 1;
 122             $unattached_actions->row('/' . ($parents[0] || $endpoint)->reverse, $parent);
 123             next ENDPOINT;
 124         }
 125         my @rows;
 126         foreach my $p (@parents) {
 127             my $name = "/${p}";
 128
 129             if (defined(my $extra = $self->_list_extra_http_methods($p))) {
 130                 $name = "${extra} ${name}";
 131             }
 132             if (defined(my $cap = $p->list_extra_info->{CaptureArgs})) {
 133                 $name .= ' ('.$cap.')';
 134             }
 135             if (defined(my $ct = $p->list_extra_info->{Consumes})) {
 136                 $name .= ' :'.$ct;
 137             }
 138             if (defined(my $s = $p->list_extra_info->{Scheme})) {
 139                 $scheme = uc $s;
 140             }
 141
 142             unless ($p eq $parents[0]) {
 143                 $name = "-> ${name}";
 144             }
 145             push(@rows, [ '', $name ]);
 146         }
 147         push(@rows, [ '', (@rows ? "=> " : '').($extra ? "$extra " : ''). ($scheme ? "$scheme: ":'')."/${endpoint}". ($consumes ? " :$consumes":"" ) ]);
 148         my @display_parts = map { $_ =~s/%([0-9A-Fa-f]{2})/chr(hex($1))/eg; decode_utf8 $_ } @parts;
 149         $rows[0][0] = join('/', '', @display_parts) || '/';
 150         $paths->row(@$_) for @rows;
 151     }
 152
 153     $c->log->debug( "Loaded Chained actions:\n" . $paths->draw . "\n" );
 154     $c->log->debug( "Unattached Chained actions:\n", $unattached_actions->draw . "\n" )
 155         if $has_unattached_actions;
 156 }
 157
 158 sub _list_extra_http_methods {
 159     my ( $self, $action ) = @_;
 160     return unless defined $action->list_extra_info->{HTTP_METHODS};
 161     return join(', ', @{$action->list_extra_info->{HTTP_METHODS}});
 162
 163 }
 164
 165 sub _list_extra_consumes {
 166     my ( $self, $action ) = @_;
 167     return unless defined $action->list_extra_info->{CONSUMES};
 168     return join(', ', @{$action->list_extra_info->{CONSUMES}});
 169 }
 170
 171 sub _list_extra_scheme {
 172     my ( $self, $action ) = @_;
 173     return unless defined $action->list_extra_info->{Scheme};
 174     return uc $action->list_extra_info->{Scheme};
 175 }
 176
 177 =head2 $self->match( $c, $path )
 178
 179 Calls C<recurse_match> to see if a chain matches the C<$path>.
 180
 181 =cut
 182
 183 sub match {
 184     my ( $self, $c, $path ) = @_;
 185
 186     my $request = $c->request;
 187     return 0 if @{$request->args};
 188
 189     my @parts = split('/', $path);
 190
 191     my ($chain, $captures, $parts) = $self->recurse_match($c, '/', \@parts);
 192
 193     if ($parts && @$parts) {
 194         for my $arg (@$parts) {
 195             $arg =~ s/%([0-9A-Fa-f]{2})/chr(hex($1))/eg;
 196             push @{$request->args}, $arg;
 197         }
 198     }
 199
 200     return 0 unless $chain;
 201
 202     my $action = Catalyst::ActionChain->from_chain($chain);
 203
 204     $request->action("/${action}");
 205     $request->match("/${action}");
 206     $request->captures($captures);
 207     $c->action($action);
 208     $c->namespace( $action->namespace );
 209
 210     return 1;
 211 }
 212
 213 =head2 $self->recurse_match( $c, $parent, \@path_parts )
 214
 215 Recursive search for a matching chain.
 216
 217 =cut
 218
 219 sub recurse_match {
 220     my ( $self, $c, $parent, $path_parts ) = @_;
 221     my $children = $self->_children_of->{$parent};
 222     return () unless $children;
 223     my $best_action;
 224     my @captures;
 225     TRY: foreach my $try_part (sort { length($b) <=> length($a) }
 226                                    keys %$children) {
 227                                # $b then $a to try longest part first
 228         my @parts = @$path_parts;
 229         if (length $try_part) { # test and strip PathPart
 230             next TRY unless
 231               ($try_part eq join('/', # assemble equal number of parts
 232                               splice( # and strip them off @parts as well
 233                                 @parts, 0, scalar(@{[split('/', $try_part)]})
 234                               ))); # @{[]} to avoid split to @_
 235         }
 236         my @try_actions = @{$children->{$try_part}};
 237         TRY_ACTION: foreach my $action (@try_actions) {
 238             if (my $capture_attr = $action->attributes->{CaptureArgs}) {
 239                 my $capture_count = $capture_attr->[0] || 0;
 240
 241                 # Short-circuit if not enough remaining parts
 242                 next TRY_ACTION unless @parts >= $capture_count;
 243
 244                 my @captures;
 245                 my @parts = @parts; # localise
 246
 247                 # strip CaptureArgs into list
 248                 push(@captures, splice(@parts, 0, $capture_count));
 249
 250                 # check if the action may fit, depending on a given test by the app
 251                 if ($action->can('match_captures')) { next TRY_ACTION unless $action->match_captures($c, \@captures) }
 252
 253                 # try the remaining parts against children of this action
 254                 my ($actions, $captures, $action_parts, $n_pathparts) = $self->recurse_match(
 255                                              $c, '/'.$action->reverse, \@parts
 256                                            );
 257                 #    No best action currently
 258                 # OR The action has less parts
 259                 # OR The action has equal parts but less captured data (ergo more defined)
 260                 if ($actions    &&
 261                     (!$best_action                                 ||
 262                      $#$action_parts < $#{$best_action->{parts}}   ||
 263                      ($#$action_parts == $#{$best_action->{parts}} &&
 264                       $#$captures < $#{$best_action->{captures}} &&
 265                       $n_pathparts > $best_action->{n_pathparts}))) {
 266                     my @pathparts = split /\//, $action->attributes->{PathPart}->[0];
 267                     $best_action = {
 268                         actions => [ $action, @$actions ],
 269                         captures=> [ @captures, @$captures ],
 270                         parts   => $action_parts,
 271                         n_pathparts => scalar(@pathparts) + $n_pathparts,
 272                     };
 273                 }
 274             }
 275             else {
 276                 {
 277                     local $c->req->{arguments} = [ @{$c->req->args}, @parts ];
 278                     next TRY_ACTION unless $action->match($c);
 279                 }
 280                 my $args_attr = $action->attributes->{Args}->[0];
 281                 my @pathparts = split /\//, $action->attributes->{PathPart}->[0];
 282                 #    No best action currently
 283                 # OR This one matches with fewer parts left than the current best action,
 284                 #    And therefore is a better match
 285                 # OR No parts and this expects 0
 286                 #    The current best action might also be Args(0),
 287                 #    but we couldn't chose between then anyway so we'll take the last seen
 288
 289                 if (
 290                     !$best_action                       ||
 291                     @parts < @{$best_action->{parts}}   ||
 292                     (
 293                         !@parts &&
 294                         defined($args_attr) &&
 295                         $args_attr eq "0"
 296                     )
 297                 ){
 298                     $best_action = {
 299                         actions => [ $action ],
 300                         captures=> [],
 301                         parts   => \@parts,
 302                         n_pathparts => scalar(@pathparts),
 303                     };
 304                 }
 305             }
 306         }
 307     }
 308     return @$best_action{qw/actions captures parts n_pathparts/} if $best_action;
 309     return ();
 310 }
 311
 312 =head2 $self->register( $c, $action )
 313
 314 Calls register_path for every Path attribute for the given $action.
 315
 316 =cut
 317
 318 sub _check_args_attr {
 319     my ( $self, $action, $name ) = @_;
 320
 321     return unless exists $action->attributes->{$name};
 322
 323     if (@{$action->attributes->{$name}} > 1) {
 324         Catalyst::Exception->throw(
 325           "Multiple $name attributes not supported registering " . $action->reverse()
 326         );
 327     }
 328     my $args = $action->attributes->{$name}->[0];
 329     if (defined($args) and not (
 330         Scalar::Util::looks_like_number($args) and
 331         int($args) == $args and $args >= 0
 332     )) {
 333         require Data::Dumper;
 334         local $Data::Dumper::Terse = 1;
 335         local $Data::Dumper::Indent = 0;
 336         $args = Data::Dumper::Dumper($args);
 337         Catalyst::Exception->throw(
 338           "Invalid $name($args) for action " . $action->reverse() .
 339           " (use '$name' or '$name(<number>)')"
 340         );
 341     }
 342 }
 343
 344 sub register {
 345     my ( $self, $c, $action ) = @_;
 346
 347     my @chained_attr = @{ $action->attributes->{Chained} || [] };
 348
 349     return 0 unless @chained_attr;
 350
 351     if (@chained_attr > 1) {
 352         Catalyst::Exception->throw(
 353           "Multiple Chained attributes not supported registering ${action}"
 354         );
 355     }
 356     my $chained_to = $chained_attr[0];
 357
 358     Catalyst::Exception->throw(
 359       "Actions cannot chain to themselves registering /${action}"
 360     ) if ($chained_to eq '/' . $action);
 361
 362     my $children = ($self->_children_of->{ $chained_to } ||= {});
 363
 364     my @path_part = @{ $action->attributes->{PathPart} || [] };
 365
 366     my $part = $action->name;
 367
 368     if (@path_part == 1 && defined $path_part[0]) {
 369         $part = $path_part[0];
 370     } elsif (@path_part > 1) {
 371         Catalyst::Exception->throw(
 372           "Multiple PathPart attributes not supported registering " . $action->reverse()
 373         );
 374     }
 375
 376     if ($part =~ m(^/)) {
 377         Catalyst::Exception->throw(
 378           "Absolute parameters to PathPart not allowed registering " . $action->reverse()
 379         );
 380     }
 381
 382     my $encoded_part = URI->new($part)->canonical;
 383     $encoded_part =~ s{(?<=[^/])/+\z}{};
 384
 385     $action->attributes->{PathPart} = [ $encoded_part ];
 386
 387     unshift(@{ $children->{$encoded_part} ||= [] }, $action);
 388
 389     $self->_actions->{'/'.$action->reverse} = $action;
 390
 391     foreach my $name (qw(Args CaptureArgs)) {
 392         $self->_check_args_attr($action, $name);
 393     }
 394
 395     if (exists $action->attributes->{Args} and exists $action->attributes->{CaptureArgs}) {
 396         Catalyst::Exception->throw(
 397           "Combining Args and CaptureArgs attributes not supported registering " .
 398           $action->reverse()
 399         );
 400     }
 401
 402     unless ($action->attributes->{CaptureArgs}) {
 403         unshift(@{ $self->_endpoints }, $action);
 404     }
 405
 406     return 1;
 407 }
 408
 409 =head2 $self->uri_for_action($action, $captures)
 410
 411 Get the URI part for the action, using C<$captures> to fill
 412 the capturing parts.
 413
 414 =cut
 415
 416 sub uri_for_action {
 417     my ( $self, $action, $captures ) = @_;
 418
 419     return undef unless ($action->attributes->{Chained}
 420                            && !$action->attributes->{CaptureArgs});
 421
 422     my @parts = ();
 423     my @captures = @$captures;
 424     my $parent = "DUMMY";
 425     my $curr = $action;
 426     while ($curr) {
 427         if (my $cap = $curr->attributes->{CaptureArgs}) {
 428             return undef unless @captures >= ($cap->[0]||0); # not enough captures
 429             if ($cap->[0]) {
 430                 unshift(@parts, splice(@captures, -$cap->[0]));
 431             }
 432         }
 433         if (my $pp = $curr->attributes->{PathPart}) {
 434             unshift(@parts, $pp->[0])
 435                 if (defined($pp->[0]) && length($pp->[0]));
 436         }
 437         $parent = $curr->attributes->{Chained}->[0];
 438         $curr = $self->_actions->{$parent};
 439     }
 440
 441     return undef unless $parent eq '/'; # fail for dangling action
 442
 443     return undef if @captures; # fail for too many captures
 444
 445     return join('/', '', @parts);
 446
 447 }
 448
 449 =head2 $c->expand_action($action)
 450
 451 Return a list of actions that represents a chained action. See
 452 L<Catalyst::Dispatcher> for more info. You probably want to
 453 use the expand_action it provides rather than this directly.
 454
 455 =cut
 456
 457 sub expand_action {
 458     my ($self, $action) = @_;
 459
 460     return unless $action->attributes && $action->attributes->{Chained};
 461
 462     my @chain;
 463     my $curr = $action;
 464
 465     while ($curr) {
 466         push @chain, $curr;
 467         my $parent = $curr->attributes->{Chained}->[0];
 468         $curr = $self->_actions->{$parent};
 469     }
 470
 471     return Catalyst::ActionChain->from_chain([reverse @chain]);
 472 }
 473
 474 __PACKAGE__->meta->make_immutable;
 475 1;
 476
 477 =head1 USAGE
 478
 479 =head2 Introduction
 480
 481 The C<Chained> attribute allows you to chain public path parts together
 482 by their private names. A chain part's path can be specified with
 483 C<PathPart> and can be declared to expect an arbitrary number of
 484 arguments. The endpoint of the chain specifies how many arguments it
 485 gets through the C<Args> attribute. C<:Args(0)> would be none at all,
 486 C<:Args> without an integer would be unlimited. The path parts that
 487 aren't endpoints are using C<CaptureArgs> to specify how many parameters
 488 they expect to receive. As an example setup:
 489
 490   package MyApp::Controller::Greeting;
 491   use base qw/ Catalyst::Controller /;
 492
 493   #   this is the beginning of our chain
 494   sub hello : PathPart('hello') Chained('/') CaptureArgs(1) {
 495       my ( $self, $c, $integer ) = @_;
 496       $c->stash->{ message } = "Hello ";
 497       $c->stash->{ arg_sum } = $integer;
 498   }
 499
 500   #   this is our endpoint, because it has no :CaptureArgs
 501   sub world : PathPart('world') Chained('hello') Args(1) {
 502       my ( $self, $c, $integer ) = @_;
 503       $c->stash->{ message } .= "World!";
 504       $c->stash->{ arg_sum } += $integer;
 505
 506       $c->response->body( join "<br/>\n" =>
 507           $c->stash->{ message }, $c->stash->{ arg_sum } );
 508   }
 509
 510 The debug output provides a separate table for chained actions, showing
 511 the whole chain as it would match and the actions it contains. Here's an
 512 example of the startup output with our actions above:
 513
 514   ...
 515   [debug] Loaded Path Part actions:
 516   .-----------------------+------------------------------.
 517   | Path Spec             | Private                      |
 518   +-----------------------+------------------------------+
 519   | /hello/*/world/*      | /greeting/hello (1)          |
 520   |                       | => /greeting/world           |
 521   '-----------------------+------------------------------'
 522   ...
 523
 524 As you can see, Catalyst only deals with chains as whole paths and
 525 builds one for each endpoint, which are the actions with C<:Chained> but
 526 without C<:CaptureArgs>.
 527
 528 Let's assume this application gets a request at the path
 529 C</hello/23/world/12>. What happens then? First, Catalyst will dispatch
 530 to the C<hello> action and pass the value C<23> as an argument to it
 531 after the context. It does so because we have previously used
 532 C<:CaptureArgs(1)> to declare that it has one path part after itself as
 533 its argument. We told Catalyst that this is the beginning of the chain
 534 by specifying C<:Chained('/')>. Also note that instead of saying
 535 C<:PathPart('hello')> we could also just have said C<:PathPart>, as it
 536 defaults to the name of the action.
 537
 538 After C<hello> has run, Catalyst goes on to dispatch to the C<world>
 539 action. This is the last action to be called: Catalyst knows this is an
 540 endpoint because we did not specify a C<:CaptureArgs>
 541 attribute. Nevertheless we specify that this action expects an argument,
 542 but at this point we're using C<:Args(1)> to do that. We could also have
 543 said C<:Args> or left it out altogether, which would mean this action
 544 would get all arguments that are there. This action's C<:Chained>
 545 attribute says C<hello> and tells Catalyst that the C<hello> action in
 546 the current controller is its parent.
 547
 548 With this we have built a chain consisting of two public path parts.
 549 C<hello> captures one part of the path as its argument, and also
 550 specifies the path root as its parent. So this part is
 551 C</hello/$arg>. The next part is the endpoint C<world>, expecting one
 552 argument. It sums up to the path part C<world/$arg>. This leads to a
 553 complete chain of C</hello/$arg/world/$arg> which is matched against the
 554 requested paths.
 555
 556 This example application would, if run and called by e.g.
 557 C</hello/23/world/12>, set the stash value C<message> to "Hello" and the
 558 value C<arg_sum> to "23". The C<world> action would then append "World!"
 559 to C<message> and add C<12> to the stash's C<arg_sum> value.  For the
 560 sake of simplicity no view is shown. Instead we just put the values of
 561 the stash into our body. So the output would look like:
 562
 563   Hello World!
 564   35
 565
 566 And our test server would have given us this debugging output for the
 567 request:
 568
 569   ...
 570   [debug] "GET" request for "hello/23/world/12" from "127.0.0.1"
 571   [debug] Path is "/greeting/world"
 572   [debug] Arguments are "12"
 573   [info] Request took 0.164113s (6.093/s)
 574   .------------------------------------------+-----------.
 575   | Action                                   | Time      |
 576   +------------------------------------------+-----------+
 577   | /greeting/hello                          | 0.000029s |
 578   | /greeting/world                          | 0.000024s |
 579   '------------------------------------------+-----------'
 580   ...
 581
 582 What would be common uses of this dispatch technique? It gives the
 583 possibility to split up logic that contains steps that each depend on
 584 each other. An example would be, for example, a wiki path like
 585 C</wiki/FooBarPage/rev/23/view>. This chain can be easily built with
 586 these actions:
 587
 588   sub wiki : PathPart('wiki') Chained('/') CaptureArgs(1) {
 589       my ( $self, $c, $page_name ) = @_;
 590       #  load the page named $page_name and put the object
 591       #  into the stash
 592   }
 593
 594   sub rev : PathPart('rev') Chained('wiki') CaptureArgs(1) {
 595       my ( $self, $c, $revision_id ) = @_;
 596       #  use the page object in the stash to get at its
 597       #  revision with number $revision_id
 598   }
 599
 600   sub view : PathPart Chained('rev') Args(0) {
 601       my ( $self, $c ) = @_;
 602       #  display the revision in our stash. Another option
 603       #  would be to forward a compatible object to the action
 604       #  that displays the default wiki pages, unless we want
 605       #  a different interface here, for example restore
 606       #  functionality.
 607   }
 608
 609 It would now be possible to add other endpoints, for example C<restore>
 610 to restore this specific revision as the current state.
 611
 612 You don't have to put all the chained actions in one controller. The
 613 specification of the parent through C<:Chained> also takes an absolute
 614 action path as its argument. Just specify it with a leading C</>.
 615
 616 If you want, for example, to have actions for the public paths
 617 C</foo/12/edit> and C</foo/12>, just specify two actions with
 618 C<:PathPart('foo')> and C<:Chained('/')>. The handler for the former
 619 path needs a C<:CaptureArgs(1)> attribute and a endpoint with
 620 C<:PathPart('edit')> and C<:Chained('foo')>. For the latter path give
 621 the action just a C<:Args(1)> to mark it as endpoint. This sums up to
 622 this debugging output:
 623
 624   ...
 625   [debug] Loaded Path Part actions:
 626   .-----------------------+------------------------------.
 627   | Path Spec             | Private                      |
 628   +-----------------------+------------------------------+
 629   | /foo/*                | /controller/foo_view         |
 630   | /foo/*/edit           | /controller/foo_load (1)     |
 631   |                       | => /controller/edit          |
 632   '-----------------------+------------------------------'
 633   ...
 634
 635 Here's a more detailed specification of the attributes belonging to
 636 C<:Chained>:
 637
 638 =head2 Attributes
 639
 640 =over 8
 641
 642 =item PathPart
 643
 644 Sets the name of this part of the chain. If it is specified without
 645 arguments, it takes the name of the action as default. So basically
 646 C<sub foo :PathPart> and C<sub foo :PathPart('foo')> are identical.
 647 This can also contain slashes to bind to a deeper level. An action
 648 with C<sub bar :PathPart('foo/bar') :Chained('/')> would bind to
 649 C</foo/bar/...>. If you don't specify C<:PathPart> it has the same
 650 effect as using C<:PathPart>, it would default to the action name.
 651
 652 =item PathPrefix
 653
 654 Sets PathPart to the path_prefix of the current controller.
 655
 656 =item Chained
 657
 658 Has to be specified for every child in the chain. Possible values are
 659 absolute and relative private action paths or a single slash C</> to
 660 tell Catalyst that this is the root of a chain. The attribute
 661 C<:Chained> without arguments also defaults to the C</> behavior.
 662 Relative action paths may use C<../> to refer to actions in parent
 663 controllers.
 664
 665 Because you can specify an absolute path to the parent action, it
 666 doesn't matter to Catalyst where that parent is located. So, if your
 667 design requests it, you can redispatch a chain through any controller or
 668 namespace you want.
 669
 670 Another interesting possibility gives C<:Chained('.')>, which chains
 671 itself to an action with the path of the current controller's namespace.
 672 For example:
 673
 674   #   in MyApp::Controller::Foo
 675   sub bar : Chained CaptureArgs(1) { ... }
 676
 677   #   in MyApp::Controller::Foo::Bar
 678   sub baz : Chained('.') Args(1) { ... }
 679
 680 This builds up a chain like C</bar/*/baz/*>. The specification of C<.>
 681 as the argument to Chained here chains the C<baz> action to an action
 682 with the path of the current controller namespace, namely
 683 C</foo/bar>. That action chains directly to C</>, so the C</bar/*/baz/*>
 684 chain comes out as the end product.
 685
 686 =item ChainedParent
 687
 688 Chains an action to another action with the same name in the parent
 689 controller. For Example:
 690
 691   # in MyApp::Controller::Foo
 692   sub bar : Chained CaptureArgs(1) { ... }
 693
 694   # in MyApp::Controller::Foo::Moo
 695   sub bar : ChainedParent Args(1) { ... }
 696
 697 This builds a chain like C</bar/*/bar/*>.
 698
 699 =item CaptureArgs
 700
 701 Must be specified for every part of the chain that is not an
 702 endpoint. With this attribute Catalyst knows how many of the following
 703 parts of the path (separated by C</>) this action wants to capture as
 704 its arguments. If it doesn't expect any, just specify
 705 C<:CaptureArgs(0)>.  The captures get passed to the action's C<@_> right
 706 after the context, but you can also find them as array references in
 707 C<$c-E<gt>request-E<gt>captures-E<gt>[$level]>. The C<$level> is the
 708 level of the action in the chain that captured the parts of the path.
 709
 710 An action that is part of a chain (that is, one that has a C<:Chained>
 711 attribute) but has no C<:CaptureArgs> attribute is treated by Catalyst
 712 as a chain end.
 713
 714 =item Args
 715
 716 By default, endpoints receive the rest of the arguments in the path. You
 717 can tell Catalyst through C<:Args> explicitly how many arguments your
 718 endpoint expects, just like you can with C<:CaptureArgs>. Note that this
 719 also affects whether this chain is invoked on a request. A chain with an
 720 endpoint specifying one argument will only match if exactly one argument
 721 exists in the path.
 722
 723 You can specify an exact number of arguments like C<:Args(3)>, including
 724 C<0>. If you just say C<:Args> without any arguments, it is the same as
 725 leaving it out altogether: The chain is matched regardless of the number
 726 of path parts after the endpoint.
 727
 728 Just as with C<:CaptureArgs>, the arguments get passed to the action in
 729 C<@_> after the context object. They can also be reached through
 730 C<$c-E<gt>request-E<gt>arguments>.
 731
 732 =back
 733
 734 =head2 Auto actions, dispatching and forwarding
 735
 736 Note that the list of C<auto> actions called depends on the private path
 737 of the endpoint of the chain, not on the chained actions way. The
 738 C<auto> actions will be run before the chain dispatching begins. In
 739 every other aspect, C<auto> actions behave as documented.
 740
 741 The C<forward>ing to other actions does just what you would expect. i.e.
 742 only the target action is run. The actions that that action is chained
 743 to are not run.
 744 If you C<detach> out of a chain, the rest of the chain will not get
 745 called after the C<detach>.
 746
 747 =head2 match_captures
 748
 749 A method which can optionally be implemented by actions to
 750 stop chain matching.
 751
 752 See L<Catalyst::Action> for further details.
 753
 754 =head1 AUTHORS
 755
 756 Catalyst Contributors, see Catalyst.pm
 757
 758 =head1 COPYRIGHT
 759
 760 This library is free software. You can redistribute it and/or modify it under
 761 the same terms as Perl itself.
 762
 763 =cut
 764
 765 1;