lib/Catalyst/Controller.pm

   1 package Catalyst::Controller;
   2
   3 #switch to BEGIN { extends qw/ ... /; } ?
   4 use base qw/Catalyst::Component Catalyst::AttrContainer/;
   5 use Moose;
   6
   7 use Scalar::Util qw/blessed/;
   8 use Catalyst::Exception;
   9 use Catalyst::Utils;
  10 use Class::Inspector;
  11
  12 has path_prefix =>
  13     (
  14      is => 'rw',
  15      isa => 'Str',
  16      init_arg => 'path',
  17      predicate => 'has_path_prefix',
  18     );
  19
  20 has action_namespace =>
  21     (
  22      is => 'rw',
  23      isa => 'Str',
  24      init_arg => 'namespace',
  25      predicate => 'has_action_namespace',
  26     );
  27
  28 has actions =>
  29     (
  30      is => 'rw',
  31      isa => 'HashRef',
  32      init_arg => undef,
  33     );
  34
  35 # isa => 'ClassName|Catalyst' ?
  36 has _application => (is => 'rw');
  37 sub _app{ shift->_application(@_) }
  38
  39 sub BUILD {
  40     my ($self, $args) = @_;
  41     my $action  = delete $args->{action}  || {};
  42     my $actions = delete $args->{actions} || {};
  43     my $attr_value = $self->merge_config_hashes($actions, $action);
  44     $self->actions($attr_value);
  45 }
  46
  47 =head1 NAME
  48
  49 Catalyst::Controller - Catalyst Controller base class
  50
  51 =head1 SYNOPSIS
  52
  53   package MyApp::Controller::Search
  54   use base qw/Catalyst::Controller/;
  55
  56   sub foo : Local {
  57     my ($self,$c,@args) = @_;
  58     ...
  59   } # Dispatches to /search/foo
  60
  61 =head1 DESCRIPTION
  62
  63 Controllers are where the actions in the Catalyst framework
  64 reside. Each action is represented by a function with an attribute to
  65 identify what kind of action it is. See the L<Catalyst::Dispatcher>
  66 for more info about how Catalyst dispatches to actions.
  67
  68 =cut
  69
  70 #I think both of these could be attributes. doesn't really seem like they need
  71 #to ble class data. i think that attributes +default would work just fine
  72 __PACKAGE__->mk_classdata($_) for qw/_dispatch_steps _action_class/;
  73
  74 __PACKAGE__->_dispatch_steps( [qw/_BEGIN _AUTO _ACTION/] );
  75 __PACKAGE__->_action_class('Catalyst::Action');
  76
  77
  78 sub _DISPATCH : Private {
  79     my ( $self, $c ) = @_;
  80
  81     foreach my $disp ( @{ $self->_dispatch_steps } ) {
  82         last unless $c->forward($disp);
  83     }
  84
  85     $c->forward('_END');
  86 }
  87
  88 sub _BEGIN : Private {
  89     my ( $self, $c ) = @_;
  90     my $begin = ( $c->get_actions( 'begin', $c->namespace ) )[-1];
  91     return 1 unless $begin;
  92     $begin->dispatch( $c );
  93     return !@{ $c->error };
  94 }
  95
  96 sub _AUTO : Private {
  97     my ( $self, $c ) = @_;
  98     my @auto = $c->get_actions( 'auto', $c->namespace );
  99     foreach my $auto (@auto) {
 100         $auto->dispatch( $c );
 101         return 0 unless $c->state;
 102     }
 103     return 1;
 104 }
 105
 106 sub _ACTION : Private {
 107     my ( $self, $c ) = @_;
 108     if (   ref $c->action
 109         && $c->action->can('execute')
 110         && $c->req->action )
 111     {
 112         $c->action->dispatch( $c );
 113     }
 114     return !@{ $c->error };
 115 }
 116
 117 sub _END : Private {
 118     my ( $self, $c ) = @_;
 119     my $end = ( $c->get_actions( 'end', $c->namespace ) )[-1];
 120     return 1 unless $end;
 121     $end->dispatch( $c );
 122     return !@{ $c->error };
 123 }
 124
 125 around new => sub {
 126     my $orig = shift;
 127     my $self = shift;
 128     my $app = $_[0];
 129     my $new = $self->$orig(@_);
 130     $new->_application( $app );
 131     return $new;
 132 };
 133
 134 sub action_for {
 135     my ( $self, $name ) = @_;
 136     my $app = ($self->isa('Catalyst') ? $self : $self->_application);
 137     return $app->dispatcher->get_action($name, $self->action_namespace);
 138 }
 139
 140 #my opinion is that this whole sub really should be a builder method, not
 141 #something that happens on every call. Anyone else disagree?? -- groditi
 142 ## -- apparently this is all just waiting for app/ctx split
 143 around action_namespace => sub {
 144     my $orig = shift;
 145     my ( $self, $c ) = @_;
 146
 147     if( ref($self) ){
 148         return $self->$orig if $self->has_action_namespace;
 149     } else {
 150         return $self->config->{namespace} if exists $self->config->{namespace};
 151     }
 152
 153     my $case_s;
 154     if( $c ){
 155         $case_s = $c->config->{case_sensitive};
 156     } else {
 157         if ($self->isa('Catalyst')) {
 158             $case_s = $self->config->{case_sensitive};
 159         } else {
 160             if (ref $self) {
 161                 $case_s = $self->_application->config->{case_sensitive};
 162             } else {
 163                 confess("Can't figure out case_sensitive setting");
 164             }
 165         }
 166     }
 167
 168     my $namespace = Catalyst::Utils::class2prefix(ref($self) || $self, $case_s) || '';
 169     $self->$orig($namespace) if ref($self);
 170     return $namespace;
 171 };
 172
 173 #Once again, this is probably better written as a builder method
 174 around path_prefix => sub {
 175     my $orig = shift;
 176     my $self = shift;
 177     if( ref($self) ){
 178       return $self->$orig if $self->has_path_prefix;
 179     } else {
 180       return $self->config->{path} if exists $self->config->{path};
 181     }
 182     my $namespace = $self->action_namespace(@_);
 183     $self->$orig($namespace) if ref($self);
 184     return $namespace;
 185 };
 186
 187
 188 sub register_actions {
 189     my ( $self, $c ) = @_;
 190     my $class = ref $self || $self;
 191     #this is still not correct for some reason.
 192     my $namespace = $self->action_namespace($c);
 193     my $meta = $self->meta;
 194     my %methods = map{ $_->{code}->body => $_->{name} }
 195         grep {$_->{class} ne 'Moose::Object'} #ignore Moose::Object methods
 196             $meta->compute_all_applicable_methods;
 197
 198
 199     # Advanced inheritance support for plugins and the like
 200     #moose todo: migrate to eliminate CDI compat
 201     my @action_cache;
 202     for my $isa ( $meta->superclasses, $class ) {
 203         if(my $coderef = $isa->can('_action_cache')){
 204             push(@action_cache, @{ $isa->$coderef });
 205         }
 206     }
 207
 208     foreach my $cache (@action_cache) {
 209         my $code   = $cache->[0];
 210         my $method = delete $methods{$code}; # avoid dupe registers
 211         next unless $method;
 212         my $attrs = $self->_parse_attrs( $c, $method, @{ $cache->[1] } );
 213         if ( $attrs->{Private} && ( keys %$attrs > 1 ) ) {
 214             $c->log->debug( 'Bad action definition "'
 215                   . join( ' ', @{ $cache->[1] } )
 216                   . qq/" for "$class->$method"/ )
 217               if $c->debug;
 218             next;
 219         }
 220         my $reverse = $namespace ? "${namespace}/${method}" : $method;
 221         my $action = $self->create_action(
 222             name       => $method,
 223             code       => $code,
 224             reverse    => $reverse,
 225             namespace  => $namespace,
 226             class      => $class,
 227             attributes => $attrs,
 228         );
 229
 230         $c->dispatcher->register( $c, $action );
 231     }
 232 }
 233
 234 sub create_action {
 235     my $self = shift;
 236     my %args = @_;
 237
 238     my $class = (exists $args{attributes}{ActionClass}
 239                     ? $args{attributes}{ActionClass}[0]
 240                     : $self->_action_class);
 241
 242     Class::MOP::load_class($class);
 243     return $class->new( \%args );
 244 }
 245
 246 sub _parse_attrs {
 247     my ( $self, $c, $name, @attrs ) = @_;
 248
 249     my %raw_attributes;
 250
 251     foreach my $attr (@attrs) {
 252
 253         # Parse out :Foo(bar) into Foo => bar etc (and arrayify)
 254
 255         if ( my ( $key, $value ) = ( $attr =~ /^(.*?)(?:\(\s*(.+?)\s*\))?$/ ) )
 256         {
 257
 258             if ( defined $value ) {
 259                 ( $value =~ s/^'(.*)'$/$1/ ) || ( $value =~ s/^"(.*)"/$1/ );
 260             }
 261             push( @{ $raw_attributes{$key} }, $value );
 262         }
 263     }
 264
 265     #I know that the original behavior was to ignore action if actions was set
 266     # but i actually think this may be a little more sane? we can always remove
 267     # the merge behavior quite easily and go back to having actions have
 268     # presedence over action by modifying the keys. i honestly think this is
 269     # superior while mantaining really high degree of compat
 270     my $actions;
 271     if( ref($self) ) {
 272         $actions = $self->actions;
 273     } else {
 274         my $cfg = $self->config;
 275         $actions = $self->merge_config_hashes($cfg->{actions}, $cfg->{action});
 276     }
 277
 278     %raw_attributes = ((exists $actions->{'*'} ? %{$actions->{'*'}} : ()),
 279                        %raw_attributes,
 280                        (exists $actions->{$name} ? %{$actions->{$name}} : ()));
 281
 282
 283     my %final_attributes;
 284
 285     foreach my $key (keys %raw_attributes) {
 286
 287         my $raw = $raw_attributes{$key};
 288
 289         foreach my $value (ref($raw) eq 'ARRAY' ? @$raw : $raw) {
 290
 291             my $meth = "_parse_${key}_attr";
 292             if ( my $code = $self->can($meth) ) {
 293                 ( $key, $value ) = $self->$code( $c, $name, $value );
 294             }
 295             push( @{ $final_attributes{$key} }, $value );
 296         }
 297     }
 298
 299     return \%final_attributes;
 300 }
 301
 302 sub _parse_Global_attr {
 303     my ( $self, $c, $name, $value ) = @_;
 304     return $self->_parse_Path_attr( $c, $name, "/$name" );
 305 }
 306
 307 sub _parse_Absolute_attr { shift->_parse_Global_attr(@_); }
 308
 309 sub _parse_Local_attr {
 310     my ( $self, $c, $name, $value ) = @_;
 311     return $self->_parse_Path_attr( $c, $name, $name );
 312 }
 313
 314 sub _parse_Relative_attr { shift->_parse_Local_attr(@_); }
 315
 316 sub _parse_Path_attr {
 317     my ( $self, $c, $name, $value ) = @_;
 318     $value ||= '';
 319     if ( $value =~ m!^/! ) {
 320         return ( 'Path', $value );
 321     }
 322     elsif ( length $value ) {
 323         return ( 'Path', join( '/', $self->path_prefix($c), $value ) );
 324     }
 325     else {
 326         return ( 'Path', $self->path_prefix($c) );
 327     }
 328 }
 329
 330 sub _parse_Regex_attr {
 331     my ( $self, $c, $name, $value ) = @_;
 332     return ( 'Regex', $value );
 333 }
 334
 335 sub _parse_Regexp_attr { shift->_parse_Regex_attr(@_); }
 336
 337 sub _parse_LocalRegex_attr {
 338     my ( $self, $c, $name, $value ) = @_;
 339     unless ( $value =~ s/^\^// ) { $value = "(?:.*?)$value"; }
 340     return ( 'Regex', '^' . $self->path_prefix($c) . "/${value}" );
 341 }
 342
 343 sub _parse_LocalRegexp_attr { shift->_parse_LocalRegex_attr(@_); }
 344
 345 sub _parse_ActionClass_attr {
 346     my ( $self, $c, $name, $value ) = @_;
 347     unless ( $value =~ s/^\+// ) {
 348       $value = join('::', $self->_action_class, $value );
 349     }
 350     return ( 'ActionClass', $value );
 351 }
 352
 353 sub _parse_MyAction_attr {
 354     my ( $self, $c, $name, $value ) = @_;
 355
 356     my $appclass = Catalyst::Utils::class2appclass($self);
 357     $value = "${appclass}::Action::${value}";
 358
 359     return ( 'ActionClass', $value );
 360 }
 361
 362 no Moose;
 363
 364 __PACKAGE__->meta->make_immutable;
 365
 366 1;
 367
 368 __END__
 369
 370 =head1 CONFIGURATION
 371
 372 Like any other L<Catalyst::Component>, controllers have a config hash,
 373 accessible through $self->config from the controller actions.  Some
 374 settings are in use by the Catalyst framework:
 375
 376 =head2 namespace
 377
 378 This specifies the internal namespace the controller should be bound
 379 to. By default the controller is bound to the URI version of the
 380 controller name. For instance controller 'MyApp::Controller::Foo::Bar'
 381 will be bound to 'foo/bar'. The default Root controller is an example
 382 of setting namespace to '' (the null string).
 383
 384 =head2 path
 385
 386 Sets 'path_prefix', as described below.
 387
 388 =head1 METHODS
 389
 390 =head2 $class->new($app, @args)
 391
 392 Proxies through to NEXT::new and stashes the application instance as
 393 $self->_application.
 394
 395 =head2 $self->action_for('name')
 396
 397 Returns the Catalyst::Action object (if any) for a given method name
 398 in this component.
 399
 400 =head2 $self->register_actions($c)
 401
 402 Finds all applicable actions for this component, creates
 403 Catalyst::Action objects (using $self->create_action) for them and
 404 registers them with $c->dispatcher.
 405
 406 =head2 $self->action_namespace($c)
 407
 408 Returns the private namespace for actions in this component. Defaults
 409 to a value from the controller name (for
 410 e.g. MyApp::Controller::Foo::Bar becomes "foo/bar") or can be
 411 overridden from the "namespace" config key.
 412
 413
 414 =head2 $self->path_prefix($c)
 415
 416 Returns the default path prefix for :Local, :LocalRegex and relative
 417 :Path actions in this component. Defaults to the action_namespace or
 418 can be overridden from the "path" config key.
 419
 420 =head2 $self->create_action(%args)
 421
 422 Called with a hash of data to be use for construction of a new
 423 Catalyst::Action (or appropriate sub/alternative class) object.
 424
 425 Primarily designed for the use of register_actions.
 426
 427 =head2 $self->_application
 428
 429 =head2 $self->_app
 430
 431 Returns the application instance stored by C<new()>
 432
 433 =head1 AUTHOR
 434
 435 Sebastian Riedel, C<sri@oook.de>
 436 Marcus Ramberg C<mramberg@cpan.org>
 437
 438 =head1 COPYRIGHT
 439
 440 This program is free software, you can redistribute it and/or modify
 441 it under the same terms as Perl itself.
 442
 443 =cut