lib/Catalyst/Controller.pm

   1 package Catalyst::Controller;
   2
   3 use Moose;
   4 use Moose::Util qw/find_meta/;
   5
   6 use namespace::clean -except => 'meta';
   7
   8 BEGIN { extends qw/Catalyst::Component MooseX::MethodAttributes::Inheritable/; }
   9
  10 use MooseX::MethodAttributes;
  11 use Catalyst::Exception;
  12 use Catalyst::Utils;
  13
  14 with 'Catalyst::Component::ApplicationAttribute';
  15
  16 has path_prefix =>
  17     (
  18      is => 'rw',
  19      isa => 'Str',
  20      init_arg => 'path',
  21      predicate => 'has_path_prefix',
  22     );
  23
  24 has action_namespace =>
  25     (
  26      is => 'rw',
  27      isa => 'Str',
  28      init_arg => 'namespace',
  29      predicate => 'has_action_namespace',
  30     );
  31
  32 has _controller_actions =>
  33     (
  34      is => 'rw',
  35      isa => 'HashRef',
  36      init_arg => undef,
  37     );
  38
  39 sub BUILD {
  40     my ($self, $args) = @_;
  41     my $action  = delete $args->{action}  || {};
  42     my $actions = delete $args->{actions} || {};
  43     my $attr_value = $self->merge_config_hashes($actions, $action);
  44     $self->_controller_actions($attr_value);
  45 }
  46
  47 =head1 NAME
  48
  49 Catalyst::Controller - Catalyst Controller base class
  50
  51 =head1 SYNOPSIS
  52
  53   package MyApp::Controller::Search
  54   use base qw/Catalyst::Controller/;
  55
  56   sub foo : Local {
  57     my ($self,$c,@args) = @_;
  58     ...
  59   } # Dispatches to /search/foo
  60
  61 =head1 DESCRIPTION
  62
  63 Controllers are where the actions in the Catalyst framework
  64 reside. Each action is represented by a function with an attribute to
  65 identify what kind of action it is. See the L<Catalyst::Dispatcher>
  66 for more info about how Catalyst dispatches to actions.
  67
  68 =cut
  69
  70 #I think both of these could be attributes. doesn't really seem like they need
  71 #to ble class data. i think that attributes +default would work just fine
  72 __PACKAGE__->mk_classdata($_) for qw/_dispatch_steps _action_class/;
  73
  74 __PACKAGE__->_dispatch_steps( [qw/_BEGIN _AUTO _ACTION/] );
  75 __PACKAGE__->_action_class('Catalyst::Action');
  76
  77
  78 sub _DISPATCH : Private {
  79     my ( $self, $c ) = @_;
  80
  81     foreach my $disp ( @{ $self->_dispatch_steps } ) {
  82         last unless $c->forward($disp);
  83     }
  84
  85     $c->forward('_END');
  86 }
  87
  88 sub _BEGIN : Private {
  89     my ( $self, $c ) = @_;
  90     my $begin = ( $c->get_actions( 'begin', $c->namespace ) )[-1];
  91     return 1 unless $begin;
  92     $begin->dispatch( $c );
  93     return !@{ $c->error };
  94 }
  95
  96 sub _AUTO : Private {
  97     my ( $self, $c ) = @_;
  98     my @auto = $c->get_actions( 'auto', $c->namespace );
  99     foreach my $auto (@auto) {
 100         $auto->dispatch( $c );
 101         return 0 unless $c->state;
 102     }
 103     return 1;
 104 }
 105
 106 sub _ACTION : Private {
 107     my ( $self, $c ) = @_;
 108     if (   ref $c->action
 109         && $c->action->can('execute')
 110         && defined $c->req->action )
 111     {
 112         $c->action->dispatch( $c );
 113     }
 114     return !@{ $c->error };
 115 }
 116
 117 sub _END : Private {
 118     my ( $self, $c ) = @_;
 119     my $end = ( $c->get_actions( 'end', $c->namespace ) )[-1];
 120     return 1 unless $end;
 121     $end->dispatch( $c );
 122     return !@{ $c->error };
 123 }
 124
 125 sub action_for {
 126     my ( $self, $name ) = @_;
 127     my $app = ($self->isa('Catalyst') ? $self : $self->_application);
 128     return $app->dispatcher->get_action($name, $self->action_namespace);
 129 }
 130
 131 #my opinion is that this whole sub really should be a builder method, not
 132 #something that happens on every call. Anyone else disagree?? -- groditi
 133 ## -- apparently this is all just waiting for app/ctx split
 134 around action_namespace => sub {
 135     my $orig = shift;
 136     my ( $self, $c ) = @_;
 137
 138     if( ref($self) ){
 139         return $self->$orig if $self->has_action_namespace;
 140     } else {
 141         return $self->config->{namespace} if exists $self->config->{namespace};
 142     }
 143
 144     my $case_s;
 145     if( $c ){
 146         $case_s = $c->config->{case_sensitive};
 147     } else {
 148         if ($self->isa('Catalyst')) {
 149             $case_s = $self->config->{case_sensitive};
 150         } else {
 151             if (ref $self) {
 152                 $case_s = $self->_application->config->{case_sensitive};
 153             } else {
 154                 confess("Can't figure out case_sensitive setting");
 155             }
 156         }
 157     }
 158
 159     my $namespace = Catalyst::Utils::class2prefix(ref($self) || $self, $case_s) || '';
 160     $self->$orig($namespace) if ref($self);
 161     return $namespace;
 162 };
 163
 164 #Once again, this is probably better written as a builder method
 165 around path_prefix => sub {
 166     my $orig = shift;
 167     my $self = shift;
 168     if( ref($self) ){
 169       return $self->$orig if $self->has_path_prefix;
 170     } else {
 171       return $self->config->{path} if exists $self->config->{path};
 172     }
 173     my $namespace = $self->action_namespace(@_);
 174     $self->$orig($namespace) if ref($self);
 175     return $namespace;
 176 };
 177
 178 sub get_action_methods {
 179     my $self = shift;
 180     my $meta = find_meta($self);
 181     confess("Metaclass for "
 182           . ref($meta) . " for "
 183           . $meta->name
 184           . " cannot support register_actions." )
 185       unless $meta->can('get_nearest_methods_with_attributes');
 186     my @methods = $meta->get_nearest_methods_with_attributes;
 187
 188     # actions specified via config are also action_methods
 189     push(
 190         @methods,
 191         map {
 192             $meta->get_method($_)
 193               || confess( 'Action "'
 194                   . $_
 195                   . '" is not available from controller '
 196                   . ( ref $self ) )
 197           } keys %{ $self->_controller_actions }
 198     ) if ( ref $self );
 199     return @methods;
 200 }
 201
 202
 203 sub register_actions {
 204     my ( $self, $c ) = @_;
 205     $self->register_action_methods( $c, $self->get_action_methods );
 206 }
 207
 208 sub register_action_methods {
 209     my ( $self, $c, @methods ) = @_;
 210     my $class = ref $self || $self;
 211     #this is still not correct for some reason.
 212     my $namespace = $self->action_namespace($c);
 213
 214     foreach my $method (@methods) {
 215         my $name = $method->name;
 216         my $attributes = $method->attributes;
 217         #next unless $attributes;
 218         my $attrs = $self->_parse_attrs( $c, $name, @{ $attributes } );
 219         if ( $attrs->{Private} && ( keys %$attrs > 1 ) ) {
 220             $c->log->debug( 'Bad action definition "'
 221                   . join( ' ', @{ $attributes } )
 222                   . qq/" for "$class->$name"/ )
 223               if $c->debug;
 224             next;
 225         }
 226         my $reverse = $namespace ? "${namespace}/${name}" : $name;
 227         my $action = $self->create_action(
 228             name       => $name,
 229             code       => $method->body,
 230             reverse    => $reverse,
 231             namespace  => $namespace,
 232             class      => $class,
 233             attributes => $attrs,
 234         );
 235
 236         $c->dispatcher->register( $c, $action );
 237     }
 238 }
 239
 240 sub create_action {
 241     my $self = shift;
 242     my %args = @_;
 243
 244     my $class = (exists $args{attributes}{ActionClass}
 245                     ? $args{attributes}{ActionClass}[0]
 246                     : $self->_action_class);
 247
 248     Class::MOP::load_class($class);
 249     return $class->new( \%args );
 250 }
 251
 252 sub _parse_attrs {
 253     my ( $self, $c, $name, @attrs ) = @_;
 254
 255     my %raw_attributes;
 256
 257     foreach my $attr (@attrs) {
 258
 259         # Parse out :Foo(bar) into Foo => bar etc (and arrayify)
 260
 261         if ( my ( $key, $value ) = ( $attr =~ /^(.*?)(?:\(\s*(.+?)\s*\))?$/ ) )
 262         {
 263
 264             if ( defined $value ) {
 265                 ( $value =~ s/^'(.*)'$/$1/ ) || ( $value =~ s/^"(.*)"/$1/ );
 266             }
 267             push( @{ $raw_attributes{$key} }, $value );
 268         }
 269     }
 270
 271     #I know that the original behavior was to ignore action if actions was set
 272     # but i actually think this may be a little more sane? we can always remove
 273     # the merge behavior quite easily and go back to having actions have
 274     # presedence over action by modifying the keys. i honestly think this is
 275     # superior while mantaining really high degree of compat
 276     my $actions;
 277     if( ref($self) ) {
 278         $actions = $self->_controller_actions;
 279     } else {
 280         my $cfg = $self->config;
 281         $actions = $self->merge_config_hashes($cfg->{actions}, $cfg->{action});
 282     }
 283
 284     %raw_attributes = ((exists $actions->{'*'} ? %{$actions->{'*'}} : ()),
 285                        %raw_attributes,
 286                        (exists $actions->{$name} ? %{$actions->{$name}} : ()));
 287
 288
 289     my %final_attributes;
 290
 291     foreach my $key (keys %raw_attributes) {
 292
 293         my $raw = $raw_attributes{$key};
 294
 295         foreach my $value (ref($raw) eq 'ARRAY' ? @$raw : $raw) {
 296
 297             my $meth = "_parse_${key}_attr";
 298             if ( my $code = $self->can($meth) ) {
 299                 ( $key, $value ) = $self->$code( $c, $name, $value );
 300             }
 301             push( @{ $final_attributes{$key} }, $value );
 302         }
 303     }
 304
 305     return \%final_attributes;
 306 }
 307
 308 sub _parse_Global_attr {
 309     my ( $self, $c, $name, $value ) = @_;
 310     return $self->_parse_Path_attr( $c, $name, "/$name" );
 311 }
 312
 313 sub _parse_Absolute_attr { shift->_parse_Global_attr(@_); }
 314
 315 sub _parse_Local_attr {
 316     my ( $self, $c, $name, $value ) = @_;
 317     return $self->_parse_Path_attr( $c, $name, $name );
 318 }
 319
 320 sub _parse_Relative_attr { shift->_parse_Local_attr(@_); }
 321
 322 sub _parse_Path_attr {
 323     my ( $self, $c, $name, $value ) = @_;
 324     $value = '' if !defined $value;
 325     if ( $value =~ m!^/! ) {
 326         return ( 'Path', $value );
 327     }
 328     elsif ( length $value ) {
 329         return ( 'Path', join( '/', $self->path_prefix($c), $value ) );
 330     }
 331     else {
 332         return ( 'Path', $self->path_prefix($c) );
 333     }
 334 }
 335
 336 sub _parse_Regex_attr {
 337     my ( $self, $c, $name, $value ) = @_;
 338     return ( 'Regex', $value );
 339 }
 340
 341 sub _parse_Regexp_attr { shift->_parse_Regex_attr(@_); }
 342
 343 sub _parse_LocalRegex_attr {
 344     my ( $self, $c, $name, $value ) = @_;
 345     unless ( $value =~ s/^\^// ) { $value = "(?:.*?)$value"; }
 346
 347     my $prefix = $self->path_prefix( $c );
 348     $prefix .= '/' if length( $prefix );
 349
 350     return ( 'Regex', "^${prefix}${value}" );
 351 }
 352
 353 sub _parse_LocalRegexp_attr { shift->_parse_LocalRegex_attr(@_); }
 354
 355 sub _parse_Chained_attr {
 356     my ($self, $c, $name, $value) = @_;
 357
 358     if (defined($value) && length($value)) {
 359         if ($value eq '.') {
 360             $value = '/'.$self->action_namespace($c);
 361         } elsif (my ($rel, $rest) = $value =~ /^((?:\.{2}\/)+)(.*)$/) {
 362             my @parts = split '/', $self->action_namespace($c);
 363             my @levels = split '/', $rel;
 364
 365             $value = '/'.join('/', @parts[0 .. $#parts - @levels], $rest);
 366         } elsif ($value !~ m/^\//) {
 367             my $action_ns = $self->action_namespace($c);
 368
 369             if ($action_ns) {
 370                 $value = '/'.join('/', $action_ns, $value);
 371             } else {
 372                 $value = '/'.$value; # special case namespace '' (root)
 373             }
 374         }
 375     } else {
 376         $value = '/'
 377     }
 378
 379     return Chained => $value;
 380 }
 381
 382 sub _parse_ChainedParent_attr {
 383     my ($self, $c, $name, $value) = @_;
 384     return $self->_parse_Chained_attr($c, $name, '../'.$name);
 385 }
 386
 387 sub _parse_PathPrefix_attr {
 388     my $self = shift;
 389     return PathPart => $self->path_prefix;
 390 }
 391
 392 sub _parse_ActionClass_attr {
 393     my ( $self, $c, $name, $value ) = @_;
 394     $value = Catalyst::Utils::resolve_namespace($self->_action_class, $value);
 395     return ( 'ActionClass', $value );
 396 }
 397
 398 sub _parse_MyAction_attr {
 399     my ( $self, $c, $name, $value ) = @_;
 400
 401     my $appclass = Catalyst::Utils::class2appclass($self);
 402     $value = "${appclass}::Action::${value}";
 403
 404     return ( 'ActionClass', $value );
 405 }
 406
 407 __PACKAGE__->meta->make_immutable;
 408
 409 1;
 410
 411 __END__
 412
 413 =head1 CONFIGURATION
 414
 415 Like any other L<Catalyst::Component>, controllers have a config hash,
 416 accessible through $self->config from the controller actions.  Some
 417 settings are in use by the Catalyst framework:
 418
 419 =head2 namespace
 420
 421 This specifies the internal namespace the controller should be bound
 422 to. By default the controller is bound to the URI version of the
 423 controller name. For instance controller 'MyApp::Controller::Foo::Bar'
 424 will be bound to 'foo/bar'. The default Root controller is an example
 425 of setting namespace to '' (the null string).
 426
 427 =head2 path
 428
 429 Sets 'path_prefix', as described below.
 430
 431 =head1 METHODS
 432
 433 =head2 BUILDARGS ($app, @args)
 434
 435 From L<Catalyst::Component::ApplicationAttribute>, stashes the application
 436 instance as $self->_application.
 437
 438 =head2 $self->action_for('name')
 439
 440 Returns the Catalyst::Action object (if any) for a given method name
 441 in this component.
 442
 443 =head2 $self->action_namespace($c)
 444
 445 Returns the private namespace for actions in this component. Defaults
 446 to a value from the controller name (for
 447 e.g. MyApp::Controller::Foo::Bar becomes "foo/bar") or can be
 448 overridden from the "namespace" config key.
 449
 450
 451 =head2 $self->path_prefix($c)
 452
 453 Returns the default path prefix for :PathPrefix, :Local, :LocalRegex and
 454 relative :Path actions in this component. Defaults to the action_namespace or
 455 can be overridden from the "path" config key.
 456
 457 =head2 $self->register_actions($c)
 458
 459 Finds all applicable actions for this component, creates
 460 Catalyst::Action objects (using $self->create_action) for them and
 461 registers them with $c->dispatcher.
 462
 463 =head2 $self->get_action_methods()
 464
 465 Returns a list of L<Moose::Meta::Method> objects, doing the
 466 L<MooseX::MethodAttributes::Role::Meta::Method> role, which are the set of
 467 action methods for this package.
 468
 469 =head2 $self->register_action_methods($c, @methods)
 470
 471 Creates action objects for a set of action methods using C< create_action >,
 472 and registers them with the dispatcher.
 473
 474 =head2 $self->create_action(%args)
 475
 476 Called with a hash of data to be use for construction of a new
 477 Catalyst::Action (or appropriate sub/alternative class) object.
 478
 479 =head2 $self->_application
 480
 481 =head2 $self->_app
 482
 483 Returns the application instance stored by C<new()>
 484
 485 =head1 AUTHORS
 486
 487 Catalyst Contributors, see Catalyst.pm
 488
 489 =head1 COPYRIGHT
 490
 491 This program is free software, you can redistribute it and/or modify
 492 it under the same terms as Perl itself.
 493
 494 =cut