lib/Catalyst/Controller.pm

   1 package Catalyst::Controller;
   2
   3 use Moose;
   4 use Moose::Util qw/find_meta/;
   5
   6 use namespace::clean -except => 'meta';
   7
   8 BEGIN { extends qw/Catalyst::Component MooseX::MethodAttributes::Inheritable/; }
   9
  10 use Catalyst::Exception;
  11 use Catalyst::Utils;
  12
  13 with 'Catalyst::Component::ApplicationAttribute';
  14
  15 has path_prefix =>
  16     (
  17      is => 'rw',
  18      isa => 'Str',
  19      init_arg => 'path',
  20      predicate => 'has_path_prefix',
  21     );
  22
  23 has action_namespace =>
  24     (
  25      is => 'rw',
  26      isa => 'Str',
  27      init_arg => 'namespace',
  28      predicate => 'has_action_namespace',
  29     );
  30
  31 has actions =>
  32     (
  33      is => 'rw',
  34      isa => 'HashRef',
  35      init_arg => undef,
  36     );
  37
  38 sub BUILD {
  39     my ($self, $args) = @_;
  40     my $action  = delete $args->{action}  || {};
  41     my $actions = delete $args->{actions} || {};
  42     my $attr_value = $self->merge_config_hashes($actions, $action);
  43     $self->actions($attr_value);
  44 }
  45
  46 =head1 NAME
  47
  48 Catalyst::Controller - Catalyst Controller base class
  49
  50 =head1 SYNOPSIS
  51
  52   package MyApp::Controller::Search
  53   use base qw/Catalyst::Controller/;
  54
  55   sub foo : Local {
  56     my ($self,$c,@args) = @_;
  57     ...
  58   } # Dispatches to /search/foo
  59
  60 =head1 DESCRIPTION
  61
  62 Controllers are where the actions in the Catalyst framework
  63 reside. Each action is represented by a function with an attribute to
  64 identify what kind of action it is. See the L<Catalyst::Dispatcher>
  65 for more info about how Catalyst dispatches to actions.
  66
  67 =cut
  68
  69 #I think both of these could be attributes. doesn't really seem like they need
  70 #to ble class data. i think that attributes +default would work just fine
  71 __PACKAGE__->mk_classdata($_) for qw/_dispatch_steps _action_class/;
  72
  73 __PACKAGE__->_dispatch_steps( [qw/_BEGIN _AUTO _ACTION/] );
  74 __PACKAGE__->_action_class('Catalyst::Action');
  75
  76
  77 sub _DISPATCH : Private {
  78     my ( $self, $c ) = @_;
  79
  80     foreach my $disp ( @{ $self->_dispatch_steps } ) {
  81         last unless $c->forward($disp);
  82     }
  83
  84     $c->forward('_END');
  85 }
  86
  87 sub _BEGIN : Private {
  88     my ( $self, $c ) = @_;
  89     my $begin = ( $c->get_actions( 'begin', $c->namespace ) )[-1];
  90     return 1 unless $begin;
  91     $begin->dispatch( $c );
  92     return !@{ $c->error };
  93 }
  94
  95 sub _AUTO : Private {
  96     my ( $self, $c ) = @_;
  97     my @auto = $c->get_actions( 'auto', $c->namespace );
  98     foreach my $auto (@auto) {
  99         $auto->dispatch( $c );
 100         return 0 unless $c->state;
 101     }
 102     return 1;
 103 }
 104
 105 sub _ACTION : Private {
 106     my ( $self, $c ) = @_;
 107     if (   ref $c->action
 108         && $c->action->can('execute')
 109         && defined $c->req->action )
 110     {
 111         $c->action->dispatch( $c );
 112     }
 113     return !@{ $c->error };
 114 }
 115
 116 sub _END : Private {
 117     my ( $self, $c ) = @_;
 118     my $end = ( $c->get_actions( 'end', $c->namespace ) )[-1];
 119     return 1 unless $end;
 120     $end->dispatch( $c );
 121     return !@{ $c->error };
 122 }
 123
 124 sub action_for {
 125     my ( $self, $name ) = @_;
 126     my $app = ($self->isa('Catalyst') ? $self : $self->_application);
 127     return $app->dispatcher->get_action($name, $self->action_namespace);
 128 }
 129
 130 #my opinion is that this whole sub really should be a builder method, not
 131 #something that happens on every call. Anyone else disagree?? -- groditi
 132 ## -- apparently this is all just waiting for app/ctx split
 133 around action_namespace => sub {
 134     my $orig = shift;
 135     my ( $self, $c ) = @_;
 136
 137     if( ref($self) ){
 138         return $self->$orig if $self->has_action_namespace;
 139     } else {
 140         return $self->config->{namespace} if exists $self->config->{namespace};
 141     }
 142
 143     my $case_s;
 144     if( $c ){
 145         $case_s = $c->config->{case_sensitive};
 146     } else {
 147         if ($self->isa('Catalyst')) {
 148             $case_s = $self->config->{case_sensitive};
 149         } else {
 150             if (ref $self) {
 151                 $case_s = $self->_application->config->{case_sensitive};
 152             } else {
 153                 confess("Can't figure out case_sensitive setting");
 154             }
 155         }
 156     }
 157
 158     my $namespace = Catalyst::Utils::class2prefix(ref($self) || $self, $case_s) || '';
 159     $self->$orig($namespace) if ref($self);
 160     return $namespace;
 161 };
 162
 163 #Once again, this is probably better written as a builder method
 164 around path_prefix => sub {
 165     my $orig = shift;
 166     my $self = shift;
 167     if( ref($self) ){
 168       return $self->$orig if $self->has_path_prefix;
 169     } else {
 170       return $self->config->{path} if exists $self->config->{path};
 171     }
 172     my $namespace = $self->action_namespace(@_);
 173     $self->$orig($namespace) if ref($self);
 174     return $namespace;
 175 };
 176
 177
 178 sub register_actions {
 179     my ( $self, $c ) = @_;
 180     my $class = ref $self || $self;
 181     #this is still not correct for some reason.
 182     my $namespace = $self->action_namespace($c);
 183     my $meta = find_meta($self);
 184     my @methods = $meta->get_all_methods_with_attributes;
 185
 186     foreach my $method (@methods) {
 187         my $name = $method->name;
 188         my $attributes = $method->attributes;
 189         next unless $attributes;
 190         my $attrs = $self->_parse_attrs( $c, $name, @{ $attributes } );
 191         if ( $attrs->{Private} && ( keys %$attrs > 1 ) ) {
 192             $c->log->debug( 'Bad action definition "'
 193                   . join( ' ', @{ $attributes } )
 194                   . qq/" for "$class->$name"/ )
 195               if $c->debug;
 196             next;
 197         }
 198         my $reverse = $namespace ? "${namespace}/${name}" : $name;
 199         my $action = $self->create_action(
 200             name       => $name,
 201             code       => $method->body,
 202             reverse    => $reverse,
 203             namespace  => $namespace,
 204             class      => $class,
 205             attributes => $attrs,
 206         );
 207
 208         $c->dispatcher->register( $c, $action );
 209     }
 210 }
 211
 212 sub create_action {
 213     my $self = shift;
 214     my %args = @_;
 215
 216     my $class = (exists $args{attributes}{ActionClass}
 217                     ? $args{attributes}{ActionClass}[0]
 218                     : $self->_action_class);
 219
 220     Class::MOP::load_class($class);
 221     return $class->new( \%args );
 222 }
 223
 224 sub _parse_attrs {
 225     my ( $self, $c, $name, @attrs ) = @_;
 226
 227     my %raw_attributes;
 228
 229     foreach my $attr (@attrs) {
 230
 231         # Parse out :Foo(bar) into Foo => bar etc (and arrayify)
 232
 233         if ( my ( $key, $value ) = ( $attr =~ /^(.*?)(?:\(\s*(.+?)\s*\))?$/ ) )
 234         {
 235
 236             if ( defined $value ) {
 237                 ( $value =~ s/^'(.*)'$/$1/ ) || ( $value =~ s/^"(.*)"/$1/ );
 238             }
 239             push( @{ $raw_attributes{$key} }, $value );
 240         }
 241     }
 242
 243     #I know that the original behavior was to ignore action if actions was set
 244     # but i actually think this may be a little more sane? we can always remove
 245     # the merge behavior quite easily and go back to having actions have
 246     # presedence over action by modifying the keys. i honestly think this is
 247     # superior while mantaining really high degree of compat
 248     my $actions;
 249     if( ref($self) ) {
 250         $actions = $self->actions;
 251     } else {
 252         my $cfg = $self->config;
 253         $actions = $self->merge_config_hashes($cfg->{actions}, $cfg->{action});
 254     }
 255
 256     %raw_attributes = ((exists $actions->{'*'} ? %{$actions->{'*'}} : ()),
 257                        %raw_attributes,
 258                        (exists $actions->{$name} ? %{$actions->{$name}} : ()));
 259
 260
 261     my %final_attributes;
 262
 263     foreach my $key (keys %raw_attributes) {
 264
 265         my $raw = $raw_attributes{$key};
 266
 267         foreach my $value (ref($raw) eq 'ARRAY' ? @$raw : $raw) {
 268
 269             my $meth = "_parse_${key}_attr";
 270             if ( my $code = $self->can($meth) ) {
 271                 ( $key, $value ) = $self->$code( $c, $name, $value );
 272             }
 273             push( @{ $final_attributes{$key} }, $value );
 274         }
 275     }
 276
 277     return \%final_attributes;
 278 }
 279
 280 sub _parse_Global_attr {
 281     my ( $self, $c, $name, $value ) = @_;
 282     return $self->_parse_Path_attr( $c, $name, "/$name" );
 283 }
 284
 285 sub _parse_Absolute_attr { shift->_parse_Global_attr(@_); }
 286
 287 sub _parse_Local_attr {
 288     my ( $self, $c, $name, $value ) = @_;
 289     return $self->_parse_Path_attr( $c, $name, $name );
 290 }
 291
 292 sub _parse_Relative_attr { shift->_parse_Local_attr(@_); }
 293
 294 sub _parse_Path_attr {
 295     my ( $self, $c, $name, $value ) = @_;
 296     $value = '' if !defined $value;
 297     if ( $value =~ m!^/! ) {
 298         return ( 'Path', $value );
 299     }
 300     elsif ( length $value ) {
 301         return ( 'Path', join( '/', $self->path_prefix($c), $value ) );
 302     }
 303     else {
 304         return ( 'Path', $self->path_prefix($c) );
 305     }
 306 }
 307
 308 sub _parse_Regex_attr {
 309     my ( $self, $c, $name, $value ) = @_;
 310     return ( 'Regex', $value );
 311 }
 312
 313 sub _parse_Regexp_attr { shift->_parse_Regex_attr(@_); }
 314
 315 sub _parse_LocalRegex_attr {
 316     my ( $self, $c, $name, $value ) = @_;
 317     unless ( $value =~ s/^\^// ) { $value = "(?:.*?)$value"; }
 318
 319     my $prefix = $self->path_prefix( $c );
 320     $prefix .= '/' if length( $prefix );
 321
 322     return ( 'Regex', "^${prefix}${value}" );
 323 }
 324
 325 sub _parse_LocalRegexp_attr { shift->_parse_LocalRegex_attr(@_); }
 326
 327 sub _parse_Chained_attr {
 328     my ($self, $c, $name, $value) = @_;
 329
 330     if (defined($value) && length($value)) {
 331         if ($value eq '.') {
 332             $value = '/'.$self->action_namespace($c);
 333         } elsif (my ($rel, $rest) = $value =~ /^((?:\.{2}\/)+)(.*)$/) {
 334             my @parts = split '/', $self->action_namespace($c);
 335             my @levels = split '/', $rel;
 336
 337             $value = '/'.join('/', @parts[0 .. $#parts - @levels], $rest);
 338         } elsif ($value !~ m/^\//) {
 339             my $action_ns = $self->action_namespace($c);
 340
 341             if ($action_ns) {
 342                 $value = '/'.join('/', $action_ns, $value);
 343             } else {
 344                 $value = '/'.$value; # special case namespace '' (root)
 345             }
 346         }
 347     } else {
 348         $value = '/'
 349     }
 350
 351     return Chained => $value;
 352 }
 353
 354 sub _parse_ChainedParent_attr {
 355     my ($self, $c, $name, $value) = @_;
 356     return $self->_parse_Chained_attr($c, $name, '../'.$name);
 357 }
 358
 359 sub _parse_PathPrefix_attr {
 360     my $self = shift;
 361     return PathPart => $self->path_prefix;
 362 }
 363
 364 sub _parse_ActionClass_attr {
 365     my ( $self, $c, $name, $value ) = @_;
 366     unless ( $value =~ s/^\+// ) {
 367       $value = join('::', $self->_action_class, $value );
 368     }
 369     return ( 'ActionClass', $value );
 370 }
 371
 372 sub _parse_MyAction_attr {
 373     my ( $self, $c, $name, $value ) = @_;
 374
 375     my $appclass = Catalyst::Utils::class2appclass($self);
 376     $value = "${appclass}::Action::${value}";
 377
 378     return ( 'ActionClass', $value );
 379 }
 380
 381 __PACKAGE__->meta->make_immutable;
 382
 383 1;
 384
 385 __END__
 386
 387 =head1 CONFIGURATION
 388
 389 Like any other L<Catalyst::Component>, controllers have a config hash,
 390 accessible through $self->config from the controller actions.  Some
 391 settings are in use by the Catalyst framework:
 392
 393 =head2 namespace
 394
 395 This specifies the internal namespace the controller should be bound
 396 to. By default the controller is bound to the URI version of the
 397 controller name. For instance controller 'MyApp::Controller::Foo::Bar'
 398 will be bound to 'foo/bar'. The default Root controller is an example
 399 of setting namespace to '' (the null string).
 400
 401 =head2 path
 402
 403 Sets 'path_prefix', as described below.
 404
 405 =head1 METHODS
 406
 407 =head2 $class->new($app, @args)
 408
 409 Proxies through to NEXT::new and stashes the application instance as
 410 $self->_application.
 411
 412 =head2 $self->action_for('name')
 413
 414 Returns the Catalyst::Action object (if any) for a given method name
 415 in this component.
 416
 417 =head2 $self->register_actions($c)
 418
 419 Finds all applicable actions for this component, creates
 420 Catalyst::Action objects (using $self->create_action) for them and
 421 registers them with $c->dispatcher.
 422
 423 =head2 $self->action_namespace($c)
 424
 425 Returns the private namespace for actions in this component. Defaults
 426 to a value from the controller name (for
 427 e.g. MyApp::Controller::Foo::Bar becomes "foo/bar") or can be
 428 overridden from the "namespace" config key.
 429
 430
 431 =head2 $self->path_prefix($c)
 432
 433 Returns the default path prefix for :PathPrefix, :Local, :LocalRegex and
 434 relative :Path actions in this component. Defaults to the action_namespace or
 435 can be overridden from the "path" config key.
 436
 437 =head2 $self->create_action(%args)
 438
 439 Called with a hash of data to be use for construction of a new
 440 Catalyst::Action (or appropriate sub/alternative class) object.
 441
 442 Primarily designed for the use of register_actions.
 443
 444 =head2 $self->_application
 445
 446 =head2 $self->_app
 447
 448 Returns the application instance stored by C<new()>
 449
 450 =head1 AUTHORS
 451
 452 Catalyst Contributors, see Catalyst.pm
 453
 454 =head1 COPYRIGHT
 455
 456 This program is free software, you can redistribute it and/or modify
 457 it under the same terms as Perl itself.
 458
 459 =cut