lib/Catalyst/Component.pm

   1 package Catalyst::Component;
   2
   3 use strict;
   4 use base qw/Class::Accessor::Fast Class::Data::Inheritable/;
   5 use NEXT;
   6
   7 __PACKAGE__->mk_classdata($_) for qw/_config _plugins/;
   8
   9 =head1 NAME
  10
  11 Catalyst::Component - Catalyst Component Base Class
  12
  13 =head1 SYNOPSIS
  14
  15     # lib/MyApp/Model/Something.pm
  16     package MyApp::Model::Something;
  17
  18     use base 'Catalyst::Component';
  19
  20     __PACKAGE__->config( foo => 'bar' );
  21
  22     sub test {
  23         my $self = shift;
  24         return $self->{foo};
  25     }
  26
  27     sub forward_to_me {
  28         my ( $self, $c ) = @_;
  29         $c->response->output( $self->{foo} );
  30     }
  31
  32     1;
  33
  34     # Methods can be a request step
  35     $c->forward(qw/MyApp::Model::Something forward_to_me/);
  36
  37     # Or just methods
  38     print $c->comp('MyApp::Model::Something')->test;
  39
  40     print $c->comp('MyApp::Model::Something')->{foo};
  41
  42 =head1 DESCRIPTION
  43
  44 This is the universal base class for Catalyst components
  45 (Model/View/Controller).
  46
  47 It provides you with a generic new() for instantiation through Catalyst's
  48 component loader with config() support and a process() method placeholder.
  49
  50 =head1 METHODS
  51
  52 =head2 new($c, $arguments)
  53
  54 Called by COMPONENT to instantiate the component; should return an object
  55 to be stored in the application's component hash.
  56
  57 =cut
  58
  59 sub new {
  60     my ( $self, $c ) = @_;
  61
  62     # Temporary fix, some components does not pass context to constructor
  63     my $arguments = ( ref( $_[-1] ) eq 'HASH' ) ? $_[-1] : {};
  64
  65     return $self->NEXT::new( { %{ $self->config }, %{$arguments} } );
  66 }
  67
  68 =head2 COMPONENT($c, $arguments)
  69
  70 If this method is present (as it is on all Catalyst::Component subclasses,
  71 it is called by Catalyst during setup_components with the application class
  72 as $c and any config entry on the application for this component (for example,
  73 in the case of MyApp::Controller::Foo this would be
  74 MyApp->config->{'Controller::Foo'}). The arguments are expected to be a hashref
  75 and are merged with the __PACKAGE__->config hashref before calling ->new to
  76 instantiate the component.
  77
  78 =cut
  79
  80 sub COMPONENT {
  81     my ( $self, $c ) = @_;
  82
  83     # Temporary fix, some components does not pass context to constructor
  84     my $arguments = ( ref( $_[-1] ) eq 'HASH' ) ? $_[-1] : {};
  85
  86     if ( my $new = $self->NEXT::COMPONENT( $c, $arguments ) ) {
  87         return $new;
  88     }
  89     else {
  90         if ( my $new = $self->new( $c, $arguments ) ) {
  91             return $new;
  92         }
  93         else {
  94             my $class = ref $self || $self;
  95             my $new = { %{ $self->config }, %{$arguments} };
  96             return bless $new, $class;
  97         }
  98     }
  99 }
 100
 101 # remember to leave blank lines between the consecutive =head2's
 102 # otherwise the pod tools don't recognize the subsequent =head2s
 103
 104 =head2 $c->config
 105
 106 =head2 $c->config($hashref)
 107
 108 =head2 $c->config($key, $value, ...)
 109
 110 =cut
 111
 112 sub config {
 113     my $self = shift;
 114     my $config = $self->_config;
 115     unless ($config) {
 116         $self->_config( $config = {} );
 117     }
 118     if (@_) {
 119         $config = { %{$config}, %{@_ > 1 ? {@_} : $_[0]} };
 120         $self->_config($config);
 121     }
 122     return $config;
 123 }
 124
 125 =head2 $c->process()
 126
 127 =cut
 128
 129 sub process {
 130
 131     Catalyst::Exception->throw( message => ( ref $_[0] || $_[0] )
 132           . " did not override Catalyst::Component::process" );
 133 }
 134
 135 =head1 OPTIONAL METHODS
 136
 137 =head2 ACCEPT_CONTEXT($c, @args)
 138
 139 Catalyst components are normally initalized during server startup, either
 140 as a Class or a Instance. However, some components require information about
 141 the current request. To do so, they can implement an ACCEPT_CONTEXT method.
 142
 143 If this method is present, it is called during $c->comp/controller/model/view
 144 with the current $c and any additional args (e.g. $c->model('Foo', qw/bar baz/)
 145 would cause your MyApp::Model::Foo instance's ACCEPT_CONTEXT to be called with
 146 ($c, 'bar', 'baz')) and the return value of this method is returned to the
 147 calling code in the application rather than the component itself.
 148
 149 =head1 SEE ALSO
 150
 151 L<Catalyst>, L<Catalyst::Model>, L<Catalyst::View>, L<Catalyst::Controller>.
 152
 153 =head1 AUTHOR
 154
 155 Sebastian Riedel, C<sri@cpan.org>
 156 Marcus Ramberg, C<mramberg@cpan.org>
 157 Matt S Trout, C<mst@shadowcatsystems.co.uk>
 158
 159 =head1 COPYRIGHT
 160
 161 This program is free software, you can redistribute it and/or modify it under
 162 the same terms as Perl itself.
 163
 164 =cut
 165
 166 1;