lib/Catalyst/Controller.pm

   1 package Catalyst::Controller;
   2
   3 use Moose;
   4 use Moose::Util qw/find_meta/;
   5
   6 use namespace::clean -except => 'meta';
   7
   8 BEGIN { extends qw/Catalyst::Component MooseX::MethodAttributes::Inheritable/; }
   9
  10 use MooseX::MethodAttributes;
  11 use Catalyst::Exception;
  12 use Catalyst::Utils;
  13
  14 with 'Catalyst::Component::ApplicationAttribute';
  15
  16 has path_prefix =>
  17     (
  18      is => 'rw',
  19      isa => 'Str',
  20      init_arg => 'path',
  21      predicate => 'has_path_prefix',
  22     );
  23
  24 has action_namespace =>
  25     (
  26      is => 'rw',
  27      isa => 'Str',
  28      init_arg => 'namespace',
  29      predicate => 'has_action_namespace',
  30     );
  31
  32 has actions =>
  33     (
  34      accessor => '_controller_actions',
  35      isa => 'HashRef',
  36      init_arg => undef,
  37     );
  38
  39 sub BUILD {
  40     my ($self, $args) = @_;
  41     my $action  = delete $args->{action}  || {};
  42     my $actions = delete $args->{actions} || {};
  43     my $attr_value = $self->merge_config_hashes($actions, $action);
  44     $self->_controller_actions($attr_value);
  45 }
  46
  47
  48
  49 =head1 NAME
  50
  51 Catalyst::Controller - Catalyst Controller base class
  52
  53 =head1 SYNOPSIS
  54
  55   package MyApp::Controller::Search
  56   use base qw/Catalyst::Controller/;
  57
  58   sub foo : Local {
  59     my ($self,$c,@args) = @_;
  60     ...
  61   } # Dispatches to /search/foo
  62
  63 =head1 DESCRIPTION
  64
  65 Controllers are where the actions in the Catalyst framework
  66 reside. Each action is represented by a function with an attribute to
  67 identify what kind of action it is. See the L<Catalyst::Dispatcher>
  68 for more info about how Catalyst dispatches to actions.
  69
  70 =cut
  71
  72 #I think both of these could be attributes. doesn't really seem like they need
  73 #to ble class data. i think that attributes +default would work just fine
  74 __PACKAGE__->mk_classdata($_) for qw/_dispatch_steps _action_class/;
  75
  76 __PACKAGE__->_dispatch_steps( [qw/_BEGIN _AUTO _ACTION/] );
  77 __PACKAGE__->_action_class('Catalyst::Action');
  78
  79
  80 sub _DISPATCH : Private {
  81     my ( $self, $c ) = @_;
  82
  83     foreach my $disp ( @{ $self->_dispatch_steps } ) {
  84         last unless $c->forward($disp);
  85     }
  86
  87     $c->forward('_END');
  88 }
  89
  90 sub _BEGIN : Private {
  91     my ( $self, $c ) = @_;
  92     my $begin = ( $c->get_actions( 'begin', $c->namespace ) )[-1];
  93     return 1 unless $begin;
  94     $begin->dispatch( $c );
  95     return !@{ $c->error };
  96 }
  97
  98 sub _AUTO : Private {
  99     my ( $self, $c ) = @_;
 100     my @auto = $c->get_actions( 'auto', $c->namespace );
 101     foreach my $auto (@auto) {
 102         $auto->dispatch( $c );
 103         return 0 unless $c->state;
 104     }
 105     return 1;
 106 }
 107
 108 sub _ACTION : Private {
 109     my ( $self, $c ) = @_;
 110     if (   ref $c->action
 111         && $c->action->can('execute')
 112         && defined $c->req->action )
 113     {
 114         $c->action->dispatch( $c );
 115     }
 116     return !@{ $c->error };
 117 }
 118
 119 sub _END : Private {
 120     my ( $self, $c ) = @_;
 121     my $end = ( $c->get_actions( 'end', $c->namespace ) )[-1];
 122     return 1 unless $end;
 123     $end->dispatch( $c );
 124     return !@{ $c->error };
 125 }
 126
 127 sub action_for {
 128     my ( $self, $name ) = @_;
 129     my $app = ($self->isa('Catalyst') ? $self : $self->_application);
 130     return $app->dispatcher->get_action($name, $self->action_namespace);
 131 }
 132
 133 #my opinion is that this whole sub really should be a builder method, not
 134 #something that happens on every call. Anyone else disagree?? -- groditi
 135 ## -- apparently this is all just waiting for app/ctx split
 136 around action_namespace => sub {
 137     my $orig = shift;
 138     my ( $self, $c ) = @_;
 139
 140     my $class = ref($self) || $self;
 141     my $appclass = ref($c) || $c;
 142     if( ref($self) ){
 143         return $self->$orig if $self->has_action_namespace;
 144     } else {
 145         return $class->config->{namespace} if exists $class->config->{namespace};
 146     }
 147
 148     my $case_s;
 149     if( $c ){
 150         $case_s = $appclass->config->{case_sensitive};
 151     } else {
 152         if ($self->isa('Catalyst')) {
 153             $case_s = $class->config->{case_sensitive};
 154         } else {
 155             if (ref $self) {
 156                 $case_s = ref($self->_application)->config->{case_sensitive};
 157             } else {
 158                 confess("Can't figure out case_sensitive setting");
 159             }
 160         }
 161     }
 162
 163     my $namespace = Catalyst::Utils::class2prefix($self->catalyst_component_name, $case_s) || '';
 164     $self->$orig($namespace) if ref($self);
 165     return $namespace;
 166 };
 167
 168 #Once again, this is probably better written as a builder method
 169 around path_prefix => sub {
 170     my $orig = shift;
 171     my $self = shift;
 172     if( ref($self) ){
 173       return $self->$orig if $self->has_path_prefix;
 174     } else {
 175       return $self->config->{path} if exists $self->config->{path};
 176     }
 177     my $namespace = $self->action_namespace(@_);
 178     $self->$orig($namespace) if ref($self);
 179     return $namespace;
 180 };
 181
 182 sub get_action_methods {
 183     my $self = shift;
 184     my $meta = find_meta($self) || confess("No metaclass setup for $self");
 185     confess("Metaclass "
 186           . ref($meta) . " for "
 187           . $meta->name
 188           . " cannot support register_actions." )
 189       unless $meta->can('get_nearest_methods_with_attributes');
 190
 191     # Find (and de-dup) action methods from attributes and those from config.
 192     my %methods = (
 193         map({ $_->name => 1 } $meta->get_nearest_methods_with_attributes),
 194         %{ $self->_controller_actions }
 195     );
 196
 197     if (ref $self) {
 198         foreach (keys %methods) {
 199             $meta->find_method_by_name($_)
 200               || confess( 'Action "'
 201                   . $_
 202                   . '" is not available from controller '
 203                   . ( ref $self ) );
 204         }
 205     }
 206     return keys %methods;
 207 }
 208
 209
 210 sub register_actions {
 211     my ( $self, $c ) = @_;
 212     $self->register_action_methods( $c, $self->get_action_methods );
 213 }
 214
 215 sub register_action_methods {
 216     my ( $self, $c, @methods ) = @_;
 217     my $class = $self->catalyst_component_name;
 218     #this is still not correct for some reason.
 219     my $namespace = $self->action_namespace($c);
 220
 221     # Uncomment as soon as you fix the tests :)
 222     #if (!blessed($self) && $self eq $c && scalar(@methods)) {
 223     #    $c->log->warn("Action methods found defined in your application class, $self. This is deprecated, please move them into a Root controller.");
 224     #}
 225
 226     foreach my $method (@methods) {
 227         my $name = $method->name;
 228         my $attributes = $method->attributes;
 229         my $attrs = $self->_parse_attrs( $c, $name, @{ $attributes } );
 230         if ( $attrs->{Private} && ( keys %$attrs > 1 ) ) {
 231             $c->log->debug( 'Bad action definition "'
 232                   . join( ' ', @{ $attributes } )
 233                   . qq/" for "$class->$name"/ )
 234               if $c->debug;
 235             next;
 236         }
 237         my $reverse = $namespace ? "${namespace}/${name}" : $name;
 238         my $action = $self->create_action(
 239             name       => $name,
 240             code       => $method->body,
 241             reverse    => $reverse,
 242             namespace  => $namespace,
 243             class      => $class,
 244             attributes => $attrs,
 245         );
 246
 247         $c->dispatcher->register( $c, $action );
 248     }
 249 }
 250
 251 sub create_action {
 252     my $self = shift;
 253     my %args = @_;
 254
 255     my $class = (exists $args{attributes}{ActionClass}
 256                     ? $args{attributes}{ActionClass}[0]
 257                     : $self->_action_class);
 258
 259     Class::MOP::load_class($class);
 260     return $class->new( \%args );
 261 }
 262
 263 sub _parse_attrs {
 264     my ( $self, $c, $name, @attrs ) = @_;
 265
 266     my %raw_attributes;
 267
 268     foreach my $attr (@attrs) {
 269
 270         # Parse out :Foo(bar) into Foo => bar etc (and arrayify)
 271
 272         if ( my ( $key, $value ) = ( $attr =~ /^(.*?)(?:\(\s*(.+?)\s*\))?$/ ) )
 273         {
 274
 275             if ( defined $value ) {
 276                 ( $value =~ s/^'(.*)'$/$1/ ) || ( $value =~ s/^"(.*)"/$1/ );
 277             }
 278             push( @{ $raw_attributes{$key} }, $value );
 279         }
 280     }
 281
 282     #I know that the original behavior was to ignore action if actions was set
 283     # but i actually think this may be a little more sane? we can always remove
 284     # the merge behavior quite easily and go back to having actions have
 285     # presedence over action by modifying the keys. i honestly think this is
 286     # superior while mantaining really high degree of compat
 287     my $actions;
 288     if( ref($self) ) {
 289         $actions = $self->_controller_actions;
 290     } else {
 291         my $cfg = $self->config;
 292         $actions = $self->merge_config_hashes($cfg->{actions}, $cfg->{action});
 293     }
 294
 295     %raw_attributes = ((exists $actions->{'*'} ? %{$actions->{'*'}} : ()),
 296                        %raw_attributes,
 297                        (exists $actions->{$name} ? %{$actions->{$name}} : ()));
 298
 299
 300     my %final_attributes;
 301
 302     foreach my $key (keys %raw_attributes) {
 303
 304         my $raw = $raw_attributes{$key};
 305
 306         foreach my $value (ref($raw) eq 'ARRAY' ? @$raw : $raw) {
 307
 308             my $meth = "_parse_${key}_attr";
 309             if ( my $code = $self->can($meth) ) {
 310                 ( $key, $value ) = $self->$code( $c, $name, $value );
 311             }
 312             push( @{ $final_attributes{$key} }, $value );
 313         }
 314     }
 315
 316     return \%final_attributes;
 317 }
 318
 319 sub _parse_Global_attr {
 320     my ( $self, $c, $name, $value ) = @_;
 321     return $self->_parse_Path_attr( $c, $name, "/$name" );
 322 }
 323
 324 sub _parse_Absolute_attr { shift->_parse_Global_attr(@_); }
 325
 326 sub _parse_Local_attr {
 327     my ( $self, $c, $name, $value ) = @_;
 328     return $self->_parse_Path_attr( $c, $name, $name );
 329 }
 330
 331 sub _parse_Relative_attr { shift->_parse_Local_attr(@_); }
 332
 333 sub _parse_Path_attr {
 334     my ( $self, $c, $name, $value ) = @_;
 335     $value = '' if !defined $value;
 336     if ( $value =~ m!^/! ) {
 337         return ( 'Path', $value );
 338     }
 339     elsif ( length $value ) {
 340         return ( 'Path', join( '/', $self->path_prefix($c), $value ) );
 341     }
 342     else {
 343         return ( 'Path', $self->path_prefix($c) );
 344     }
 345 }
 346
 347 sub _parse_Regex_attr {
 348     my ( $self, $c, $name, $value ) = @_;
 349     return ( 'Regex', $value );
 350 }
 351
 352 sub _parse_Regexp_attr { shift->_parse_Regex_attr(@_); }
 353
 354 sub _parse_LocalRegex_attr {
 355     my ( $self, $c, $name, $value ) = @_;
 356     unless ( $value =~ s/^\^// ) { $value = "(?:.*?)$value"; }
 357
 358     my $prefix = $self->path_prefix( $c );
 359     $prefix .= '/' if length( $prefix );
 360
 361     return ( 'Regex', "^${prefix}${value}" );
 362 }
 363
 364 sub _parse_LocalRegexp_attr { shift->_parse_LocalRegex_attr(@_); }
 365
 366 sub _parse_Chained_attr {
 367     my ($self, $c, $name, $value) = @_;
 368
 369     if (defined($value) && length($value)) {
 370         if ($value eq '.') {
 371             $value = '/'.$self->action_namespace($c);
 372         } elsif (my ($rel, $rest) = $value =~ /^((?:\.{2}\/)+)(.*)$/) {
 373             my @parts = split '/', $self->action_namespace($c);
 374             my @levels = split '/', $rel;
 375
 376             $value = '/'.join('/', @parts[0 .. $#parts - @levels], $rest);
 377         } elsif ($value !~ m/^\//) {
 378             my $action_ns = $self->action_namespace($c);
 379
 380             if ($action_ns) {
 381                 $value = '/'.join('/', $action_ns, $value);
 382             } else {
 383                 $value = '/'.$value; # special case namespace '' (root)
 384             }
 385         }
 386     } else {
 387         $value = '/'
 388     }
 389
 390     return Chained => $value;
 391 }
 392
 393 sub _parse_ChainedParent_attr {
 394     my ($self, $c, $name, $value) = @_;
 395     return $self->_parse_Chained_attr($c, $name, '../'.$name);
 396 }
 397
 398 sub _parse_PathPrefix_attr {
 399     my ( $self, $c ) = @_;
 400     return PathPart => $self->path_prefix($c);
 401 }
 402
 403 sub _parse_ActionClass_attr {
 404     my ( $self, $c, $name, $value ) = @_;
 405     my $appname = $self->_application;
 406     $value = Catalyst::Utils::resolve_namespace($appname . '::Action', $self->_action_class, $value);
 407     return ( 'ActionClass', $value );
 408 }
 409
 410 sub _parse_MyAction_attr {
 411     my ( $self, $c, $name, $value ) = @_;
 412
 413     my $appclass = Catalyst::Utils::class2appclass($self);
 414     $value = "${appclass}::Action::${value}";
 415
 416     return ( 'ActionClass', $value );
 417 }
 418
 419 __PACKAGE__->meta->make_immutable;
 420
 421 1;
 422
 423 __END__
 424
 425 =head1 CONFIGURATION
 426
 427 Like any other L<Catalyst::Component>, controllers have a config hash,
 428 accessible through $self->config from the controller actions.  Some
 429 settings are in use by the Catalyst framework:
 430
 431 =head2 namespace
 432
 433 This specifies the internal namespace the controller should be bound
 434 to. By default the controller is bound to the URI version of the
 435 controller name. For instance controller 'MyApp::Controller::Foo::Bar'
 436 will be bound to 'foo/bar'. The default Root controller is an example
 437 of setting namespace to '' (the null string).
 438
 439 =head2 path
 440
 441 Sets 'path_prefix', as described below.
 442
 443 =head1 METHODS
 444
 445 =head2 BUILDARGS ($app, @args)
 446
 447 From L<Catalyst::Component::ApplicationAttribute>, stashes the application
 448 instance as $self->_application.
 449
 450 =head2 $self->action_for('name')
 451
 452 Returns the Catalyst::Action object (if any) for a given method name
 453 in this component.
 454
 455 =head2 $self->action_namespace($c)
 456
 457 Returns the private namespace for actions in this component. Defaults
 458 to a value from the controller name (for
 459 e.g. MyApp::Controller::Foo::Bar becomes "foo/bar") or can be
 460 overridden from the "namespace" config key.
 461
 462
 463 =head2 $self->path_prefix($c)
 464
 465 Returns the default path prefix for :PathPrefix, :Local, :LocalRegex and
 466 relative :Path actions in this component. Defaults to the action_namespace or
 467 can be overridden from the "path" config key.
 468
 469 =head2 $self->register_actions($c)
 470
 471 Finds all applicable actions for this component, creates
 472 Catalyst::Action objects (using $self->create_action) for them and
 473 registers them with $c->dispatcher.
 474
 475 =head2 $self->get_action_methods()
 476
 477 Returns a list of L<Moose::Meta::Method> objects, doing the
 478 L<MooseX::MethodAttributes::Role::Meta::Method> role, which are the set of
 479 action methods for this package.
 480
 481 =head2 $self->register_action_methods($c, @methods)
 482
 483 Creates action objects for a set of action methods using C< create_action >,
 484 and registers them with the dispatcher.
 485
 486 =head2 $self->create_action(%args)
 487
 488 Called with a hash of data to be use for construction of a new
 489 Catalyst::Action (or appropriate sub/alternative class) object.
 490
 491 =head2 $self->_application
 492
 493 =head2 $self->_app
 494
 495 Returns the application instance stored by C<new()>
 496
 497 =head1 AUTHORS
 498
 499 Catalyst Contributors, see Catalyst.pm
 500
 501 =head1 COPYRIGHT
 502
 503 This library is free software. You can redistribute it and/or modify
 504 it under the same terms as Perl itself.
 505
 506 =cut