lib/Catalyst/Controller.pm

   1 package Catalyst::Controller;
   2
   3 use Moose;
   4 use Moose::Util qw/find_meta/;
   5 use List::MoreUtils qw/uniq/;
   6 use namespace::clean -except => 'meta';
   7
   8 BEGIN { extends qw/Catalyst::Component MooseX::MethodAttributes::Inheritable/; }
   9
  10 use MooseX::MethodAttributes;
  11 use Catalyst::Exception;
  12 use Catalyst::Utils;
  13
  14 with 'Catalyst::Component::ApplicationAttribute';
  15
  16 has path_prefix =>
  17     (
  18      is => 'rw',
  19      isa => 'Str',
  20      init_arg => 'path',
  21      predicate => 'has_path_prefix',
  22     );
  23
  24 has action_namespace =>
  25     (
  26      is => 'rw',
  27      isa => 'Str',
  28      init_arg => 'namespace',
  29      predicate => 'has_action_namespace',
  30     );
  31
  32 has actions =>
  33     (
  34      accessor => '_controller_actions',
  35      isa => 'HashRef',
  36      init_arg => undef,
  37     );
  38
  39 sub BUILD {
  40     my ($self, $args) = @_;
  41     my $action  = delete $args->{action}  || {};
  42     my $actions = delete $args->{actions} || {};
  43     my $attr_value = $self->merge_config_hashes($actions, $action);
  44     $self->_controller_actions($attr_value);
  45 }
  46
  47
  48
  49 =head1 NAME
  50
  51 Catalyst::Controller - Catalyst Controller base class
  52
  53 =head1 SYNOPSIS
  54
  55   package MyApp::Controller::Search
  56   use base qw/Catalyst::Controller/;
  57
  58   sub foo : Local {
  59     my ($self,$c,@args) = @_;
  60     ...
  61   } # Dispatches to /search/foo
  62
  63 =head1 DESCRIPTION
  64
  65 Controllers are where the actions in the Catalyst framework
  66 reside. Each action is represented by a function with an attribute to
  67 identify what kind of action it is. See the L<Catalyst::Dispatcher>
  68 for more info about how Catalyst dispatches to actions.
  69
  70 =cut
  71
  72 #I think both of these could be attributes. doesn't really seem like they need
  73 #to ble class data. i think that attributes +default would work just fine
  74 __PACKAGE__->mk_classdata($_) for qw/_dispatch_steps _action_class/;
  75
  76 __PACKAGE__->_dispatch_steps( [qw/_BEGIN _AUTO _ACTION/] );
  77 __PACKAGE__->_action_class('Catalyst::Action');
  78
  79
  80 sub _DISPATCH : Private {
  81     my ( $self, $c ) = @_;
  82
  83     foreach my $disp ( @{ $self->_dispatch_steps } ) {
  84         last unless $c->forward($disp);
  85     }
  86
  87     $c->forward('_END');
  88 }
  89
  90 sub _BEGIN : Private {
  91     my ( $self, $c ) = @_;
  92     my $begin = ( $c->get_actions( 'begin', $c->namespace ) )[-1];
  93     return 1 unless $begin;
  94     $begin->dispatch( $c );
  95     return !@{ $c->error };
  96 }
  97
  98 sub _AUTO : Private {
  99     my ( $self, $c ) = @_;
 100     my @auto = $c->get_actions( 'auto', $c->namespace );
 101     foreach my $auto (@auto) {
 102         $auto->dispatch( $c );
 103         return 0 unless $c->state;
 104     }
 105     return 1;
 106 }
 107
 108 sub _ACTION : Private {
 109     my ( $self, $c ) = @_;
 110     if (   ref $c->action
 111         && $c->action->can('execute')
 112         && defined $c->req->action )
 113     {
 114         $c->action->dispatch( $c );
 115     }
 116     return !@{ $c->error };
 117 }
 118
 119 sub _END : Private {
 120     my ( $self, $c ) = @_;
 121     my $end = ( $c->get_actions( 'end', $c->namespace ) )[-1];
 122     return 1 unless $end;
 123     $end->dispatch( $c );
 124     return !@{ $c->error };
 125 }
 126
 127 sub action_for {
 128     my ( $self, $name ) = @_;
 129     my $app = ($self->isa('Catalyst') ? $self : $self->_application);
 130     return $app->dispatcher->get_action($name, $self->action_namespace);
 131 }
 132
 133 #my opinion is that this whole sub really should be a builder method, not
 134 #something that happens on every call. Anyone else disagree?? -- groditi
 135 ## -- apparently this is all just waiting for app/ctx split
 136 around action_namespace => sub {
 137     my $orig = shift;
 138     my ( $self, $c ) = @_;
 139
 140     my $class = ref($self) || $self;
 141     my $appclass = ref($c) || $c;
 142     if( ref($self) ){
 143         return $self->$orig if $self->has_action_namespace;
 144     } else {
 145         return $class->config->{namespace} if exists $class->config->{namespace};
 146     }
 147
 148     my $case_s;
 149     if( $c ){
 150         $case_s = $appclass->config->{case_sensitive};
 151     } else {
 152         if ($self->isa('Catalyst')) {
 153             $case_s = $class->config->{case_sensitive};
 154         } else {
 155             if (ref $self) {
 156                 $case_s = ref($self->_application)->config->{case_sensitive};
 157             } else {
 158                 confess("Can't figure out case_sensitive setting");
 159             }
 160         }
 161     }
 162
 163     my $namespace = Catalyst::Utils::class2prefix($self->catalyst_component_name, $case_s) || '';
 164     $self->$orig($namespace) if ref($self);
 165     return $namespace;
 166 };
 167
 168 #Once again, this is probably better written as a builder method
 169 around path_prefix => sub {
 170     my $orig = shift;
 171     my $self = shift;
 172     if( ref($self) ){
 173       return $self->$orig if $self->has_path_prefix;
 174     } else {
 175       return $self->config->{path} if exists $self->config->{path};
 176     }
 177     my $namespace = $self->action_namespace(@_);
 178     $self->$orig($namespace) if ref($self);
 179     return $namespace;
 180 };
 181
 182 sub get_action_methods {
 183     my $self = shift;
 184     my $meta = find_meta($self) || confess("No metaclass setup for $self");
 185     confess("Metaclass "
 186           . ref($meta) . " for "
 187           . $meta->name
 188           . " cannot support register_actions." )
 189       unless $meta->can('get_nearest_methods_with_attributes');
 190     my @methods = $meta->get_nearest_methods_with_attributes;
 191
 192     # actions specified via config are also action_methods
 193     push(
 194         @methods,
 195         map {
 196             $meta->find_method_by_name($_)
 197               || confess( 'Action "'
 198                   . $_
 199                   . '" is not available from controller '
 200                   . ( ref $self ) )
 201           } keys %{ $self->_controller_actions }
 202     ) if ( ref $self );
 203     return uniq @methods;
 204 }
 205
 206
 207 sub register_actions {
 208     my ( $self, $c ) = @_;
 209     $self->register_action_methods( $c, $self->get_action_methods );
 210 }
 211
 212 sub register_action_methods {
 213     my ( $self, $c, @methods ) = @_;
 214     my $class = $self->catalyst_component_name;
 215     #this is still not correct for some reason.
 216     my $namespace = $self->action_namespace($c);
 217
 218     # FIXME - fugly
 219     if (!blessed($self) && $self eq $c && scalar(@methods)) {
 220         my @really_bad_methods = grep { ! /^_(DISPATCH|BEGIN|AUTO|ACTION|END)$/ } map { $_->name } @methods;
 221         if (scalar(@really_bad_methods)) {
 222             $c->log->warn("Action methods (" . join(', ', @really_bad_methods) . ") found defined in your application class, $self. This is deprecated, please move them into a Root controller.");
 223         }
 224     }
 225
 226     foreach my $method (@methods) {
 227         my $name = $method->name;
 228         # Horrible hack! All method metaclasses should have an attributes
 229         # method, core Moose bug - see r13354.
 230         my $attributes = $method->can('attributes') ? $method->attributes : [];
 231         my $attrs = $self->_parse_attrs( $c, $name, @{ $attributes } );
 232         if ( $attrs->{Private} && ( keys %$attrs > 1 ) ) {
 233             $c->log->debug( 'Bad action definition "'
 234                   . join( ' ', @{ $attributes } )
 235                   . qq/" for "$class->$name"/ )
 236               if $c->debug;
 237             next;
 238         }
 239         my $reverse = $namespace ? "${namespace}/${name}" : $name;
 240         my $action = $self->create_action(
 241             name       => $name,
 242             code       => $method->body,
 243             reverse    => $reverse,
 244             namespace  => $namespace,
 245             class      => $class,
 246             attributes => $attrs,
 247         );
 248
 249         $c->dispatcher->register( $c, $action );
 250     }
 251 }
 252
 253 sub action_class {
 254     my $self = shift;
 255     my %args = @_;
 256
 257     my $class = (exists $args{attributes}{ActionClass}
 258         ? $args{attributes}{ActionClass}[0]
 259         : $self->_action_class);
 260
 261     Class::MOP::load_class($class);
 262     return $class;
 263 }
 264
 265 sub create_action {
 266     my $self = shift;
 267     my %args = @_;
 268
 269     my $class = $self->action_class(%args);
 270     my $action_args = $self->config->{action_args};
 271
 272     my %extra_args = (
 273         %{ $action_args->{'*'}           || {} },
 274         %{ $action_args->{ $args{name} } || {} },
 275     );
 276
 277     return $class->new({ %extra_args, %args });
 278 }
 279
 280 sub _parse_attrs {
 281     my ( $self, $c, $name, @attrs ) = @_;
 282
 283     my %raw_attributes;
 284
 285     foreach my $attr (@attrs) {
 286
 287         # Parse out :Foo(bar) into Foo => bar etc (and arrayify)
 288
 289         if ( my ( $key, $value ) = ( $attr =~ /^(.*?)(?:\(\s*(.+?)\s*\))?$/ ) )
 290         {
 291
 292             if ( defined $value ) {
 293                 ( $value =~ s/^'(.*)'$/$1/ ) || ( $value =~ s/^"(.*)"/$1/ );
 294             }
 295             push( @{ $raw_attributes{$key} }, $value );
 296         }
 297     }
 298
 299     my $actions;
 300     if( ref($self) ) {
 301         $actions = $self->_controller_actions;
 302     } else {
 303         my $cfg = $self->config;
 304         $actions = $self->merge_config_hashes($cfg->{actions}, $cfg->{action});
 305     }
 306
 307     %raw_attributes = ((exists $actions->{'*'} ? %{$actions->{'*'}} : ()),
 308                        %raw_attributes,
 309                        (exists $actions->{$name} ? %{$actions->{$name}} : ()));
 310
 311
 312     my %final_attributes;
 313
 314     foreach my $key (keys %raw_attributes) {
 315
 316         my $raw = $raw_attributes{$key};
 317
 318         foreach my $value (ref($raw) eq 'ARRAY' ? @$raw : $raw) {
 319
 320             my $meth = "_parse_${key}_attr";
 321             if ( my $code = $self->can($meth) ) {
 322                 ( $key, $value ) = $self->$code( $c, $name, $value );
 323             }
 324             push( @{ $final_attributes{$key} }, $value );
 325         }
 326     }
 327
 328     return \%final_attributes;
 329 }
 330
 331 sub _parse_Global_attr {
 332     my ( $self, $c, $name, $value ) = @_;
 333     return $self->_parse_Path_attr( $c, $name, "/$name" );
 334 }
 335
 336 sub _parse_Absolute_attr { shift->_parse_Global_attr(@_); }
 337
 338 sub _parse_Local_attr {
 339     my ( $self, $c, $name, $value ) = @_;
 340     return $self->_parse_Path_attr( $c, $name, $name );
 341 }
 342
 343 sub _parse_Relative_attr { shift->_parse_Local_attr(@_); }
 344
 345 sub _parse_Path_attr {
 346     my ( $self, $c, $name, $value ) = @_;
 347     $value = '' if !defined $value;
 348     if ( $value =~ m!^/! ) {
 349         return ( 'Path', $value );
 350     }
 351     elsif ( length $value ) {
 352         return ( 'Path', join( '/', $self->path_prefix($c), $value ) );
 353     }
 354     else {
 355         return ( 'Path', $self->path_prefix($c) );
 356     }
 357 }
 358
 359 sub _parse_Regex_attr {
 360     my ( $self, $c, $name, $value ) = @_;
 361     return ( 'Regex', $value );
 362 }
 363
 364 sub _parse_Regexp_attr { shift->_parse_Regex_attr(@_); }
 365
 366 sub _parse_LocalRegex_attr {
 367     my ( $self, $c, $name, $value ) = @_;
 368     unless ( $value =~ s/^\^// ) { $value = "(?:.*?)$value"; }
 369
 370     my $prefix = $self->path_prefix( $c );
 371     $prefix .= '/' if length( $prefix );
 372
 373     return ( 'Regex', "^${prefix}${value}" );
 374 }
 375
 376 sub _parse_LocalRegexp_attr { shift->_parse_LocalRegex_attr(@_); }
 377
 378 sub _parse_Chained_attr {
 379     my ($self, $c, $name, $value) = @_;
 380
 381     if (defined($value) && length($value)) {
 382         if ($value eq '.') {
 383             $value = '/'.$self->action_namespace($c);
 384         } elsif (my ($rel, $rest) = $value =~ /^((?:\.{2}\/)+)(.*)$/) {
 385             my @parts = split '/', $self->action_namespace($c);
 386             my @levels = split '/', $rel;
 387
 388             $value = '/'.join('/', @parts[0 .. $#parts - @levels], $rest);
 389         } elsif ($value !~ m/^\//) {
 390             my $action_ns = $self->action_namespace($c);
 391
 392             if ($action_ns) {
 393                 $value = '/'.join('/', $action_ns, $value);
 394             } else {
 395                 $value = '/'.$value; # special case namespace '' (root)
 396             }
 397         }
 398     } else {
 399         $value = '/'
 400     }
 401
 402     return Chained => $value;
 403 }
 404
 405 sub _parse_ChainedParent_attr {
 406     my ($self, $c, $name, $value) = @_;
 407     return $self->_parse_Chained_attr($c, $name, '../'.$name);
 408 }
 409
 410 sub _parse_PathPrefix_attr {
 411     my ( $self, $c ) = @_;
 412     return PathPart => $self->path_prefix($c);
 413 }
 414
 415 sub _parse_ActionClass_attr {
 416     my ( $self, $c, $name, $value ) = @_;
 417     my $appname = $self->_application;
 418     $value = Catalyst::Utils::resolve_namespace($appname . '::Action', $self->_action_class, $value);
 419     return ( 'ActionClass', $value );
 420 }
 421
 422 sub _parse_MyAction_attr {
 423     my ( $self, $c, $name, $value ) = @_;
 424
 425     my $appclass = Catalyst::Utils::class2appclass($self);
 426     $value = "${appclass}::Action::${value}";
 427
 428     return ( 'ActionClass', $value );
 429 }
 430
 431 __PACKAGE__->meta->make_immutable;
 432
 433 1;
 434
 435 __END__
 436
 437 =head1 CONFIGURATION
 438
 439 Like any other L<Catalyst::Component>, controllers have a config hash,
 440 accessible through $self->config from the controller actions.  Some
 441 settings are in use by the Catalyst framework:
 442
 443 =head2 namespace
 444
 445 This specifies the internal namespace the controller should be bound
 446 to. By default the controller is bound to the URI version of the
 447 controller name. For instance controller 'MyApp::Controller::Foo::Bar'
 448 will be bound to 'foo/bar'. The default Root controller is an example
 449 of setting namespace to '' (the null string).
 450
 451 =head2 path
 452
 453 Sets 'path_prefix', as described below.
 454
 455 =head2 action
 456
 457 Allows you to set the attributes that the dispatcher creates actions out of.
 458 This allows you to do 'rails style routes', or override some of the
 459 attribute defintions of actions composed from Roles.
 460 You can set arguments globally (for all actions of the controller) and
 461 specifically (for a single action).
 462
 463     __PACKAGE__->config(
 464         action => {
 465             '*' => { Chained => 'base', Args => 0  },
 466             base => { Chained => '/', PathPart => '', CaptureArgs => 0 },
 467         },
 468      );
 469
 470 In the case above every sub in the package would be made into a Chain
 471 endpoint with a URI the same as the sub name for each sub, chained
 472 to the sub named C<base>. Ergo dispatch to C</example> would call the
 473 C<base> method, then the C<example> method.
 474
 475 =head2 action_args
 476
 477 Allows you to set constructor arguments on your actions. You can set arguments
 478 globally and specifically (as above).
 479 This is particularly useful when using C<ActionRole>s
 480 (L<Catalyst::Controller::ActionRole>) and custom C<ActionClass>es.
 481
 482     __PACKAGE__->config(
 483         action_args => {
 484             '*' => { globalarg1 => 'hello', globalarg2 => 'goodbye' },
 485             'specific_action' => { customarg => 'arg1' },
 486         },
 487      );
 488
 489 In the case above the action class associated with C<specific_action> would get
 490 passed the following arguments, in addition to the normal action constructor
 491 arguments, when it is instantiated:
 492
 493   (globalarg1 => 'hello', globalarg2 => 'goodbye', customarg => 'arg1')
 494
 495 =head1 METHODS
 496
 497 =head2 BUILDARGS ($app, @args)
 498
 499 From L<Catalyst::Component::ApplicationAttribute>, stashes the application
 500 instance as $self->_application.
 501
 502 =head2 $self->action_for('name')
 503
 504 Returns the Catalyst::Action object (if any) for a given method name
 505 in this component.
 506
 507 =head2 $self->action_namespace($c)
 508
 509 Returns the private namespace for actions in this component. Defaults
 510 to a value from the controller name (for
 511 e.g. MyApp::Controller::Foo::Bar becomes "foo/bar") or can be
 512 overridden from the "namespace" config key.
 513
 514
 515 =head2 $self->path_prefix($c)
 516
 517 Returns the default path prefix for :PathPrefix, :Local, :LocalRegex and
 518 relative :Path actions in this component. Defaults to the action_namespace or
 519 can be overridden from the "path" config key.
 520
 521 =head2 $self->register_actions($c)
 522
 523 Finds all applicable actions for this component, creates
 524 Catalyst::Action objects (using $self->create_action) for them and
 525 registers them with $c->dispatcher.
 526
 527 =head2 $self->get_action_methods()
 528
 529 Returns a list of L<Moose::Meta::Method> objects, doing the
 530 L<MooseX::MethodAttributes::Role::Meta::Method> role, which are the set of
 531 action methods for this package.
 532
 533 =head2 $self->register_action_methods($c, @methods)
 534
 535 Creates action objects for a set of action methods using C< create_action >,
 536 and registers them with the dispatcher.
 537
 538 =head2 $self->action_class(%args)
 539
 540 Used when a controller is creating an action to determine the correct base
 541 action class to use.
 542
 543 =head2 $self->create_action(%args)
 544
 545 Called with a hash of data to be use for construction of a new
 546 Catalyst::Action (or appropriate sub/alternative class) object.
 547
 548 =head2 $self->_application
 549
 550 =head2 $self->_app
 551
 552 Returns the application instance stored by C<new()>
 553
 554 =head1 AUTHORS
 555
 556 Catalyst Contributors, see Catalyst.pm
 557
 558 =head1 COPYRIGHT
 559
 560 This library is free software. You can redistribute it and/or modify
 561 it under the same terms as Perl itself.
 562
 563 =cut