lib/Catalyst/Controller.pm

   1 package Catalyst::Controller;
   2
   3 use Moose;
   4 use Moose::Util qw/find_meta/;
   5
   6 use namespace::clean -except => 'meta';
   7
   8 BEGIN { extends qw/Catalyst::Component MooseX::MethodAttributes::Inheritable/; }
   9
  10 use MooseX::MethodAttributes;
  11 use Catalyst::Exception;
  12 use Catalyst::Utils;
  13
  14 with 'Catalyst::Component::ApplicationAttribute';
  15
  16 has path_prefix =>
  17     (
  18      is => 'rw',
  19      isa => 'Str',
  20      init_arg => 'path',
  21      predicate => 'has_path_prefix',
  22     );
  23
  24 has action_namespace =>
  25     (
  26      is => 'rw',
  27      isa => 'Str',
  28      init_arg => 'namespace',
  29      predicate => 'has_action_namespace',
  30     );
  31
  32 has _controller_actions =>
  33     (
  34      is => 'rw',
  35      isa => 'HashRef',
  36      init_arg => undef,
  37     );
  38
  39 sub BUILD {
  40     my ($self, $args) = @_;
  41     my $action  = delete $args->{action}  || {};
  42     my $actions = delete $args->{actions} || {};
  43     my $attr_value = $self->merge_config_hashes($actions, $action);
  44     $self->_controller_actions($attr_value);
  45 }
  46
  47 =head1 NAME
  48
  49 Catalyst::Controller - Catalyst Controller base class
  50
  51 =head1 SYNOPSIS
  52
  53   package MyApp::Controller::Search
  54   use base qw/Catalyst::Controller/;
  55
  56   sub foo : Local {
  57     my ($self,$c,@args) = @_;
  58     ...
  59   } # Dispatches to /search/foo
  60
  61 =head1 DESCRIPTION
  62
  63 Controllers are where the actions in the Catalyst framework
  64 reside. Each action is represented by a function with an attribute to
  65 identify what kind of action it is. See the L<Catalyst::Dispatcher>
  66 for more info about how Catalyst dispatches to actions.
  67
  68 =cut
  69
  70 #I think both of these could be attributes. doesn't really seem like they need
  71 #to ble class data. i think that attributes +default would work just fine
  72 __PACKAGE__->mk_classdata($_) for qw/_dispatch_steps _action_class/;
  73
  74 __PACKAGE__->_dispatch_steps( [qw/_BEGIN _AUTO _ACTION/] );
  75 __PACKAGE__->_action_class('Catalyst::Action');
  76
  77
  78 sub _DISPATCH : Private {
  79     my ( $self, $c ) = @_;
  80
  81     foreach my $disp ( @{ $self->_dispatch_steps } ) {
  82         last unless $c->forward($disp);
  83     }
  84
  85     $c->forward('_END');
  86 }
  87
  88 sub _BEGIN : Private {
  89     my ( $self, $c ) = @_;
  90     my $begin = ( $c->get_actions( 'begin', $c->namespace ) )[-1];
  91     return 1 unless $begin;
  92     $begin->dispatch( $c );
  93     return !@{ $c->error };
  94 }
  95
  96 sub _AUTO : Private {
  97     my ( $self, $c ) = @_;
  98     my @auto = $c->get_actions( 'auto', $c->namespace );
  99     foreach my $auto (@auto) {
 100         $auto->dispatch( $c );
 101         return 0 unless $c->state;
 102     }
 103     return 1;
 104 }
 105
 106 sub _ACTION : Private {
 107     my ( $self, $c ) = @_;
 108     if (   ref $c->action
 109         && $c->action->can('execute')
 110         && defined $c->req->action )
 111     {
 112         $c->action->dispatch( $c );
 113     }
 114     return !@{ $c->error };
 115 }
 116
 117 sub _END : Private {
 118     my ( $self, $c ) = @_;
 119     my $end = ( $c->get_actions( 'end', $c->namespace ) )[-1];
 120     return 1 unless $end;
 121     $end->dispatch( $c );
 122     return !@{ $c->error };
 123 }
 124
 125 sub action_for {
 126     my ( $self, $name ) = @_;
 127     my $app = ($self->isa('Catalyst') ? $self : $self->_application);
 128     return $app->dispatcher->get_action($name, $self->action_namespace);
 129 }
 130
 131 #my opinion is that this whole sub really should be a builder method, not
 132 #something that happens on every call. Anyone else disagree?? -- groditi
 133 ## -- apparently this is all just waiting for app/ctx split
 134 around action_namespace => sub {
 135     my $orig = shift;
 136     my ( $self, $c ) = @_;
 137
 138     if( ref($self) ){
 139         return $self->$orig if $self->has_action_namespace;
 140     } else {
 141         return $self->config->{namespace} if exists $self->config->{namespace};
 142     }
 143
 144     my $case_s;
 145     if( $c ){
 146         $case_s = $c->config->{case_sensitive};
 147     } else {
 148         if ($self->isa('Catalyst')) {
 149             $case_s = $self->config->{case_sensitive};
 150         } else {
 151             if (ref $self) {
 152                 $case_s = $self->_application->config->{case_sensitive};
 153             } else {
 154                 confess("Can't figure out case_sensitive setting");
 155             }
 156         }
 157     }
 158
 159     my $namespace = Catalyst::Utils::class2prefix($self->_component_name, $case_s) || '';
 160     $self->$orig($namespace) if ref($self);
 161     return $namespace;
 162 };
 163
 164 #Once again, this is probably better written as a builder method
 165 around path_prefix => sub {
 166     my $orig = shift;
 167     my $self = shift;
 168     if( ref($self) ){
 169       return $self->$orig if $self->has_path_prefix;
 170     } else {
 171       return $self->config->{path} if exists $self->config->{path};
 172     }
 173     my $namespace = $self->action_namespace(@_);
 174     $self->$orig($namespace) if ref($self);
 175     return $namespace;
 176 };
 177
 178 sub get_action_methods {
 179     my $self = shift;
 180     my $meta = find_meta($self);
 181     confess("Metaclass for "
 182           . ref($meta) . " for "
 183           . $meta->name
 184           . " cannot support register_actions." )
 185       unless $meta->can('get_nearest_methods_with_attributes');
 186     my @methods = $meta->get_nearest_methods_with_attributes;
 187
 188     # actions specified via config are also action_methods
 189     push(
 190         @methods,
 191         map {
 192             $meta->find_method_by_name($_)
 193               || confess( 'Action "'
 194                   . $_
 195                   . '" is not available from controller '
 196                   . ( ref $self ) )
 197           } keys %{ $self->_controller_actions }
 198     ) if ( ref $self );
 199     return @methods;
 200 }
 201
 202
 203 sub register_actions {
 204     my ( $self, $c ) = @_;
 205     $self->register_action_methods( $c, $self->get_action_methods );
 206 }
 207
 208 sub register_action_methods {
 209     my ( $self, $c, @methods ) = @_;
 210     my $class = $self->_component_name;
 211     #this is still not correct for some reason.
 212     my $namespace = $self->action_namespace($c);
 213
 214     if (!blessed($self) && $self eq $c && scalar(@methods)) {
 215         $c->log->warn("Action methods found defined in your application class, $self. This is deprecated, please move them into a Root controller.");
 216     }
 217
 218     foreach my $method (@methods) {
 219         my $name = $method->name;
 220         my $attributes = $method->attributes;
 221         my $attrs = $self->_parse_attrs( $c, $name, @{ $attributes } );
 222         if ( $attrs->{Private} && ( keys %$attrs > 1 ) ) {
 223             $c->log->debug( 'Bad action definition "'
 224                   . join( ' ', @{ $attributes } )
 225                   . qq/" for "$class->$name"/ )
 226               if $c->debug;
 227             next;
 228         }
 229         my $reverse = $namespace ? "${namespace}/${name}" : $name;
 230         my $action = $self->create_action(
 231             name       => $name,
 232             code       => $method->body,
 233             reverse    => $reverse,
 234             namespace  => $namespace,
 235             class      => $class,
 236             attributes => $attrs,
 237         );
 238
 239         $c->dispatcher->register( $c, $action );
 240     }
 241 }
 242
 243 sub create_action {
 244     my $self = shift;
 245     my %args = @_;
 246
 247     my $class = (exists $args{attributes}{ActionClass}
 248                     ? $args{attributes}{ActionClass}[0]
 249                     : $self->_action_class);
 250
 251     Class::MOP::load_class($class);
 252     return $class->new( \%args );
 253 }
 254
 255 sub _parse_attrs {
 256     my ( $self, $c, $name, @attrs ) = @_;
 257
 258     my %raw_attributes;
 259
 260     foreach my $attr (@attrs) {
 261
 262         # Parse out :Foo(bar) into Foo => bar etc (and arrayify)
 263
 264         if ( my ( $key, $value ) = ( $attr =~ /^(.*?)(?:\(\s*(.+?)\s*\))?$/ ) )
 265         {
 266
 267             if ( defined $value ) {
 268                 ( $value =~ s/^'(.*)'$/$1/ ) || ( $value =~ s/^"(.*)"/$1/ );
 269             }
 270             push( @{ $raw_attributes{$key} }, $value );
 271         }
 272     }
 273
 274     #I know that the original behavior was to ignore action if actions was set
 275     # but i actually think this may be a little more sane? we can always remove
 276     # the merge behavior quite easily and go back to having actions have
 277     # presedence over action by modifying the keys. i honestly think this is
 278     # superior while mantaining really high degree of compat
 279     my $actions;
 280     if( ref($self) ) {
 281         $actions = $self->_controller_actions;
 282     } else {
 283         my $cfg = $self->config;
 284         $actions = $self->merge_config_hashes($cfg->{actions}, $cfg->{action});
 285     }
 286
 287     %raw_attributes = ((exists $actions->{'*'} ? %{$actions->{'*'}} : ()),
 288                        %raw_attributes,
 289                        (exists $actions->{$name} ? %{$actions->{$name}} : ()));
 290
 291
 292     my %final_attributes;
 293
 294     foreach my $key (keys %raw_attributes) {
 295
 296         my $raw = $raw_attributes{$key};
 297
 298         foreach my $value (ref($raw) eq 'ARRAY' ? @$raw : $raw) {
 299
 300             my $meth = "_parse_${key}_attr";
 301             if ( my $code = $self->can($meth) ) {
 302                 ( $key, $value ) = $self->$code( $c, $name, $value );
 303             }
 304             push( @{ $final_attributes{$key} }, $value );
 305         }
 306     }
 307
 308     return \%final_attributes;
 309 }
 310
 311 sub _parse_Global_attr {
 312     my ( $self, $c, $name, $value ) = @_;
 313     return $self->_parse_Path_attr( $c, $name, "/$name" );
 314 }
 315
 316 sub _parse_Absolute_attr { shift->_parse_Global_attr(@_); }
 317
 318 sub _parse_Local_attr {
 319     my ( $self, $c, $name, $value ) = @_;
 320     return $self->_parse_Path_attr( $c, $name, $name );
 321 }
 322
 323 sub _parse_Relative_attr { shift->_parse_Local_attr(@_); }
 324
 325 sub _parse_Path_attr {
 326     my ( $self, $c, $name, $value ) = @_;
 327     $value = '' if !defined $value;
 328     if ( $value =~ m!^/! ) {
 329         return ( 'Path', $value );
 330     }
 331     elsif ( length $value ) {
 332         return ( 'Path', join( '/', $self->path_prefix($c), $value ) );
 333     }
 334     else {
 335         return ( 'Path', $self->path_prefix($c) );
 336     }
 337 }
 338
 339 sub _parse_Regex_attr {
 340     my ( $self, $c, $name, $value ) = @_;
 341     return ( 'Regex', $value );
 342 }
 343
 344 sub _parse_Regexp_attr { shift->_parse_Regex_attr(@_); }
 345
 346 sub _parse_LocalRegex_attr {
 347     my ( $self, $c, $name, $value ) = @_;
 348     unless ( $value =~ s/^\^// ) { $value = "(?:.*?)$value"; }
 349
 350     my $prefix = $self->path_prefix( $c );
 351     $prefix .= '/' if length( $prefix );
 352
 353     return ( 'Regex', "^${prefix}${value}" );
 354 }
 355
 356 sub _parse_LocalRegexp_attr { shift->_parse_LocalRegex_attr(@_); }
 357
 358 sub _parse_Chained_attr {
 359     my ($self, $c, $name, $value) = @_;
 360
 361     if (defined($value) && length($value)) {
 362         if ($value eq '.') {
 363             $value = '/'.$self->action_namespace($c);
 364         } elsif (my ($rel, $rest) = $value =~ /^((?:\.{2}\/)+)(.*)$/) {
 365             my @parts = split '/', $self->action_namespace($c);
 366             my @levels = split '/', $rel;
 367
 368             $value = '/'.join('/', @parts[0 .. $#parts - @levels], $rest);
 369         } elsif ($value !~ m/^\//) {
 370             my $action_ns = $self->action_namespace($c);
 371
 372             if ($action_ns) {
 373                 $value = '/'.join('/', $action_ns, $value);
 374             } else {
 375                 $value = '/'.$value; # special case namespace '' (root)
 376             }
 377         }
 378     } else {
 379         $value = '/'
 380     }
 381
 382     return Chained => $value;
 383 }
 384
 385 sub _parse_ChainedParent_attr {
 386     my ($self, $c, $name, $value) = @_;
 387     return $self->_parse_Chained_attr($c, $name, '../'.$name);
 388 }
 389
 390 sub _parse_PathPrefix_attr {
 391     my ( $self, $c ) = @_;
 392     return PathPart => $self->path_prefix($c);
 393 }
 394
 395 sub _parse_ActionClass_attr {
 396     my ( $self, $c, $name, $value ) = @_;
 397     my $appname = $self->_application;
 398     $value = Catalyst::Utils::resolve_namespace($appname . '::Action', $self->_action_class, $value);
 399     return ( 'ActionClass', $value );
 400 }
 401
 402 sub _parse_MyAction_attr {
 403     my ( $self, $c, $name, $value ) = @_;
 404
 405     my $appclass = Catalyst::Utils::class2appclass($self);
 406     $value = "${appclass}::Action::${value}";
 407
 408     return ( 'ActionClass', $value );
 409 }
 410
 411 __PACKAGE__->meta->make_immutable;
 412
 413 1;
 414
 415 __END__
 416
 417 =head1 CONFIGURATION
 418
 419 Like any other L<Catalyst::Component>, controllers have a config hash,
 420 accessible through $self->config from the controller actions.  Some
 421 settings are in use by the Catalyst framework:
 422
 423 =head2 namespace
 424
 425 This specifies the internal namespace the controller should be bound
 426 to. By default the controller is bound to the URI version of the
 427 controller name. For instance controller 'MyApp::Controller::Foo::Bar'
 428 will be bound to 'foo/bar'. The default Root controller is an example
 429 of setting namespace to '' (the null string).
 430
 431 =head2 path
 432
 433 Sets 'path_prefix', as described below.
 434
 435 =head1 METHODS
 436
 437 =head2 BUILDARGS ($app, @args)
 438
 439 From L<Catalyst::Component::ApplicationAttribute>, stashes the application
 440 instance as $self->_application.
 441
 442 =head2 $self->action_for('name')
 443
 444 Returns the Catalyst::Action object (if any) for a given method name
 445 in this component.
 446
 447 =head2 $self->action_namespace($c)
 448
 449 Returns the private namespace for actions in this component. Defaults
 450 to a value from the controller name (for
 451 e.g. MyApp::Controller::Foo::Bar becomes "foo/bar") or can be
 452 overridden from the "namespace" config key.
 453
 454
 455 =head2 $self->path_prefix($c)
 456
 457 Returns the default path prefix for :PathPrefix, :Local, :LocalRegex and
 458 relative :Path actions in this component. Defaults to the action_namespace or
 459 can be overridden from the "path" config key.
 460
 461 =head2 $self->register_actions($c)
 462
 463 Finds all applicable actions for this component, creates
 464 Catalyst::Action objects (using $self->create_action) for them and
 465 registers them with $c->dispatcher.
 466
 467 =head2 $self->get_action_methods()
 468
 469 Returns a list of L<Moose::Meta::Method> objects, doing the
 470 L<MooseX::MethodAttributes::Role::Meta::Method> role, which are the set of
 471 action methods for this package.
 472
 473 =head2 $self->register_action_methods($c, @methods)
 474
 475 Creates action objects for a set of action methods using C< create_action >,
 476 and registers them with the dispatcher.
 477
 478 =head2 $self->create_action(%args)
 479
 480 Called with a hash of data to be use for construction of a new
 481 Catalyst::Action (or appropriate sub/alternative class) object.
 482
 483 =head2 $self->_application
 484
 485 =head2 $self->_app
 486
 487 Returns the application instance stored by C<new()>
 488
 489 =head1 AUTHORS
 490
 491 Catalyst Contributors, see Catalyst.pm
 492
 493 =head1 COPYRIGHT
 494
 495 This library is free software. You can redistribute it and/or modify
 496 it under the same terms as Perl itself.
 497
 498 =cut