lib/Catalyst/ClassData.pm

   1 package Catalyst::ClassData;
   2
   3 use Moose::Role;
   4 use Class::MOP;
   5 use Class::MOP::Object;
   6
   7 sub mk_classdata {
   8   my ($class, $attribute) = @_;
   9   confess("mk_classdata() is a class method, not an object method")
  10     if blessed $class;
  11
  12   my $slot = '$'.$attribute;
  13   my $accessor =  sub {
  14     my $pkg = ref $_[0] || $_[0];
  15     # Hack - delberately create a metaclass instance
  16     my $meta = $pkg->Moose::Object::meta();
  17     if (@_ > 1) {
  18       $meta->namespace->{$attribute} = \$_[1];
  19       return $_[1];
  20     }
  21
  22     # tighter version of
  23     # if ( $meta->has_package_symbol($slot) ) {
  24     #   return ${ $meta->get_package_symbol($slot) };
  25     # }
  26     no strict 'refs';
  27     my $v = *{"${pkg}::${attribute}"}{SCALAR};
  28     if (defined ${$v}) {
  29      return ${$v};
  30     } else {
  31       foreach my $super ( $meta->linearized_isa ) {
  32         # tighter version of same after
  33         # my $super_meta = Moose::Meta::Class->initialize($super);
  34         my $v = ${"${super}::"}{$attribute} ? *{"${super}::${attribute}"}{SCALAR} : undef;
  35         if (defined ${$v}) {
  36           return ${$v};
  37         }
  38       }
  39     }
  40     return;
  41   };
  42
  43   confess("Failed to create accessor: $@ ")
  44     unless ref $accessor eq 'CODE';
  45
  46   my $meta = $class->Class::MOP::Object::meta();
  47   my $immutable_options;
  48   if( $meta->is_immutable ){
  49     $immutable_options = $meta->get_immutable_options;
  50     $meta->make_mutable;
  51   }
  52   my $alias = "_${attribute}_accessor";
  53   $meta->add_method($alias, $accessor);
  54   $meta->add_method($attribute, $accessor);
  55   if(defined $immutable_options){
  56     $meta->make_immutable(%{ $immutable_options });
  57   }
  58   $class->$attribute($_[2]) if(@_ > 2);
  59   return $accessor;
  60 }
  61
  62 1;
  63
  64 __END__
  65
  66
  67 =head1 NAME
  68
  69 Catalyst::ClassData - Class data accessors
  70
  71 =head1 METHODS
  72
  73 =head2 mk_classdata $name, $optional_value
  74
  75 A moose-safe clone of L<Class::Data::Inheritable> that borrows some ideas from
  76 L<Class::Accessor::Grouped>;
  77
  78 =head1 AUTHOR
  79
  80 Guillermo Roditi
  81
  82 =head1 COPYRIGHT
  83
  84 This program is free software, you can redistribute it and/or modify it under
  85 the same terms as Perl itself.
  86
  87 =cut