lib/Catalyst/Base.pm

   1 package Catalyst::Base;
   2
   3 use strict;
   4 use base qw/Catalyst::Component Catalyst::AttrContainer Class::Accessor::Fast/;
   5
   6 use Catalyst::Exception;
   7 use Catalyst::Utils;
   8 use Class::Inspector;
   9 use NEXT;
  10
  11 __PACKAGE__->mk_classdata($_) for qw/_dispatch_steps _action_class/;
  12
  13 __PACKAGE__->_dispatch_steps( [qw/_BEGIN _AUTO _ACTION/] );
  14 __PACKAGE__->_action_class('Catalyst::Action');
  15
  16 sub _DISPATCH : Private {
  17     my ( $self, $c ) = @_;
  18
  19     foreach my $disp ( @{ $self->_dispatch_steps } ) {
  20         last unless $c->forward($disp);
  21     }
  22
  23     $c->forward('_END');
  24 }
  25
  26 sub _BEGIN : Private {
  27     my ( $self, $c ) = @_;
  28     my $begin = ( $c->get_actions( 'begin', $c->namespace ) )[-1];
  29     return 1 unless $begin;
  30     $begin->dispatch( $c );
  31     return !@{ $c->error };
  32 }
  33
  34 sub _AUTO : Private {
  35     my ( $self, $c ) = @_;
  36     my @auto = $c->get_actions( 'auto', $c->namespace );
  37     foreach my $auto (@auto) {
  38         $auto->dispatch( $c );
  39         return 0 unless $c->state;
  40     }
  41     return 1;
  42 }
  43
  44 sub _ACTION : Private {
  45     my ( $self, $c ) = @_;
  46     if (   ref $c->action
  47         && $c->action->can('execute')
  48         && $c->req->action )
  49     {
  50         $c->action->dispatch( $c );
  51     }
  52     return !@{ $c->error };
  53 }
  54
  55 sub _END : Private {
  56     my ( $self, $c ) = @_;
  57     my $end = ( $c->get_actions( 'end', $c->namespace ) )[-1];
  58     return 1 unless $end;
  59     $end->dispatch( $c );
  60     return !@{ $c->error };
  61 }
  62
  63 =head1 NAME
  64
  65 Catalyst::Base - Catalyst Base Class
  66
  67 =head1 SYNOPSIS
  68
  69 See L<Catalyst>
  70
  71 =head1 DESCRIPTION
  72
  73 Catalyst Base Class
  74
  75 This is the base class for all Catalyst components. It also handles
  76 dispatch of actions for controllers.
  77
  78 =head1 METHODS
  79
  80 =head2 $self->action_namespace($c)
  81
  82 Determine the namespace for actions in this component.
  83
  84 =cut
  85
  86 sub action_namespace {
  87     my ( $self, $c ) = @_;
  88     return $self->config->{namespace} if exists $self->config->{namespace};
  89     return Catalyst::Utils::class2prefix( ref($self) || $self,
  90         $c->config->{case_sensitive} )
  91       || '';
  92 }
  93
  94 =head2 $self->path_prefix($c)
  95
  96 alias for action_namespace
  97
  98 =cut
  99
 100 sub path_prefix { shift->action_namespace(@_); }
 101
 102 =head2 $self->register_actions($c)
 103
 104 register all actions for this component based on a given context.
 105
 106 =cut
 107
 108 sub register_actions {
 109     my ( $self, $c ) = @_;
 110     my $class = ref $self || $self;
 111     my $namespace = $self->action_namespace($c);
 112     my %methods;
 113     $methods{ $self->can($_) } = $_
 114       for @{ Class::Inspector->methods($class) || [] };
 115
 116     # Advanced inheritance support for plugins and the like
 117     my @action_cache;
 118     {
 119         no strict 'refs';
 120         for my $isa ( @{"$class\::ISA"}, $class ) {
 121             push @action_cache, @{ $isa->_action_cache }
 122               if $isa->can('_action_cache');
 123         }
 124     }
 125
 126     foreach my $cache (@action_cache) {
 127         my $code   = $cache->[0];
 128         my $method = $methods{$code};
 129         next unless $method;
 130         my $attrs = $self->_parse_attrs( $c, $method, @{ $cache->[1] } );
 131         if ( $attrs->{Private} && ( keys %$attrs > 1 ) ) {
 132             $c->log->debug( 'Bad action definition "'
 133                   . join( ' ', @{ $cache->[1] } )
 134                   . qq/" for "$class->$method"/ )
 135               if $c->debug;
 136             next;
 137         }
 138         my $reverse = $namespace ? "$namespace/$method" : $method;
 139         my $action = $self->create_action(
 140             name       => $method,
 141             code       => $code,
 142             reverse    => $reverse,
 143             namespace  => $namespace,
 144             class      => $class,
 145             attributes => $attrs,
 146         );
 147
 148         $c->dispatcher->register( $c, $action );
 149     }
 150 }
 151
 152 sub create_action {
 153     my $self = shift;
 154     $self->_action_class->new( { @_ } );
 155 }
 156
 157 sub _parse_attrs {
 158     my ( $self, $c, $name, @attrs ) = @_;
 159     my %attributes;
 160     foreach my $attr (@attrs) {
 161
 162         # Parse out :Foo(bar) into Foo => bar etc (and arrayify)
 163
 164         if ( my ( $key, $value ) = ( $attr =~ /^(.*?)(?:\(\s*(.+?)\s*\))?$/ ) )
 165         {
 166
 167             if ( defined $value ) {
 168                 ( $value =~ s/^'(.*)'$/$1/ ) || ( $value =~ s/^"(.*)"/$1/ );
 169             }
 170             my $meth = "_parse_${key}_attr";
 171             if ( $self->can($meth) ) {
 172                 ( $key, $value ) = $self->$meth( $c, $name, $value );
 173             }
 174             push( @{ $attributes{$key} }, $value );
 175         }
 176     }
 177     return \%attributes;
 178 }
 179
 180 sub _parse_Global_attr {
 181     my ( $self, $c, $name, $value ) = @_;
 182     return $self->_parse_Path_attr( $c, $name, "/$name" );
 183 }
 184
 185 sub _parse_Absolute_attr { shift->_parse_Global_attr(@_); }
 186
 187 sub _parse_Local_attr {
 188     my ( $self, $c, $name, $value ) = @_;
 189     return $self->_parse_Path_attr( $c, $name, $name );
 190 }
 191
 192 sub _parse_Relative_attr { shift->_parse_Local_attr(@_); }
 193
 194 sub _parse_Path_attr {
 195     my ( $self, $c, $name, $value ) = @_;
 196     $value ||= '';
 197     if ( $value =~ m!^/! ) {
 198         return ( 'Path', $value );
 199     }
 200     elsif ( length $value ) {
 201         return ( 'Path', join( '/', $self->path_prefix($c), $value ) );
 202     }
 203     else {
 204         return ( 'Path', $self->path_prefix($c) );
 205     }
 206 }
 207
 208 sub _parse_Regex_attr {
 209     my ( $self, $c, $name, $value ) = @_;
 210     return ( 'Regex', $value );
 211 }
 212
 213 sub _parse_Regexp_attr { shift->_parse_Regex_attr(@_); }
 214
 215 sub _parse_LocalRegex_attr {
 216     my ( $self, $c, $name, $value ) = @_;
 217     unless ( $value =~ s/^\^// ) { $value = "(?:.*?)$value"; }
 218     return ( 'Regex', '^' . $self->path_prefix($c) . "/${value}" );
 219 }
 220
 221 sub _parse_LocalRegexp_attr { shift->_parse_LocalRegex_attr(@_); }
 222
 223 =head1 SEE ALSO
 224
 225 L<Catalyst>, L<Catalyst::Controller>.
 226
 227 =head1 AUTHOR
 228
 229 Sebastian Riedel, C<sri@cpan.org>
 230 Marcus Ramberg, C<mramberg@cpan.org>
 231 Matt S Trout, C<mst@shadowcatsystems.co.uk>
 232
 233 =head1 COPYRIGHT
 234
 235 This program is free software, you can redistribute it and/or modify it under
 236 the same terms as Perl itself.
 237
 238 =cut
 239
 240 1;