lib/Catalyst/Controller.pm

   1 package Catalyst::Controller;
   2
   3 use Moose;
   4 use Moose::Util qw/find_meta does_role/;
   5
   6 use namespace::clean -except => 'meta';
   7
   8 BEGIN { extends qw/Catalyst::Component MooseX::MethodAttributes::Inheritable/; }
   9
  10 use Catalyst::Exception;
  11 use Catalyst::Utils;
  12
  13 with 'Catalyst::Component::ApplicationAttribute';
  14
  15 has path_prefix =>
  16     (
  17      is => 'rw',
  18      isa => 'Str',
  19      init_arg => 'path',
  20      predicate => 'has_path_prefix',
  21     );
  22
  23 has action_namespace =>
  24     (
  25      is => 'rw',
  26      isa => 'Str',
  27      init_arg => 'namespace',
  28      predicate => 'has_action_namespace',
  29     );
  30
  31 has actions =>
  32     (
  33      is => 'rw',
  34      isa => 'HashRef',
  35      init_arg => undef,
  36     );
  37
  38 sub BUILD {
  39     my ($self, $args) = @_;
  40     my $action  = delete $args->{action}  || {};
  41     my $actions = delete $args->{actions} || {};
  42     my $attr_value = $self->merge_config_hashes($actions, $action);
  43     $self->actions($attr_value);
  44 }
  45
  46 =head1 NAME
  47
  48 Catalyst::Controller - Catalyst Controller base class
  49
  50 =head1 SYNOPSIS
  51
  52   package MyApp::Controller::Search
  53   use base qw/Catalyst::Controller/;
  54
  55   sub foo : Local {
  56     my ($self,$c,@args) = @_;
  57     ...
  58   } # Dispatches to /search/foo
  59
  60 =head1 DESCRIPTION
  61
  62 Controllers are where the actions in the Catalyst framework
  63 reside. Each action is represented by a function with an attribute to
  64 identify what kind of action it is. See the L<Catalyst::Dispatcher>
  65 for more info about how Catalyst dispatches to actions.
  66
  67 =cut
  68
  69 #I think both of these could be attributes. doesn't really seem like they need
  70 #to ble class data. i think that attributes +default would work just fine
  71 __PACKAGE__->mk_classdata($_) for qw/_dispatch_steps _action_class/;
  72
  73 __PACKAGE__->_dispatch_steps( [qw/_BEGIN _AUTO _ACTION/] );
  74 __PACKAGE__->_action_class('Catalyst::Action');
  75
  76
  77 sub _DISPATCH : Private {
  78     my ( $self, $c ) = @_;
  79
  80     foreach my $disp ( @{ $self->_dispatch_steps } ) {
  81         last unless $c->forward($disp);
  82     }
  83
  84     $c->forward('_END');
  85 }
  86
  87 sub _BEGIN : Private {
  88     my ( $self, $c ) = @_;
  89     my $begin = ( $c->get_actions( 'begin', $c->namespace ) )[-1];
  90     return 1 unless $begin;
  91     $begin->dispatch( $c );
  92     return !@{ $c->error };
  93 }
  94
  95 sub _AUTO : Private {
  96     my ( $self, $c ) = @_;
  97     my @auto = $c->get_actions( 'auto', $c->namespace );
  98     foreach my $auto (@auto) {
  99         $auto->dispatch( $c );
 100         return 0 unless $c->state;
 101     }
 102     return 1;
 103 }
 104
 105 sub _ACTION : Private {
 106     my ( $self, $c ) = @_;
 107     if (   ref $c->action
 108         && $c->action->can('execute')
 109         && defined $c->req->action )
 110     {
 111         $c->action->dispatch( $c );
 112     }
 113     return !@{ $c->error };
 114 }
 115
 116 sub _END : Private {
 117     my ( $self, $c ) = @_;
 118     my $end = ( $c->get_actions( 'end', $c->namespace ) )[-1];
 119     return 1 unless $end;
 120     $end->dispatch( $c );
 121     return !@{ $c->error };
 122 }
 123
 124 sub action_for {
 125     my ( $self, $name ) = @_;
 126     my $app = ($self->isa('Catalyst') ? $self : $self->_application);
 127     return $app->dispatcher->get_action($name, $self->action_namespace);
 128 }
 129
 130 #my opinion is that this whole sub really should be a builder method, not
 131 #something that happens on every call. Anyone else disagree?? -- groditi
 132 ## -- apparently this is all just waiting for app/ctx split
 133 around action_namespace => sub {
 134     my $orig = shift;
 135     my ( $self, $c ) = @_;
 136
 137     if( ref($self) ){
 138         return $self->$orig if $self->has_action_namespace;
 139     } else {
 140         return $self->config->{namespace} if exists $self->config->{namespace};
 141     }
 142
 143     my $case_s;
 144     if( $c ){
 145         $case_s = $c->config->{case_sensitive};
 146     } else {
 147         if ($self->isa('Catalyst')) {
 148             $case_s = $self->config->{case_sensitive};
 149         } else {
 150             if (ref $self) {
 151                 $case_s = $self->_application->config->{case_sensitive};
 152             } else {
 153                 confess("Can't figure out case_sensitive setting");
 154             }
 155         }
 156     }
 157
 158     my $namespace = Catalyst::Utils::class2prefix(ref($self) || $self, $case_s) || '';
 159     $self->$orig($namespace) if ref($self);
 160     return $namespace;
 161 };
 162
 163 #Once again, this is probably better written as a builder method
 164 around path_prefix => sub {
 165     my $orig = shift;
 166     my $self = shift;
 167     if( ref($self) ){
 168       return $self->$orig if $self->has_path_prefix;
 169     } else {
 170       return $self->config->{path} if exists $self->config->{path};
 171     }
 172     my $namespace = $self->action_namespace(@_);
 173     $self->$orig($namespace) if ref($self);
 174     return $namespace;
 175 };
 176
 177
 178 sub register_actions {
 179     my ( $self, $c ) = @_;
 180     my $class = ref $self || $self;
 181     #this is still not correct for some reason.
 182     my $namespace = $self->action_namespace($c);
 183     my $meta = find_meta($self);
 184     my @methods = grep { does_role($_, 'MooseX::MethodAttributes::Role::Meta::Method') }
 185             $meta->get_all_methods;
 186
 187     foreach my $method (@methods) {
 188         my $name = $method->name;
 189         my $attributes = $method->attributes;
 190         next unless $attributes;
 191         my $attrs = $self->_parse_attrs( $c, $name, @{ $attributes } );
 192         if ( $attrs->{Private} && ( keys %$attrs > 1 ) ) {
 193             $c->log->debug( 'Bad action definition "'
 194                   . join( ' ', @{ $attributes } )
 195                   . qq/" for "$class->$name"/ )
 196               if $c->debug;
 197             next;
 198         }
 199         my $reverse = $namespace ? "${namespace}/${name}" : $name;
 200         my $action = $self->create_action(
 201             name       => $name,
 202             code       => $method->body,
 203             reverse    => $reverse,
 204             namespace  => $namespace,
 205             class      => $class,
 206             attributes => $attrs,
 207         );
 208
 209         $c->dispatcher->register( $c, $action );
 210     }
 211 }
 212
 213 sub create_action {
 214     my $self = shift;
 215     my %args = @_;
 216
 217     my $class = (exists $args{attributes}{ActionClass}
 218                     ? $args{attributes}{ActionClass}[0]
 219                     : $self->_action_class);
 220
 221     Class::MOP::load_class($class);
 222     return $class->new( \%args );
 223 }
 224
 225 sub _parse_attrs {
 226     my ( $self, $c, $name, @attrs ) = @_;
 227
 228     my %raw_attributes;
 229
 230     foreach my $attr (@attrs) {
 231
 232         # Parse out :Foo(bar) into Foo => bar etc (and arrayify)
 233
 234         if ( my ( $key, $value ) = ( $attr =~ /^(.*?)(?:\(\s*(.+?)\s*\))?$/ ) )
 235         {
 236
 237             if ( defined $value ) {
 238                 ( $value =~ s/^'(.*)'$/$1/ ) || ( $value =~ s/^"(.*)"/$1/ );
 239             }
 240             push( @{ $raw_attributes{$key} }, $value );
 241         }
 242     }
 243
 244     #I know that the original behavior was to ignore action if actions was set
 245     # but i actually think this may be a little more sane? we can always remove
 246     # the merge behavior quite easily and go back to having actions have
 247     # presedence over action by modifying the keys. i honestly think this is
 248     # superior while mantaining really high degree of compat
 249     my $actions;
 250     if( ref($self) ) {
 251         $actions = $self->actions;
 252     } else {
 253         my $cfg = $self->config;
 254         $actions = $self->merge_config_hashes($cfg->{actions}, $cfg->{action});
 255     }
 256
 257     %raw_attributes = ((exists $actions->{'*'} ? %{$actions->{'*'}} : ()),
 258                        %raw_attributes,
 259                        (exists $actions->{$name} ? %{$actions->{$name}} : ()));
 260
 261
 262     my %final_attributes;
 263
 264     foreach my $key (keys %raw_attributes) {
 265
 266         my $raw = $raw_attributes{$key};
 267
 268         foreach my $value (ref($raw) eq 'ARRAY' ? @$raw : $raw) {
 269
 270             my $meth = "_parse_${key}_attr";
 271             if ( my $code = $self->can($meth) ) {
 272                 ( $key, $value ) = $self->$code( $c, $name, $value );
 273             }
 274             push( @{ $final_attributes{$key} }, $value );
 275         }
 276     }
 277
 278     return \%final_attributes;
 279 }
 280
 281 sub _parse_Global_attr {
 282     my ( $self, $c, $name, $value ) = @_;
 283     return $self->_parse_Path_attr( $c, $name, "/$name" );
 284 }
 285
 286 sub _parse_Absolute_attr { shift->_parse_Global_attr(@_); }
 287
 288 sub _parse_Local_attr {
 289     my ( $self, $c, $name, $value ) = @_;
 290     return $self->_parse_Path_attr( $c, $name, $name );
 291 }
 292
 293 sub _parse_Relative_attr { shift->_parse_Local_attr(@_); }
 294
 295 sub _parse_Path_attr {
 296     my ( $self, $c, $name, $value ) = @_;
 297     $value = '' if !defined $value;
 298     if ( $value =~ m!^/! ) {
 299         return ( 'Path', $value );
 300     }
 301     elsif ( length $value ) {
 302         return ( 'Path', join( '/', $self->path_prefix($c), $value ) );
 303     }
 304     else {
 305         return ( 'Path', $self->path_prefix($c) );
 306     }
 307 }
 308
 309 sub _parse_Regex_attr {
 310     my ( $self, $c, $name, $value ) = @_;
 311     return ( 'Regex', $value );
 312 }
 313
 314 sub _parse_Regexp_attr { shift->_parse_Regex_attr(@_); }
 315
 316 sub _parse_LocalRegex_attr {
 317     my ( $self, $c, $name, $value ) = @_;
 318     unless ( $value =~ s/^\^// ) { $value = "(?:.*?)$value"; }
 319
 320     my $prefix = $self->path_prefix( $c );
 321     $prefix .= '/' if length( $prefix );
 322
 323     return ( 'Regex', "^${prefix}${value}" );
 324 }
 325
 326 sub _parse_LocalRegexp_attr { shift->_parse_LocalRegex_attr(@_); }
 327
 328 sub _parse_Chained_attr {
 329     my ($self, $c, $name, $value) = @_;
 330
 331     if (defined($value) && length($value)) {
 332         if ($value eq '.') {
 333             $value = '/'.$self->action_namespace($c);
 334         } elsif (my ($rel, $rest) = $value =~ /^((?:\.{2}\/)+)(.*)$/) {
 335             my @parts = split '/', $self->action_namespace($c);
 336             my @levels = split '/', $rel;
 337
 338             $value = '/'.join('/', @parts[0 .. $#parts - @levels], $rest);
 339         } elsif ($value !~ m/^\//) {
 340             my $action_ns = $self->action_namespace($c);
 341
 342             if ($action_ns) {
 343                 $value = '/'.join('/', $action_ns, $value);
 344             } else {
 345                 $value = '/'.$value; # special case namespace '' (root)
 346             }
 347         }
 348     } else {
 349         $value = '/'
 350     }
 351
 352     return Chained => $value;
 353 }
 354
 355 sub _parse_ChainedParent_attr {
 356     my ($self, $c, $name, $value) = @_;
 357     return $self->_parse_Chained_attr($c, $name, '../'.$name);
 358 }
 359
 360 sub _parse_PathPrefix_attr {
 361     my $self = shift;
 362     return PathPart => $self->path_prefix;
 363 }
 364
 365 sub _parse_ActionClass_attr {
 366     my ( $self, $c, $name, $value ) = @_;
 367     unless ( $value =~ s/^\+// ) {
 368       $value = join('::', $self->_action_class, $value );
 369     }
 370     return ( 'ActionClass', $value );
 371 }
 372
 373 sub _parse_MyAction_attr {
 374     my ( $self, $c, $name, $value ) = @_;
 375
 376     my $appclass = Catalyst::Utils::class2appclass($self);
 377     $value = "${appclass}::Action::${value}";
 378
 379     return ( 'ActionClass', $value );
 380 }
 381
 382 __PACKAGE__->meta->make_immutable;
 383
 384 1;
 385
 386 __END__
 387
 388 =head1 CONFIGURATION
 389
 390 Like any other L<Catalyst::Component>, controllers have a config hash,
 391 accessible through $self->config from the controller actions.  Some
 392 settings are in use by the Catalyst framework:
 393
 394 =head2 namespace
 395
 396 This specifies the internal namespace the controller should be bound
 397 to. By default the controller is bound to the URI version of the
 398 controller name. For instance controller 'MyApp::Controller::Foo::Bar'
 399 will be bound to 'foo/bar'. The default Root controller is an example
 400 of setting namespace to '' (the null string).
 401
 402 =head2 path
 403
 404 Sets 'path_prefix', as described below.
 405
 406 =head1 METHODS
 407
 408 =head2 $class->new($app, @args)
 409
 410 Proxies through to NEXT::new and stashes the application instance as
 411 $self->_application.
 412
 413 =head2 $self->action_for('name')
 414
 415 Returns the Catalyst::Action object (if any) for a given method name
 416 in this component.
 417
 418 =head2 $self->register_actions($c)
 419
 420 Finds all applicable actions for this component, creates
 421 Catalyst::Action objects (using $self->create_action) for them and
 422 registers them with $c->dispatcher.
 423
 424 =head2 $self->action_namespace($c)
 425
 426 Returns the private namespace for actions in this component. Defaults
 427 to a value from the controller name (for
 428 e.g. MyApp::Controller::Foo::Bar becomes "foo/bar") or can be
 429 overridden from the "namespace" config key.
 430
 431
 432 =head2 $self->path_prefix($c)
 433
 434 Returns the default path prefix for :PathPrefix, :Local, :LocalRegex and
 435 relative :Path actions in this component. Defaults to the action_namespace or
 436 can be overridden from the "path" config key.
 437
 438 =head2 $self->create_action(%args)
 439
 440 Called with a hash of data to be use for construction of a new
 441 Catalyst::Action (or appropriate sub/alternative class) object.
 442
 443 Primarily designed for the use of register_actions.
 444
 445 =head2 $self->_application
 446
 447 =head2 $self->_app
 448
 449 Returns the application instance stored by C<new()>
 450
 451 =head1 AUTHORS
 452
 453 Catalyst Contributors, see Catalyst.pm
 454
 455 =head1 COPYRIGHT
 456
 457 This program is free software, you can redistribute it and/or modify
 458 it under the same terms as Perl itself.
 459
 460 =cut