lib/Catalyst/Controller.pm

   1 package Catalyst::Controller;
   2
   3 use Moose;
   4 use Moose::Util qw/find_meta/;
   5 use List::MoreUtils qw/uniq/;
   6 use namespace::clean -except => 'meta';
   7
   8 BEGIN { extends qw/Catalyst::Component MooseX::MethodAttributes::Inheritable/; }
   9
  10 use MooseX::MethodAttributes;
  11 use Catalyst::Exception;
  12 use Catalyst::Utils;
  13
  14 with 'Catalyst::Component::ApplicationAttribute';
  15
  16 has path_prefix =>
  17     (
  18      is => 'rw',
  19      isa => 'Str',
  20      init_arg => 'path',
  21      predicate => 'has_path_prefix',
  22     );
  23
  24 has action_namespace =>
  25     (
  26      is => 'rw',
  27      isa => 'Str',
  28      init_arg => 'namespace',
  29      predicate => 'has_action_namespace',
  30     );
  31
  32 has actions =>
  33     (
  34      accessor => '_controller_actions',
  35      isa => 'HashRef',
  36      init_arg => undef,
  37     );
  38
  39 # ->config(actions => { '*' => ...
  40 has _all_actions_attributes => (
  41     is       => 'ro',
  42     isa      => 'HashRef',
  43     init_arg => undef,
  44     lazy     => 1,
  45     builder  => '_build__all_actions_attributes',
  46 );
  47
  48 sub BUILD {
  49     my ($self, $args) = @_;
  50     my $action  = delete $args->{action}  || {};
  51     my $actions = delete $args->{actions} || {};
  52     my $attr_value = $self->merge_config_hashes($actions, $action);
  53     $self->_controller_actions($attr_value);
  54
  55     # trigger lazy builder
  56     $self->_all_actions_attributes;
  57 }
  58
  59 sub _build__all_actions_attributes {
  60     my ($self) = @_;
  61     delete $self->_controller_actions->{'*'} || {};
  62 }
  63
  64 =head1 NAME
  65
  66 Catalyst::Controller - Catalyst Controller base class
  67
  68 =head1 SYNOPSIS
  69
  70   package MyApp::Controller::Search
  71   use base qw/Catalyst::Controller/;
  72
  73   sub foo : Local {
  74     my ($self,$c,@args) = @_;
  75     ...
  76   } # Dispatches to /search/foo
  77
  78 =head1 DESCRIPTION
  79
  80 Controllers are where the actions in the Catalyst framework
  81 reside. Each action is represented by a function with an attribute to
  82 identify what kind of action it is. See the L<Catalyst::Dispatcher>
  83 for more info about how Catalyst dispatches to actions.
  84
  85 =cut
  86
  87 #I think both of these could be attributes. doesn't really seem like they need
  88 #to ble class data. i think that attributes +default would work just fine
  89 __PACKAGE__->mk_classdata($_) for qw/_dispatch_steps _action_class/;
  90
  91 __PACKAGE__->_dispatch_steps( [qw/_BEGIN _AUTO _ACTION/] );
  92 __PACKAGE__->_action_class('Catalyst::Action');
  93
  94
  95 sub _DISPATCH : Private {
  96     my ( $self, $c ) = @_;
  97
  98     foreach my $disp ( @{ $self->_dispatch_steps } ) {
  99         last unless $c->forward($disp);
 100     }
 101
 102     $c->forward('_END');
 103 }
 104
 105 sub _BEGIN : Private {
 106     my ( $self, $c ) = @_;
 107     my $begin = ( $c->get_actions( 'begin', $c->namespace ) )[-1];
 108     return 1 unless $begin;
 109     $begin->dispatch( $c );
 110     return !@{ $c->error };
 111 }
 112
 113 sub _AUTO : Private {
 114     my ( $self, $c ) = @_;
 115     my @auto = $c->get_actions( 'auto', $c->namespace );
 116     foreach my $auto (@auto) {
 117         $auto->dispatch( $c );
 118         return 0 unless $c->state;
 119     }
 120     return 1;
 121 }
 122
 123 sub _ACTION : Private {
 124     my ( $self, $c ) = @_;
 125     if (   ref $c->action
 126         && $c->action->can('execute')
 127         && defined $c->req->action )
 128     {
 129         $c->action->dispatch( $c );
 130     }
 131     return !@{ $c->error };
 132 }
 133
 134 sub _END : Private {
 135     my ( $self, $c ) = @_;
 136     my $end = ( $c->get_actions( 'end', $c->namespace ) )[-1];
 137     return 1 unless $end;
 138     $end->dispatch( $c );
 139     return !@{ $c->error };
 140 }
 141
 142 sub action_for {
 143     my ( $self, $name ) = @_;
 144     my $app = ($self->isa('Catalyst') ? $self : $self->_application);
 145     return $app->dispatcher->get_action($name, $self->action_namespace);
 146 }
 147
 148 #my opinion is that this whole sub really should be a builder method, not
 149 #something that happens on every call. Anyone else disagree?? -- groditi
 150 ## -- apparently this is all just waiting for app/ctx split
 151 around action_namespace => sub {
 152     my $orig = shift;
 153     my ( $self, $c ) = @_;
 154
 155     my $class = ref($self) || $self;
 156     my $appclass = ref($c) || $c;
 157
 158     # FIXME - catalyst_component_name is no longer a class accessor, because
 159     # 'MyApp as a controller' behavior is removed. But is this call to
 160     # catalyst_component_name necessary, or is it always the same as $class?
 161     my $component_name = ref($self) ? $self->catalyst_component_name : $self;
 162
 163     if( ref($self) ){
 164         return $self->$orig if $self->has_action_namespace;
 165     } else {
 166         return $class->config->{namespace} if exists $class->config->{namespace};
 167     }
 168
 169     my $case_s;
 170     if( $c ){
 171         $case_s = $appclass->config->{case_sensitive};
 172     } else {
 173         if ($self->isa('Catalyst')) {
 174             $case_s = $class->config->{case_sensitive};
 175         } else {
 176             if (ref $self) {
 177                 $case_s = ref($self->_application)->config->{case_sensitive};
 178             } else {
 179                 confess("Can't figure out case_sensitive setting");
 180             }
 181         }
 182     }
 183
 184     my $namespace = Catalyst::Utils::class2prefix($component_name, $case_s) || '';
 185     $self->$orig($namespace) if ref($self);
 186     return $namespace;
 187 };
 188
 189 #Once again, this is probably better written as a builder method
 190 around path_prefix => sub {
 191     my $orig = shift;
 192     my $self = shift;
 193     if( ref($self) ){
 194       return $self->$orig if $self->has_path_prefix;
 195     } else {
 196       return $self->config->{path} if exists $self->config->{path};
 197     }
 198     my $namespace = $self->action_namespace(@_);
 199     $self->$orig($namespace) if ref($self);
 200     return $namespace;
 201 };
 202
 203 sub get_action_methods {
 204     my $self = shift;
 205     my $meta = find_meta($self) || confess("No metaclass setup for $self");
 206     confess(
 207         sprintf "Metaclass %s for %s cannot support register_actions.",
 208             ref $meta, $meta->name,
 209     ) unless $meta->can('get_nearest_methods_with_attributes');
 210     my @methods = $meta->get_nearest_methods_with_attributes;
 211
 212     # actions specified via config are also action_methods
 213     push(
 214         @methods,
 215         map {
 216             $meta->find_method_by_name($_)
 217                 || confess( sprintf 'Action "%s" is not available from controller %s',
 218                             $_, ref $self )
 219         } keys %{ $self->_controller_actions }
 220     ) if ( ref $self );
 221     return uniq @methods;
 222 }
 223
 224
 225 sub register_actions {
 226     my ( $self, $c ) = @_;
 227     $self->register_action_methods( $c, $self->get_action_methods );
 228 }
 229
 230 sub register_action_methods {
 231     my ( $self, $c, @methods ) = @_;
 232     my $class = $self->catalyst_component_name;
 233     #this is still not correct for some reason.
 234     my $namespace = $self->action_namespace($c);
 235
 236     # FIXME - fugly
 237     if (!blessed($self) && $self eq $c && scalar(@methods)) {
 238         my @really_bad_methods = grep { ! /^_(DISPATCH|BEGIN|AUTO|ACTION|END)$/ } map { $_->name } @methods;
 239         if (scalar(@really_bad_methods)) {
 240             $c->log->warn("Action methods (" . join(', ', @really_bad_methods) . ") found defined in your application class, $self. This is deprecated, please move them into a Root controller.");
 241         }
 242     }
 243
 244     foreach my $method (@methods) {
 245         my $name = $method->name;
 246         # Horrible hack! All method metaclasses should have an attributes
 247         # method, core Moose bug - see r13354.
 248         my $attributes = $method->can('attributes') ? $method->attributes : [];
 249         my $attrs = $self->_parse_attrs( $c, $name, @{ $attributes } );
 250         if ( $attrs->{Private} && ( keys %$attrs > 1 ) ) {
 251             $c->log->debug( 'Bad action definition "'
 252                   . join( ' ', @{ $attributes } )
 253                   . qq/" for "$class->$name"/ )
 254               if $c->debug;
 255             next;
 256         }
 257         my $reverse = $namespace ? "${namespace}/${name}" : $name;
 258         my $action = $self->create_action(
 259             name       => $name,
 260             code       => $method->body,
 261             reverse    => $reverse,
 262             namespace  => $namespace,
 263             class      => $class,
 264             attributes => $attrs,
 265         );
 266
 267         $c->dispatcher->register( $c, $action );
 268     }
 269 }
 270
 271 sub action_class {
 272     my $self = shift;
 273     my %args = @_;
 274
 275     my $class = (exists $args{attributes}{ActionClass}
 276         ? $args{attributes}{ActionClass}[0]
 277         : $self->_action_class);
 278
 279     Class::MOP::load_class($class);
 280     return $class;
 281 }
 282
 283 sub create_action {
 284     my $self = shift;
 285     my %args = @_;
 286
 287     my $class = $self->action_class(%args);
 288     my $action_args = $self->config->{action_args};
 289
 290     my %extra_args = (
 291         %{ $action_args->{'*'}           || {} },
 292         %{ $action_args->{ $args{name} } || {} },
 293     );
 294
 295     return $class->new({ %extra_args, %args });
 296 }
 297
 298 sub _parse_attrs {
 299     my ( $self, $c, $name, @attrs ) = @_;
 300
 301     my %raw_attributes;
 302
 303     foreach my $attr (@attrs) {
 304
 305         # Parse out :Foo(bar) into Foo => bar etc (and arrayify)
 306
 307         if ( my ( $key, $value ) = ( $attr =~ /^(.*?)(?:\(\s*(.+?)\s*\))?$/ ) )
 308         {
 309
 310             if ( defined $value ) {
 311                 ( $value =~ s/^'(.*)'$/$1/ ) || ( $value =~ s/^"(.*)"/$1/ );
 312             }
 313             push( @{ $raw_attributes{$key} }, $value );
 314         }
 315     }
 316
 317     my ($actions_config, $all_actions_config);
 318     if( ref($self) ) {
 319         $actions_config = $self->_controller_actions;
 320         # No, you're not getting actions => { '*' => ... } with actions in MyApp.
 321         $all_actions_config = $self->_all_actions_attributes;
 322     } else {
 323         my $cfg = $self->config;
 324         $actions_config = $self->merge_config_hashes($cfg->{actions}, $cfg->{action});
 325         $all_actions_config = {};
 326     }
 327
 328     %raw_attributes = (
 329         %raw_attributes,
 330         exists $actions_config->{$name} ? %{ $actions_config->{$name } } : (),
 331     );
 332
 333     # Private actions with additional attributes will raise a warning and then
 334     # be ignored. Adding '*' arguments to the default _DISPATCH / etc. methods,
 335     # which are Private, will prevent those from being registered. They should
 336     # probably be turned into :Actions instead, or we might want to otherwise
 337     # disambiguate between those built-in internal actions and user-level
 338     # Private ones.
 339     %raw_attributes = (%{ $all_actions_config }, %raw_attributes)
 340         unless $raw_attributes{Private};
 341
 342     my %final_attributes;
 343
 344     foreach my $key (keys %raw_attributes) {
 345
 346         my $raw = $raw_attributes{$key};
 347
 348         foreach my $value (ref($raw) eq 'ARRAY' ? @$raw : $raw) {
 349
 350             my $meth = "_parse_${key}_attr";
 351             if ( my $code = $self->can($meth) ) {
 352                 ( $key, $value ) = $self->$code( $c, $name, $value );
 353             }
 354             push( @{ $final_attributes{$key} }, $value );
 355         }
 356     }
 357
 358     return \%final_attributes;
 359 }
 360
 361 sub _parse_Global_attr {
 362     my ( $self, $c, $name, $value ) = @_;
 363     return $self->_parse_Path_attr( $c, $name, "/$name" );
 364 }
 365
 366 sub _parse_Absolute_attr { shift->_parse_Global_attr(@_); }
 367
 368 sub _parse_Local_attr {
 369     my ( $self, $c, $name, $value ) = @_;
 370     return $self->_parse_Path_attr( $c, $name, $name );
 371 }
 372
 373 sub _parse_Relative_attr { shift->_parse_Local_attr(@_); }
 374
 375 sub _parse_Path_attr {
 376     my ( $self, $c, $name, $value ) = @_;
 377     $value = '' if !defined $value;
 378     if ( $value =~ m!^/! ) {
 379         return ( 'Path', $value );
 380     }
 381     elsif ( length $value ) {
 382         return ( 'Path', join( '/', $self->path_prefix($c), $value ) );
 383     }
 384     else {
 385         return ( 'Path', $self->path_prefix($c) );
 386     }
 387 }
 388
 389 sub _parse_Regex_attr {
 390     my ( $self, $c, $name, $value ) = @_;
 391     return ( 'Regex', $value );
 392 }
 393
 394 sub _parse_Regexp_attr { shift->_parse_Regex_attr(@_); }
 395
 396 sub _parse_LocalRegex_attr {
 397     my ( $self, $c, $name, $value ) = @_;
 398     unless ( $value =~ s/^\^// ) { $value = "(?:.*?)$value"; }
 399
 400     my $prefix = $self->path_prefix( $c );
 401     $prefix .= '/' if length( $prefix );
 402
 403     return ( 'Regex', "^${prefix}${value}" );
 404 }
 405
 406 sub _parse_LocalRegexp_attr { shift->_parse_LocalRegex_attr(@_); }
 407
 408 sub _parse_Chained_attr {
 409     my ($self, $c, $name, $value) = @_;
 410
 411     if (defined($value) && length($value)) {
 412         if ($value eq '.') {
 413             $value = '/'.$self->action_namespace($c);
 414         } elsif (my ($rel, $rest) = $value =~ /^((?:\.{2}\/)+)(.*)$/) {
 415             my @parts = split '/', $self->action_namespace($c);
 416             my @levels = split '/', $rel;
 417
 418             $value = '/'.join('/', @parts[0 .. $#parts - @levels], $rest);
 419         } elsif ($value !~ m/^\//) {
 420             my $action_ns = $self->action_namespace($c);
 421
 422             if ($action_ns) {
 423                 $value = '/'.join('/', $action_ns, $value);
 424             } else {
 425                 $value = '/'.$value; # special case namespace '' (root)
 426             }
 427         }
 428     } else {
 429         $value = '/'
 430     }
 431
 432     return Chained => $value;
 433 }
 434
 435 sub _parse_ChainedParent_attr {
 436     my ($self, $c, $name, $value) = @_;
 437     return $self->_parse_Chained_attr($c, $name, '../'.$name);
 438 }
 439
 440 sub _parse_PathPrefix_attr {
 441     my ( $self, $c ) = @_;
 442     return PathPart => $self->path_prefix($c);
 443 }
 444
 445 sub _parse_ActionClass_attr {
 446     my ( $self, $c, $name, $value ) = @_;
 447     my $appname = $self->_application;
 448     $value = Catalyst::Utils::resolve_namespace($appname . '::Action', $self->_action_class, $value);
 449     return ( 'ActionClass', $value );
 450 }
 451
 452 sub _parse_MyAction_attr {
 453     my ( $self, $c, $name, $value ) = @_;
 454
 455     my $appclass = Catalyst::Utils::class2appclass($self);
 456     $value = "${appclass}::Action::${value}";
 457
 458     return ( 'ActionClass', $value );
 459 }
 460
 461 __PACKAGE__->meta->make_immutable;
 462
 463 1;
 464
 465 __END__
 466
 467 =head1 CONFIGURATION
 468
 469 Like any other L<Catalyst::Component>, controllers have a config hash,
 470 accessible through $self->config from the controller actions.  Some
 471 settings are in use by the Catalyst framework:
 472
 473 =head2 namespace
 474
 475 This specifies the internal namespace the controller should be bound
 476 to. By default the controller is bound to the URI version of the
 477 controller name. For instance controller 'MyApp::Controller::Foo::Bar'
 478 will be bound to 'foo/bar'. The default Root controller is an example
 479 of setting namespace to '' (the null string).
 480
 481 =head2 path
 482
 483 Sets 'path_prefix', as described below.
 484
 485 =head2 action
 486
 487 Allows you to set the attributes that the dispatcher creates actions out of.
 488 This allows you to do 'rails style routes', or override some of the
 489 attribute defintions of actions composed from Roles.
 490 You can set arguments globally (for all actions of the controller) and
 491 specifically (for a single action).
 492
 493     __PACKAGE__->config(
 494         action => {
 495             '*' => { Chained => 'base', Args => 0  },
 496             base => { Chained => '/', PathPart => '', CaptureArgs => 0 },
 497         },
 498      );
 499
 500 In the case above every sub in the package would be made into a Chain
 501 endpoint with a URI the same as the sub name for each sub, chained
 502 to the sub named C<base>. Ergo dispatch to C</example> would call the
 503 C<base> method, then the C<example> method.
 504
 505 =head2 action_args
 506
 507 Allows you to set constructor arguments on your actions. You can set arguments
 508 globally and specifically (as above).
 509 This is particularly useful when using C<ActionRole>s
 510 (L<Catalyst::Controller::ActionRole>) and custom C<ActionClass>es.
 511
 512     __PACKAGE__->config(
 513         action_args => {
 514             '*' => { globalarg1 => 'hello', globalarg2 => 'goodbye' },
 515             'specific_action' => { customarg => 'arg1' },
 516         },
 517      );
 518
 519 In the case above the action class associated with C<specific_action> would get
 520 passed the following arguments, in addition to the normal action constructor
 521 arguments, when it is instantiated:
 522
 523   (globalarg1 => 'hello', globalarg2 => 'goodbye', customarg => 'arg1')
 524
 525 =head1 METHODS
 526
 527 =head2 BUILDARGS ($app, @args)
 528
 529 From L<Catalyst::Component::ApplicationAttribute>, stashes the application
 530 instance as $self->_application.
 531
 532 =head2 $self->action_for('name')
 533
 534 Returns the Catalyst::Action object (if any) for a given method name
 535 in this component.
 536
 537 =head2 $self->action_namespace($c)
 538
 539 Returns the private namespace for actions in this component. Defaults
 540 to a value from the controller name (for
 541 e.g. MyApp::Controller::Foo::Bar becomes "foo/bar") or can be
 542 overridden from the "namespace" config key.
 543
 544
 545 =head2 $self->path_prefix($c)
 546
 547 Returns the default path prefix for :PathPrefix, :Local, :LocalRegex and
 548 relative :Path actions in this component. Defaults to the action_namespace or
 549 can be overridden from the "path" config key.
 550
 551 =head2 $self->register_actions($c)
 552
 553 Finds all applicable actions for this component, creates
 554 Catalyst::Action objects (using $self->create_action) for them and
 555 registers them with $c->dispatcher.
 556
 557 =head2 $self->get_action_methods()
 558
 559 Returns a list of L<Moose::Meta::Method> objects, doing the
 560 L<MooseX::MethodAttributes::Role::Meta::Method> role, which are the set of
 561 action methods for this package.
 562
 563 =head2 $self->register_action_methods($c, @methods)
 564
 565 Creates action objects for a set of action methods using C< create_action >,
 566 and registers them with the dispatcher.
 567
 568 =head2 $self->action_class(%args)
 569
 570 Used when a controller is creating an action to determine the correct base
 571 action class to use.
 572
 573 =head2 $self->create_action(%args)
 574
 575 Called with a hash of data to be use for construction of a new
 576 Catalyst::Action (or appropriate sub/alternative class) object.
 577
 578 =head2 $self->_application
 579
 580 =head2 $self->_app
 581
 582 Returns the application instance stored by C<new()>
 583
 584 =head1 AUTHORS
 585
 586 Catalyst Contributors, see Catalyst.pm
 587
 588 =head1 COPYRIGHT
 589
 590 This library is free software. You can redistribute it and/or modify
 591 it under the same terms as Perl itself.
 592
 593 =cut