lib/Catalyst/ClassData.pm

   1 package Catalyst::ClassData;
   2
   3 use Moose::Role;
   4 use Class::MOP;
   5 use Class::MOP::Object;
   6 use Scalar::Util 'blessed';
   7
   8 sub mk_classdata {
   9   my ($class, $attribute) = @_;
  10   confess("mk_classdata() is a class method, not an object method")
  11     if blessed $class;
  12
  13   my $slot = '$'.$attribute;
  14   my $accessor =  sub {
  15     my $pkg = ref $_[0] || $_[0];
  16     my $meta = $pkg->Class::MOP::Object::meta();
  17     if (@_ > 1){
  18       $meta->namespace->{$attribute} = \$_[1];
  19       return $_[1];
  20     }
  21
  22     # tighter version of
  23     # if ( $meta->has_package_symbol($slot) ) {
  24     #   return ${ $meta->get_package_symbol($slot) };
  25     # }
  26     no strict 'refs';
  27     my $v = *{"${pkg}::${attribute}"}{SCALAR};
  28     if (defined ${$v}) {
  29      return ${$v};
  30     } else {
  31       foreach my $super ( $meta->linearized_isa ) {
  32         # If there is a code symbol for this attr in a parent class,
  33         # then copy it into our package. Is this the correct
  34         # fix for C::D::I back-compat? (t0m)
  35         my $parent_symbol = *{"${super}::${attribute}"}{CODE} ? \&{"${super}::${attribute}"} : undef;
  36         # FIXME - this is over-enthusiastic?
  37         if (defined $parent_symbol) {
  38           *{"${pkg}::${attribute}"} = $parent_symbol;
  39         }
  40         # tighter version of same after
  41         # my $super_meta = Moose::Meta::Class->initialize($super);
  42         my $v = ${"${super}::"}{$attribute} ? *{"${super}::${attribute}"}{SCALAR} : undef;
  43         if (defined ${$v}) {
  44           return ${$v};
  45         }
  46       }
  47     }
  48     return;
  49   };
  50
  51   confess("Failed to create accessor: $@ ")
  52     unless ref $accessor eq 'CODE';
  53
  54   my $meta = $class->Class::MOP::Object::meta();
  55   my $immutable_options;
  56   if( $meta->is_immutable ){
  57     $immutable_options = $meta->get_immutable_options;
  58     $meta->make_mutable;
  59   }
  60   my $alias = "_${attribute}_accessor";
  61   $meta->add_method($alias, $accessor);
  62   $meta->add_method($attribute, $accessor);
  63   if(defined $immutable_options){
  64     $meta->make_immutable(%{ $immutable_options });
  65   }
  66   $class->$attribute($_[2]) if(@_ > 2);
  67   return $accessor;
  68 }
  69
  70 1;
  71
  72 __END__
  73
  74
  75 =head1 NAME
  76
  77 Catalyst::ClassData - Class data acessors
  78
  79 =head1 METHODS
  80
  81 =head2 mk_classdata $name, $optional_value
  82
  83 A moose-safe clone of L<Class::Data::Inheritable> that borrows some ideas from
  84 L<Class::Accessor::Grouped>;
  85
  86 =head1 AUTHOR
  87
  88 Guillermo Roditi
  89
  90 =head1 COPYRIGHT
  91
  92 This program is free software, you can redistribute it and/or modify it under
  93 the same terms as Perl itself.
  94
  95 =cut