lib/Catalyst/Controller.pm

   1 package Catalyst::Controller;
   2
   3 use Moose;
   4 use Moose::Util qw/find_meta/;
   5
   6 use namespace::clean -except => 'meta';
   7
   8 BEGIN { extends qw/Catalyst::Component MooseX::MethodAttributes::Inheritable/; }
   9
  10 use MooseX::MethodAttributes;
  11 use Catalyst::Exception;
  12 use Catalyst::Utils;
  13
  14 with 'Catalyst::Component::ApplicationAttribute';
  15
  16 has path_prefix =>
  17     (
  18      is => 'rw',
  19      isa => 'Str',
  20      init_arg => 'path',
  21      predicate => 'has_path_prefix',
  22     );
  23
  24 has action_namespace =>
  25     (
  26      is => 'rw',
  27      isa => 'Str',
  28      init_arg => 'namespace',
  29      predicate => 'has_action_namespace',
  30     );
  31
  32 has _controller_actions =>
  33     (
  34      is => 'rw',
  35      isa => 'HashRef',
  36      init_arg => undef,
  37     );
  38
  39 sub BUILD {
  40     my ($self, $args) = @_;
  41     my $action  = delete $args->{action}  || {};
  42     my $actions = delete $args->{actions} || {};
  43     my $attr_value = $self->merge_config_hashes($actions, $action);
  44     $self->_controller_actions($attr_value);
  45 }
  46
  47 =head1 NAME
  48
  49 Catalyst::Controller - Catalyst Controller base class
  50
  51 =head1 SYNOPSIS
  52
  53   package MyApp::Controller::Search
  54   use base qw/Catalyst::Controller/;
  55
  56   sub foo : Local {
  57     my ($self,$c,@args) = @_;
  58     ...
  59   } # Dispatches to /search/foo
  60
  61 =head1 DESCRIPTION
  62
  63 Controllers are where the actions in the Catalyst framework
  64 reside. Each action is represented by a function with an attribute to
  65 identify what kind of action it is. See the L<Catalyst::Dispatcher>
  66 for more info about how Catalyst dispatches to actions.
  67
  68 =cut
  69
  70 #I think both of these could be attributes. doesn't really seem like they need
  71 #to ble class data. i think that attributes +default would work just fine
  72 __PACKAGE__->mk_classdata($_) for qw/_dispatch_steps _action_class/;
  73
  74 __PACKAGE__->_dispatch_steps( [qw/_BEGIN _AUTO _ACTION/] );
  75 __PACKAGE__->_action_class('Catalyst::Action');
  76
  77
  78 sub _DISPATCH : Private {
  79     my ( $self, $c ) = @_;
  80
  81     foreach my $disp ( @{ $self->_dispatch_steps } ) {
  82         last unless $c->forward($disp);
  83     }
  84
  85     $c->forward('_END');
  86 }
  87
  88 sub _BEGIN : Private {
  89     my ( $self, $c ) = @_;
  90     my $begin = ( $c->get_actions( 'begin', $c->namespace ) )[-1];
  91     return 1 unless $begin;
  92     $begin->dispatch( $c );
  93     return !@{ $c->error };
  94 }
  95
  96 sub _AUTO : Private {
  97     my ( $self, $c ) = @_;
  98     my @auto = $c->get_actions( 'auto', $c->namespace );
  99     foreach my $auto (@auto) {
 100         $auto->dispatch( $c );
 101         return 0 unless $c->state;
 102     }
 103     return 1;
 104 }
 105
 106 sub _ACTION : Private {
 107     my ( $self, $c ) = @_;
 108     if (   ref $c->action
 109         && $c->action->can('execute')
 110         && defined $c->req->action )
 111     {
 112         $c->action->dispatch( $c );
 113     }
 114     return !@{ $c->error };
 115 }
 116
 117 sub _END : Private {
 118     my ( $self, $c ) = @_;
 119     my $end = ( $c->get_actions( 'end', $c->namespace ) )[-1];
 120     return 1 unless $end;
 121     $end->dispatch( $c );
 122     return !@{ $c->error };
 123 }
 124
 125 sub action_for {
 126     my ( $self, $name ) = @_;
 127     my $app = ($self->isa('Catalyst') ? $self : $self->_application);
 128     return $app->dispatcher->get_action($name, $self->action_namespace);
 129 }
 130
 131 #my opinion is that this whole sub really should be a builder method, not
 132 #something that happens on every call. Anyone else disagree?? -- groditi
 133 ## -- apparently this is all just waiting for app/ctx split
 134 around action_namespace => sub {
 135     my $orig = shift;
 136     my ( $self, $c ) = @_;
 137
 138     if( ref($self) ){
 139         return $self->$orig if $self->has_action_namespace;
 140     } else {
 141         return $self->config->{namespace} if exists $self->config->{namespace};
 142     }
 143
 144     my $case_s;
 145     if( $c ){
 146         $case_s = $c->config->{case_sensitive};
 147     } else {
 148         if ($self->isa('Catalyst')) {
 149             $case_s = $self->config->{case_sensitive};
 150         } else {
 151             if (ref $self) {
 152                 $case_s = $self->_application->config->{case_sensitive};
 153             } else {
 154                 confess("Can't figure out case_sensitive setting");
 155             }
 156         }
 157     }
 158
 159     my $namespace = Catalyst::Utils::class2prefix($self->_component_name, $case_s) || '';
 160     $self->$orig($namespace) if ref($self);
 161     return $namespace;
 162 };
 163
 164 #Once again, this is probably better written as a builder method
 165 around path_prefix => sub {
 166     my $orig = shift;
 167     my $self = shift;
 168     if( ref($self) ){
 169       return $self->$orig if $self->has_path_prefix;
 170     } else {
 171       return $self->config->{path} if exists $self->config->{path};
 172     }
 173     my $namespace = $self->action_namespace(@_);
 174     $self->$orig($namespace) if ref($self);
 175     return $namespace;
 176 };
 177
 178 sub get_action_methods {
 179     my $self = shift;
 180     my $meta = find_meta($self);
 181     confess("Metaclass for "
 182           . ref($meta) . " for "
 183           . $meta->name
 184           . " cannot support register_actions." )
 185       unless $meta->can('get_nearest_methods_with_attributes');
 186     my @methods = $meta->get_nearest_methods_with_attributes;
 187
 188     # actions specified via config are also action_methods
 189     push(
 190         @methods,
 191         map {
 192             $meta->find_method_by_name($_)
 193               || confess( 'Action "'
 194                   . $_
 195                   . '" is not available from controller '
 196                   . ( ref $self ) )
 197           } keys %{ $self->_controller_actions }
 198     ) if ( ref $self );
 199     return @methods;
 200 }
 201
 202
 203 sub register_actions {
 204     my ( $self, $c ) = @_;
 205     $self->register_action_methods( $c, $self->get_action_methods );
 206 }
 207
 208 sub register_action_methods {
 209     my ( $self, $c, @methods ) = @_;
 210     my $class = $self->_component_name;
 211     #this is still not correct for some reason.
 212     my $namespace = $self->action_namespace($c);
 213
 214     # FIXME - fugly
 215     if (!blessed($self) && $self eq $c && scalar(@methods)) {
 216         my @really_bad_methods = grep { ! /^_(DISPATCH|BEGIN|AUTO|ACTION|END)$/ } map { $_->name } @methods;
 217         if (scalar(@really_bad_methods)) {
 218             $c->log->warn("Action methods (" . join(', ', @really_bad_methods) . ") found defined in your application class, $self. This is deprecated, please move them into a Root controller.");
 219         }
 220     }
 221
 222     foreach my $method (@methods) {
 223         my $name = $method->name;
 224         my $attributes = $method->attributes;
 225         my $attrs = $self->_parse_attrs( $c, $name, @{ $attributes } );
 226         if ( $attrs->{Private} && ( keys %$attrs > 1 ) ) {
 227             $c->log->debug( 'Bad action definition "'
 228                   . join( ' ', @{ $attributes } )
 229                   . qq/" for "$class->$name"/ )
 230               if $c->debug;
 231             next;
 232         }
 233         my $reverse = $namespace ? "${namespace}/${name}" : $name;
 234         my $action = $self->create_action(
 235             name       => $name,
 236             code       => $method->body,
 237             reverse    => $reverse,
 238             namespace  => $namespace,
 239             class      => $class,
 240             attributes => $attrs,
 241         );
 242
 243         $c->dispatcher->register( $c, $action );
 244     }
 245 }
 246
 247 sub create_action {
 248     my $self = shift;
 249     my %args = @_;
 250
 251     my $class = (exists $args{attributes}{ActionClass}
 252                     ? $args{attributes}{ActionClass}[0]
 253                     : $self->_action_class);
 254
 255     Class::MOP::load_class($class);
 256     return $class->new( \%args );
 257 }
 258
 259 sub _parse_attrs {
 260     my ( $self, $c, $name, @attrs ) = @_;
 261
 262     my %raw_attributes;
 263
 264     foreach my $attr (@attrs) {
 265
 266         # Parse out :Foo(bar) into Foo => bar etc (and arrayify)
 267
 268         if ( my ( $key, $value ) = ( $attr =~ /^(.*?)(?:\(\s*(.+?)\s*\))?$/ ) )
 269         {
 270
 271             if ( defined $value ) {
 272                 ( $value =~ s/^'(.*)'$/$1/ ) || ( $value =~ s/^"(.*)"/$1/ );
 273             }
 274             push( @{ $raw_attributes{$key} }, $value );
 275         }
 276     }
 277
 278     #I know that the original behavior was to ignore action if actions was set
 279     # but i actually think this may be a little more sane? we can always remove
 280     # the merge behavior quite easily and go back to having actions have
 281     # presedence over action by modifying the keys. i honestly think this is
 282     # superior while mantaining really high degree of compat
 283     my $actions;
 284     if( ref($self) ) {
 285         $actions = $self->_controller_actions;
 286     } else {
 287         my $cfg = $self->config;
 288         $actions = $self->merge_config_hashes($cfg->{actions}, $cfg->{action});
 289     }
 290
 291     %raw_attributes = ((exists $actions->{'*'} ? %{$actions->{'*'}} : ()),
 292                        %raw_attributes,
 293                        (exists $actions->{$name} ? %{$actions->{$name}} : ()));
 294
 295
 296     my %final_attributes;
 297
 298     foreach my $key (keys %raw_attributes) {
 299
 300         my $raw = $raw_attributes{$key};
 301
 302         foreach my $value (ref($raw) eq 'ARRAY' ? @$raw : $raw) {
 303
 304             my $meth = "_parse_${key}_attr";
 305             if ( my $code = $self->can($meth) ) {
 306                 ( $key, $value ) = $self->$code( $c, $name, $value );
 307             }
 308             push( @{ $final_attributes{$key} }, $value );
 309         }
 310     }
 311
 312     return \%final_attributes;
 313 }
 314
 315 sub _parse_Global_attr {
 316     my ( $self, $c, $name, $value ) = @_;
 317     return $self->_parse_Path_attr( $c, $name, "/$name" );
 318 }
 319
 320 sub _parse_Absolute_attr { shift->_parse_Global_attr(@_); }
 321
 322 sub _parse_Local_attr {
 323     my ( $self, $c, $name, $value ) = @_;
 324     return $self->_parse_Path_attr( $c, $name, $name );
 325 }
 326
 327 sub _parse_Relative_attr { shift->_parse_Local_attr(@_); }
 328
 329 sub _parse_Path_attr {
 330     my ( $self, $c, $name, $value ) = @_;
 331     $value = '' if !defined $value;
 332     if ( $value =~ m!^/! ) {
 333         return ( 'Path', $value );
 334     }
 335     elsif ( length $value ) {
 336         return ( 'Path', join( '/', $self->path_prefix($c), $value ) );
 337     }
 338     else {
 339         return ( 'Path', $self->path_prefix($c) );
 340     }
 341 }
 342
 343 sub _parse_Regex_attr {
 344     my ( $self, $c, $name, $value ) = @_;
 345     return ( 'Regex', $value );
 346 }
 347
 348 sub _parse_Regexp_attr { shift->_parse_Regex_attr(@_); }
 349
 350 sub _parse_LocalRegex_attr {
 351     my ( $self, $c, $name, $value ) = @_;
 352     unless ( $value =~ s/^\^// ) { $value = "(?:.*?)$value"; }
 353
 354     my $prefix = $self->path_prefix( $c );
 355     $prefix .= '/' if length( $prefix );
 356
 357     return ( 'Regex', "^${prefix}${value}" );
 358 }
 359
 360 sub _parse_LocalRegexp_attr { shift->_parse_LocalRegex_attr(@_); }
 361
 362 sub _parse_Chained_attr {
 363     my ($self, $c, $name, $value) = @_;
 364
 365     if (defined($value) && length($value)) {
 366         if ($value eq '.') {
 367             $value = '/'.$self->action_namespace($c);
 368         } elsif (my ($rel, $rest) = $value =~ /^((?:\.{2}\/)+)(.*)$/) {
 369             my @parts = split '/', $self->action_namespace($c);
 370             my @levels = split '/', $rel;
 371
 372             $value = '/'.join('/', @parts[0 .. $#parts - @levels], $rest);
 373         } elsif ($value !~ m/^\//) {
 374             my $action_ns = $self->action_namespace($c);
 375
 376             if ($action_ns) {
 377                 $value = '/'.join('/', $action_ns, $value);
 378             } else {
 379                 $value = '/'.$value; # special case namespace '' (root)
 380             }
 381         }
 382     } else {
 383         $value = '/'
 384     }
 385
 386     return Chained => $value;
 387 }
 388
 389 sub _parse_ChainedParent_attr {
 390     my ($self, $c, $name, $value) = @_;
 391     return $self->_parse_Chained_attr($c, $name, '../'.$name);
 392 }
 393
 394 sub _parse_PathPrefix_attr {
 395     my ( $self, $c ) = @_;
 396     return PathPart => $self->path_prefix($c);
 397 }
 398
 399 sub _parse_ActionClass_attr {
 400     my ( $self, $c, $name, $value ) = @_;
 401     my $appname = $self->_application;
 402     $value = Catalyst::Utils::resolve_namespace($appname . '::Action', $self->_action_class, $value);
 403     return ( 'ActionClass', $value );
 404 }
 405
 406 sub _parse_MyAction_attr {
 407     my ( $self, $c, $name, $value ) = @_;
 408
 409     my $appclass = Catalyst::Utils::class2appclass($self);
 410     $value = "${appclass}::Action::${value}";
 411
 412     return ( 'ActionClass', $value );
 413 }
 414
 415 __PACKAGE__->meta->make_immutable;
 416
 417 1;
 418
 419 __END__
 420
 421 =head1 CONFIGURATION
 422
 423 Like any other L<Catalyst::Component>, controllers have a config hash,
 424 accessible through $self->config from the controller actions.  Some
 425 settings are in use by the Catalyst framework:
 426
 427 =head2 namespace
 428
 429 This specifies the internal namespace the controller should be bound
 430 to. By default the controller is bound to the URI version of the
 431 controller name. For instance controller 'MyApp::Controller::Foo::Bar'
 432 will be bound to 'foo/bar'. The default Root controller is an example
 433 of setting namespace to '' (the null string).
 434
 435 =head2 path
 436
 437 Sets 'path_prefix', as described below.
 438
 439 =head1 METHODS
 440
 441 =head2 BUILDARGS ($app, @args)
 442
 443 From L<Catalyst::Component::ApplicationAttribute>, stashes the application
 444 instance as $self->_application.
 445
 446 =head2 $self->action_for('name')
 447
 448 Returns the Catalyst::Action object (if any) for a given method name
 449 in this component.
 450
 451 =head2 $self->action_namespace($c)
 452
 453 Returns the private namespace for actions in this component. Defaults
 454 to a value from the controller name (for
 455 e.g. MyApp::Controller::Foo::Bar becomes "foo/bar") or can be
 456 overridden from the "namespace" config key.
 457
 458
 459 =head2 $self->path_prefix($c)
 460
 461 Returns the default path prefix for :PathPrefix, :Local, :LocalRegex and
 462 relative :Path actions in this component. Defaults to the action_namespace or
 463 can be overridden from the "path" config key.
 464
 465 =head2 $self->register_actions($c)
 466
 467 Finds all applicable actions for this component, creates
 468 Catalyst::Action objects (using $self->create_action) for them and
 469 registers them with $c->dispatcher.
 470
 471 =head2 $self->get_action_methods()
 472
 473 Returns a list of L<Moose::Meta::Method> objects, doing the
 474 L<MooseX::MethodAttributes::Role::Meta::Method> role, which are the set of
 475 action methods for this package.
 476
 477 =head2 $self->register_action_methods($c, @methods)
 478
 479 Creates action objects for a set of action methods using C< create_action >,
 480 and registers them with the dispatcher.
 481
 482 =head2 $self->create_action(%args)
 483
 484 Called with a hash of data to be use for construction of a new
 485 Catalyst::Action (or appropriate sub/alternative class) object.
 486
 487 =head2 $self->_application
 488
 489 =head2 $self->_app
 490
 491 Returns the application instance stored by C<new()>
 492
 493 =head1 AUTHORS
 494
 495 Catalyst Contributors, see Catalyst.pm
 496
 497 =head1 COPYRIGHT
 498
 499 This library is free software. You can redistribute it and/or modify
 500 it under the same terms as Perl itself.
 501
 502 =cut