lib/Catalyst/Action.pm

   1 package Catalyst::Action;
   2
   3 =head1 NAME
   4
   5 Catalyst::Action - Catalyst Action
   6
   7 =head1 SYNOPSIS
   8
   9     <form action="[%c.uri_for(c.action)%]">
  10
  11 =head1 DESCRIPTION
  12
  13 This class represents a Catalyst Action. You can access the object for the
  14 currently dispatched action via $c->action. See the L<Catalyst::Dispatcher>
  15 for more information on how actions are dispatched. Actions are defined in
  16 L<Catalyst::Controller> subclasses.
  17
  18 =cut
  19
  20 use Moose;
  21 use Scalar::Util 'looks_like_number';
  22 with 'MooseX::Emulate::Class::Accessor::Fast';
  23 use namespace::clean -except => 'meta';
  24
  25 has class => (is => 'rw');
  26 has namespace => (is => 'rw');
  27 has 'reverse' => (is => 'rw');
  28 has attributes => (is => 'rw');
  29 has name => (is => 'rw');
  30 has code => (is => 'rw');
  31
  32 use overload (
  33
  34     # Stringify to reverse for debug output etc.
  35     q{""} => sub { shift->{reverse} },
  36
  37     # Codulate to execute to invoke the encapsulated action coderef
  38     '&{}' => sub { my $self = shift; sub { $self->execute(@_); }; },
  39
  40     # Which action takes precedence
  41     'cmp' => 'compare',
  42     '<=>' => 'compare',
  43
  44     # Make general $stuff still work
  45     fallback => 1,
  46
  47 );
  48
  49
  50
  51 no warnings 'recursion';
  52
  53 #__PACKAGE__->mk_accessors(qw/class namespace reverse attributes name code/);
  54
  55 sub dispatch {    # Execute ourselves against a context
  56     my ( $self, $c ) = @_;
  57     return $c->execute( $self->class, $self );
  58 }
  59
  60 sub execute {
  61   my $self = shift;
  62   $self->code->(@_);
  63 }
  64
  65 sub match {
  66     my ( $self, $c ) = @_;
  67     #would it be unreasonable to store the number of arguments
  68     #the action has as its own attribute?
  69     #it would basically eliminate the code below.  ehhh. small fish
  70     return 1 unless exists $self->attributes->{Args};
  71     my $args = $self->attributes->{Args}[0];
  72     return 1 unless defined($args) && length($args);
  73     return scalar( @{ $c->req->args } ) == $args;
  74 }
  75
  76 sub sort_order {
  77     my $self = shift;
  78
  79     my ($args) = @{ $self->attributes->{Args} || [] };
  80
  81     return $args if looks_like_number($args);
  82
  83     return ~0;
  84 }
  85
  86 sub compare {
  87     my ($a1, $a2) = @_;
  88
  89     return $a1->sort_order <=> $a2->sort_order;
  90 }
  91
  92 __PACKAGE__->meta->make_immutable;
  93
  94 1;
  95
  96 __END__
  97
  98 =head1 METHODS
  99
 100 =head2 attributes
 101
 102 The sub attributes that are set for this action, like Local, Path, Private
 103 and so on. This determines how the action is dispatched to.
 104
 105 =head2 class
 106
 107 Returns the class name where this action is defined.
 108
 109 =head2 code
 110
 111 Returns a code reference to this action.
 112
 113 =head2 dispatch( $c )
 114
 115 Dispatch this action against a context
 116
 117 =head2 execute( $controller, $c, @args )
 118
 119 Execute this action's coderef against a given controller with a given
 120 context and arguments
 121
 122 =head2 match( $c )
 123
 124 Check Args attribute, and makes sure number of args matches the setting.
 125 Always returns true if Args is omitted.
 126
 127 =head2 namespace
 128
 129 Returns the private namespace this action lives in.
 130
 131 =head2 reverse
 132
 133 Returns the private path for this action.
 134
 135 =head2 name
 136
 137 returns the sub name of this action.
 138
 139 =head2 meta
 140
 141 Provided by Moose
 142
 143 =head1 AUTHORS
 144
 145 Catalyst Contributors, see Catalyst.pm
 146
 147 =head1 COPYRIGHT
 148
 149 This library is free software. You can redistribute it and/or modify it under
 150 the same terms as Perl itself.
 151
 152 =cut