lib/Catalyst/Controller.pm

   1 package Catalyst::Controller;
   2
   3 use Moose;
   4 use Moose::Util qw/find_meta/;
   5
   6 use namespace::clean -except => 'meta';
   7
   8 BEGIN { extends qw/Catalyst::Component MooseX::MethodAttributes::Inheritable/; }
   9
  10 use MooseX::MethodAttributes;
  11 use Catalyst::Exception;
  12 use Catalyst::Utils;
  13
  14 with 'Catalyst::Component::ApplicationAttribute';
  15
  16 has path_prefix =>
  17     (
  18      is => 'rw',
  19      isa => 'Str',
  20      init_arg => 'path',
  21      predicate => 'has_path_prefix',
  22     );
  23
  24 has action_namespace =>
  25     (
  26      is => 'rw',
  27      isa => 'Str',
  28      init_arg => 'namespace',
  29      predicate => 'has_action_namespace',
  30     );
  31
  32 has _controller_actions =>
  33     (
  34      is => 'rw',
  35      isa => 'HashRef',
  36      init_arg => undef,
  37     );
  38
  39 sub BUILD {
  40     my ($self, $args) = @_;
  41     my $action  = delete $args->{action}  || {};
  42     my $actions = delete $args->{actions} || {};
  43     my $attr_value = $self->merge_config_hashes($actions, $action);
  44     $self->_controller_actions($attr_value);
  45 }
  46
  47 =head1 NAME
  48
  49 Catalyst::Controller - Catalyst Controller base class
  50
  51 =head1 SYNOPSIS
  52
  53   package MyApp::Controller::Search
  54   use base qw/Catalyst::Controller/;
  55
  56   sub foo : Local {
  57     my ($self,$c,@args) = @_;
  58     ...
  59   } # Dispatches to /search/foo
  60
  61 =head1 DESCRIPTION
  62
  63 Controllers are where the actions in the Catalyst framework
  64 reside. Each action is represented by a function with an attribute to
  65 identify what kind of action it is. See the L<Catalyst::Dispatcher>
  66 for more info about how Catalyst dispatches to actions.
  67
  68 =cut
  69
  70 #I think both of these could be attributes. doesn't really seem like they need
  71 #to ble class data. i think that attributes +default would work just fine
  72 __PACKAGE__->mk_classdata($_) for qw/_dispatch_steps _action_class/;
  73
  74 __PACKAGE__->_dispatch_steps( [qw/_BEGIN _AUTO _ACTION/] );
  75 __PACKAGE__->_action_class('Catalyst::Action');
  76
  77
  78 sub _DISPATCH : Private {
  79     my ( $self, $c ) = @_;
  80
  81     foreach my $disp ( @{ $self->_dispatch_steps } ) {
  82         last unless $c->forward($disp);
  83     }
  84
  85     $c->forward('_END');
  86 }
  87
  88 sub _BEGIN : Private {
  89     my ( $self, $c ) = @_;
  90     my $begin = ( $c->get_actions( 'begin', $c->namespace ) )[-1];
  91     return 1 unless $begin;
  92     $begin->dispatch( $c );
  93     return !@{ $c->error };
  94 }
  95
  96 sub _AUTO : Private {
  97     my ( $self, $c ) = @_;
  98     my @auto = $c->get_actions( 'auto', $c->namespace );
  99     foreach my $auto (@auto) {
 100         $auto->dispatch( $c );
 101         return 0 unless $c->state;
 102     }
 103     return 1;
 104 }
 105
 106 sub _ACTION : Private {
 107     my ( $self, $c ) = @_;
 108     if (   ref $c->action
 109         && $c->action->can('execute')
 110         && defined $c->req->action )
 111     {
 112         $c->action->dispatch( $c );
 113     }
 114     return !@{ $c->error };
 115 }
 116
 117 sub _END : Private {
 118     my ( $self, $c ) = @_;
 119     my $end = ( $c->get_actions( 'end', $c->namespace ) )[-1];
 120     return 1 unless $end;
 121     $end->dispatch( $c );
 122     return !@{ $c->error };
 123 }
 124
 125 sub action_for {
 126     my ( $self, $name ) = @_;
 127     my $app = ($self->isa('Catalyst') ? $self : $self->_application);
 128     return $app->dispatcher->get_action($name, $self->action_namespace);
 129 }
 130
 131 #my opinion is that this whole sub really should be a builder method, not
 132 #something that happens on every call. Anyone else disagree?? -- groditi
 133 ## -- apparently this is all just waiting for app/ctx split
 134 around action_namespace => sub {
 135     my $orig = shift;
 136     my ( $self, $c ) = @_;
 137
 138     if( ref($self) ){
 139         return $self->$orig if $self->has_action_namespace;
 140     } else {
 141         return $self->config->{namespace} if exists $self->config->{namespace};
 142     }
 143
 144     my $case_s;
 145     if( $c ){
 146         $case_s = $c->config->{case_sensitive};
 147     } else {
 148         if ($self->isa('Catalyst')) {
 149             $case_s = $self->config->{case_sensitive};
 150         } else {
 151             if (ref $self) {
 152                 $case_s = $self->_application->config->{case_sensitive};
 153             } else {
 154                 confess("Can't figure out case_sensitive setting");
 155             }
 156         }
 157     }
 158
 159     my $namespace = Catalyst::Utils::class2prefix($self->_component_name, $case_s) || '';
 160     $self->$orig($namespace) if ref($self);
 161     return $namespace;
 162 };
 163
 164 #Once again, this is probably better written as a builder method
 165 around path_prefix => sub {
 166     my $orig = shift;
 167     my $self = shift;
 168     if( ref($self) ){
 169       return $self->$orig if $self->has_path_prefix;
 170     } else {
 171       return $self->config->{path} if exists $self->config->{path};
 172     }
 173     my $namespace = $self->action_namespace(@_);
 174     $self->$orig($namespace) if ref($self);
 175     return $namespace;
 176 };
 177
 178 sub get_action_methods {
 179     my $self = shift;
 180     my $meta = find_meta($self);
 181     confess("Metaclass for "
 182           . ref($meta) . " for "
 183           . $meta->name
 184           . " cannot support register_actions." )
 185       unless $meta->can('get_nearest_methods_with_attributes');
 186     my @methods = $meta->get_nearest_methods_with_attributes;
 187
 188     # actions specified via config are also action_methods
 189     push(
 190         @methods,
 191         map {
 192             $meta->find_method_by_name($_)
 193               || confess( 'Action "'
 194                   . $_
 195                   . '" is not available from controller '
 196                   . ( ref $self ) )
 197           } keys %{ $self->_controller_actions }
 198     ) if ( ref $self );
 199     return @methods;
 200 }
 201
 202
 203 sub register_actions {
 204     my ( $self, $c ) = @_;
 205     $self->register_action_methods( $c, $self->get_action_methods );
 206 }
 207
 208 sub register_action_methods {
 209     my ( $self, $c, @methods ) = @_;
 210     my $class = $self->_component_name;
 211     #this is still not correct for some reason.
 212     my $namespace = $self->action_namespace($c);
 213
 214     # Uncomment as soon as you fix the tests :)
 215     #if (!blessed($self) && $self eq $c && scalar(@methods)) {
 216     #    $c->log->warn("Action methods found defined in your application class, $self. This is deprecated, please move them into a Root controller.");
 217     #}
 218
 219     foreach my $method (@methods) {
 220         my $name = $method->name;
 221         my $attributes = $method->attributes;
 222         my $attrs = $self->_parse_attrs( $c, $name, @{ $attributes } );
 223         if ( $attrs->{Private} && ( keys %$attrs > 1 ) ) {
 224             $c->log->debug( 'Bad action definition "'
 225                   . join( ' ', @{ $attributes } )
 226                   . qq/" for "$class->$name"/ )
 227               if $c->debug;
 228             next;
 229         }
 230         my $reverse = $namespace ? "${namespace}/${name}" : $name;
 231         my $action = $self->create_action(
 232             name       => $name,
 233             code       => $method->body,
 234             reverse    => $reverse,
 235             namespace  => $namespace,
 236             class      => $class,
 237             attributes => $attrs,
 238         );
 239
 240         $c->dispatcher->register( $c, $action );
 241     }
 242 }
 243
 244 sub create_action {
 245     my $self = shift;
 246     my %args = @_;
 247
 248     my $class = (exists $args{attributes}{ActionClass}
 249                     ? $args{attributes}{ActionClass}[0]
 250                     : $self->_action_class);
 251
 252     Class::MOP::load_class($class);
 253     return $class->new( \%args );
 254 }
 255
 256 sub _parse_attrs {
 257     my ( $self, $c, $name, @attrs ) = @_;
 258
 259     my %raw_attributes;
 260
 261     foreach my $attr (@attrs) {
 262
 263         # Parse out :Foo(bar) into Foo => bar etc (and arrayify)
 264
 265         if ( my ( $key, $value ) = ( $attr =~ /^(.*?)(?:\(\s*(.+?)\s*\))?$/ ) )
 266         {
 267
 268             if ( defined $value ) {
 269                 ( $value =~ s/^'(.*)'$/$1/ ) || ( $value =~ s/^"(.*)"/$1/ );
 270             }
 271             push( @{ $raw_attributes{$key} }, $value );
 272         }
 273     }
 274
 275     #I know that the original behavior was to ignore action if actions was set
 276     # but i actually think this may be a little more sane? we can always remove
 277     # the merge behavior quite easily and go back to having actions have
 278     # presedence over action by modifying the keys. i honestly think this is
 279     # superior while mantaining really high degree of compat
 280     my $actions;
 281     if( ref($self) ) {
 282         $actions = $self->_controller_actions;
 283     } else {
 284         my $cfg = $self->config;
 285         $actions = $self->merge_config_hashes($cfg->{actions}, $cfg->{action});
 286     }
 287
 288     %raw_attributes = ((exists $actions->{'*'} ? %{$actions->{'*'}} : ()),
 289                        %raw_attributes,
 290                        (exists $actions->{$name} ? %{$actions->{$name}} : ()));
 291
 292
 293     my %final_attributes;
 294
 295     foreach my $key (keys %raw_attributes) {
 296
 297         my $raw = $raw_attributes{$key};
 298
 299         foreach my $value (ref($raw) eq 'ARRAY' ? @$raw : $raw) {
 300
 301             my $meth = "_parse_${key}_attr";
 302             if ( my $code = $self->can($meth) ) {
 303                 ( $key, $value ) = $self->$code( $c, $name, $value );
 304             }
 305             push( @{ $final_attributes{$key} }, $value );
 306         }
 307     }
 308
 309     return \%final_attributes;
 310 }
 311
 312 sub _parse_Global_attr {
 313     my ( $self, $c, $name, $value ) = @_;
 314     return $self->_parse_Path_attr( $c, $name, "/$name" );
 315 }
 316
 317 sub _parse_Absolute_attr { shift->_parse_Global_attr(@_); }
 318
 319 sub _parse_Local_attr {
 320     my ( $self, $c, $name, $value ) = @_;
 321     return $self->_parse_Path_attr( $c, $name, $name );
 322 }
 323
 324 sub _parse_Relative_attr { shift->_parse_Local_attr(@_); }
 325
 326 sub _parse_Path_attr {
 327     my ( $self, $c, $name, $value ) = @_;
 328     $value = '' if !defined $value;
 329     if ( $value =~ m!^/! ) {
 330         return ( 'Path', $value );
 331     }
 332     elsif ( length $value ) {
 333         return ( 'Path', join( '/', $self->path_prefix($c), $value ) );
 334     }
 335     else {
 336         return ( 'Path', $self->path_prefix($c) );
 337     }
 338 }
 339
 340 sub _parse_Regex_attr {
 341     my ( $self, $c, $name, $value ) = @_;
 342     return ( 'Regex', $value );
 343 }
 344
 345 sub _parse_Regexp_attr { shift->_parse_Regex_attr(@_); }
 346
 347 sub _parse_LocalRegex_attr {
 348     my ( $self, $c, $name, $value ) = @_;
 349     unless ( $value =~ s/^\^// ) { $value = "(?:.*?)$value"; }
 350
 351     my $prefix = $self->path_prefix( $c );
 352     $prefix .= '/' if length( $prefix );
 353
 354     return ( 'Regex', "^${prefix}${value}" );
 355 }
 356
 357 sub _parse_LocalRegexp_attr { shift->_parse_LocalRegex_attr(@_); }
 358
 359 sub _parse_Chained_attr {
 360     my ($self, $c, $name, $value) = @_;
 361
 362     if (defined($value) && length($value)) {
 363         if ($value eq '.') {
 364             $value = '/'.$self->action_namespace($c);
 365         } elsif (my ($rel, $rest) = $value =~ /^((?:\.{2}\/)+)(.*)$/) {
 366             my @parts = split '/', $self->action_namespace($c);
 367             my @levels = split '/', $rel;
 368
 369             $value = '/'.join('/', @parts[0 .. $#parts - @levels], $rest);
 370         } elsif ($value !~ m/^\//) {
 371             my $action_ns = $self->action_namespace($c);
 372
 373             if ($action_ns) {
 374                 $value = '/'.join('/', $action_ns, $value);
 375             } else {
 376                 $value = '/'.$value; # special case namespace '' (root)
 377             }
 378         }
 379     } else {
 380         $value = '/'
 381     }
 382
 383     return Chained => $value;
 384 }
 385
 386 sub _parse_ChainedParent_attr {
 387     my ($self, $c, $name, $value) = @_;
 388     return $self->_parse_Chained_attr($c, $name, '../'.$name);
 389 }
 390
 391 sub _parse_PathPrefix_attr {
 392     my ( $self, $c ) = @_;
 393     return PathPart => $self->path_prefix($c);
 394 }
 395
 396 sub _parse_ActionClass_attr {
 397     my ( $self, $c, $name, $value ) = @_;
 398     my $appname = $self->_application;
 399     $value = Catalyst::Utils::resolve_namespace($appname . '::Action', $self->_action_class, $value);
 400     return ( 'ActionClass', $value );
 401 }
 402
 403 sub _parse_MyAction_attr {
 404     my ( $self, $c, $name, $value ) = @_;
 405
 406     my $appclass = Catalyst::Utils::class2appclass($self);
 407     $value = "${appclass}::Action::${value}";
 408
 409     return ( 'ActionClass', $value );
 410 }
 411
 412 __PACKAGE__->meta->make_immutable;
 413
 414 1;
 415
 416 __END__
 417
 418 =head1 CONFIGURATION
 419
 420 Like any other L<Catalyst::Component>, controllers have a config hash,
 421 accessible through $self->config from the controller actions.  Some
 422 settings are in use by the Catalyst framework:
 423
 424 =head2 namespace
 425
 426 This specifies the internal namespace the controller should be bound
 427 to. By default the controller is bound to the URI version of the
 428 controller name. For instance controller 'MyApp::Controller::Foo::Bar'
 429 will be bound to 'foo/bar'. The default Root controller is an example
 430 of setting namespace to '' (the null string).
 431
 432 =head2 path
 433
 434 Sets 'path_prefix', as described below.
 435
 436 =head1 METHODS
 437
 438 =head2 BUILDARGS ($app, @args)
 439
 440 From L<Catalyst::Component::ApplicationAttribute>, stashes the application
 441 instance as $self->_application.
 442
 443 =head2 $self->action_for('name')
 444
 445 Returns the Catalyst::Action object (if any) for a given method name
 446 in this component.
 447
 448 =head2 $self->action_namespace($c)
 449
 450 Returns the private namespace for actions in this component. Defaults
 451 to a value from the controller name (for
 452 e.g. MyApp::Controller::Foo::Bar becomes "foo/bar") or can be
 453 overridden from the "namespace" config key.
 454
 455
 456 =head2 $self->path_prefix($c)
 457
 458 Returns the default path prefix for :PathPrefix, :Local, :LocalRegex and
 459 relative :Path actions in this component. Defaults to the action_namespace or
 460 can be overridden from the "path" config key.
 461
 462 =head2 $self->register_actions($c)
 463
 464 Finds all applicable actions for this component, creates
 465 Catalyst::Action objects (using $self->create_action) for them and
 466 registers them with $c->dispatcher.
 467
 468 =head2 $self->get_action_methods()
 469
 470 Returns a list of L<Moose::Meta::Method> objects, doing the
 471 L<MooseX::MethodAttributes::Role::Meta::Method> role, which are the set of
 472 action methods for this package.
 473
 474 =head2 $self->register_action_methods($c, @methods)
 475
 476 Creates action objects for a set of action methods using C< create_action >,
 477 and registers them with the dispatcher.
 478
 479 =head2 $self->create_action(%args)
 480
 481 Called with a hash of data to be use for construction of a new
 482 Catalyst::Action (or appropriate sub/alternative class) object.
 483
 484 =head2 $self->_application
 485
 486 =head2 $self->_app
 487
 488 Returns the application instance stored by C<new()>
 489
 490 =head1 AUTHORS
 491
 492 Catalyst Contributors, see Catalyst.pm
 493
 494 =head1 COPYRIGHT
 495
 496 This library is free software. You can redistribute it and/or modify
 497 it under the same terms as Perl itself.
 498
 499 =cut