lib/Catalyst/Controller.pm

   1 package Catalyst::Controller;
   2
   3 use Moose;
   4 use Moose::Util qw/find_meta/;
   5
   6 use namespace::clean -except => 'meta';
   7
   8 BEGIN { extends qw/Catalyst::Component MooseX::MethodAttributes::Inheritable/; }
   9
  10 use MooseX::MethodAttributes;
  11 use Catalyst::Exception;
  12 use Catalyst::Utils;
  13
  14 with 'Catalyst::Component::ApplicationAttribute';
  15
  16 has path_prefix =>
  17     (
  18      is => 'rw',
  19      isa => 'Str',
  20      init_arg => 'path',
  21      predicate => 'has_path_prefix',
  22     );
  23
  24 has action_namespace =>
  25     (
  26      is => 'rw',
  27      isa => 'Str',
  28      init_arg => 'namespace',
  29      predicate => 'has_action_namespace',
  30     );
  31
  32 has _controller_actions =>
  33     (
  34      is => 'rw',
  35      isa => 'HashRef',
  36      init_arg => undef,
  37     );
  38
  39 sub BUILD {
  40     my ($self, $args) = @_;
  41     my $action  = delete $args->{action}  || {};
  42     my $actions = delete $args->{actions} || {};
  43     my $attr_value = $self->merge_config_hashes($actions, $action);
  44     $self->_controller_actions($attr_value);
  45 }
  46
  47 =head1 NAME
  48
  49 Catalyst::Controller - Catalyst Controller base class
  50
  51 =head1 SYNOPSIS
  52
  53   package MyApp::Controller::Search
  54   use base qw/Catalyst::Controller/;
  55
  56   sub foo : Local {
  57     my ($self,$c,@args) = @_;
  58     ...
  59   } # Dispatches to /search/foo
  60
  61 =head1 DESCRIPTION
  62
  63 Controllers are where the actions in the Catalyst framework
  64 reside. Each action is represented by a function with an attribute to
  65 identify what kind of action it is. See the L<Catalyst::Dispatcher>
  66 for more info about how Catalyst dispatches to actions.
  67
  68 =cut
  69
  70 #I think both of these could be attributes. doesn't really seem like they need
  71 #to ble class data. i think that attributes +default would work just fine
  72 __PACKAGE__->mk_classdata($_) for qw/_dispatch_steps _action_class/;
  73
  74 __PACKAGE__->_dispatch_steps( [qw/_BEGIN _AUTO _ACTION/] );
  75 __PACKAGE__->_action_class('Catalyst::Action');
  76
  77
  78 sub _DISPATCH : Private {
  79     my ( $self, $c ) = @_;
  80
  81     foreach my $disp ( @{ $self->_dispatch_steps } ) {
  82         last unless $c->forward($disp);
  83     }
  84
  85     $c->forward('_END');
  86 }
  87
  88 sub _BEGIN : Private {
  89     my ( $self, $c ) = @_;
  90     my $begin = ( $c->get_actions( 'begin', $c->namespace ) )[-1];
  91     return 1 unless $begin;
  92     $begin->dispatch( $c );
  93     return !@{ $c->error };
  94 }
  95
  96 sub _AUTO : Private {
  97     my ( $self, $c ) = @_;
  98     my @auto = $c->get_actions( 'auto', $c->namespace );
  99     foreach my $auto (@auto) {
 100         $auto->dispatch( $c );
 101         return 0 unless $c->state;
 102     }
 103     return 1;
 104 }
 105
 106 sub _ACTION : Private {
 107     my ( $self, $c ) = @_;
 108     if (   ref $c->action
 109         && $c->action->can('execute')
 110         && defined $c->req->action )
 111     {
 112         $c->action->dispatch( $c );
 113     }
 114     return !@{ $c->error };
 115 }
 116
 117 sub _END : Private {
 118     my ( $self, $c ) = @_;
 119     my $end = ( $c->get_actions( 'end', $c->namespace ) )[-1];
 120     return 1 unless $end;
 121     $end->dispatch( $c );
 122     return !@{ $c->error };
 123 }
 124
 125 sub action_for {
 126     my ( $self, $name ) = @_;
 127     my $app = ($self->isa('Catalyst') ? $self : $self->_application);
 128     return $app->dispatcher->get_action($name, $self->action_namespace);
 129 }
 130
 131 #my opinion is that this whole sub really should be a builder method, not
 132 #something that happens on every call. Anyone else disagree?? -- groditi
 133 ## -- apparently this is all just waiting for app/ctx split
 134 around action_namespace => sub {
 135     my $orig = shift;
 136     my ( $self, $c ) = @_;
 137
 138     if( ref($self) ){
 139         return $self->$orig if $self->has_action_namespace;
 140     } else {
 141         return $self->config->{namespace} if exists $self->config->{namespace};
 142     }
 143
 144     my $case_s;
 145     if( $c ){
 146         $case_s = $c->config->{case_sensitive};
 147     } else {
 148         if ($self->isa('Catalyst')) {
 149             $case_s = $self->config->{case_sensitive};
 150         } else {
 151             if (ref $self) {
 152                 $case_s = $self->_application->config->{case_sensitive};
 153             } else {
 154                 confess("Can't figure out case_sensitive setting");
 155             }
 156         }
 157     }
 158
 159     my $namespace = Catalyst::Utils::class2prefix(ref($self) || $self, $case_s) || '';
 160     $self->$orig($namespace) if ref($self);
 161     return $namespace;
 162 };
 163
 164 #Once again, this is probably better written as a builder method
 165 around path_prefix => sub {
 166     my $orig = shift;
 167     my $self = shift;
 168     if( ref($self) ){
 169       return $self->$orig if $self->has_path_prefix;
 170     } else {
 171       return $self->config->{path} if exists $self->config->{path};
 172     }
 173     my $namespace = $self->action_namespace(@_);
 174     $self->$orig($namespace) if ref($self);
 175     return $namespace;
 176 };
 177
 178 sub get_action_methods {
 179     my $self = shift;
 180     my $meta = find_meta($self);
 181     confess("Metaclass for " . ref($meta) ." for " . $meta->name
 182         . " cannot support register_actions.")
 183         unless $meta->can('get_nearest_methods_with_attributes');
 184     my @methods = $meta->get_nearest_methods_with_attributes;
 185     return @methods;
 186 }
 187
 188 sub register_actions {
 189     my ( $self, $c ) = @_;
 190     $self->register_action_methods( $c, $self->get_action_methods );
 191 }
 192
 193 sub register_action_methods {
 194     my ( $self, $c, @methods ) = @_;
 195     my $class = ref $self || $self;
 196     #this is still not correct for some reason.
 197     my $namespace = $self->action_namespace($c);
 198
 199     foreach my $method (@methods) {
 200         my $name = $method->name;
 201         my $attributes = $method->attributes;
 202         next unless $attributes;
 203         my $attrs = $self->_parse_attrs( $c, $name, @{ $attributes } );
 204         if ( $attrs->{Private} && ( keys %$attrs > 1 ) ) {
 205             $c->log->debug( 'Bad action definition "'
 206                   . join( ' ', @{ $attributes } )
 207                   . qq/" for "$class->$name"/ )
 208               if $c->debug;
 209             next;
 210         }
 211         my $reverse = $namespace ? "${namespace}/${name}" : $name;
 212         my $action = $self->create_action(
 213             name       => $name,
 214             code       => $method->body,
 215             reverse    => $reverse,
 216             namespace  => $namespace,
 217             class      => $class,
 218             attributes => $attrs,
 219         );
 220
 221         $c->dispatcher->register( $c, $action );
 222     }
 223 }
 224
 225 sub create_action {
 226     my $self = shift;
 227     my %args = @_;
 228
 229     my $class = (exists $args{attributes}{ActionClass}
 230                     ? $args{attributes}{ActionClass}[0]
 231                     : $self->_action_class);
 232
 233     Class::MOP::load_class($class);
 234     return $class->new( \%args );
 235 }
 236
 237 sub _parse_attrs {
 238     my ( $self, $c, $name, @attrs ) = @_;
 239
 240     my %raw_attributes;
 241
 242     foreach my $attr (@attrs) {
 243
 244         # Parse out :Foo(bar) into Foo => bar etc (and arrayify)
 245
 246         if ( my ( $key, $value ) = ( $attr =~ /^(.*?)(?:\(\s*(.+?)\s*\))?$/ ) )
 247         {
 248
 249             if ( defined $value ) {
 250                 ( $value =~ s/^'(.*)'$/$1/ ) || ( $value =~ s/^"(.*)"/$1/ );
 251             }
 252             push( @{ $raw_attributes{$key} }, $value );
 253         }
 254     }
 255
 256     #I know that the original behavior was to ignore action if actions was set
 257     # but i actually think this may be a little more sane? we can always remove
 258     # the merge behavior quite easily and go back to having actions have
 259     # presedence over action by modifying the keys. i honestly think this is
 260     # superior while mantaining really high degree of compat
 261     my $actions;
 262     if( ref($self) ) {
 263         $actions = $self->_controller_actions;
 264     } else {
 265         my $cfg = $self->config;
 266         $actions = $self->merge_config_hashes($cfg->{actions}, $cfg->{action});
 267     }
 268
 269     %raw_attributes = ((exists $actions->{'*'} ? %{$actions->{'*'}} : ()),
 270                        %raw_attributes,
 271                        (exists $actions->{$name} ? %{$actions->{$name}} : ()));
 272
 273
 274     my %final_attributes;
 275
 276     foreach my $key (keys %raw_attributes) {
 277
 278         my $raw = $raw_attributes{$key};
 279
 280         foreach my $value (ref($raw) eq 'ARRAY' ? @$raw : $raw) {
 281
 282             my $meth = "_parse_${key}_attr";
 283             if ( my $code = $self->can($meth) ) {
 284                 ( $key, $value ) = $self->$code( $c, $name, $value );
 285             }
 286             push( @{ $final_attributes{$key} }, $value );
 287         }
 288     }
 289
 290     return \%final_attributes;
 291 }
 292
 293 sub _parse_Global_attr {
 294     my ( $self, $c, $name, $value ) = @_;
 295     return $self->_parse_Path_attr( $c, $name, "/$name" );
 296 }
 297
 298 sub _parse_Absolute_attr { shift->_parse_Global_attr(@_); }
 299
 300 sub _parse_Local_attr {
 301     my ( $self, $c, $name, $value ) = @_;
 302     return $self->_parse_Path_attr( $c, $name, $name );
 303 }
 304
 305 sub _parse_Relative_attr { shift->_parse_Local_attr(@_); }
 306
 307 sub _parse_Path_attr {
 308     my ( $self, $c, $name, $value ) = @_;
 309     $value = '' if !defined $value;
 310     if ( $value =~ m!^/! ) {
 311         return ( 'Path', $value );
 312     }
 313     elsif ( length $value ) {
 314         return ( 'Path', join( '/', $self->path_prefix($c), $value ) );
 315     }
 316     else {
 317         return ( 'Path', $self->path_prefix($c) );
 318     }
 319 }
 320
 321 sub _parse_Regex_attr {
 322     my ( $self, $c, $name, $value ) = @_;
 323     return ( 'Regex', $value );
 324 }
 325
 326 sub _parse_Regexp_attr { shift->_parse_Regex_attr(@_); }
 327
 328 sub _parse_LocalRegex_attr {
 329     my ( $self, $c, $name, $value ) = @_;
 330     unless ( $value =~ s/^\^// ) { $value = "(?:.*?)$value"; }
 331
 332     my $prefix = $self->path_prefix( $c );
 333     $prefix .= '/' if length( $prefix );
 334
 335     return ( 'Regex', "^${prefix}${value}" );
 336 }
 337
 338 sub _parse_LocalRegexp_attr { shift->_parse_LocalRegex_attr(@_); }
 339
 340 sub _parse_Chained_attr {
 341     my ($self, $c, $name, $value) = @_;
 342
 343     if (defined($value) && length($value)) {
 344         if ($value eq '.') {
 345             $value = '/'.$self->action_namespace($c);
 346         } elsif (my ($rel, $rest) = $value =~ /^((?:\.{2}\/)+)(.*)$/) {
 347             my @parts = split '/', $self->action_namespace($c);
 348             my @levels = split '/', $rel;
 349
 350             $value = '/'.join('/', @parts[0 .. $#parts - @levels], $rest);
 351         } elsif ($value !~ m/^\//) {
 352             my $action_ns = $self->action_namespace($c);
 353
 354             if ($action_ns) {
 355                 $value = '/'.join('/', $action_ns, $value);
 356             } else {
 357                 $value = '/'.$value; # special case namespace '' (root)
 358             }
 359         }
 360     } else {
 361         $value = '/'
 362     }
 363
 364     return Chained => $value;
 365 }
 366
 367 sub _parse_ChainedParent_attr {
 368     my ($self, $c, $name, $value) = @_;
 369     return $self->_parse_Chained_attr($c, $name, '../'.$name);
 370 }
 371
 372 sub _parse_PathPrefix_attr {
 373     my $self = shift;
 374     return PathPart => $self->path_prefix;
 375 }
 376
 377 sub _parse_ActionClass_attr {
 378     my ( $self, $c, $name, $value ) = @_;
 379     $value = Catalyst::Utils::resolve_namespace($self->_action_class, $value);
 380     return ( 'ActionClass', $value );
 381 }
 382
 383 sub _parse_MyAction_attr {
 384     my ( $self, $c, $name, $value ) = @_;
 385
 386     my $appclass = Catalyst::Utils::class2appclass($self);
 387     $value = "${appclass}::Action::${value}";
 388
 389     return ( 'ActionClass', $value );
 390 }
 391
 392 __PACKAGE__->meta->make_immutable;
 393
 394 1;
 395
 396 __END__
 397
 398 =head1 CONFIGURATION
 399
 400 Like any other L<Catalyst::Component>, controllers have a config hash,
 401 accessible through $self->config from the controller actions.  Some
 402 settings are in use by the Catalyst framework:
 403
 404 =head2 namespace
 405
 406 This specifies the internal namespace the controller should be bound
 407 to. By default the controller is bound to the URI version of the
 408 controller name. For instance controller 'MyApp::Controller::Foo::Bar'
 409 will be bound to 'foo/bar'. The default Root controller is an example
 410 of setting namespace to '' (the null string).
 411
 412 =head2 path
 413
 414 Sets 'path_prefix', as described below.
 415
 416 =head1 METHODS
 417
 418 =head2 BUILDARGS ($app, @args)
 419
 420 From L<Catalyst::Component::ApplicationAttribute>, stashes the application
 421 instance as $self->_application.
 422
 423 =head2 $self->action_for('name')
 424
 425 Returns the Catalyst::Action object (if any) for a given method name
 426 in this component.
 427
 428 =head2 $self->action_namespace($c)
 429
 430 Returns the private namespace for actions in this component. Defaults
 431 to a value from the controller name (for
 432 e.g. MyApp::Controller::Foo::Bar becomes "foo/bar") or can be
 433 overridden from the "namespace" config key.
 434
 435
 436 =head2 $self->path_prefix($c)
 437
 438 Returns the default path prefix for :PathPrefix, :Local, :LocalRegex and
 439 relative :Path actions in this component. Defaults to the action_namespace or
 440 can be overridden from the "path" config key.
 441
 442 =head2 $self->register_actions($c)
 443
 444 Finds all applicable actions for this component, creates
 445 Catalyst::Action objects (using $self->create_action) for them and
 446 registers them with $c->dispatcher.
 447
 448 =head2 $self->get_action_methods()
 449
 450 Returns a list of L<Moose::Meta::Method> objects, doing the
 451 L<MooseX::MethodAttributes::Role::Meta::Method> role, which are the set of
 452 action methods for this package.
 453
 454 =head2 $self->register_action_methods($c, @methods)
 455
 456 Creates action objects for a set of action methods using C< create_action >,
 457 and registers them with the dispatcher.
 458
 459 =head2 $self->create_action(%args)
 460
 461 Called with a hash of data to be use for construction of a new
 462 Catalyst::Action (or appropriate sub/alternative class) object.
 463
 464 =head2 $self->_application
 465
 466 =head2 $self->_app
 467
 468 Returns the application instance stored by C<new()>
 469
 470 =head1 AUTHORS
 471
 472 Catalyst Contributors, see Catalyst.pm
 473
 474 =head1 COPYRIGHT
 475
 476 This program is free software, you can redistribute it and/or modify
 477 it under the same terms as Perl itself.
 478
 479 =cut