lib/Catalyst/Controller.pm

   1 package Catalyst::Controller;
   2
   3 use Moose;
   4 use Moose::Util qw/find_meta/;
   5
   6 use namespace::clean -except => 'meta';
   7
   8 BEGIN { extends qw/Catalyst::Component MooseX::MethodAttributes::Inheritable/; }
   9
  10 use MooseX::MethodAttributes;
  11 use Catalyst::Exception;
  12 use Catalyst::Utils;
  13
  14 with 'Catalyst::Component::ApplicationAttribute';
  15
  16 has path_prefix =>
  17     (
  18      is => 'rw',
  19      isa => 'Str',
  20      init_arg => 'path',
  21      predicate => 'has_path_prefix',
  22     );
  23
  24 has action_namespace =>
  25     (
  26      is => 'rw',
  27      isa => 'Str',
  28      init_arg => 'namespace',
  29      predicate => 'has_action_namespace',
  30     );
  31
  32 has _controller_actions =>
  33     (
  34      is => 'rw',
  35      isa => 'HashRef',
  36      init_arg => undef,
  37     );
  38
  39 sub BUILD {
  40     my ($self, $args) = @_;
  41     my $action  = delete $args->{action}  || {};
  42     my $actions = delete $args->{actions} || {};
  43     my $attr_value = $self->merge_config_hashes($actions, $action);
  44     $self->_controller_actions($attr_value);
  45 }
  46
  47
  48
  49 =head1 NAME
  50
  51 Catalyst::Controller - Catalyst Controller base class
  52
  53 =head1 SYNOPSIS
  54
  55   package MyApp::Controller::Search
  56   use base qw/Catalyst::Controller/;
  57
  58   sub foo : Local {
  59     my ($self,$c,@args) = @_;
  60     ...
  61   } # Dispatches to /search/foo
  62
  63 =head1 DESCRIPTION
  64
  65 Controllers are where the actions in the Catalyst framework
  66 reside. Each action is represented by a function with an attribute to
  67 identify what kind of action it is. See the L<Catalyst::Dispatcher>
  68 for more info about how Catalyst dispatches to actions.
  69
  70 =cut
  71
  72 #I think both of these could be attributes. doesn't really seem like they need
  73 #to ble class data. i think that attributes +default would work just fine
  74 __PACKAGE__->mk_classdata($_) for qw/_dispatch_steps _action_class/;
  75
  76 __PACKAGE__->_dispatch_steps( [qw/_BEGIN _AUTO _ACTION/] );
  77 __PACKAGE__->_action_class('Catalyst::Action');
  78
  79
  80 sub _DISPATCH : Private {
  81     my ( $self, $c ) = @_;
  82
  83     foreach my $disp ( @{ $self->_dispatch_steps } ) {
  84         last unless $c->forward($disp);
  85     }
  86
  87     $c->forward('_END');
  88 }
  89
  90 sub _BEGIN : Private {
  91     my ( $self, $c ) = @_;
  92     my $begin = ( $c->get_actions( 'begin', $c->namespace ) )[-1];
  93     return 1 unless $begin;
  94     $begin->dispatch( $c );
  95     return !@{ $c->error };
  96 }
  97
  98 sub _AUTO : Private {
  99     my ( $self, $c ) = @_;
 100     my @auto = $c->get_actions( 'auto', $c->namespace );
 101     foreach my $auto (@auto) {
 102         $auto->dispatch( $c );
 103         return 0 unless $c->state;
 104     }
 105     return 1;
 106 }
 107
 108 sub _ACTION : Private {
 109     my ( $self, $c ) = @_;
 110     if (   ref $c->action
 111         && $c->action->can('execute')
 112         && defined $c->req->action )
 113     {
 114         $c->action->dispatch( $c );
 115     }
 116     return !@{ $c->error };
 117 }
 118
 119 sub _END : Private {
 120     my ( $self, $c ) = @_;
 121     my $end = ( $c->get_actions( 'end', $c->namespace ) )[-1];
 122     return 1 unless $end;
 123     $end->dispatch( $c );
 124     return !@{ $c->error };
 125 }
 126
 127 sub action_for {
 128     my ( $self, $name ) = @_;
 129     my $app = ($self->isa('Catalyst') ? $self : $self->_application);
 130     return $app->dispatcher->get_action($name, $self->action_namespace);
 131 }
 132
 133 #my opinion is that this whole sub really should be a builder method, not
 134 #something that happens on every call. Anyone else disagree?? -- groditi
 135 ## -- apparently this is all just waiting for app/ctx split
 136 around action_namespace => sub {
 137     my $orig = shift;
 138     my ( $self, $c ) = @_;
 139
 140     my $class = ref($self) || $self;
 141     my $appclass = ref($c) || $c;
 142     if( ref($self) ){
 143         return $self->$orig if $self->has_action_namespace;
 144     } else {
 145         return $class->config->{namespace} if exists $class->config->{namespace};
 146     }
 147
 148     my $case_s;
 149     if( $c ){
 150         $case_s = $appclass->config->{case_sensitive};
 151     } else {
 152         if ($self->isa('Catalyst')) {
 153             $case_s = $class->config->{case_sensitive};
 154         } else {
 155             if (ref $self) {
 156                 $case_s = ref($self->_application)->config->{case_sensitive};
 157             } else {
 158                 confess("Can't figure out case_sensitive setting");
 159             }
 160         }
 161     }
 162
 163     my $namespace = Catalyst::Utils::class2prefix($self->catalyst_component_name, $case_s) || '';
 164     $self->$orig($namespace) if ref($self);
 165     return $namespace;
 166 };
 167
 168 #Once again, this is probably better written as a builder method
 169 around path_prefix => sub {
 170     my $orig = shift;
 171     my $self = shift;
 172     if( ref($self) ){
 173       return $self->$orig if $self->has_path_prefix;
 174     } else {
 175       return $self->config->{path} if exists $self->config->{path};
 176     }
 177     my $namespace = $self->action_namespace(@_);
 178     $self->$orig($namespace) if ref($self);
 179     return $namespace;
 180 };
 181
 182 sub get_action_methods {
 183     my $self = shift;
 184     my $meta = find_meta($self) || confess("No metaclass setup for $self");
 185     confess("Metaclass "
 186           . ref($meta) . " for "
 187           . $meta->name
 188           . " cannot support register_actions." )
 189       unless $meta->can('get_nearest_methods_with_attributes');
 190     my @methods = $meta->get_nearest_methods_with_attributes;
 191
 192     # actions specified via config are also action_methods
 193     push(
 194         @methods,
 195         map {
 196             $meta->find_method_by_name($_)
 197               || confess( 'Action "'
 198                   . $_
 199                   . '" is not available from controller '
 200                   . ( ref $self ) )
 201           } keys %{ $self->_controller_actions }
 202     ) if ( ref $self );
 203     return @methods;
 204 }
 205
 206
 207 sub register_actions {
 208     my ( $self, $c ) = @_;
 209     $self->register_action_methods( $c, $self->get_action_methods );
 210 }
 211
 212 sub register_action_methods {
 213     my ( $self, $c, @methods ) = @_;
 214     my $class = $self->catalyst_component_name;
 215     #this is still not correct for some reason.
 216     my $namespace = $self->action_namespace($c);
 217
 218     # Uncomment as soon as you fix the tests :)
 219     #if (!blessed($self) && $self eq $c && scalar(@methods)) {
 220     #    $c->log->warn("Action methods found defined in your application class, $self. This is deprecated, please move them into a Root controller.");
 221     #}
 222
 223     foreach my $method (@methods) {
 224         my $name = $method->name;
 225         my $attributes = $method->attributes;
 226         my $attrs = $self->_parse_attrs( $c, $name, @{ $attributes } );
 227         if ( $attrs->{Private} && ( keys %$attrs > 1 ) ) {
 228             $c->log->debug( 'Bad action definition "'
 229                   . join( ' ', @{ $attributes } )
 230                   . qq/" for "$class->$name"/ )
 231               if $c->debug;
 232             next;
 233         }
 234         my $reverse = $namespace ? "${namespace}/${name}" : $name;
 235         my $action = $self->create_action(
 236             name       => $name,
 237             code       => $method->body,
 238             reverse    => $reverse,
 239             namespace  => $namespace,
 240             class      => $class,
 241             attributes => $attrs,
 242         );
 243
 244         $c->dispatcher->register( $c, $action );
 245     }
 246 }
 247
 248 sub create_action {
 249     my $self = shift;
 250     my %args = @_;
 251
 252     my $class = (exists $args{attributes}{ActionClass}
 253                     ? $args{attributes}{ActionClass}[0]
 254                     : $self->_action_class);
 255
 256     Class::MOP::load_class($class);
 257     return $class->new( \%args );
 258 }
 259
 260 sub _parse_attrs {
 261     my ( $self, $c, $name, @attrs ) = @_;
 262
 263     my %raw_attributes;
 264
 265     foreach my $attr (@attrs) {
 266
 267         # Parse out :Foo(bar) into Foo => bar etc (and arrayify)
 268
 269         if ( my ( $key, $value ) = ( $attr =~ /^(.*?)(?:\(\s*(.+?)\s*\))?$/ ) )
 270         {
 271
 272             if ( defined $value ) {
 273                 ( $value =~ s/^'(.*)'$/$1/ ) || ( $value =~ s/^"(.*)"/$1/ );
 274             }
 275             push( @{ $raw_attributes{$key} }, $value );
 276         }
 277     }
 278
 279     #I know that the original behavior was to ignore action if actions was set
 280     # but i actually think this may be a little more sane? we can always remove
 281     # the merge behavior quite easily and go back to having actions have
 282     # presedence over action by modifying the keys. i honestly think this is
 283     # superior while mantaining really high degree of compat
 284     my $actions;
 285     if( ref($self) ) {
 286         $actions = $self->_controller_actions;
 287     } else {
 288         my $cfg = $self->config;
 289         $actions = $self->merge_config_hashes($cfg->{actions}, $cfg->{action});
 290     }
 291
 292     %raw_attributes = ((exists $actions->{'*'} ? %{$actions->{'*'}} : ()),
 293                        %raw_attributes,
 294                        (exists $actions->{$name} ? %{$actions->{$name}} : ()));
 295
 296
 297     my %final_attributes;
 298
 299     foreach my $key (keys %raw_attributes) {
 300
 301         my $raw = $raw_attributes{$key};
 302
 303         foreach my $value (ref($raw) eq 'ARRAY' ? @$raw : $raw) {
 304
 305             my $meth = "_parse_${key}_attr";
 306             if ( my $code = $self->can($meth) ) {
 307                 ( $key, $value ) = $self->$code( $c, $name, $value );
 308             }
 309             push( @{ $final_attributes{$key} }, $value );
 310         }
 311     }
 312
 313     return \%final_attributes;
 314 }
 315
 316 sub _parse_Global_attr {
 317     my ( $self, $c, $name, $value ) = @_;
 318     return $self->_parse_Path_attr( $c, $name, "/$name" );
 319 }
 320
 321 sub _parse_Absolute_attr { shift->_parse_Global_attr(@_); }
 322
 323 sub _parse_Local_attr {
 324     my ( $self, $c, $name, $value ) = @_;
 325     return $self->_parse_Path_attr( $c, $name, $name );
 326 }
 327
 328 sub _parse_Relative_attr { shift->_parse_Local_attr(@_); }
 329
 330 sub _parse_Path_attr {
 331     my ( $self, $c, $name, $value ) = @_;
 332     $value = '' if !defined $value;
 333     if ( $value =~ m!^/! ) {
 334         return ( 'Path', $value );
 335     }
 336     elsif ( length $value ) {
 337         return ( 'Path', join( '/', $self->path_prefix($c), $value ) );
 338     }
 339     else {
 340         return ( 'Path', $self->path_prefix($c) );
 341     }
 342 }
 343
 344 sub _parse_Regex_attr {
 345     my ( $self, $c, $name, $value ) = @_;
 346     return ( 'Regex', $value );
 347 }
 348
 349 sub _parse_Regexp_attr { shift->_parse_Regex_attr(@_); }
 350
 351 sub _parse_LocalRegex_attr {
 352     my ( $self, $c, $name, $value ) = @_;
 353     unless ( $value =~ s/^\^// ) { $value = "(?:.*?)$value"; }
 354
 355     my $prefix = $self->path_prefix( $c );
 356     $prefix .= '/' if length( $prefix );
 357
 358     return ( 'Regex', "^${prefix}${value}" );
 359 }
 360
 361 sub _parse_LocalRegexp_attr { shift->_parse_LocalRegex_attr(@_); }
 362
 363 sub _parse_Chained_attr {
 364     my ($self, $c, $name, $value) = @_;
 365
 366     if (defined($value) && length($value)) {
 367         if ($value eq '.') {
 368             $value = '/'.$self->action_namespace($c);
 369         } elsif (my ($rel, $rest) = $value =~ /^((?:\.{2}\/)+)(.*)$/) {
 370             my @parts = split '/', $self->action_namespace($c);
 371             my @levels = split '/', $rel;
 372
 373             $value = '/'.join('/', @parts[0 .. $#parts - @levels], $rest);
 374         } elsif ($value !~ m/^\//) {
 375             my $action_ns = $self->action_namespace($c);
 376
 377             if ($action_ns) {
 378                 $value = '/'.join('/', $action_ns, $value);
 379             } else {
 380                 $value = '/'.$value; # special case namespace '' (root)
 381             }
 382         }
 383     } else {
 384         $value = '/'
 385     }
 386
 387     return Chained => $value;
 388 }
 389
 390 sub _parse_ChainedParent_attr {
 391     my ($self, $c, $name, $value) = @_;
 392     return $self->_parse_Chained_attr($c, $name, '../'.$name);
 393 }
 394
 395 sub _parse_PathPrefix_attr {
 396     my ( $self, $c ) = @_;
 397     return PathPart => $self->path_prefix($c);
 398 }
 399
 400 sub _parse_ActionClass_attr {
 401     my ( $self, $c, $name, $value ) = @_;
 402     my $appname = $self->_application;
 403     $value = Catalyst::Utils::resolve_namespace($appname . '::Action', $self->_action_class, $value);
 404     return ( 'ActionClass', $value );
 405 }
 406
 407 sub _parse_MyAction_attr {
 408     my ( $self, $c, $name, $value ) = @_;
 409
 410     my $appclass = Catalyst::Utils::class2appclass($self);
 411     $value = "${appclass}::Action::${value}";
 412
 413     return ( 'ActionClass', $value );
 414 }
 415
 416 __PACKAGE__->meta->make_immutable;
 417
 418 1;
 419
 420 __END__
 421
 422 =head1 CONFIGURATION
 423
 424 Like any other L<Catalyst::Component>, controllers have a config hash,
 425 accessible through $self->config from the controller actions.  Some
 426 settings are in use by the Catalyst framework:
 427
 428 =head2 namespace
 429
 430 This specifies the internal namespace the controller should be bound
 431 to. By default the controller is bound to the URI version of the
 432 controller name. For instance controller 'MyApp::Controller::Foo::Bar'
 433 will be bound to 'foo/bar'. The default Root controller is an example
 434 of setting namespace to '' (the null string).
 435
 436 =head2 path
 437
 438 Sets 'path_prefix', as described below.
 439
 440 =head1 METHODS
 441
 442 =head2 BUILDARGS ($app, @args)
 443
 444 From L<Catalyst::Component::ApplicationAttribute>, stashes the application
 445 instance as $self->_application.
 446
 447 =head2 $self->action_for('name')
 448
 449 Returns the Catalyst::Action object (if any) for a given method name
 450 in this component.
 451
 452 =head2 $self->action_namespace($c)
 453
 454 Returns the private namespace for actions in this component. Defaults
 455 to a value from the controller name (for
 456 e.g. MyApp::Controller::Foo::Bar becomes "foo/bar") or can be
 457 overridden from the "namespace" config key.
 458
 459
 460 =head2 $self->path_prefix($c)
 461
 462 Returns the default path prefix for :PathPrefix, :Local, :LocalRegex and
 463 relative :Path actions in this component. Defaults to the action_namespace or
 464 can be overridden from the "path" config key.
 465
 466 =head2 $self->register_actions($c)
 467
 468 Finds all applicable actions for this component, creates
 469 Catalyst::Action objects (using $self->create_action) for them and
 470 registers them with $c->dispatcher.
 471
 472 =head2 $self->get_action_methods()
 473
 474 Returns a list of L<Moose::Meta::Method> objects, doing the
 475 L<MooseX::MethodAttributes::Role::Meta::Method> role, which are the set of
 476 action methods for this package.
 477
 478 =head2 $self->register_action_methods($c, @methods)
 479
 480 Creates action objects for a set of action methods using C< create_action >,
 481 and registers them with the dispatcher.
 482
 483 =head2 $self->create_action(%args)
 484
 485 Called with a hash of data to be use for construction of a new
 486 Catalyst::Action (or appropriate sub/alternative class) object.
 487
 488 =head2 $self->_application
 489
 490 =head2 $self->_app
 491
 492 Returns the application instance stored by C<new()>
 493
 494 =head1 AUTHORS
 495
 496 Catalyst Contributors, see Catalyst.pm
 497
 498 =head1 COPYRIGHT
 499
 500 This library is free software. You can redistribute it and/or modify
 501 it under the same terms as Perl itself.
 502
 503 =cut