lib/Catalyst/Controller.pm

   1 package Catalyst::Controller;
   2
   3 use Moose;
   4 use Moose::Util qw/find_meta/;
   5 use List::MoreUtils qw/uniq/;
   6 use namespace::clean -except => 'meta';
   7
   8 BEGIN { extends qw/Catalyst::Component MooseX::MethodAttributes::Inheritable/; }
   9
  10 use MooseX::MethodAttributes;
  11 use Catalyst::Exception;
  12 use Catalyst::Utils;
  13
  14 with 'Catalyst::Component::ApplicationAttribute';
  15
  16 has path_prefix =>
  17     (
  18      is => 'rw',
  19      isa => 'Str',
  20      init_arg => 'path',
  21      predicate => 'has_path_prefix',
  22     );
  23
  24 has action_namespace =>
  25     (
  26      is => 'rw',
  27      isa => 'Str',
  28      init_arg => 'namespace',
  29      predicate => 'has_action_namespace',
  30     );
  31
  32 has actions =>
  33     (
  34      accessor => '_controller_actions',
  35      isa => 'HashRef',
  36      init_arg => undef,
  37     );
  38
  39 sub BUILD {
  40     my ($self, $args) = @_;
  41     my $action  = delete $args->{action}  || {};
  42     my $actions = delete $args->{actions} || {};
  43     my $attr_value = $self->merge_config_hashes($actions, $action);
  44     $self->_controller_actions($attr_value);
  45 }
  46
  47
  48
  49 =head1 NAME
  50
  51 Catalyst::Controller - Catalyst Controller base class
  52
  53 =head1 SYNOPSIS
  54
  55   package MyApp::Controller::Search
  56   use base qw/Catalyst::Controller/;
  57
  58   sub foo : Local {
  59     my ($self,$c,@args) = @_;
  60     ...
  61   } # Dispatches to /search/foo
  62
  63 =head1 DESCRIPTION
  64
  65 Controllers are where the actions in the Catalyst framework
  66 reside. Each action is represented by a function with an attribute to
  67 identify what kind of action it is. See the L<Catalyst::Dispatcher>
  68 for more info about how Catalyst dispatches to actions.
  69
  70 =cut
  71
  72 #I think both of these could be attributes. doesn't really seem like they need
  73 #to ble class data. i think that attributes +default would work just fine
  74 __PACKAGE__->mk_classdata($_) for qw/_dispatch_steps _action_class/;
  75
  76 __PACKAGE__->_dispatch_steps( [qw/_BEGIN _AUTO _ACTION/] );
  77 __PACKAGE__->_action_class('Catalyst::Action');
  78
  79
  80 sub _DISPATCH : Private {
  81     my ( $self, $c ) = @_;
  82
  83     foreach my $disp ( @{ $self->_dispatch_steps } ) {
  84         last unless $c->forward($disp);
  85     }
  86
  87     $c->forward('_END');
  88 }
  89
  90 sub _BEGIN : Private {
  91     my ( $self, $c ) = @_;
  92     my $begin = ( $c->get_actions( 'begin', $c->namespace ) )[-1];
  93     return 1 unless $begin;
  94     $begin->dispatch( $c );
  95     return !@{ $c->error };
  96 }
  97
  98 sub _AUTO : Private {
  99     my ( $self, $c ) = @_;
 100     my @auto = $c->get_actions( 'auto', $c->namespace );
 101     foreach my $auto (@auto) {
 102         $auto->dispatch( $c );
 103         return 0 unless $c->state;
 104     }
 105     return 1;
 106 }
 107
 108 sub _ACTION : Private {
 109     my ( $self, $c ) = @_;
 110     if (   ref $c->action
 111         && $c->action->can('execute')
 112         && defined $c->req->action )
 113     {
 114         $c->action->dispatch( $c );
 115     }
 116     return !@{ $c->error };
 117 }
 118
 119 sub _END : Private {
 120     my ( $self, $c ) = @_;
 121     my $end = ( $c->get_actions( 'end', $c->namespace ) )[-1];
 122     return 1 unless $end;
 123     $end->dispatch( $c );
 124     return !@{ $c->error };
 125 }
 126
 127 sub action_for {
 128     my ( $self, $name ) = @_;
 129     my $app = ($self->isa('Catalyst') ? $self : $self->_application);
 130     return $app->dispatcher->get_action($name, $self->action_namespace);
 131 }
 132
 133 #my opinion is that this whole sub really should be a builder method, not
 134 #something that happens on every call. Anyone else disagree?? -- groditi
 135 ## -- apparently this is all just waiting for app/ctx split
 136 around action_namespace => sub {
 137     my $orig = shift;
 138     my ( $self, $c ) = @_;
 139
 140     my $class = ref($self) || $self;
 141     my $appclass = ref($c) || $c;
 142     if( ref($self) ){
 143         return $self->$orig if $self->has_action_namespace;
 144     } else {
 145         return $class->config->{namespace} if exists $class->config->{namespace};
 146     }
 147
 148     my $case_s;
 149     if( $c ){
 150         $case_s = $appclass->config->{case_sensitive};
 151     } else {
 152         if ($self->isa('Catalyst')) {
 153             $case_s = $class->config->{case_sensitive};
 154         } else {
 155             if (ref $self) {
 156                 $case_s = ref($self->_application)->config->{case_sensitive};
 157             } else {
 158                 confess("Can't figure out case_sensitive setting");
 159             }
 160         }
 161     }
 162
 163     my $namespace = Catalyst::Utils::class2prefix($self->catalyst_component_name, $case_s) || '';
 164     $self->$orig($namespace) if ref($self);
 165     return $namespace;
 166 };
 167
 168 #Once again, this is probably better written as a builder method
 169 around path_prefix => sub {
 170     my $orig = shift;
 171     my $self = shift;
 172     if( ref($self) ){
 173       return $self->$orig if $self->has_path_prefix;
 174     } else {
 175       return $self->config->{path} if exists $self->config->{path};
 176     }
 177     my $namespace = $self->action_namespace(@_);
 178     $self->$orig($namespace) if ref($self);
 179     return $namespace;
 180 };
 181
 182 sub get_action_methods {
 183     my $self = shift;
 184     my $meta = find_meta($self) || confess("No metaclass setup for $self");
 185     confess("Metaclass "
 186           . ref($meta) . " for "
 187           . $meta->name
 188           . " cannot support register_actions." )
 189       unless $meta->can('get_nearest_methods_with_attributes');
 190     my @methods = $meta->get_nearest_methods_with_attributes;
 191
 192     # actions specified via config are also action_methods
 193     push(
 194         @methods,
 195         map {
 196             $meta->find_method_by_name($_)
 197               || confess( 'Action "'
 198                   . $_
 199                   . '" is not available from controller '
 200                   . ( ref $self ) )
 201           } keys %{ $self->_controller_actions }
 202     ) if ( ref $self );
 203     return uniq @methods;
 204 }
 205
 206
 207 sub register_actions {
 208     my ( $self, $c ) = @_;
 209     $self->register_action_methods( $c, $self->get_action_methods );
 210 }
 211
 212 sub register_action_methods {
 213     my ( $self, $c, @methods ) = @_;
 214     my $class = $self->catalyst_component_name;
 215     #this is still not correct for some reason.
 216     my $namespace = $self->action_namespace($c);
 217
 218     # FIXME - fugly
 219     if (!blessed($self) && $self eq $c && scalar(@methods)) {
 220         my @really_bad_methods = grep { ! /^_(DISPATCH|BEGIN|AUTO|ACTION|END)$/ } map { $_->name } @methods;
 221         if (scalar(@really_bad_methods)) {
 222             $c->log->warn("Action methods (" . join(', ', @really_bad_methods) . ") found defined in your application class, $self. This is deprecated, please move them into a Root controller.");
 223         }
 224     }
 225
 226     foreach my $method (@methods) {
 227         my $name = $method->name;
 228         my $attributes = $method->attributes;
 229         my $attrs = $self->_parse_attrs( $c, $name, @{ $attributes } );
 230         if ( $attrs->{Private} && ( keys %$attrs > 1 ) ) {
 231             $c->log->debug( 'Bad action definition "'
 232                   . join( ' ', @{ $attributes } )
 233                   . qq/" for "$class->$name"/ )
 234               if $c->debug;
 235             next;
 236         }
 237         my $reverse = $namespace ? "${namespace}/${name}" : $name;
 238         my $action = $self->create_action(
 239             name       => $name,
 240             code       => $method->body,
 241             reverse    => $reverse,
 242             namespace  => $namespace,
 243             class      => $class,
 244             attributes => $attrs,
 245         );
 246
 247         $c->dispatcher->register( $c, $action );
 248     }
 249 }
 250
 251 sub create_action {
 252     my $self = shift;
 253     my %args = @_;
 254
 255     my $class = (exists $args{attributes}{ActionClass}
 256                     ? $args{attributes}{ActionClass}[0]
 257                     : $self->_action_class);
 258     Class::MOP::load_class($class);
 259
 260     my $action_args = $self->config->{action_args};
 261     my %extra_args = (
 262         %{ $action_args->{'*'}           || {} },
 263         %{ $action_args->{ $args{name} } || {} },
 264     );
 265
 266     return $class->new({ %extra_args, %args });
 267 }
 268
 269 sub _parse_attrs {
 270     my ( $self, $c, $name, @attrs ) = @_;
 271
 272     my %raw_attributes;
 273
 274     foreach my $attr (@attrs) {
 275
 276         # Parse out :Foo(bar) into Foo => bar etc (and arrayify)
 277
 278         if ( my ( $key, $value ) = ( $attr =~ /^(.*?)(?:\(\s*(.+?)\s*\))?$/ ) )
 279         {
 280
 281             if ( defined $value ) {
 282                 ( $value =~ s/^'(.*)'$/$1/ ) || ( $value =~ s/^"(.*)"/$1/ );
 283             }
 284             push( @{ $raw_attributes{$key} }, $value );
 285         }
 286     }
 287
 288     #I know that the original behavior was to ignore action if actions was set
 289     # but i actually think this may be a little more sane? we can always remove
 290     # the merge behavior quite easily and go back to having actions have
 291     # presedence over action by modifying the keys. i honestly think this is
 292     # superior while mantaining really high degree of compat
 293     my $actions;
 294     if( ref($self) ) {
 295         $actions = $self->_controller_actions;
 296     } else {
 297         my $cfg = $self->config;
 298         $actions = $self->merge_config_hashes($cfg->{actions}, $cfg->{action});
 299     }
 300
 301     %raw_attributes = ((exists $actions->{'*'} ? %{$actions->{'*'}} : ()),
 302                        %raw_attributes,
 303                        (exists $actions->{$name} ? %{$actions->{$name}} : ()));
 304
 305
 306     my %final_attributes;
 307
 308     foreach my $key (keys %raw_attributes) {
 309
 310         my $raw = $raw_attributes{$key};
 311
 312         foreach my $value (ref($raw) eq 'ARRAY' ? @$raw : $raw) {
 313
 314             my $meth = "_parse_${key}_attr";
 315             if ( my $code = $self->can($meth) ) {
 316                 ( $key, $value ) = $self->$code( $c, $name, $value );
 317             }
 318             push( @{ $final_attributes{$key} }, $value );
 319         }
 320     }
 321
 322     return \%final_attributes;
 323 }
 324
 325 sub _parse_Global_attr {
 326     my ( $self, $c, $name, $value ) = @_;
 327     return $self->_parse_Path_attr( $c, $name, "/$name" );
 328 }
 329
 330 sub _parse_Absolute_attr { shift->_parse_Global_attr(@_); }
 331
 332 sub _parse_Local_attr {
 333     my ( $self, $c, $name, $value ) = @_;
 334     return $self->_parse_Path_attr( $c, $name, $name );
 335 }
 336
 337 sub _parse_Relative_attr { shift->_parse_Local_attr(@_); }
 338
 339 sub _parse_Path_attr {
 340     my ( $self, $c, $name, $value ) = @_;
 341     $value = '' if !defined $value;
 342     if ( $value =~ m!^/! ) {
 343         return ( 'Path', $value );
 344     }
 345     elsif ( length $value ) {
 346         return ( 'Path', join( '/', $self->path_prefix($c), $value ) );
 347     }
 348     else {
 349         return ( 'Path', $self->path_prefix($c) );
 350     }
 351 }
 352
 353 sub _parse_Regex_attr {
 354     my ( $self, $c, $name, $value ) = @_;
 355     return ( 'Regex', $value );
 356 }
 357
 358 sub _parse_Regexp_attr { shift->_parse_Regex_attr(@_); }
 359
 360 sub _parse_LocalRegex_attr {
 361     my ( $self, $c, $name, $value ) = @_;
 362     unless ( $value =~ s/^\^// ) { $value = "(?:.*?)$value"; }
 363
 364     my $prefix = $self->path_prefix( $c );
 365     $prefix .= '/' if length( $prefix );
 366
 367     return ( 'Regex', "^${prefix}${value}" );
 368 }
 369
 370 sub _parse_LocalRegexp_attr { shift->_parse_LocalRegex_attr(@_); }
 371
 372 sub _parse_Chained_attr {
 373     my ($self, $c, $name, $value) = @_;
 374
 375     if (defined($value) && length($value)) {
 376         if ($value eq '.') {
 377             $value = '/'.$self->action_namespace($c);
 378         } elsif (my ($rel, $rest) = $value =~ /^((?:\.{2}\/)+)(.*)$/) {
 379             my @parts = split '/', $self->action_namespace($c);
 380             my @levels = split '/', $rel;
 381
 382             $value = '/'.join('/', @parts[0 .. $#parts - @levels], $rest);
 383         } elsif ($value !~ m/^\//) {
 384             my $action_ns = $self->action_namespace($c);
 385
 386             if ($action_ns) {
 387                 $value = '/'.join('/', $action_ns, $value);
 388             } else {
 389                 $value = '/'.$value; # special case namespace '' (root)
 390             }
 391         }
 392     } else {
 393         $value = '/'
 394     }
 395
 396     return Chained => $value;
 397 }
 398
 399 sub _parse_ChainedParent_attr {
 400     my ($self, $c, $name, $value) = @_;
 401     return $self->_parse_Chained_attr($c, $name, '../'.$name);
 402 }
 403
 404 sub _parse_PathPrefix_attr {
 405     my ( $self, $c ) = @_;
 406     return PathPart => $self->path_prefix($c);
 407 }
 408
 409 sub _parse_ActionClass_attr {
 410     my ( $self, $c, $name, $value ) = @_;
 411     my $appname = $self->_application;
 412     $value = Catalyst::Utils::resolve_namespace($appname . '::Action', $self->_action_class, $value);
 413     return ( 'ActionClass', $value );
 414 }
 415
 416 sub _parse_MyAction_attr {
 417     my ( $self, $c, $name, $value ) = @_;
 418
 419     my $appclass = Catalyst::Utils::class2appclass($self);
 420     $value = "${appclass}::Action::${value}";
 421
 422     return ( 'ActionClass', $value );
 423 }
 424
 425 __PACKAGE__->meta->make_immutable;
 426
 427 1;
 428
 429 __END__
 430
 431 =head1 CONFIGURATION
 432
 433 Like any other L<Catalyst::Component>, controllers have a config hash,
 434 accessible through $self->config from the controller actions.  Some
 435 settings are in use by the Catalyst framework:
 436
 437 =head2 namespace
 438
 439 This specifies the internal namespace the controller should be bound
 440 to. By default the controller is bound to the URI version of the
 441 controller name. For instance controller 'MyApp::Controller::Foo::Bar'
 442 will be bound to 'foo/bar'. The default Root controller is an example
 443 of setting namespace to '' (the null string).
 444
 445 =head2 path
 446
 447 Sets 'path_prefix', as described below.
 448
 449 =head2 action
 450
 451 Allows you to set the attributes that the dispatcher creates actions out of.
 452 This allows you to do 'rails style routes', or override some of the
 453 attribute defintions of actions composed from Roles.
 454 You can set arguments globally (for all actions of the controller) and
 455 specifically (for a single action).
 456
 457     __PACKAGE__->config(
 458         action => {
 459             '*' => { Chained => 'base', Args => 0  },
 460             base => { Chained => '/', PathPart => '', CaptureArgs => 0 },
 461         },
 462      );
 463
 464 In the case above every sub in the package would be made into a Chain
 465 endpoint with a URI the same as the sub name for each sub, chained
 466 to the sub named C<base>. Ergo dispatch to C</example> would call the
 467 C<base> method, then the C<example> method.
 468
 469 =head2 action_args
 470
 471 Allows you to set constructor arguments on your actions. You can set arguments
 472 globally and specifically (as above).
 473 This is particularly useful when using C<ActionRole>s
 474 (L<Catalyst::Controller::ActionRole>) and custom C<ActionClass>es.
 475
 476     __PACKAGE__->config(
 477         action_args => {
 478             '*' => { globalarg1 => 'hello', globalarg2 => 'goodbye' },
 479             'specific_action' => { customarg => 'arg1' },
 480         },
 481      );
 482
 483 In the case above the action class associated with C<specific_action> would get
 484 passed the following arguments, in addition to the normal action constructor
 485 arguments, when it is instantiated:
 486
 487   (globalarg1 => 'hello', globalarg2 => 'goodbye', customarg => 'arg1')
 488
 489 =head1 METHODS
 490
 491 =head2 BUILDARGS ($app, @args)
 492
 493 From L<Catalyst::Component::ApplicationAttribute>, stashes the application
 494 instance as $self->_application.
 495
 496 =head2 $self->action_for('name')
 497
 498 Returns the Catalyst::Action object (if any) for a given method name
 499 in this component.
 500
 501 =head2 $self->action_namespace($c)
 502
 503 Returns the private namespace for actions in this component. Defaults
 504 to a value from the controller name (for
 505 e.g. MyApp::Controller::Foo::Bar becomes "foo/bar") or can be
 506 overridden from the "namespace" config key.
 507
 508
 509 =head2 $self->path_prefix($c)
 510
 511 Returns the default path prefix for :PathPrefix, :Local, :LocalRegex and
 512 relative :Path actions in this component. Defaults to the action_namespace or
 513 can be overridden from the "path" config key.
 514
 515 =head2 $self->register_actions($c)
 516
 517 Finds all applicable actions for this component, creates
 518 Catalyst::Action objects (using $self->create_action) for them and
 519 registers them with $c->dispatcher.
 520
 521 =head2 $self->get_action_methods()
 522
 523 Returns a list of L<Moose::Meta::Method> objects, doing the
 524 L<MooseX::MethodAttributes::Role::Meta::Method> role, which are the set of
 525 action methods for this package.
 526
 527 =head2 $self->register_action_methods($c, @methods)
 528
 529 Creates action objects for a set of action methods using C< create_action >,
 530 and registers them with the dispatcher.
 531
 532 =head2 $self->create_action(%args)
 533
 534 Called with a hash of data to be use for construction of a new
 535 Catalyst::Action (or appropriate sub/alternative class) object.
 536
 537 =head2 $self->_application
 538
 539 =head2 $self->_app
 540
 541 Returns the application instance stored by C<new()>
 542
 543 =head1 AUTHORS
 544
 545 Catalyst Contributors, see Catalyst.pm
 546
 547 =head1 COPYRIGHT
 548
 549 This library is free software. You can redistribute it and/or modify
 550 it under the same terms as Perl itself.
 551
 552 =cut