lib/Catalyst/ClassData.pm

   1 package Catalyst::ClassData;
   2
   3 use Moose::Role;
   4 use Class::MOP;
   5 use Class::MOP::Object;
   6
   7 sub mk_classdata {
   8   my ($class, $attribute) = @_;
   9   confess("mk_classdata() is a class method, not an object method")
  10     if blessed $class;
  11
  12   my $slot = '$'.$attribute;
  13   my $accessor =  sub {
  14     my $pkg = ref $_[0] || $_[0];
  15     # Hack - delberately create a metaclass instance
  16     my $meta = $pkg->Class::MOP::Object::meta();
  17     if (@_ > 1) {
  18       $meta->namespace->{$attribute} = \$_[1];
  19       return $_[1];
  20     }
  21
  22     # tighter version of
  23     # if ( $meta->has_package_symbol($slot) ) {
  24     #   return ${ $meta->get_package_symbol($slot) };
  25     # }
  26     no strict 'refs';
  27     my $v = *{"${pkg}::${attribute}"}{SCALAR};
  28     if (defined ${$v}) {
  29      return ${$v};
  30     } else {
  31       foreach my $super ( $meta->linearized_isa ) {
  32         # tighter version of same after
  33         # my $super_meta = Moose::Meta::Class->initialize($super);
  34         my $v = ${"${super}::"}{$attribute} ? *{"${super}::${attribute}"}{SCALAR} : undef;
  35         if (defined ${$v}) {
  36           return ${$v};
  37         }
  38       }
  39     }
  40     return;
  41   };
  42
  43   confess("Failed to create accessor: $@ ")
  44     unless ref $accessor eq 'CODE';
  45
  46   my $meta = $class->Class::MOP::Object::meta();
  47   confess "${class}'s metaclass is not a Class::MOP::Class"
  48     unless $meta->isa('Class::MOP::Class');
  49
  50   my $was_immutable = $meta->is_immutable;
  51   $meta->make_mutable if $was_immutable;
  52
  53   my $alias = "_${attribute}_accessor";
  54   $meta->add_method($alias, $accessor);
  55   $meta->add_method($attribute, $accessor);
  56
  57   $meta->make_immutable if $was_immutable;
  58
  59   $class->$attribute($_[2]) if(@_ > 2);
  60   return $accessor;
  61 }
  62
  63 1;
  64
  65 __END__
  66
  67
  68 =head1 NAME
  69
  70 Catalyst::ClassData - Class data accessors
  71
  72 =head1 METHODS
  73
  74 =head2 mk_classdata $name, $optional_value
  75
  76 A moose-safe clone of L<Class::Data::Inheritable> that borrows some ideas from
  77 L<Class::Accessor::Grouped>;
  78
  79 =head1 AUTHOR
  80
  81 Guillermo Roditi
  82
  83 =head1 COPYRIGHT
  84
  85 This program is free software, you can redistribute it and/or modify it under
  86 the same terms as Perl itself.
  87
  88 =cut