lib/Catalyst/Controller.pm

   1 package Catalyst::Controller;
   2
   3 use Moose;
   4 use Moose::Util qw/find_meta/;
   5 use List::MoreUtils qw/uniq/;
   6 use namespace::clean -except => 'meta';
   7
   8 BEGIN { extends qw/Catalyst::Component MooseX::MethodAttributes::Inheritable/; }
   9
  10 use MooseX::MethodAttributes;
  11 use Catalyst::Exception;
  12 use Catalyst::Utils;
  13
  14 with 'Catalyst::Component::ApplicationAttribute';
  15
  16 has path_prefix =>
  17     (
  18      is => 'rw',
  19      isa => 'Str',
  20      init_arg => 'path',
  21      predicate => 'has_path_prefix',
  22     );
  23
  24 has action_namespace =>
  25     (
  26      is => 'rw',
  27      isa => 'Str',
  28      init_arg => 'namespace',
  29      predicate => 'has_action_namespace',
  30     );
  31
  32 has actions =>
  33     (
  34      accessor => '_controller_actions',
  35      isa => 'HashRef',
  36      init_arg => undef,
  37     );
  38
  39 sub BUILD {
  40     my ($self, $args) = @_;
  41     my $action  = delete $args->{action}  || {};
  42     my $actions = delete $args->{actions} || {};
  43     my $attr_value = $self->merge_config_hashes($actions, $action);
  44     $self->_controller_actions($attr_value);
  45 }
  46
  47
  48
  49 =head1 NAME
  50
  51 Catalyst::Controller - Catalyst Controller base class
  52
  53 =head1 SYNOPSIS
  54
  55   package MyApp::Controller::Search
  56   use base qw/Catalyst::Controller/;
  57
  58   sub foo : Local {
  59     my ($self,$c,@args) = @_;
  60     ...
  61   } # Dispatches to /search/foo
  62
  63 =head1 DESCRIPTION
  64
  65 Controllers are where the actions in the Catalyst framework
  66 reside. Each action is represented by a function with an attribute to
  67 identify what kind of action it is. See the L<Catalyst::Dispatcher>
  68 for more info about how Catalyst dispatches to actions.
  69
  70 =cut
  71
  72 #I think both of these could be attributes. doesn't really seem like they need
  73 #to ble class data. i think that attributes +default would work just fine
  74 __PACKAGE__->mk_classdata($_) for qw/_dispatch_steps _action_class/;
  75
  76 __PACKAGE__->_dispatch_steps( [qw/_BEGIN _AUTO _ACTION/] );
  77 __PACKAGE__->_action_class('Catalyst::Action');
  78
  79
  80 sub _DISPATCH : Private {
  81     my ( $self, $c ) = @_;
  82
  83     foreach my $disp ( @{ $self->_dispatch_steps } ) {
  84         last unless $c->forward($disp);
  85     }
  86
  87     $c->forward('_END');
  88 }
  89
  90 sub _BEGIN : Private {
  91     my ( $self, $c ) = @_;
  92     my $begin = ( $c->get_actions( 'begin', $c->namespace ) )[-1];
  93     return 1 unless $begin;
  94     $begin->dispatch( $c );
  95     return !@{ $c->error };
  96 }
  97
  98 sub _AUTO : Private {
  99     my ( $self, $c ) = @_;
 100     my @auto = $c->get_actions( 'auto', $c->namespace );
 101     foreach my $auto (@auto) {
 102         $auto->dispatch( $c );
 103         return 0 unless $c->state;
 104     }
 105     return 1;
 106 }
 107
 108 sub _ACTION : Private {
 109     my ( $self, $c ) = @_;
 110     if (   ref $c->action
 111         && $c->action->can('execute')
 112         && defined $c->req->action )
 113     {
 114         $c->action->dispatch( $c );
 115     }
 116     return !@{ $c->error };
 117 }
 118
 119 sub _END : Private {
 120     my ( $self, $c ) = @_;
 121     my $end = ( $c->get_actions( 'end', $c->namespace ) )[-1];
 122     return 1 unless $end;
 123     $end->dispatch( $c );
 124     return !@{ $c->error };
 125 }
 126
 127 sub action_for {
 128     my ( $self, $name ) = @_;
 129     my $app = ($self->isa('Catalyst') ? $self : $self->_application);
 130     return $app->dispatcher->get_action($name, $self->action_namespace);
 131 }
 132
 133 #my opinion is that this whole sub really should be a builder method, not
 134 #something that happens on every call. Anyone else disagree?? -- groditi
 135 ## -- apparently this is all just waiting for app/ctx split
 136 around action_namespace => sub {
 137     my $orig = shift;
 138     my ( $self, $c ) = @_;
 139
 140     my $class = ref($self) || $self;
 141     my $appclass = ref($c) || $c;
 142     if( ref($self) ){
 143         return $self->$orig if $self->has_action_namespace;
 144     } else {
 145         return $class->config->{namespace} if exists $class->config->{namespace};
 146     }
 147
 148     my $case_s;
 149     if( $c ){
 150         $case_s = $appclass->config->{case_sensitive};
 151     } else {
 152         if ($self->isa('Catalyst')) {
 153             $case_s = $class->config->{case_sensitive};
 154         } else {
 155             if (ref $self) {
 156                 $case_s = ref($self->_application)->config->{case_sensitive};
 157             } else {
 158                 confess("Can't figure out case_sensitive setting");
 159             }
 160         }
 161     }
 162
 163     my $namespace = Catalyst::Utils::class2prefix($self->catalyst_component_name, $case_s) || '';
 164     $self->$orig($namespace) if ref($self);
 165     return $namespace;
 166 };
 167
 168 #Once again, this is probably better written as a builder method
 169 around path_prefix => sub {
 170     my $orig = shift;
 171     my $self = shift;
 172     if( ref($self) ){
 173       return $self->$orig if $self->has_path_prefix;
 174     } else {
 175       return $self->config->{path} if exists $self->config->{path};
 176     }
 177     my $namespace = $self->action_namespace(@_);
 178     $self->$orig($namespace) if ref($self);
 179     return $namespace;
 180 };
 181
 182 sub get_action_methods {
 183     my $self = shift;
 184     my $meta = find_meta($self) || confess("No metaclass setup for $self");
 185     confess(
 186         sprintf "Metaclass %s for %s cannot support register_actions.",
 187             ref $meta, $meta->name,
 188     ) unless $meta->can('get_nearest_methods_with_attributes');
 189     my @methods = $meta->get_nearest_methods_with_attributes;
 190
 191     # actions specified via config are also action_methods
 192     push(
 193         @methods,
 194         map {
 195             $meta->find_method_by_name($_)
 196                 || confess( sprintf 'Action "%s" is not available from controller %s',
 197                             $_, ref $self )
 198           } grep {
 199               # '*' is a special action configuration key to apply config to all
 200               # actions. It's not to be looked up as a method
 201               # name. _controller_actions should probably be cleaned up before
 202               # we even get here.
 203               $_ ne '*'
 204           } keys %{ $self->_controller_actions }
 205     ) if ( ref $self );
 206     return uniq @methods;
 207 }
 208
 209
 210 sub register_actions {
 211     my ( $self, $c ) = @_;
 212     $self->register_action_methods( $c, $self->get_action_methods );
 213 }
 214
 215 sub register_action_methods {
 216     my ( $self, $c, @methods ) = @_;
 217     my $class = $self->catalyst_component_name;
 218     #this is still not correct for some reason.
 219     my $namespace = $self->action_namespace($c);
 220
 221     # FIXME - fugly
 222     if (!blessed($self) && $self eq $c && scalar(@methods)) {
 223         my @really_bad_methods = grep { ! /^_(DISPATCH|BEGIN|AUTO|ACTION|END)$/ } map { $_->name } @methods;
 224         if (scalar(@really_bad_methods)) {
 225             $c->log->warn("Action methods (" . join(', ', @really_bad_methods) . ") found defined in your application class, $self. This is deprecated, please move them into a Root controller.");
 226         }
 227     }
 228
 229     foreach my $method (@methods) {
 230         my $name = $method->name;
 231         # Horrible hack! All method metaclasses should have an attributes
 232         # method, core Moose bug - see r13354.
 233         my $attributes = $method->can('attributes') ? $method->attributes : [];
 234         my $attrs = $self->_parse_attrs( $c, $name, @{ $attributes } );
 235         if ( $attrs->{Private} && ( keys %$attrs > 1 ) ) {
 236             $c->log->debug( 'Bad action definition "'
 237                   . join( ' ', @{ $attributes } )
 238                   . qq/" for "$class->$name"/ )
 239               if $c->debug;
 240             next;
 241         }
 242         my $reverse = $namespace ? "${namespace}/${name}" : $name;
 243         my $action = $self->create_action(
 244             name       => $name,
 245             code       => $method->body,
 246             reverse    => $reverse,
 247             namespace  => $namespace,
 248             class      => $class,
 249             attributes => $attrs,
 250         );
 251
 252         $c->dispatcher->register( $c, $action );
 253     }
 254 }
 255
 256 sub action_class {
 257     my $self = shift;
 258     my %args = @_;
 259
 260     my $class = (exists $args{attributes}{ActionClass}
 261         ? $args{attributes}{ActionClass}[0]
 262         : $self->_action_class);
 263
 264     Class::MOP::load_class($class);
 265     return $class;
 266 }
 267
 268 sub create_action {
 269     my $self = shift;
 270     my %args = @_;
 271
 272     my $class = $self->action_class(%args);
 273     my $action_args = $self->config->{action_args};
 274
 275     my %extra_args = (
 276         %{ $action_args->{'*'}           || {} },
 277         %{ $action_args->{ $args{name} } || {} },
 278     );
 279
 280     return $class->new({ %extra_args, %args });
 281 }
 282
 283 sub _parse_attrs {
 284     my ( $self, $c, $name, @attrs ) = @_;
 285
 286     my %raw_attributes;
 287
 288     foreach my $attr (@attrs) {
 289
 290         # Parse out :Foo(bar) into Foo => bar etc (and arrayify)
 291
 292         if ( my ( $key, $value ) = ( $attr =~ /^(.*?)(?:\(\s*(.+?)\s*\))?$/ ) )
 293         {
 294
 295             if ( defined $value ) {
 296                 ( $value =~ s/^'(.*)'$/$1/ ) || ( $value =~ s/^"(.*)"/$1/ );
 297             }
 298             push( @{ $raw_attributes{$key} }, $value );
 299         }
 300     }
 301
 302     my $actions;
 303     if( ref($self) ) {
 304         $actions = $self->_controller_actions;
 305     } else {
 306         my $cfg = $self->config;
 307         $actions = $self->merge_config_hashes($cfg->{actions}, $cfg->{action});
 308     }
 309
 310     %raw_attributes = (
 311         %raw_attributes,
 312         exists $actions->{$name} ? %{ $actions->{$name } } : (),
 313     );
 314
 315     # Private actions with additional attributes will raise a warning and then
 316     # be ignored. Adding '*' arguments to the default _DISPATCH / etc. methods,
 317     # which are Private, will prevent those from being registered. They should
 318     # probably be turned into :Actions instead, or we might want to otherwise
 319     # disambiguate between those built-in internal actions and user-level
 320     # Private ones.
 321     %raw_attributes = (
 322         (exists $actions->{'*'} ? %{ $actions->{'*'} } : ()),
 323         %raw_attributes,
 324     ) unless $raw_attributes{Private};
 325
 326     my %final_attributes;
 327
 328     foreach my $key (keys %raw_attributes) {
 329
 330         my $raw = $raw_attributes{$key};
 331
 332         foreach my $value (ref($raw) eq 'ARRAY' ? @$raw : $raw) {
 333
 334             my $meth = "_parse_${key}_attr";
 335             if ( my $code = $self->can($meth) ) {
 336                 ( $key, $value ) = $self->$code( $c, $name, $value );
 337             }
 338             push( @{ $final_attributes{$key} }, $value );
 339         }
 340     }
 341
 342     return \%final_attributes;
 343 }
 344
 345 sub _parse_Global_attr {
 346     my ( $self, $c, $name, $value ) = @_;
 347     return $self->_parse_Path_attr( $c, $name, "/$name" );
 348 }
 349
 350 sub _parse_Absolute_attr { shift->_parse_Global_attr(@_); }
 351
 352 sub _parse_Local_attr {
 353     my ( $self, $c, $name, $value ) = @_;
 354     return $self->_parse_Path_attr( $c, $name, $name );
 355 }
 356
 357 sub _parse_Relative_attr { shift->_parse_Local_attr(@_); }
 358
 359 sub _parse_Path_attr {
 360     my ( $self, $c, $name, $value ) = @_;
 361     $value = '' if !defined $value;
 362     if ( $value =~ m!^/! ) {
 363         return ( 'Path', $value );
 364     }
 365     elsif ( length $value ) {
 366         return ( 'Path', join( '/', $self->path_prefix($c), $value ) );
 367     }
 368     else {
 369         return ( 'Path', $self->path_prefix($c) );
 370     }
 371 }
 372
 373 sub _parse_Regex_attr {
 374     my ( $self, $c, $name, $value ) = @_;
 375     return ( 'Regex', $value );
 376 }
 377
 378 sub _parse_Regexp_attr { shift->_parse_Regex_attr(@_); }
 379
 380 sub _parse_LocalRegex_attr {
 381     my ( $self, $c, $name, $value ) = @_;
 382     unless ( $value =~ s/^\^// ) { $value = "(?:.*?)$value"; }
 383
 384     my $prefix = $self->path_prefix( $c );
 385     $prefix .= '/' if length( $prefix );
 386
 387     return ( 'Regex', "^${prefix}${value}" );
 388 }
 389
 390 sub _parse_LocalRegexp_attr { shift->_parse_LocalRegex_attr(@_); }
 391
 392 sub _parse_Chained_attr {
 393     my ($self, $c, $name, $value) = @_;
 394
 395     if (defined($value) && length($value)) {
 396         if ($value eq '.') {
 397             $value = '/'.$self->action_namespace($c);
 398         } elsif (my ($rel, $rest) = $value =~ /^((?:\.{2}\/)+)(.*)$/) {
 399             my @parts = split '/', $self->action_namespace($c);
 400             my @levels = split '/', $rel;
 401
 402             $value = '/'.join('/', @parts[0 .. $#parts - @levels], $rest);
 403         } elsif ($value !~ m/^\//) {
 404             my $action_ns = $self->action_namespace($c);
 405
 406             if ($action_ns) {
 407                 $value = '/'.join('/', $action_ns, $value);
 408             } else {
 409                 $value = '/'.$value; # special case namespace '' (root)
 410             }
 411         }
 412     } else {
 413         $value = '/'
 414     }
 415
 416     return Chained => $value;
 417 }
 418
 419 sub _parse_ChainedParent_attr {
 420     my ($self, $c, $name, $value) = @_;
 421     return $self->_parse_Chained_attr($c, $name, '../'.$name);
 422 }
 423
 424 sub _parse_PathPrefix_attr {
 425     my ( $self, $c ) = @_;
 426     return PathPart => $self->path_prefix($c);
 427 }
 428
 429 sub _parse_ActionClass_attr {
 430     my ( $self, $c, $name, $value ) = @_;
 431     my $appname = $self->_application;
 432     $value = Catalyst::Utils::resolve_namespace($appname . '::Action', $self->_action_class, $value);
 433     return ( 'ActionClass', $value );
 434 }
 435
 436 sub _parse_MyAction_attr {
 437     my ( $self, $c, $name, $value ) = @_;
 438
 439     my $appclass = Catalyst::Utils::class2appclass($self);
 440     $value = "${appclass}::Action::${value}";
 441
 442     return ( 'ActionClass', $value );
 443 }
 444
 445 __PACKAGE__->meta->make_immutable;
 446
 447 1;
 448
 449 __END__
 450
 451 =head1 CONFIGURATION
 452
 453 Like any other L<Catalyst::Component>, controllers have a config hash,
 454 accessible through $self->config from the controller actions.  Some
 455 settings are in use by the Catalyst framework:
 456
 457 =head2 namespace
 458
 459 This specifies the internal namespace the controller should be bound
 460 to. By default the controller is bound to the URI version of the
 461 controller name. For instance controller 'MyApp::Controller::Foo::Bar'
 462 will be bound to 'foo/bar'. The default Root controller is an example
 463 of setting namespace to '' (the null string).
 464
 465 =head2 path
 466
 467 Sets 'path_prefix', as described below.
 468
 469 =head2 action
 470
 471 Allows you to set the attributes that the dispatcher creates actions out of.
 472 This allows you to do 'rails style routes', or override some of the
 473 attribute defintions of actions composed from Roles.
 474 You can set arguments globally (for all actions of the controller) and
 475 specifically (for a single action).
 476
 477     __PACKAGE__->config(
 478         action => {
 479             '*' => { Chained => 'base', Args => 0  },
 480             base => { Chained => '/', PathPart => '', CaptureArgs => 0 },
 481         },
 482      );
 483
 484 In the case above every sub in the package would be made into a Chain
 485 endpoint with a URI the same as the sub name for each sub, chained
 486 to the sub named C<base>. Ergo dispatch to C</example> would call the
 487 C<base> method, then the C<example> method.
 488
 489 =head2 action_args
 490
 491 Allows you to set constructor arguments on your actions. You can set arguments
 492 globally and specifically (as above).
 493 This is particularly useful when using C<ActionRole>s
 494 (L<Catalyst::Controller::ActionRole>) and custom C<ActionClass>es.
 495
 496     __PACKAGE__->config(
 497         action_args => {
 498             '*' => { globalarg1 => 'hello', globalarg2 => 'goodbye' },
 499             'specific_action' => { customarg => 'arg1' },
 500         },
 501      );
 502
 503 In the case above the action class associated with C<specific_action> would get
 504 passed the following arguments, in addition to the normal action constructor
 505 arguments, when it is instantiated:
 506
 507   (globalarg1 => 'hello', globalarg2 => 'goodbye', customarg => 'arg1')
 508
 509 =head1 METHODS
 510
 511 =head2 BUILDARGS ($app, @args)
 512
 513 From L<Catalyst::Component::ApplicationAttribute>, stashes the application
 514 instance as $self->_application.
 515
 516 =head2 $self->action_for('name')
 517
 518 Returns the Catalyst::Action object (if any) for a given method name
 519 in this component.
 520
 521 =head2 $self->action_namespace($c)
 522
 523 Returns the private namespace for actions in this component. Defaults
 524 to a value from the controller name (for
 525 e.g. MyApp::Controller::Foo::Bar becomes "foo/bar") or can be
 526 overridden from the "namespace" config key.
 527
 528
 529 =head2 $self->path_prefix($c)
 530
 531 Returns the default path prefix for :PathPrefix, :Local, :LocalRegex and
 532 relative :Path actions in this component. Defaults to the action_namespace or
 533 can be overridden from the "path" config key.
 534
 535 =head2 $self->register_actions($c)
 536
 537 Finds all applicable actions for this component, creates
 538 Catalyst::Action objects (using $self->create_action) for them and
 539 registers them with $c->dispatcher.
 540
 541 =head2 $self->get_action_methods()
 542
 543 Returns a list of L<Moose::Meta::Method> objects, doing the
 544 L<MooseX::MethodAttributes::Role::Meta::Method> role, which are the set of
 545 action methods for this package.
 546
 547 =head2 $self->register_action_methods($c, @methods)
 548
 549 Creates action objects for a set of action methods using C< create_action >,
 550 and registers them with the dispatcher.
 551
 552 =head2 $self->action_class(%args)
 553
 554 Used when a controller is creating an action to determine the correct base
 555 action class to use.
 556
 557 =head2 $self->create_action(%args)
 558
 559 Called with a hash of data to be use for construction of a new
 560 Catalyst::Action (or appropriate sub/alternative class) object.
 561
 562 =head2 $self->_application
 563
 564 =head2 $self->_app
 565
 566 Returns the application instance stored by C<new()>
 567
 568 =head1 AUTHORS
 569
 570 Catalyst Contributors, see Catalyst.pm
 571
 572 =head1 COPYRIGHT
 573
 574 This library is free software. You can redistribute it and/or modify
 575 it under the same terms as Perl itself.
 576
 577 =cut