lib/Catalyst/Controller.pm

   1 package Catalyst::Controller;
   2
   3 #switch to BEGIN { extends qw/ ... /; } ?
   4 use base qw/Catalyst::Component Catalyst::AttrContainer/;
   5 use Moose;
   6
   7 use Class::MOP::Object ();
   8 use Scalar::Util qw/blessed/;
   9 use Catalyst::Exception;
  10 use Catalyst::Utils;
  11
  12 has path_prefix =>
  13     (
  14      is => 'rw',
  15      isa => 'Str',
  16      init_arg => 'path',
  17      predicate => 'has_path_prefix',
  18     );
  19
  20 has action_namespace =>
  21     (
  22      is => 'rw',
  23      isa => 'Str',
  24      init_arg => 'namespace',
  25      predicate => 'has_action_namespace',
  26     );
  27
  28 has actions =>
  29     (
  30      is => 'rw',
  31      isa => 'HashRef',
  32      init_arg => undef,
  33     );
  34
  35 # Future - isa => 'ClassName|Catalyst' performance?
  36 #           required => 1 breaks tests..
  37 has _application => (is => 'ro');
  38 sub _app { shift->_application(@_) }
  39
  40 override 'BUILDARGS' => sub {
  41     my ($self, $app) = @_;
  42
  43     my $args = super();
  44     $args->{_application} = $app;
  45
  46     return $args;
  47 };
  48
  49 sub BUILD {
  50     my ($self, $args) = @_;
  51     my $action  = delete $args->{action}  || {};
  52     my $actions = delete $args->{actions} || {};
  53     my $attr_value = $self->merge_config_hashes($actions, $action);
  54     $self->actions($attr_value);
  55 }
  56
  57 =head1 NAME
  58
  59 Catalyst::Controller - Catalyst Controller base class
  60
  61 =head1 SYNOPSIS
  62
  63   package MyApp::Controller::Search
  64   use base qw/Catalyst::Controller/;
  65
  66   sub foo : Local {
  67     my ($self,$c,@args) = @_;
  68     ...
  69   } # Dispatches to /search/foo
  70
  71 =head1 DESCRIPTION
  72
  73 Controllers are where the actions in the Catalyst framework
  74 reside. Each action is represented by a function with an attribute to
  75 identify what kind of action it is. See the L<Catalyst::Dispatcher>
  76 for more info about how Catalyst dispatches to actions.
  77
  78 =cut
  79
  80 #I think both of these could be attributes. doesn't really seem like they need
  81 #to ble class data. i think that attributes +default would work just fine
  82 __PACKAGE__->mk_classdata($_) for qw/_dispatch_steps _action_class/;
  83
  84 __PACKAGE__->_dispatch_steps( [qw/_BEGIN _AUTO _ACTION/] );
  85 __PACKAGE__->_action_class('Catalyst::Action');
  86
  87
  88 sub _DISPATCH : Private {
  89     my ( $self, $c ) = @_;
  90
  91     foreach my $disp ( @{ $self->_dispatch_steps } ) {
  92         last unless $c->forward($disp);
  93     }
  94
  95     $c->forward('_END');
  96 }
  97
  98 sub _BEGIN : Private {
  99     my ( $self, $c ) = @_;
 100     my $begin = ( $c->get_actions( 'begin', $c->namespace ) )[-1];
 101     return 1 unless $begin;
 102     $begin->dispatch( $c );
 103     return !@{ $c->error };
 104 }
 105
 106 sub _AUTO : Private {
 107     my ( $self, $c ) = @_;
 108     my @auto = $c->get_actions( 'auto', $c->namespace );
 109     foreach my $auto (@auto) {
 110         $auto->dispatch( $c );
 111         return 0 unless $c->state;
 112     }
 113     return 1;
 114 }
 115
 116 sub _ACTION : Private {
 117     my ( $self, $c ) = @_;
 118     if (   ref $c->action
 119         && $c->action->can('execute')
 120         && defined $c->req->action )
 121     {
 122         $c->action->dispatch( $c );
 123     }
 124     return !@{ $c->error };
 125 }
 126
 127 sub _END : Private {
 128     my ( $self, $c ) = @_;
 129     my $end = ( $c->get_actions( 'end', $c->namespace ) )[-1];
 130     return 1 unless $end;
 131     $end->dispatch( $c );
 132     return !@{ $c->error };
 133 }
 134
 135 sub action_for {
 136     my ( $self, $name ) = @_;
 137     my $app = ($self->isa('Catalyst') ? $self : $self->_application);
 138     return $app->dispatcher->get_action($name, $self->action_namespace);
 139 }
 140
 141 #my opinion is that this whole sub really should be a builder method, not
 142 #something that happens on every call. Anyone else disagree?? -- groditi
 143 ## -- apparently this is all just waiting for app/ctx split
 144 around action_namespace => sub {
 145     my $orig = shift;
 146     my ( $self, $c ) = @_;
 147
 148     if( ref($self) ){
 149         return $self->$orig if $self->has_action_namespace;
 150     } else {
 151         return $self->config->{namespace} if exists $self->config->{namespace};
 152     }
 153
 154     my $case_s;
 155     if( $c ){
 156         $case_s = $c->config->{case_sensitive};
 157     } else {
 158         if ($self->isa('Catalyst')) {
 159             $case_s = $self->config->{case_sensitive};
 160         } else {
 161             if (ref $self) {
 162                 $case_s = $self->_application->config->{case_sensitive};
 163             } else {
 164                 confess("Can't figure out case_sensitive setting");
 165             }
 166         }
 167     }
 168
 169     my $namespace = Catalyst::Utils::class2prefix(ref($self) || $self, $case_s) || '';
 170     $self->$orig($namespace) if ref($self);
 171     return $namespace;
 172 };
 173
 174 #Once again, this is probably better written as a builder method
 175 around path_prefix => sub {
 176     my $orig = shift;
 177     my $self = shift;
 178     if( ref($self) ){
 179       return $self->$orig if $self->has_path_prefix;
 180     } else {
 181       return $self->config->{path} if exists $self->config->{path};
 182     }
 183     my $namespace = $self->action_namespace(@_);
 184     $self->$orig($namespace) if ref($self);
 185     return $namespace;
 186 };
 187
 188
 189 sub register_actions {
 190     my ( $self, $c ) = @_;
 191     my $class = ref $self || $self;
 192     #this is still not correct for some reason.
 193     my $namespace = $self->action_namespace($c);
 194     my $meta = $self->Class::MOP::Object::meta();
 195     my %methods = map { $_->body => $_->name }
 196         grep { $_->package_name ne 'Moose::Object' } #ignore Moose::Object methods
 197             $meta->get_all_methods;
 198
 199     # Advanced inheritance support for plugins and the like
 200     #moose todo: migrate to eliminate CDI compat
 201     my @action_cache;
 202     for my $isa ( $meta->superclasses, $class ) {
 203         if(my $coderef = $isa->can('_action_cache')){
 204             push(@action_cache, @{ $isa->$coderef });
 205         }
 206     }
 207
 208     foreach my $cache (@action_cache) {
 209         my $code   = $cache->[0];
 210         my $method = delete $methods{$code}; # avoid dupe registers
 211         next unless $method;
 212         my $attrs = $self->_parse_attrs( $c, $method, @{ $cache->[1] } );
 213         if ( $attrs->{Private} && ( keys %$attrs > 1 ) ) {
 214             $c->log->debug( 'Bad action definition "'
 215                   . join( ' ', @{ $cache->[1] } )
 216                   . qq/" for "$class->$method"/ )
 217               if $c->debug;
 218             next;
 219         }
 220         my $reverse = $namespace ? "${namespace}/${method}" : $method;
 221         my $action = $self->create_action(
 222             name       => $method,
 223             code       => $code,
 224             reverse    => $reverse,
 225             namespace  => $namespace,
 226             class      => $class,
 227             attributes => $attrs,
 228         );
 229
 230         $c->dispatcher->register( $c, $action );
 231     }
 232 }
 233
 234 sub create_action {
 235     my $self = shift;
 236     my %args = @_;
 237
 238     my $class = (exists $args{attributes}{ActionClass}
 239                     ? $args{attributes}{ActionClass}[0]
 240                     : $self->_action_class);
 241
 242     Class::MOP::load_class($class);
 243     return $class->new( \%args );
 244 }
 245
 246 sub _parse_attrs {
 247     my ( $self, $c, $name, @attrs ) = @_;
 248
 249     my %raw_attributes;
 250
 251     foreach my $attr (@attrs) {
 252
 253         # Parse out :Foo(bar) into Foo => bar etc (and arrayify)
 254
 255         if ( my ( $key, $value ) = ( $attr =~ /^(.*?)(?:\(\s*(.+?)\s*\))?$/ ) )
 256         {
 257
 258             if ( defined $value ) {
 259                 ( $value =~ s/^'(.*)'$/$1/ ) || ( $value =~ s/^"(.*)"/$1/ );
 260             }
 261             push( @{ $raw_attributes{$key} }, $value );
 262         }
 263     }
 264
 265     #I know that the original behavior was to ignore action if actions was set
 266     # but i actually think this may be a little more sane? we can always remove
 267     # the merge behavior quite easily and go back to having actions have
 268     # presedence over action by modifying the keys. i honestly think this is
 269     # superior while mantaining really high degree of compat
 270     my $actions;
 271     if( ref($self) ) {
 272         $actions = $self->actions;
 273     } else {
 274         my $cfg = $self->config;
 275         $actions = $self->merge_config_hashes($cfg->{actions}, $cfg->{action});
 276     }
 277
 278     %raw_attributes = ((exists $actions->{'*'} ? %{$actions->{'*'}} : ()),
 279                        %raw_attributes,
 280                        (exists $actions->{$name} ? %{$actions->{$name}} : ()));
 281
 282
 283     my %final_attributes;
 284
 285     foreach my $key (keys %raw_attributes) {
 286
 287         my $raw = $raw_attributes{$key};
 288
 289         foreach my $value (ref($raw) eq 'ARRAY' ? @$raw : $raw) {
 290
 291             my $meth = "_parse_${key}_attr";
 292             if ( my $code = $self->can($meth) ) {
 293                 ( $key, $value ) = $self->$code( $c, $name, $value );
 294             }
 295             push( @{ $final_attributes{$key} }, $value );
 296         }
 297     }
 298
 299     return \%final_attributes;
 300 }
 301
 302 sub _parse_Global_attr {
 303     my ( $self, $c, $name, $value ) = @_;
 304     return $self->_parse_Path_attr( $c, $name, "/$name" );
 305 }
 306
 307 sub _parse_Absolute_attr { shift->_parse_Global_attr(@_); }
 308
 309 sub _parse_Local_attr {
 310     my ( $self, $c, $name, $value ) = @_;
 311     return $self->_parse_Path_attr( $c, $name, $name );
 312 }
 313
 314 sub _parse_Relative_attr { shift->_parse_Local_attr(@_); }
 315
 316 sub _parse_Path_attr {
 317     my ( $self, $c, $name, $value ) = @_;
 318     $value = '' if !defined $value;
 319     if ( $value =~ m!^/! ) {
 320         return ( 'Path', $value );
 321     }
 322     elsif ( length $value ) {
 323         return ( 'Path', join( '/', $self->path_prefix($c), $value ) );
 324     }
 325     else {
 326         return ( 'Path', $self->path_prefix($c) );
 327     }
 328 }
 329
 330 sub _parse_Regex_attr {
 331     my ( $self, $c, $name, $value ) = @_;
 332     return ( 'Regex', $value );
 333 }
 334
 335 sub _parse_Regexp_attr { shift->_parse_Regex_attr(@_); }
 336
 337 sub _parse_LocalRegex_attr {
 338     my ( $self, $c, $name, $value ) = @_;
 339     unless ( $value =~ s/^\^// ) { $value = "(?:.*?)$value"; }
 340
 341     my $prefix = $self->path_prefix( $c );
 342     $prefix .= '/' if length( $prefix );
 343
 344     return ( 'Regex', "^${prefix}${value}" );
 345 }
 346
 347 sub _parse_LocalRegexp_attr { shift->_parse_LocalRegex_attr(@_); }
 348
 349 sub _parse_Chained_attr {
 350     my ($self, $c, $name, $value) = @_;
 351
 352     if (defined($value) && length($value)) {
 353         if ($value eq '.') {
 354             $value = '/'.$self->action_namespace($c);
 355         } elsif (my ($rel, $rest) = $value =~ /^((?:\.{2}\/)+)(.*)$/) {
 356             my @parts = split '/', $self->action_namespace($c);
 357             my @levels = split '/', $rel;
 358
 359             $value = '/'.join('/', @parts[0 .. $#parts - @levels], $rest);
 360         } elsif ($value !~ m/^\//) {
 361             my $action_ns = $self->action_namespace($c);
 362
 363             if ($action_ns) {
 364                 $value = '/'.join('/', $action_ns, $value);
 365             } else {
 366                 $value = '/'.$value; # special case namespace '' (root)
 367             }
 368         }
 369     } else {
 370         $value = '/'
 371     }
 372
 373     return Chained => $value;
 374 }
 375
 376 sub _parse_ChainedParent_attr {
 377     my ($self, $c, $name, $value) = @_;
 378     return $self->_parse_Chained_attr($c, $name, '../'.$name);
 379 }
 380
 381 sub _parse_PathPrefix_attr {
 382     my $self = shift;
 383     return PathPart => $self->path_prefix;
 384 }
 385
 386 sub _parse_ActionClass_attr {
 387     my ( $self, $c, $name, $value ) = @_;
 388     unless ( $value =~ s/^\+// ) {
 389       $value = join('::', $self->_action_class, $value );
 390     }
 391     return ( 'ActionClass', $value );
 392 }
 393
 394 sub _parse_MyAction_attr {
 395     my ( $self, $c, $name, $value ) = @_;
 396
 397     my $appclass = Catalyst::Utils::class2appclass($self);
 398     $value = "${appclass}::Action::${value}";
 399
 400     return ( 'ActionClass', $value );
 401 }
 402
 403 no Moose;
 404
 405 __PACKAGE__->meta->make_immutable;
 406
 407 1;
 408
 409 __END__
 410
 411 =head1 CONFIGURATION
 412
 413 Like any other L<Catalyst::Component>, controllers have a config hash,
 414 accessible through $self->config from the controller actions.  Some
 415 settings are in use by the Catalyst framework:
 416
 417 =head2 namespace
 418
 419 This specifies the internal namespace the controller should be bound
 420 to. By default the controller is bound to the URI version of the
 421 controller name. For instance controller 'MyApp::Controller::Foo::Bar'
 422 will be bound to 'foo/bar'. The default Root controller is an example
 423 of setting namespace to '' (the null string).
 424
 425 =head2 path
 426
 427 Sets 'path_prefix', as described below.
 428
 429 =head1 METHODS
 430
 431 =head2 $class->new($app, @args)
 432
 433 Proxies through to NEXT::new and stashes the application instance as
 434 $self->_application.
 435
 436 =head2 $self->action_for('name')
 437
 438 Returns the Catalyst::Action object (if any) for a given method name
 439 in this component.
 440
 441 =head2 $self->register_actions($c)
 442
 443 Finds all applicable actions for this component, creates
 444 Catalyst::Action objects (using $self->create_action) for them and
 445 registers them with $c->dispatcher.
 446
 447 =head2 $self->action_namespace($c)
 448
 449 Returns the private namespace for actions in this component. Defaults
 450 to a value from the controller name (for
 451 e.g. MyApp::Controller::Foo::Bar becomes "foo/bar") or can be
 452 overridden from the "namespace" config key.
 453
 454
 455 =head2 $self->path_prefix($c)
 456
 457 Returns the default path prefix for :PathPrefix, :Local, :LocalRegex and
 458 relative :Path actions in this component. Defaults to the action_namespace or
 459 can be overridden from the "path" config key.
 460
 461 =head2 $self->create_action(%args)
 462
 463 Called with a hash of data to be use for construction of a new
 464 Catalyst::Action (or appropriate sub/alternative class) object.
 465
 466 Primarily designed for the use of register_actions.
 467
 468 =head2 $self->_application
 469
 470 =head2 $self->_app
 471
 472 Returns the application instance stored by C<new()>
 473
 474 =head1 AUTHORS
 475
 476 Catalyst Contributors, see Catalyst.pm
 477
 478 =head1 COPYRIGHT
 479
 480 This program is free software, you can redistribute it and/or modify
 481 it under the same terms as Perl itself.
 482
 483 =cut