lib/Catalyst/Base.pm

   1 package Catalyst::Base;
   2
   3 use strict;
   4 use base qw/Catalyst::Component Catalyst::AttrContainer Class::Accessor::Fast/;
   5
   6 use Catalyst::Exception;
   7 use Catalyst::Utils;
   8 use Class::Inspector;
   9 use NEXT;
  10
  11 __PACKAGE__->mk_classdata($_) for qw/_dispatch_steps _action_class/;
  12
  13 __PACKAGE__->_dispatch_steps( [qw/_BEGIN _AUTO _ACTION/] );
  14 __PACKAGE__->_action_class('Catalyst::Action');
  15
  16 sub _DISPATCH : Private {
  17     my ( $self, $c ) = @_;
  18
  19     foreach my $disp ( @{ $self->_dispatch_steps } ) {
  20         last unless $c->forward($disp);
  21     }
  22
  23     $c->forward('_END');
  24 }
  25
  26 sub _BEGIN : Private {
  27     my ( $self, $c ) = @_;
  28     my $begin = ( $c->get_actions( 'begin', $c->namespace ) )[-1];
  29     return 1 unless $begin;
  30     $begin->execute($c);
  31     return !@{ $c->error };
  32 }
  33
  34 sub _AUTO : Private {
  35     my ( $self, $c ) = @_;
  36     my @auto = $c->get_actions( 'auto', $c->namespace );
  37     foreach my $auto (@auto) {
  38         $auto->execute($c);
  39         return 0 unless $c->state;
  40     }
  41     return 1;
  42 }
  43
  44 sub _ACTION : Private {
  45     my ( $self, $c ) = @_;
  46     if (   ref $c->action
  47         && $c->action->isa('Catalyst::Action')
  48         && $c->req->action )
  49     {
  50         $c->action->execute($c);
  51     }
  52     return !@{ $c->error };
  53 }
  54
  55 sub _END : Private {
  56     my ( $self, $c ) = @_;
  57     my $end = ( $c->get_actions( 'end', $c->namespace ) )[-1];
  58     return 1 unless $end;
  59     $end->execute($c);
  60     return !@{ $c->error };
  61 }
  62
  63 =head1 NAME
  64
  65 Catalyst::Base - Catalyst Base Class
  66
  67 =head1 SYNOPSIS
  68
  69 See L<Catalyst>
  70
  71 =head1 DESCRIPTION
  72
  73 Catalyst Base Class
  74
  75 =head1 METHODS
  76
  77 =over 4
  78
  79 =item $self->action_namespace($c)
  80
  81 =cut
  82
  83 sub action_namespace {
  84     my ( $self, $c ) = @_;
  85     return Catalyst::Utils::class2prefix( ref $self,
  86         $c->config->{case_sensitive} )
  87       || '';
  88 }
  89
  90 =item $self->register_actions($c)
  91
  92 =cut
  93
  94 sub register_actions {
  95     my ( $self, $c ) = @_;
  96     my $class = ref $self || $self;
  97     my $namespace = $self->action_namespace($c);
  98     my %methods;
  99     $methods{ $self->can($_) } = $_
 100       for @{ Class::Inspector->methods($class) || [] };
 101
 102     # Advanced inheritance support for plugins and the like
 103     my @action_cache;
 104     {
 105         no strict 'refs';
 106         for my $isa ( @{"$class\::ISA"}, $class ) {
 107             push @action_cache, @{ $isa->_action_cache }
 108               if $isa->can('_action_cache');
 109         }
 110     }
 111
 112     foreach my $cache (@action_cache) {
 113         my $code   = $cache->[0];
 114         my $method = $methods{$code};
 115         next unless $method;
 116         my $attrs = $self->_parse_attrs( @{ $cache->[1] } );
 117         if ( $attrs->{Private} && ( keys %$attrs > 1 ) ) {
 118             $c->log->debug( 'Bad action definition "'
 119                   . join( ' ', @{ $cache->[1] } )
 120                   . qq/" for "$class->$method"/ )
 121               if $c->debug;
 122             next;
 123         }
 124         my $reverse = $namespace ? "$namespace/$method" : $method;
 125         my $action = $self->_action_class->new(
 126             {
 127                 name       => $method,
 128                 code       => $code,
 129                 reverse    => $reverse,
 130                 namespace  => $namespace,
 131                 class      => $class,
 132                 attributes => $attrs,
 133             }
 134         );
 135         $c->dispatcher->register( $c, $action );
 136     }
 137 }
 138
 139 sub _parse_attrs {
 140     my ( $self, @attrs ) = @_;
 141     my %attributes;
 142     foreach my $attr (@attrs) {
 143
 144         # Parse out :Foo(bar) into Foo => bar etc (and arrayify)
 145
 146         if ( my ( $key, $value ) = ( $attr =~ /^(.*?)(?:\(\s*(.+?)\s*\))?$/ ) )
 147         {
 148
 149             if ( defined $value ) {
 150                 ( $value =~ s/^'(.*)'$/$1/ ) || ( $value =~ s/^"(.*)"/$1/ );
 151             }
 152             push( @{ $attributes{$key} }, $value );
 153         }
 154     }
 155     return \%attributes;
 156 }
 157
 158 =back
 159
 160 =head1 SEE ALSO
 161
 162 L<Catalyst>, L<Catalyst::Controller>.
 163
 164 =head1 AUTHOR
 165
 166 Sebastian Riedel, C<sri@cpan.org>
 167 Marcus Ramberg, C<mramberg@cpan.org>
 168 Matt S Trout, C<mst@shadowcatsystems.co.uk>
 169
 170 =head1 COPYRIGHT
 171
 172 This program is free software, you can redistribute it and/or modify it under
 173 the same terms as Perl itself.
 174
 175 =cut
 176
 177 1;