lib/Catalyst/Base.pm

   1 package Catalyst::Base;
   2
   3 use strict;
   4 use base qw/Catalyst::Component Catalyst::AttrContainer Class::Accessor::Fast/;
   5
   6 use Catalyst::Exception;
   7 use Catalyst::Utils;
   8 use Class::Inspector;
   9 use NEXT;
  10
  11 __PACKAGE__->mk_classdata($_) for qw/_dispatch_steps _action_class/;
  12
  13 __PACKAGE__->_dispatch_steps( [qw/_BEGIN _AUTO _ACTION/] );
  14 __PACKAGE__->_action_class('Catalyst::Action');
  15
  16 sub _DISPATCH : Private {
  17     my ( $self, $c ) = @_;
  18
  19     foreach my $disp ( @{ $self->_dispatch_steps } ) {
  20         last unless $c->forward($disp);
  21     }
  22
  23     $c->forward('_END');
  24 }
  25
  26 sub _BEGIN : Private {
  27     my ( $self, $c ) = @_;
  28     my $begin = ( $c->get_actions( 'begin', $c->namespace ) )[-1];
  29     return 1 unless $begin;
  30     $begin->dispatch( $c );
  31     return !@{ $c->error };
  32 }
  33
  34 sub _AUTO : Private {
  35     my ( $self, $c ) = @_;
  36     my @auto = $c->get_actions( 'auto', $c->namespace );
  37     foreach my $auto (@auto) {
  38         $auto->dispatch( $c );
  39         return 0 unless $c->state;
  40     }
  41     return 1;
  42 }
  43
  44 sub _ACTION : Private {
  45     my ( $self, $c ) = @_;
  46     if (   ref $c->action
  47         && $c->action->can('execute')
  48         && $c->req->action )
  49     {
  50         $c->action->dispatch( $c );
  51     }
  52     return !@{ $c->error };
  53 }
  54
  55 sub _END : Private {
  56     my ( $self, $c ) = @_;
  57     my $end = ( $c->get_actions( 'end', $c->namespace ) )[-1];
  58     return 1 unless $end;
  59     $end->dispatch( $c );
  60     return !@{ $c->error };
  61 }
  62
  63 =head1 NAME
  64
  65 Catalyst::Base - Catalyst Base Class
  66
  67 =head1 SYNOPSIS
  68
  69 See L<Catalyst>
  70
  71 =head1 DESCRIPTION
  72
  73 Catalyst Base Class
  74
  75 This is the base class for all Catalyst components. It also handles
  76 dispatch of actions for controllers.
  77
  78 =head1 METHODS
  79
  80 =head2 $self->action_namespace($c)
  81
  82 Determine the namespace for actions in this component.
  83
  84 =cut
  85
  86 sub action_namespace {
  87     my ( $self, $c ) = @_;
  88     return $self->config->{namespace} if exists $self->config->{namespace};
  89     return Catalyst::Utils::class2prefix( ref($self) || $self,
  90         $c->config->{case_sensitive} )
  91       || '';
  92 }
  93
  94 =head2 $self->path_prefix($c)
  95
  96 alias for action_namespace
  97
  98 =cut
  99
 100 sub path_prefix { shift->action_namespace(@_); }
 101
 102 =head2 $self->register_actions($c)
 103
 104 register all actions for this component based on a given context.
 105
 106 =cut
 107
 108 sub register_actions {
 109     my ( $self, $c ) = @_;
 110     my $class = ref $self || $self;
 111     my $namespace = $self->action_namespace($c);
 112     my %methods;
 113     $methods{ $self->can($_) } = $_
 114       for @{ Class::Inspector->methods($class) || [] };
 115
 116     # Advanced inheritance support for plugins and the like
 117     my @action_cache;
 118     {
 119         no strict 'refs';
 120         for my $isa ( @{"$class\::ISA"}, $class ) {
 121             push @action_cache, @{ $isa->_action_cache }
 122               if $isa->can('_action_cache');
 123         }
 124     }
 125
 126     foreach my $cache (@action_cache) {
 127         my $code   = $cache->[0];
 128         my $method = $methods{$code};
 129         next unless $method;
 130         my $attrs = $self->_parse_attrs( $c, $method, @{ $cache->[1] } );
 131         if ( $attrs->{Private} && ( keys %$attrs > 1 ) ) {
 132             $c->log->debug( 'Bad action definition "'
 133                   . join( ' ', @{ $cache->[1] } )
 134                   . qq/" for "$class->$method"/ )
 135               if $c->debug;
 136             next;
 137         }
 138         my $reverse = $namespace ? "$namespace/$method" : $method;
 139         my $action = $self->create_action(
 140             name       => $method,
 141             code       => $code,
 142             reverse    => $reverse,
 143             namespace  => $namespace,
 144             class      => $class,
 145             attributes => $attrs,
 146         );
 147
 148         $c->dispatcher->register( $c, $action );
 149     }
 150 }
 151
 152 sub create_action {
 153     my $self = shift;
 154     my %args = @_;
 155
 156     my $class = (exists $args{attributes}{ActionClass}
 157                     ? $args{attributes}{ActionClass}[0]
 158                     : $self->_action_class);
 159
 160     unless ( Class::Inspector->loaded($class) ) {
 161       $class->require;
 162       die "Couldn't load action class ${class}: $@" if $@;
 163     }
 164
 165     return $class->new( \%args );
 166 }
 167
 168 sub _parse_attrs {
 169     my ( $self, $c, $name, @attrs ) = @_;
 170     my %attributes;
 171     foreach my $attr (@attrs) {
 172
 173         # Parse out :Foo(bar) into Foo => bar etc (and arrayify)
 174
 175         if ( my ( $key, $value ) = ( $attr =~ /^(.*?)(?:\(\s*(.+?)\s*\))?$/ ) )
 176         {
 177
 178             if ( defined $value ) {
 179                 ( $value =~ s/^'(.*)'$/$1/ ) || ( $value =~ s/^"(.*)"/$1/ );
 180             }
 181             my $meth = "_parse_${key}_attr";
 182             if ( $self->can($meth) ) {
 183                 ( $key, $value ) = $self->$meth( $c, $name, $value );
 184             }
 185             push( @{ $attributes{$key} }, $value );
 186         }
 187     }
 188     return \%attributes;
 189 }
 190
 191 sub _parse_Global_attr {
 192     my ( $self, $c, $name, $value ) = @_;
 193     return $self->_parse_Path_attr( $c, $name, "/$name" );
 194 }
 195
 196 sub _parse_Absolute_attr { shift->_parse_Global_attr(@_); }
 197
 198 sub _parse_Local_attr {
 199     my ( $self, $c, $name, $value ) = @_;
 200     return $self->_parse_Path_attr( $c, $name, $name );
 201 }
 202
 203 sub _parse_Relative_attr { shift->_parse_Local_attr(@_); }
 204
 205 sub _parse_Path_attr {
 206     my ( $self, $c, $name, $value ) = @_;
 207     $value ||= '';
 208     if ( $value =~ m!^/! ) {
 209         return ( 'Path', $value );
 210     }
 211     elsif ( length $value ) {
 212         return ( 'Path', join( '/', $self->path_prefix($c), $value ) );
 213     }
 214     else {
 215         return ( 'Path', $self->path_prefix($c) );
 216     }
 217 }
 218
 219 sub _parse_Regex_attr {
 220     my ( $self, $c, $name, $value ) = @_;
 221     return ( 'Regex', $value );
 222 }
 223
 224 sub _parse_Regexp_attr { shift->_parse_Regex_attr(@_); }
 225
 226 sub _parse_LocalRegex_attr {
 227     my ( $self, $c, $name, $value ) = @_;
 228     unless ( $value =~ s/^\^// ) { $value = "(?:.*?)$value"; }
 229     return ( 'Regex', '^' . $self->path_prefix($c) . "/${value}" );
 230 }
 231
 232 sub _parse_LocalRegexp_attr { shift->_parse_LocalRegex_attr(@_); }
 233
 234 sub _parse_ActionClass_attr {
 235     my ( $self, $c, $name, $value ) = @_;
 236     unless ( $value =~ s/^\+// ) {
 237       $value = join('::', $self->_action_class, $value );
 238     }
 239     return ( 'ActionClass', $value );
 240 }
 241
 242 =head1 SEE ALSO
 243
 244 L<Catalyst>, L<Catalyst::Controller>.
 245
 246 =head1 AUTHOR
 247
 248 Sebastian Riedel, C<sri@cpan.org>
 249 Marcus Ramberg, C<mramberg@cpan.org>
 250 Matt S Trout, C<mst@shadowcatsystems.co.uk>
 251
 252 =head1 COPYRIGHT
 253
 254 This program is free software, you can redistribute it and/or modify it under
 255 the same terms as Perl itself.
 256
 257 =cut
 258
 259 1;