lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use namespace::clean -except => 'meta';
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use Module::Pluggable::Object ();
  20 use Text::SimpleTable ();
  21 use Path::Class::Dir ();
  22 use Path::Class::File ();
  23 use URI ();
  24 use URI::http;
  25 use URI::https;
  26 use HTML::Entities;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use List::MoreUtils qw/uniq/;
  31 use attributes;
  32 use String::RewritePrefix;
  33 use Catalyst::EngineLoader;
  34 use utf8;
  35 use Carp qw/croak carp shortmess/;
  36 use Try::Tiny;
  37 use Safe::Isa;
  38 use Plack::Middleware::Conditional;
  39 use Plack::Middleware::ReverseProxy;
  40 use Plack::Middleware::IIS6ScriptNameFix;
  41 use Plack::Middleware::IIS7KeepAliveFix;
  42 use Plack::Middleware::LighttpdScriptNameFix;
  43 use Plack::Util;
  44
  45 BEGIN { require 5.008003; }
  46
  47 has stack => (is => 'ro', default => sub { [] });
  48 has stash => (is => 'rw', default => sub { {} });
  49 has state => (is => 'rw', default => 0);
  50 has stats => (is => 'rw');
  51 has action => (is => 'rw');
  52 has counter => (is => 'rw', default => sub { {} });
  53 has request => (
  54     is => 'rw',
  55     default => sub {
  56         my $self = shift;
  57         $self->request_class->new($self->_build_request_constructor_args);
  58     },
  59     lazy => 1,
  60 );
  61 sub _build_request_constructor_args {
  62     my $self = shift;
  63     my %p = ( _log => $self->log );
  64     $p{_uploadtmp} = $self->_uploadtmp if $self->_has_uploadtmp;
  65     \%p;
  66 }
  67
  68 has response => (
  69     is => 'rw',
  70     default => sub {
  71         my $self = shift;
  72         $self->response_class->new($self->_build_response_constructor_args);
  73     },
  74     lazy => 1,
  75 );
  76 sub _build_response_constructor_args {
  77     my $self = shift;
  78     { _log => $self->log };
  79 }
  80
  81 has namespace => (is => 'rw');
  82
  83 sub depth { scalar @{ shift->stack || [] }; }
  84 sub comp { shift->component(@_) }
  85
  86 sub req {
  87     my $self = shift; return $self->request(@_);
  88 }
  89 sub res {
  90     my $self = shift; return $self->response(@_);
  91 }
  92
  93 # For backwards compatibility
  94 sub finalize_output { shift->finalize_body(@_) };
  95
  96 # For statistics
  97 our $COUNT     = 1;
  98 our $START     = time;
  99 our $RECURSION = 1000;
 100 our $DETACH    = Catalyst::Exception::Detach->new;
 101 our $GO        = Catalyst::Exception::Go->new;
 102
 103 #I imagine that very few of these really need to be class variables. if any.
 104 #maybe we should just make them attributes with a default?
 105 __PACKAGE__->mk_classdata($_)
 106   for qw/components arguments dispatcher engine log dispatcher_class
 107   engine_loader context_class request_class response_class stats_class
 108   setup_finished _psgi_app loading_psgi_file run_options _psgi_middleware/;
 109
 110 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
 111 __PACKAGE__->request_class('Catalyst::Request');
 112 __PACKAGE__->response_class('Catalyst::Response');
 113 __PACKAGE__->stats_class('Catalyst::Stats');
 114
 115 # Remember to update this in Catalyst::Runtime as well!
 116
 117 our $VERSION = '5.90049_001';
 118
 119 sub import {
 120     my ( $class, @arguments ) = @_;
 121
 122     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
 123     # callers @ISA.
 124     return unless $class eq 'Catalyst';
 125
 126     my $caller = caller();
 127     return if $caller eq 'main';
 128
 129     my $meta = Moose::Meta::Class->initialize($caller);
 130     unless ( $caller->isa('Catalyst') ) {
 131         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 132         $meta->superclasses(@superclasses);
 133     }
 134     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 135     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 136
 137     unless( $meta->has_method('meta') ){
 138         if ($Moose::VERSION >= 1.15) {
 139             $meta->_add_meta_method('meta');
 140         }
 141         else {
 142             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 143         }
 144     }
 145
 146     $caller->arguments( [@arguments] );
 147     $caller->setup_home;
 148 }
 149
 150 sub _application { $_[0] }
 151
 152 =encoding UTF-8
 153
 154 =head1 NAME
 155
 156 Catalyst - The Elegant MVC Web Application Framework
 157
 158 =head1 SYNOPSIS
 159
 160 See the L<Catalyst::Manual> distribution for comprehensive
 161 documentation and tutorials.
 162
 163     # Install Catalyst::Devel for helpers and other development tools
 164     # use the helper to create a new application
 165     catalyst.pl MyApp
 166
 167     # add models, views, controllers
 168     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 169     script/myapp_create.pl view MyTemplate TT
 170     script/myapp_create.pl controller Search
 171
 172     # built in testserver -- use -r to restart automatically on changes
 173     # --help to see all available options
 174     script/myapp_server.pl
 175
 176     # command line testing interface
 177     script/myapp_test.pl /yada
 178
 179     ### in lib/MyApp.pm
 180     use Catalyst qw/-Debug/; # include plugins here as well
 181
 182     ### In lib/MyApp/Controller/Root.pm (autocreated)
 183     sub foo : Chained('/') Args() { # called for /foo, /foo/1, /foo/1/2, etc.
 184         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 185         $c->stash->{template} = 'foo.tt'; # set the template
 186         # lookup something from db -- stash vars are passed to TT
 187         $c->stash->{data} =
 188           $c->model('Database::Foo')->search( { country => $args[0] } );
 189         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 190             $c->forward( 'bar' ); # process another action
 191             # do something else after forward returns
 192         }
 193     }
 194
 195     # The foo.tt TT template can use the stash data from the database
 196     [% WHILE (item = data.next) %]
 197         [% item.foo %]
 198     [% END %]
 199
 200     # called for /bar/of/soap, /bar/of/soap/10, etc.
 201     sub bar : Chained('/') PathPart('/bar/of/soap') Args() { ... }
 202
 203     # called after all actions are finished
 204     sub end : Action {
 205         my ( $self, $c ) = @_;
 206         if ( scalar @{ $c->error } ) { ... } # handle errors
 207         return if $c->res->body; # already have a response
 208         $c->forward( 'MyApp::View::TT' ); # render template
 209     }
 210
 211 See L<Catalyst::Manual::Intro> for additional information.
 212
 213 =head1 DESCRIPTION
 214
 215 Catalyst is a modern framework for making web applications without the
 216 pain usually associated with this process. This document is a reference
 217 to the main Catalyst application. If you are a new user, we suggest you
 218 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 219
 220 See L<Catalyst::Manual> for more documentation.
 221
 222 Catalyst plugins can be loaded by naming them as arguments to the "use
 223 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 224 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 225 C<My::Module>.
 226
 227     use Catalyst qw/My::Module/;
 228
 229 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 230 fully qualify the name by using a unary plus:
 231
 232     use Catalyst qw/
 233         My::Module
 234         +Fully::Qualified::Plugin::Name
 235     /;
 236
 237 Special flags like C<-Debug> can also be specified as
 238 arguments when Catalyst is loaded:
 239
 240     use Catalyst qw/-Debug My::Module/;
 241
 242 The position of plugins and flags in the chain is important, because
 243 they are loaded in the order in which they appear.
 244
 245 The following flags are supported:
 246
 247 =head2 -Debug
 248
 249 Enables debug output. You can also force this setting from the system
 250 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 251 settings override the application, with <MYAPP>_DEBUG having the highest
 252 priority.
 253
 254 This sets the log level to 'debug' and enables full debug output on the
 255 error screen. If you only want the latter, see L<< $c->debug >>.
 256
 257 =head2 -Home
 258
 259 Forces Catalyst to use a specific home directory, e.g.:
 260
 261     use Catalyst qw[-Home=/usr/mst];
 262
 263 This can also be done in the shell environment by setting either the
 264 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 265 is replaced with the uppercased name of your application, any "::" in
 266 the name will be replaced with underscores, e.g. MyApp::Web should use
 267 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 268
 269 If none of these are set, Catalyst will attempt to automatically detect the
 270 home directory. If you are working in a development environment, Catalyst
 271 will try and find the directory containing either Makefile.PL, Build.PL,
 272 dist.ini, or cpanfile. If the application has been installed into the system
 273 (i.e. you have done C<make install>), then Catalyst will use the path to your
 274 application module, without the .pm extension (e.g., /foo/MyApp if your
 275 application was installed at /foo/MyApp.pm)
 276
 277 =head2 -Log
 278
 279     use Catalyst '-Log=warn,fatal,error';
 280
 281 Specifies a comma-delimited list of log levels.
 282
 283 =head2 -Stats
 284
 285 Enables statistics collection and reporting.
 286
 287    use Catalyst qw/-Stats=1/;
 288
 289 You can also force this setting from the system environment with CATALYST_STATS
 290 or <MYAPP>_STATS. The environment settings override the application, with
 291 <MYAPP>_STATS having the highest priority.
 292
 293 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 294
 295 =head1 METHODS
 296
 297 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 298
 299 =head2 $c->action
 300
 301 Returns a L<Catalyst::Action> object for the current action, which
 302 stringifies to the action name. See L<Catalyst::Action>.
 303
 304 =head2 $c->namespace
 305
 306 Returns the namespace of the current action, i.e., the URI prefix
 307 corresponding to the controller of the current action. For example:
 308
 309     # in Controller::Foo::Bar
 310     $c->namespace; # returns 'foo/bar';
 311
 312 =head2 $c->request
 313
 314 =head2 $c->req
 315
 316 Returns the current L<Catalyst::Request> object, giving access to
 317 information about the current client request (including parameters,
 318 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 319
 320 =head2 REQUEST FLOW HANDLING
 321
 322 =head2 $c->forward( $action [, \@arguments ] )
 323
 324 =head2 $c->forward( $class, $method, [, \@arguments ] )
 325
 326 Forwards processing to another action, by its private name. If you give a
 327 class name but no method, C<process()> is called. You may also optionally
 328 pass arguments in an arrayref. The action will receive the arguments in
 329 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 330 C<< $c->req->args >> will be restored to the previous values.
 331
 332 Any data C<return>ed from the action forwarded to, will be returned by the
 333 call to forward.
 334
 335     my $foodata = $c->forward('/foo');
 336     $c->forward('index');
 337     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 338     $c->forward('View::TT');
 339
 340 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 341 an C<< eval { } >> around the call (actually
 342 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus rendering all
 343 exceptions thrown by the called action non-fatal and pushing them onto
 344 $c->error instead. If you want C<die> to propagate you need to do something
 345 like:
 346
 347     $c->forward('foo');
 348     die join "\n", @{ $c->error } if @{ $c->error };
 349
 350 Or make sure to always return true values from your actions and write
 351 your code like this:
 352
 353     $c->forward('foo') || return;
 354
 355 Another note is that C<< $c->forward >> always returns a scalar because it
 356 actually returns $c->state which operates in a scalar context.
 357 Thus, something like:
 358
 359     return @array;
 360
 361 in an action that is forwarded to is going to return a scalar,
 362 i.e. how many items are in that array, which is probably not what you want.
 363 If you need to return an array then return a reference to it,
 364 or stash it like so:
 365
 366     $c->stash->{array} = \@array;
 367
 368 and access it from the stash.
 369
 370 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 371
 372 =cut
 373
 374 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 375
 376 =head2 $c->detach( $action [, \@arguments ] )
 377
 378 =head2 $c->detach( $class, $method, [, \@arguments ] )
 379
 380 =head2 $c->detach()
 381
 382 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 383 doesn't return to the previous action when processing is finished.
 384
 385 When called with no arguments it escapes the processing chain entirely.
 386
 387 =cut
 388
 389 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 390
 391 =head2 $c->visit( $action [, \@arguments ] )
 392
 393 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 394
 395 =head2 $c->visit( $class, $method, [, \@arguments ] )
 396
 397 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 398
 399 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 400 but does a full dispatch, instead of just calling the new C<$action> /
 401 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 402 you go to are called, just like a new request.
 403
 404 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 405 This means, for example, that C<< $c->action >> methods such as
 406 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 407 L<reverse|Catalyst::Action/reverse> return information for the visited action
 408 when they are invoked within the visited action.  This is different from the
 409 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 410 continues to use the $c->action object from the caller action even when
 411 invoked from the called action.
 412
 413 C<< $c->stash >> is kept unchanged.
 414
 415 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 416 allows you to "wrap" another action, just as it would have been called by
 417 dispatching from a URL, while the analogous
 418 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 419 transfer control to another action as if it had been reached directly from a URL.
 420
 421 =cut
 422
 423 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 424
 425 =head2 $c->go( $action [, \@arguments ] )
 426
 427 =head2 $c->go( $action [, \@captures, \@arguments ] )
 428
 429 =head2 $c->go( $class, $method, [, \@arguments ] )
 430
 431 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 432
 433 The relationship between C<go> and
 434 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 435 the relationship between
 436 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 437 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 438 C<< $c->go >> will perform a full dispatch on the specified action or method,
 439 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 440 C<go> escapes the processing of the current request chain on completion, and
 441 does not return to its caller.
 442
 443 @arguments are arguments to the final destination of $action. @captures are
 444 arguments to the intermediate steps, if any, on the way to the final sub of
 445 $action.
 446
 447 =cut
 448
 449 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 450
 451 =head2 $c->response
 452
 453 =head2 $c->res
 454
 455 Returns the current L<Catalyst::Response> object, see there for details.
 456
 457 =head2 $c->stash
 458
 459 Returns a hashref to the stash, which may be used to store data and pass
 460 it between components during a request. You can also set hash keys by
 461 passing arguments. The stash is automatically sent to the view. The
 462 stash is cleared at the end of a request; it cannot be used for
 463 persistent storage (for this you must use a session; see
 464 L<Catalyst::Plugin::Session> for a complete system integrated with
 465 Catalyst).
 466
 467     $c->stash->{foo} = $bar;
 468     $c->stash( { moose => 'majestic', qux => 0 } );
 469     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 470
 471     # stash is automatically passed to the view for use in a template
 472     $c->forward( 'MyApp::View::TT' );
 473
 474 =cut
 475
 476 around stash => sub {
 477     my $orig = shift;
 478     my $c = shift;
 479     my $stash = $orig->($c);
 480     if (@_) {
 481         my $new_stash = @_ > 1 ? {@_} : $_[0];
 482         croak('stash takes a hash or hashref') unless ref $new_stash;
 483         foreach my $key ( keys %$new_stash ) {
 484           $stash->{$key} = $new_stash->{$key};
 485         }
 486     }
 487
 488     return $stash;
 489 };
 490
 491
 492 =head2 $c->error
 493
 494 =head2 $c->error($error, ...)
 495
 496 =head2 $c->error($arrayref)
 497
 498 Returns an arrayref containing error messages.  If Catalyst encounters an
 499 error while processing a request, it stores the error in $c->error.  This
 500 method should only be used to store fatal error messages.
 501
 502     my @error = @{ $c->error };
 503
 504 Add a new error.
 505
 506     $c->error('Something bad happened');
 507
 508 =cut
 509
 510 sub error {
 511     my $c = shift;
 512     if ( $_[0] ) {
 513         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 514         croak @$error unless ref $c;
 515         push @{ $c->{error} }, @$error;
 516     }
 517     elsif ( defined $_[0] ) { $c->{error} = undef }
 518     return $c->{error} || [];
 519 }
 520
 521
 522 =head2 $c->state
 523
 524 Contains the return value of the last executed action.
 525 Note that << $c->state >> operates in a scalar context which means that all
 526 values it returns are scalar.
 527
 528 =head2 $c->clear_errors
 529
 530 Clear errors.  You probably don't want to clear the errors unless you are
 531 implementing a custom error screen.
 532
 533 This is equivalent to running
 534
 535     $c->error(0);
 536
 537 =cut
 538
 539 sub clear_errors {
 540     my $c = shift;
 541     $c->error(0);
 542 }
 543
 544 sub _comp_search_prefixes {
 545     my $c = shift;
 546     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 547 }
 548
 549 # search components given a name and some prefixes
 550 sub _comp_names_search_prefixes {
 551     my ( $c, $name, @prefixes ) = @_;
 552     my $appclass = ref $c || $c;
 553     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 554     $filter = qr/$filter/; # Compile regex now rather than once per loop
 555
 556     # map the original component name to the sub part that we will search against
 557     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 558         grep { /$filter/ } keys %{ $c->components };
 559
 560     # undef for a name will return all
 561     return keys %eligible if !defined $name;
 562
 563     my $query  = $name->$_isa('Regexp') ? $name : qr/^$name$/i;
 564     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 565
 566     return @result if @result;
 567
 568     # if we were given a regexp to search against, we're done.
 569     return if $name->$_isa('Regexp');
 570
 571     # skip regexp fallback if configured
 572     return
 573         if $appclass->config->{disable_component_resolution_regex_fallback};
 574
 575     # regexp fallback
 576     $query  = qr/$name/i;
 577     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 578
 579     # no results? try against full names
 580     if( !@result ) {
 581         @result = grep { m{$query} } keys %eligible;
 582     }
 583
 584     # don't warn if we didn't find any results, it just might not exist
 585     if( @result ) {
 586         # Disgusting hack to work out correct method name
 587         my $warn_for = lc $prefixes[0];
 588         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 589            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 590            "component resolution is unreliable and unsafe.";
 591         my $short = $result[0];
 592         # remove the component namespace prefix
 593         $short =~ s/.*?(Model|Controller|View):://;
 594         my $shortmess = Carp::shortmess('');
 595         if ($shortmess =~ m#Catalyst/Plugin#) {
 596            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 597               "plugin's config";
 598         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 599            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 600               "component's config";
 601         } else {
 602            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 603               "but if you really wanted to search, pass in a regexp as the argument " .
 604               "like so: \$c->${warn_for}(qr/${name}/)";
 605         }
 606         $c->log->warn( "${msg}$shortmess" );
 607     }
 608
 609     return @result;
 610 }
 611
 612 # Find possible names for a prefix
 613 sub _comp_names {
 614     my ( $c, @prefixes ) = @_;
 615     my $appclass = ref $c || $c;
 616
 617     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 618
 619     my @names = map { s{$filter}{}; $_; }
 620         $c->_comp_names_search_prefixes( undef, @prefixes );
 621
 622     return @names;
 623 }
 624
 625 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 626 sub _filter_component {
 627     my ( $c, $comp, @args ) = @_;
 628
 629     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 630         return $comp->ACCEPT_CONTEXT( $c, @args );
 631     }
 632
 633     return $comp;
 634 }
 635
 636 =head2 COMPONENT ACCESSORS
 637
 638 =head2 $c->controller($name)
 639
 640 Gets a L<Catalyst::Controller> instance by name.
 641
 642     $c->controller('Foo')->do_stuff;
 643
 644 If the name is omitted, will return the controller for the dispatched
 645 action.
 646
 647 If you want to search for controllers, pass in a regexp as the argument.
 648
 649     # find all controllers that start with Foo
 650     my @foo_controllers = $c->controller(qr{^Foo});
 651
 652
 653 =cut
 654
 655 sub controller {
 656     my ( $c, $name, @args ) = @_;
 657
 658     my $appclass = ref($c) || $c;
 659     if( $name ) {
 660         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 661             my $comps = $c->components;
 662             my $check = $appclass."::Controller::".$name;
 663             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 664         }
 665         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 666         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 667         return $c->_filter_component( $result[ 0 ], @args );
 668     }
 669
 670     return $c->component( $c->action->class );
 671 }
 672
 673 =head2 $c->model($name)
 674
 675 Gets a L<Catalyst::Model> instance by name.
 676
 677     $c->model('Foo')->do_stuff;
 678
 679 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 680
 681 If the name is omitted, it will look for
 682  - a model object in $c->stash->{current_model_instance}, then
 683  - a model name in $c->stash->{current_model}, then
 684  - a config setting 'default_model', or
 685  - check if there is only one model, and return it if that's the case.
 686
 687 If you want to search for models, pass in a regexp as the argument.
 688
 689     # find all models that start with Foo
 690     my @foo_models = $c->model(qr{^Foo});
 691
 692 =cut
 693
 694 sub model {
 695     my ( $c, $name, @args ) = @_;
 696     my $appclass = ref($c) || $c;
 697     if( $name ) {
 698         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 699             my $comps = $c->components;
 700             my $check = $appclass."::Model::".$name;
 701             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 702         }
 703         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 704         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 705         return $c->_filter_component( $result[ 0 ], @args );
 706     }
 707
 708     if (ref $c) {
 709         return $c->stash->{current_model_instance}
 710           if $c->stash->{current_model_instance};
 711         return $c->model( $c->stash->{current_model} )
 712           if $c->stash->{current_model};
 713     }
 714     return $c->model( $appclass->config->{default_model} )
 715       if $appclass->config->{default_model};
 716
 717     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 718
 719     if( $rest ) {
 720         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 721         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 722         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 723         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 724         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 725     }
 726
 727     return $c->_filter_component( $comp );
 728 }
 729
 730
 731 =head2 $c->view($name)
 732
 733 Gets a L<Catalyst::View> instance by name.
 734
 735     $c->view('Foo')->do_stuff;
 736
 737 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 738
 739 If the name is omitted, it will look for
 740  - a view object in $c->stash->{current_view_instance}, then
 741  - a view name in $c->stash->{current_view}, then
 742  - a config setting 'default_view', or
 743  - check if there is only one view, and return it if that's the case.
 744
 745 If you want to search for views, pass in a regexp as the argument.
 746
 747     # find all views that start with Foo
 748     my @foo_views = $c->view(qr{^Foo});
 749
 750 =cut
 751
 752 sub view {
 753     my ( $c, $name, @args ) = @_;
 754
 755     my $appclass = ref($c) || $c;
 756     if( $name ) {
 757         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 758             my $comps = $c->components;
 759             my $check = $appclass."::View::".$name;
 760             if( exists $comps->{$check} ) {
 761                 return $c->_filter_component( $comps->{$check}, @args );
 762             }
 763             else {
 764                 $c->log->warn( "Attempted to use view '$check', but does not exist" );
 765             }
 766         }
 767         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 768         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 769         return $c->_filter_component( $result[ 0 ], @args );
 770     }
 771
 772     if (ref $c) {
 773         return $c->stash->{current_view_instance}
 774           if $c->stash->{current_view_instance};
 775         return $c->view( $c->stash->{current_view} )
 776           if $c->stash->{current_view};
 777     }
 778     return $c->view( $appclass->config->{default_view} )
 779       if $appclass->config->{default_view};
 780
 781     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 782
 783     if( $rest ) {
 784         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 785         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 786         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 787         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 788         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 789     }
 790
 791     return $c->_filter_component( $comp );
 792 }
 793
 794 =head2 $c->controllers
 795
 796 Returns the available names which can be passed to $c->controller
 797
 798 =cut
 799
 800 sub controllers {
 801     my ( $c ) = @_;
 802     return $c->_comp_names(qw/Controller C/);
 803 }
 804
 805 =head2 $c->models
 806
 807 Returns the available names which can be passed to $c->model
 808
 809 =cut
 810
 811 sub models {
 812     my ( $c ) = @_;
 813     return $c->_comp_names(qw/Model M/);
 814 }
 815
 816
 817 =head2 $c->views
 818
 819 Returns the available names which can be passed to $c->view
 820
 821 =cut
 822
 823 sub views {
 824     my ( $c ) = @_;
 825     return $c->_comp_names(qw/View V/);
 826 }
 827
 828 =head2 $c->comp($name)
 829
 830 =head2 $c->component($name)
 831
 832 Gets a component object by name. This method is not recommended,
 833 unless you want to get a specific component by full
 834 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 835 should be used instead.
 836
 837 If C<$name> is a regexp, a list of components matched against the full
 838 component name will be returned.
 839
 840 If Catalyst can't find a component by name, it will fallback to regex
 841 matching by default. To disable this behaviour set
 842 disable_component_resolution_regex_fallback to a true value.
 843
 844     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 845
 846 =cut
 847
 848 sub component {
 849     my ( $c, $name, @args ) = @_;
 850
 851     if( $name ) {
 852         my $comps = $c->components;
 853
 854         if( !ref $name ) {
 855             # is it the exact name?
 856             return $c->_filter_component( $comps->{ $name }, @args )
 857                        if exists $comps->{ $name };
 858
 859             # perhaps we just omitted "MyApp"?
 860             my $composed = ( ref $c || $c ) . "::${name}";
 861             return $c->_filter_component( $comps->{ $composed }, @args )
 862                        if exists $comps->{ $composed };
 863
 864             # search all of the models, views and controllers
 865             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 866             return $c->_filter_component( $comp, @args ) if $comp;
 867         }
 868
 869         return
 870             if $c->config->{disable_component_resolution_regex_fallback};
 871
 872         # This is here so $c->comp( '::M::' ) works
 873         my $query = ref $name ? $name : qr{$name}i;
 874
 875         my @result = grep { m{$query} } keys %{ $c->components };
 876         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 877
 878         if( $result[ 0 ] ) {
 879             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 880             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 881             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 882             return $c->_filter_component( $result[ 0 ], @args );
 883         }
 884
 885         # I would expect to return an empty list here, but that breaks back-compat
 886     }
 887
 888     # fallback
 889     return sort keys %{ $c->components };
 890 }
 891
 892 =head2 CLASS DATA AND HELPER CLASSES
 893
 894 =head2 $c->config
 895
 896 Returns or takes a hashref containing the application's configuration.
 897
 898     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 899
 900 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 901 like C<myapp.conf> in your applications home directory. See
 902 L<Catalyst::Plugin::ConfigLoader>.
 903
 904 =head3 Cascading configuration
 905
 906 The config method is present on all Catalyst components, and configuration
 907 will be merged when an application is started. Configuration loaded with
 908 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 909 followed by configuration in your top level C<MyApp> class. These two
 910 configurations are merged, and then configuration data whose hash key matches a
 911 component name is merged with configuration for that component.
 912
 913 The configuration for a component is then passed to the C<new> method when a
 914 component is constructed.
 915
 916 For example:
 917
 918     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 919     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 920
 921 will mean that C<MyApp::Model::Foo> receives the following data when
 922 constructed:
 923
 924     MyApp::Model::Foo->new({
 925         bar => 'baz',
 926         quux => 'frob',
 927         overrides => 'me',
 928     });
 929
 930 It's common practice to use a Moose attribute
 931 on the receiving component to access the config value.
 932
 933     package MyApp::Model::Foo;
 934
 935     use Moose;
 936
 937     # this attr will receive 'baz' at construction time
 938     has 'bar' => (
 939         is  => 'rw',
 940         isa => 'Str',
 941     );
 942
 943 You can then get the value 'baz' by calling $c->model('Foo')->bar
 944 (or $self->bar inside code in the model).
 945
 946 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
 947 as a way of reading config within your code, as this B<will not> give you the
 948 correctly merged config back. You B<MUST> take the config values supplied to
 949 the constructor and use those instead.
 950
 951 =cut
 952
 953 around config => sub {
 954     my $orig = shift;
 955     my $c = shift;
 956
 957     croak('Setting config after setup has been run is not allowed.')
 958         if ( @_ and $c->setup_finished );
 959
 960     $c->$orig(@_);
 961 };
 962
 963 =head2 $c->log
 964
 965 Returns the logging object instance. Unless it is already set, Catalyst
 966 sets this up with a L<Catalyst::Log> object. To use your own log class,
 967 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 968 C<< __PACKAGE__->setup >>.
 969
 970  __PACKAGE__->log( MyLogger->new );
 971  __PACKAGE__->setup;
 972
 973 And later:
 974
 975     $c->log->info( 'Now logging with my own logger!' );
 976
 977 Your log class should implement the methods described in
 978 L<Catalyst::Log>.
 979
 980
 981 =head2 $c->debug
 982
 983 Returns 1 if debug mode is enabled, 0 otherwise.
 984
 985 You can enable debug mode in several ways:
 986
 987 =over
 988
 989 =item By calling myapp_server.pl with the -d flag
 990
 991 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 992
 993 =item The -Debug option in your MyApp.pm
 994
 995 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 996
 997 =back
 998
 999 The first three also set the log level to 'debug'.
1000
1001 Calling C<< $c->debug(1) >> has no effect.
1002
1003 =cut
1004
1005 sub debug { 0 }
1006
1007 =head2 $c->dispatcher
1008
1009 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
1010
1011 =head2 $c->engine
1012
1013 Returns the engine instance. See L<Catalyst::Engine>.
1014
1015
1016 =head2 UTILITY METHODS
1017
1018 =head2 $c->path_to(@path)
1019
1020 Merges C<@path> with C<< $c->config->{home} >> and returns a
1021 L<Path::Class::Dir> object. Note you can usually use this object as
1022 a filename, but sometimes you will have to explicitly stringify it
1023 yourself by calling the C<< ->stringify >> method.
1024
1025 For example:
1026
1027     $c->path_to( 'db', 'sqlite.db' );
1028
1029 =cut
1030
1031 sub path_to {
1032     my ( $c, @path ) = @_;
1033     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
1034     if ( -d $path ) { return $path }
1035     else { return Path::Class::File->new( $c->config->{home}, @path ) }
1036 }
1037
1038 sub plugin {
1039     my ( $class, $name, $plugin, @args ) = @_;
1040
1041     # See block comment in t/unit_core_plugin.t
1042     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in a future release/);
1043
1044     $class->_register_plugin( $plugin, 1 );
1045
1046     eval { $plugin->import };
1047     $class->mk_classdata($name);
1048     my $obj;
1049     eval { $obj = $plugin->new(@args) };
1050
1051     if ($@) {
1052         Catalyst::Exception->throw( message =>
1053               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1054     }
1055
1056     $class->$name($obj);
1057     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1058       if $class->debug;
1059 }
1060
1061 =head2 MyApp->setup
1062
1063 Initializes the dispatcher and engine, loads any plugins, and loads the
1064 model, view, and controller components. You may also specify an array
1065 of plugins to load here, if you choose to not load them in the C<use
1066 Catalyst> line.
1067
1068     MyApp->setup;
1069     MyApp->setup( qw/-Debug/ );
1070
1071 B<Note:> You B<should not> wrap this method with method modifiers
1072 or bad things will happen - wrap the C<setup_finalize> method instead.
1073
1074 =cut
1075
1076 sub setup {
1077     my ( $class, @arguments ) = @_;
1078     croak('Running setup more than once')
1079         if ( $class->setup_finished );
1080
1081     unless ( $class->isa('Catalyst') ) {
1082
1083         Catalyst::Exception->throw(
1084             message => qq/'$class' does not inherit from Catalyst/ );
1085     }
1086
1087     if ( $class->arguments ) {
1088         @arguments = ( @arguments, @{ $class->arguments } );
1089     }
1090
1091     # Process options
1092     my $flags = {};
1093
1094     foreach (@arguments) {
1095
1096         if (/^-Debug$/) {
1097             $flags->{log} =
1098               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1099         }
1100         elsif (/^-(\w+)=?(.*)$/) {
1101             $flags->{ lc $1 } = $2;
1102         }
1103         else {
1104             push @{ $flags->{plugins} }, $_;
1105         }
1106     }
1107
1108     $class->setup_home( delete $flags->{home} );
1109
1110     $class->setup_log( delete $flags->{log} );
1111     $class->setup_plugins( delete $flags->{plugins} );
1112     $class->setup_middleware();
1113     $class->setup_dispatcher( delete $flags->{dispatcher} );
1114     if (my $engine = delete $flags->{engine}) {
1115         $class->log->warn("Specifying the engine in ->setup is no longer supported, see Catalyst::Upgrading");
1116     }
1117     $class->setup_engine();
1118     $class->setup_stats( delete $flags->{stats} );
1119
1120     for my $flag ( sort keys %{$flags} ) {
1121
1122         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1123             &$code( $class, delete $flags->{$flag} );
1124         }
1125         else {
1126             $class->log->warn(qq/Unknown flag "$flag"/);
1127         }
1128     }
1129
1130     eval { require Catalyst::Devel; };
1131     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1132         $class->log->warn(<<"EOF");
1133 You are running an old script!
1134
1135   Please update by running (this will overwrite existing files):
1136     catalyst.pl -force -scripts $class
1137
1138   or (this will not overwrite existing files):
1139     catalyst.pl -scripts $class
1140
1141 EOF
1142     }
1143
1144     if ( $class->debug ) {
1145         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1146
1147         if (@plugins) {
1148             my $column_width = Catalyst::Utils::term_width() - 6;
1149             my $t = Text::SimpleTable->new($column_width);
1150             $t->row($_) for @plugins;
1151             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1152         }
1153
1154         my @middleware = map { ref $_ eq 'CODE' ? "Inline Coderef" : (ref($_) .'  '. $_->VERSION || '')  }
1155           $class->registered_middlewares;
1156
1157         if (@middleware) {
1158             my $column_width = Catalyst::Utils::term_width() - 6;
1159             my $t = Text::SimpleTable->new($column_width);
1160             $t->row($_) for @middleware;
1161             $class->log->debug( "Loaded PSGI Middleware:\n" . $t->draw . "\n" );
1162         }
1163
1164         my $dispatcher = $class->dispatcher;
1165         my $engine     = $class->engine;
1166         my $home       = $class->config->{home};
1167
1168         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1169         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1170
1171         $home
1172           ? ( -d $home )
1173           ? $class->log->debug(qq/Found home "$home"/)
1174           : $class->log->debug(qq/Home "$home" doesn't exist/)
1175           : $class->log->debug(q/Couldn't find home/);
1176     }
1177
1178     # Call plugins setup, this is stupid and evil.
1179     # Also screws C3 badly on 5.10, hack to avoid.
1180     {
1181         no warnings qw/redefine/;
1182         local *setup = sub { };
1183         $class->setup unless $Catalyst::__AM_RESTARTING;
1184     }
1185
1186     # Initialize our data structure
1187     $class->components( {} );
1188
1189     $class->setup_components;
1190
1191     if ( $class->debug ) {
1192         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1193         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1194         for my $comp ( sort keys %{ $class->components } ) {
1195             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1196             $t->row( $comp, $type );
1197         }
1198         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1199           if ( keys %{ $class->components } );
1200     }
1201
1202     # Add our self to components, since we are also a component
1203     if( $class->isa('Catalyst::Controller') ){
1204       $class->components->{$class} = $class;
1205     }
1206
1207     $class->setup_actions;
1208
1209     if ( $class->debug ) {
1210         my $name = $class->config->{name} || 'Application';
1211         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1212     }
1213
1214     if ($class->config->{case_sensitive}) {
1215         $class->log->warn($class . "->config->{case_sensitive} is set.");
1216         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1217     }
1218
1219     $class->setup_finalize;
1220     # Should be the last thing we do so that user things hooking
1221     # setup_finalize can log..
1222     $class->log->_flush() if $class->log->can('_flush');
1223     return 1; # Explicit return true as people have __PACKAGE__->setup as the last thing in their class. HATE.
1224 }
1225
1226 =head2 $app->setup_finalize
1227
1228 A hook to attach modifiers to. This method does not do anything except set the
1229 C<setup_finished> accessor.
1230
1231 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1232
1233 Example:
1234
1235     after setup_finalize => sub {
1236         my $app = shift;
1237
1238         ## do stuff here..
1239     };
1240
1241 =cut
1242
1243 sub setup_finalize {
1244     my ($class) = @_;
1245     $class->setup_finished(1);
1246 }
1247
1248 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1249
1250 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1251
1252 Constructs an absolute L<URI> object based on the application root, the
1253 provided path, and the additional arguments and query parameters provided.
1254 When used as a string, provides a textual URI.  If you need more flexibility
1255 than this (i.e. the option to provide relative URIs etc.) see
1256 L<Catalyst::Plugin::SmartURI>.
1257
1258 If no arguments are provided, the URI for the current action is returned.
1259 To return the current action and also provide @args, use
1260 C<< $c->uri_for( $c->action, @args ) >>.
1261
1262 If the first argument is a string, it is taken as a public URI path relative
1263 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1264 relative to the application root (if it does). It is then merged with
1265 C<< $c->request->base >>; any C<@args> are appended as additional path
1266 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1267
1268 If the first argument is a L<Catalyst::Action> it represents an action which
1269 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1270 optional C<\@captures> argument (an arrayref) allows passing the captured
1271 variables that are needed to fill in the paths of Chained and Regex actions;
1272 once the path is resolved, C<uri_for> continues as though a path was
1273 provided, appending any arguments or parameters and creating an absolute
1274 URI.
1275
1276 The captures for the current request can be found in
1277 C<< $c->request->captures >>, and actions can be resolved using
1278 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1279 path, use C<< $c->uri_for_action >> instead.
1280
1281   # Equivalent to $c->req->uri
1282   $c->uri_for($c->action, $c->req->captures,
1283       @{ $c->req->args }, $c->req->params);
1284
1285   # For the Foo action in the Bar controller
1286   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1287
1288   # Path to a static resource
1289   $c->uri_for('/static/images/logo.png');
1290
1291 =cut
1292
1293 sub uri_for {
1294     my ( $c, $path, @args ) = @_;
1295
1296     if ( $path->$_isa('Catalyst::Controller') ) {
1297         $path = $path->path_prefix;
1298         $path =~ s{/+\z}{};
1299         $path .= '/';
1300     }
1301
1302     undef($path) if (defined $path && $path eq '');
1303
1304     my $params =
1305       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1306
1307     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1308     foreach my $arg (@args) {
1309         utf8::encode($arg) if utf8::is_utf8($arg);
1310         $arg =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1311     }
1312
1313     if ( $path->$_isa('Catalyst::Action') ) { # action object
1314         s|/|%2F|g for @args;
1315         my $captures = [ map { s|/|%2F|g; $_; }
1316                         ( scalar @args && ref $args[0] eq 'ARRAY'
1317                          ? @{ shift(@args) }
1318                          : ()) ];
1319
1320         foreach my $capture (@$captures) {
1321             utf8::encode($capture) if utf8::is_utf8($capture);
1322             $capture =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1323         }
1324
1325         my $action = $path;
1326         # ->uri_for( $action, \@captures_and_args, \%query_values? )
1327         if( !@args && $action->number_of_args ) {
1328             my $expanded_action = $c->dispatcher->expand_action( $action );
1329
1330             my $num_captures = $expanded_action->number_of_captures;
1331             unshift @args, splice @$captures, $num_captures;
1332         }
1333
1334        $path = $c->dispatcher->uri_for_action($action, $captures);
1335         if (not defined $path) {
1336             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1337                 if $c->debug;
1338             return undef;
1339         }
1340         $path = '/' if $path eq '';
1341     }
1342
1343     unshift(@args, $path);
1344
1345     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1346         my $namespace = $c->namespace;
1347         if (defined $path) { # cheesy hack to handle path '../foo'
1348            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1349         }
1350         unshift(@args, $namespace || '');
1351     }
1352
1353     # join args with '/', or a blank string
1354     my $args = join('/', grep { defined($_) } @args);
1355     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1356     $args =~ s!^/+!!;
1357
1358     my ($base, $class) = ('/', 'URI::_generic');
1359     if(blessed($c)) {
1360       $base = $c->req->base;
1361       $class = ref($base);
1362       $base =~ s{(?<!/)$}{/};
1363     }
1364
1365     my $query = '';
1366
1367     if (my @keys = keys %$params) {
1368       # somewhat lifted from URI::_query's query_form
1369       $query = '?'.join('&', map {
1370           my $val = $params->{$_};
1371           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1372           s/ /+/g;
1373           my $key = $_;
1374           $val = '' unless defined $val;
1375           (map {
1376               my $param = "$_";
1377               utf8::encode( $param ) if utf8::is_utf8($param);
1378               # using the URI::Escape pattern here so utf8 chars survive
1379               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1380               $param =~ s/ /+/g;
1381               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1382       } @keys);
1383     }
1384
1385     my $res = bless(\"${base}${args}${query}", $class);
1386     $res;
1387 }
1388
1389 =head2 $c->uri_for_action( $path, \@captures_and_args?, @args?, \%query_values? )
1390
1391 =head2 $c->uri_for_action( $action, \@captures_and_args?, @args?, \%query_values? )
1392
1393 =over
1394
1395 =item $path
1396
1397 A private path to the Catalyst action you want to create a URI for.
1398
1399 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1400 >> and passing the resulting C<$action> and the remaining arguments to C<<
1401 $c->uri_for >>.
1402
1403 You can also pass in a Catalyst::Action object, in which case it is passed to
1404 C<< $c->uri_for >>.
1405
1406 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1407
1408 For example, if the action looks like:
1409
1410  package MyApp::Controller::Users;
1411
1412  sub lst : Path('the-list') {}
1413
1414 You can use:
1415
1416  $c->uri_for_action('/users/lst')
1417
1418 and it will create the URI /users/the-list.
1419
1420 =item \@captures_and_args?
1421
1422 Optional array reference of Captures (i.e. C<<CaptureArgs or $c->req->captures>)
1423 and arguments to the request. Usually used with L<Catalyst::DispatchType::Chained>
1424 to interpolate all the parameters in the URI.
1425
1426 =item @args?
1427
1428 Optional list of extra arguments - can be supplied in the
1429 C<< \@captures_and_args? >> array ref, or here - whichever is easier for your
1430 code.
1431
1432 Your action can have zero, a fixed or a variable number of args (e.g.
1433 C<< Args(1) >> for a fixed number or C<< Args() >> for a variable number)..
1434
1435 =item \%query_values?
1436
1437 Optional array reference of query parameters to append. E.g.
1438
1439   { foo => 'bar' }
1440
1441 will generate
1442
1443   /rest/of/your/uri?foo=bar
1444
1445 =back
1446
1447 =cut
1448
1449 sub uri_for_action {
1450     my ( $c, $path, @args ) = @_;
1451     my $action = blessed($path)
1452       ? $path
1453       : $c->dispatcher->get_action_by_path($path);
1454     unless (defined $action) {
1455       croak "Can't find action for path '$path'";
1456     }
1457     return $c->uri_for( $action, @args );
1458 }
1459
1460 =head2 $c->welcome_message
1461
1462 Returns the Catalyst welcome HTML page.
1463
1464 =cut
1465
1466 sub welcome_message {
1467     my $c      = shift;
1468     my $name   = $c->config->{name};
1469     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1470     my $prefix = Catalyst::Utils::appprefix( ref $c );
1471     $c->response->content_type('text/html; charset=utf-8');
1472     return <<"EOF";
1473 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1474     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1475 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1476     <head>
1477     <meta http-equiv="Content-Language" content="en" />
1478     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1479         <title>$name on Catalyst $VERSION</title>
1480         <style type="text/css">
1481             body {
1482                 color: #000;
1483                 background-color: #eee;
1484             }
1485             div#content {
1486                 width: 640px;
1487                 margin-left: auto;
1488                 margin-right: auto;
1489                 margin-top: 10px;
1490                 margin-bottom: 10px;
1491                 text-align: left;
1492                 background-color: #ccc;
1493                 border: 1px solid #aaa;
1494             }
1495             p, h1, h2 {
1496                 margin-left: 20px;
1497                 margin-right: 20px;
1498                 font-family: verdana, tahoma, sans-serif;
1499             }
1500             a {
1501                 font-family: verdana, tahoma, sans-serif;
1502             }
1503             :link, :visited {
1504                     text-decoration: none;
1505                     color: #b00;
1506                     border-bottom: 1px dotted #bbb;
1507             }
1508             :link:hover, :visited:hover {
1509                     color: #555;
1510             }
1511             div#topbar {
1512                 margin: 0px;
1513             }
1514             pre {
1515                 margin: 10px;
1516                 padding: 8px;
1517             }
1518             div#answers {
1519                 padding: 8px;
1520                 margin: 10px;
1521                 background-color: #fff;
1522                 border: 1px solid #aaa;
1523             }
1524             h1 {
1525                 font-size: 0.9em;
1526                 font-weight: normal;
1527                 text-align: center;
1528             }
1529             h2 {
1530                 font-size: 1.0em;
1531             }
1532             p {
1533                 font-size: 0.9em;
1534             }
1535             p img {
1536                 float: right;
1537                 margin-left: 10px;
1538             }
1539             span#appname {
1540                 font-weight: bold;
1541                 font-size: 1.6em;
1542             }
1543         </style>
1544     </head>
1545     <body>
1546         <div id="content">
1547             <div id="topbar">
1548                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1549                     $VERSION</h1>
1550              </div>
1551              <div id="answers">
1552                  <p>
1553                  <img src="$logo" alt="Catalyst Logo" />
1554                  </p>
1555                  <p>Welcome to the  world of Catalyst.
1556                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1557                     framework will make web development something you had
1558                     never expected it to be: Fun, rewarding, and quick.</p>
1559                  <h2>What to do now?</h2>
1560                  <p>That really depends  on what <b>you</b> want to do.
1561                     We do, however, provide you with a few starting points.</p>
1562                  <p>If you want to jump right into web development with Catalyst
1563                     you might want to start with a tutorial.</p>
1564 <pre>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Tutorial">Catalyst::Manual::Tutorial</a></code>
1565 </pre>
1566 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1567 <pre>
1568 <code>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Intro">Catalyst::Manual::Intro</a>
1569 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1570 </code></pre>
1571                  <h2>What to do next?</h2>
1572                  <p>Next it's time to write an actual application. Use the
1573                     helper scripts to generate <a href="https://metacpan.org/search?q=Catalyst%3A%3AController">controllers</a>,
1574                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AModel">models</a>, and
1575                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AView">views</a>;
1576                     they can save you a lot of work.</p>
1577                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1578                     <p>Also, be sure to check out the vast and growing
1579                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1580                     you are likely to find what you need there.
1581                     </p>
1582
1583                  <h2>Need help?</h2>
1584                  <p>Catalyst has a very active community. Here are the main places to
1585                     get in touch with us.</p>
1586                  <ul>
1587                      <li>
1588                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1589                      </li>
1590                      <li>
1591                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1592                      </li>
1593                      <li>
1594                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1595                      </li>
1596                  </ul>
1597                  <h2>In conclusion</h2>
1598                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1599                     as we enjoyed making it. Please contact us if you have ideas
1600                     for improvement or other feedback.</p>
1601              </div>
1602          </div>
1603     </body>
1604 </html>
1605 EOF
1606 }
1607
1608 =head2 run_options
1609
1610 Contains a hash of options passed from the application script, including
1611 the original ARGV the script received, the processed values from that
1612 ARGV and any extra arguments to the script which were not processed.
1613
1614 This can be used to add custom options to your application's scripts
1615 and setup your application differently depending on the values of these
1616 options.
1617
1618 =head1 INTERNAL METHODS
1619
1620 These methods are not meant to be used by end users.
1621
1622 =head2 $c->components
1623
1624 Returns a hash of components.
1625
1626 =head2 $c->context_class
1627
1628 Returns or sets the context class.
1629
1630 =head2 $c->counter
1631
1632 Returns a hashref containing coderefs and execution counts (needed for
1633 deep recursion detection).
1634
1635 =head2 $c->depth
1636
1637 Returns the number of actions on the current internal execution stack.
1638
1639 =head2 $c->dispatch
1640
1641 Dispatches a request to actions.
1642
1643 =cut
1644
1645 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1646
1647 =head2 $c->dispatcher_class
1648
1649 Returns or sets the dispatcher class.
1650
1651 =head2 $c->dump_these
1652
1653 Returns a list of 2-element array references (name, structure) pairs
1654 that will be dumped on the error page in debug mode.
1655
1656 =cut
1657
1658 sub dump_these {
1659     my $c = shift;
1660     [ Request => $c->req ],
1661     [ Response => $c->res ],
1662     [ Stash => $c->stash ],
1663     [ Config => $c->config ];
1664 }
1665
1666 =head2 $c->engine_class
1667
1668 Returns or sets the engine class.
1669
1670 =head2 $c->execute( $class, $coderef )
1671
1672 Execute a coderef in given class and catch exceptions. Errors are available
1673 via $c->error.
1674
1675 =cut
1676
1677 sub execute {
1678     my ( $c, $class, $code ) = @_;
1679     $class = $c->component($class) || $class;
1680     $c->state(0);
1681
1682     if ( $c->depth >= $RECURSION ) {
1683         my $action = $code->reverse();
1684         $action = "/$action" unless $action =~ /->/;
1685         my $error = qq/Deep recursion detected calling "${action}"/;
1686         $c->log->error($error);
1687         $c->error($error);
1688         $c->state(0);
1689         return $c->state;
1690     }
1691
1692     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1693
1694     push( @{ $c->stack }, $code );
1695
1696     no warnings 'recursion';
1697     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1698     #      I have no idea how, ergo $ret (which appears to fix the issue)
1699     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1700
1701     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1702
1703     my $last = pop( @{ $c->stack } );
1704
1705     if ( my $error = $@ ) {
1706         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1707             $error->rethrow if $c->depth > 1;
1708         }
1709         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1710             $error->rethrow if $c->depth > 0;
1711         }
1712         else {
1713             unless ( ref $error ) {
1714                 no warnings 'uninitialized';
1715                 chomp $error;
1716                 my $class = $last->class;
1717                 my $name  = $last->name;
1718                 $error = qq/Caught exception in $class->$name "$error"/;
1719             }
1720             $c->error($error);
1721         }
1722         $c->state(0);
1723     }
1724     return $c->state;
1725 }
1726
1727 sub _stats_start_execute {
1728     my ( $c, $code ) = @_;
1729     my $appclass = ref($c) || $c;
1730     return if ( ( $code->name =~ /^_.*/ )
1731         && ( !$appclass->config->{show_internal_actions} ) );
1732
1733     my $action_name = $code->reverse();
1734     $c->counter->{$action_name}++;
1735
1736     my $action = $action_name;
1737     $action = "/$action" unless $action =~ /->/;
1738
1739     # determine if the call was the result of a forward
1740     # this is done by walking up the call stack and looking for a calling
1741     # sub of Catalyst::forward before the eval
1742     my $callsub = q{};
1743     for my $index ( 2 .. 11 ) {
1744         last
1745         if ( ( caller($index) )[0] eq 'Catalyst'
1746             && ( caller($index) )[3] eq '(eval)' );
1747
1748         if ( ( caller($index) )[3] =~ /forward$/ ) {
1749             $callsub = ( caller($index) )[3];
1750             $action  = "-> $action";
1751             last;
1752         }
1753     }
1754
1755     my $uid = $action_name . $c->counter->{$action_name};
1756
1757     # is this a root-level call or a forwarded call?
1758     if ( $callsub =~ /forward$/ ) {
1759         my $parent = $c->stack->[-1];
1760
1761         # forward, locate the caller
1762         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1763             $c->stats->profile(
1764                 begin  => $action,
1765                 parent => "$parent" . $c->counter->{"$parent"},
1766                 uid    => $uid,
1767             );
1768         }
1769         else {
1770
1771             # forward with no caller may come from a plugin
1772             $c->stats->profile(
1773                 begin => $action,
1774                 uid   => $uid,
1775             );
1776         }
1777     }
1778     else {
1779
1780         # root-level call
1781         $c->stats->profile(
1782             begin => $action,
1783             uid   => $uid,
1784         );
1785     }
1786     return $action;
1787
1788 }
1789
1790 sub _stats_finish_execute {
1791     my ( $c, $info ) = @_;
1792     $c->stats->profile( end => $info );
1793 }
1794
1795 =head2 $c->finalize
1796
1797 Finalizes the request.
1798
1799 =cut
1800
1801 sub finalize {
1802     my $c = shift;
1803
1804     for my $error ( @{ $c->error } ) {
1805         $c->log->error($error);
1806     }
1807
1808     # Support skipping finalize for psgix.io style 'jailbreak'.  Used to support
1809     # stuff like cometd and websockets
1810
1811     if($c->request->has_io_fh) {
1812       $c->log_response;
1813       return;
1814     }
1815
1816     # Allow engine to handle finalize flow (for POE)
1817     my $engine = $c->engine;
1818     if ( my $code = $engine->can('finalize') ) {
1819         $engine->$code($c);
1820     }
1821     else {
1822
1823         $c->finalize_uploads;
1824
1825         # Error
1826         if ( $#{ $c->error } >= 0 ) {
1827             $c->finalize_error;
1828         }
1829
1830         $c->finalize_headers unless $c->response->finalized_headers;
1831
1832         # HEAD request
1833         if ( $c->request->method eq 'HEAD' ) {
1834             $c->response->body('');
1835         }
1836
1837         $c->finalize_body;
1838     }
1839
1840     $c->log_response;
1841
1842     if ($c->use_stats) {
1843         my $elapsed = $c->stats->elapsed;
1844         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1845         $c->log->info(
1846             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1847     }
1848
1849     return $c->response->status;
1850 }
1851
1852 =head2 $c->finalize_body
1853
1854 Finalizes body.
1855
1856 =cut
1857
1858 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1859
1860 =head2 $c->finalize_cookies
1861
1862 Finalizes cookies.
1863
1864 =cut
1865
1866 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1867
1868 =head2 $c->finalize_error
1869
1870 Finalizes error.
1871
1872 =cut
1873
1874 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1875
1876 =head2 $c->finalize_headers
1877
1878 Finalizes headers.
1879
1880 =cut
1881
1882 sub finalize_headers {
1883     my $c = shift;
1884
1885     my $response = $c->response; #accessor calls can add up?
1886
1887     # Check if we already finalized headers
1888     return if $response->finalized_headers;
1889
1890     # Handle redirects
1891     if ( my $location = $response->redirect ) {
1892         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1893         $response->header( Location => $location );
1894
1895         if ( !$response->has_body ) {
1896             # Add a default body if none is already present
1897             my $encoded_location = encode_entities($location);
1898             $response->body(<<"EOF");
1899 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
1900 <html xmlns="http://www.w3.org/1999/xhtml">
1901   <head>
1902     <title>Moved</title>
1903   </head>
1904   <body>
1905      <p>This item has moved <a href="$encoded_location">here</a>.</p>
1906   </body>
1907 </html>
1908 EOF
1909             $response->content_type('text/html; charset=utf-8');
1910         }
1911     }
1912
1913     # Content-Length
1914     if ( defined $response->body && length $response->body && !$response->content_length ) {
1915
1916         # get the length from a filehandle
1917         if ( blessed( $response->body ) && $response->body->can('read') || ref( $response->body ) eq 'GLOB' )
1918         {
1919             my $size = -s $response->body;
1920             if ( $size ) {
1921                 $response->content_length( $size );
1922             }
1923             else {
1924                 $c->log->warn('Serving filehandle without a content-length');
1925             }
1926         }
1927         else {
1928             # everything should be bytes at this point, but just in case
1929             $response->content_length( length( $response->body ) );
1930         }
1931     }
1932
1933     # Errors
1934     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1935         $response->headers->remove_header("Content-Length");
1936         $response->body('');
1937     }
1938
1939     $c->finalize_cookies;
1940
1941     $c->response->finalize_headers();
1942
1943     # Done
1944     $response->finalized_headers(1);
1945 }
1946
1947 =head2 $c->finalize_output
1948
1949 An alias for finalize_body.
1950
1951 =head2 $c->finalize_read
1952
1953 Finalizes the input after reading is complete.
1954
1955 =cut
1956
1957 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1958
1959 =head2 $c->finalize_uploads
1960
1961 Finalizes uploads. Cleans up any temporary files.
1962
1963 =cut
1964
1965 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1966
1967 =head2 $c->get_action( $action, $namespace )
1968
1969 Gets an action in a given namespace.
1970
1971 =cut
1972
1973 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1974
1975 =head2 $c->get_actions( $action, $namespace )
1976
1977 Gets all actions of a given name in a namespace and all parent
1978 namespaces.
1979
1980 =cut
1981
1982 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1983
1984 =head2 $app->handle_request( @arguments )
1985
1986 Called to handle each HTTP request.
1987
1988 =cut
1989
1990 sub handle_request {
1991     my ( $class, @arguments ) = @_;
1992
1993     # Always expect worst case!
1994     my $status = -1;
1995     try {
1996         if ($class->debug) {
1997             my $secs = time - $START || 1;
1998             my $av = sprintf '%.3f', $COUNT / $secs;
1999             my $time = localtime time;
2000             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
2001         }
2002
2003         my $c = $class->prepare(@arguments);
2004         $c->dispatch;
2005         $status = $c->finalize;
2006     }
2007     catch {
2008         chomp(my $error = $_);
2009         $class->log->error(qq/Caught exception in engine "$error"/);
2010     };
2011
2012     $COUNT++;
2013
2014     if(my $coderef = $class->log->can('_flush')){
2015         $class->log->$coderef();
2016     }
2017     return $status;
2018 }
2019
2020 =head2 $class->prepare( @arguments )
2021
2022 Creates a Catalyst context from an engine-specific request (Apache, CGI,
2023 etc.).
2024
2025 =cut
2026
2027 has _uploadtmp => (
2028     is => 'ro',
2029     predicate => '_has_uploadtmp',
2030 );
2031
2032 sub prepare {
2033     my ( $class, @arguments ) = @_;
2034
2035     # XXX
2036     # After the app/ctxt split, this should become an attribute based on something passed
2037     # into the application.
2038     $class->context_class( ref $class || $class ) unless $class->context_class;
2039
2040     my $uploadtmp = $class->config->{uploadtmp};
2041     my $c = $class->context_class->new({ $uploadtmp ? (_uploadtmp => $uploadtmp) : ()});
2042
2043     $c->response->_context($c);
2044
2045     #surely this is not the most efficient way to do things...
2046     $c->stats($class->stats_class->new)->enable($c->use_stats);
2047     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
2048         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
2049     }
2050
2051     try {
2052         # Allow engine to direct the prepare flow (for POE)
2053         if ( my $prepare = $c->engine->can('prepare') ) {
2054             $c->engine->$prepare( $c, @arguments );
2055         }
2056         else {
2057             $c->prepare_request(@arguments);
2058             $c->prepare_connection;
2059             $c->prepare_query_parameters;
2060             $c->prepare_headers; # Just hooks, no longer needed - they just
2061             $c->prepare_cookies; # cause the lazy attribute on req to build
2062             $c->prepare_path;
2063
2064             # Prepare the body for reading, either by prepare_body
2065             # or the user, if they are using $c->read
2066             $c->prepare_read;
2067
2068             # Parse the body unless the user wants it on-demand
2069             unless ( ref($c)->config->{parse_on_demand} ) {
2070                 $c->prepare_body;
2071             }
2072         }
2073         $c->prepare_action;
2074     }
2075     # VERY ugly and probably shouldn't rely on ->finalize actually working
2076     catch {
2077         # failed prepare is always due to an invalid request, right?
2078         $c->response->status(400);
2079         $c->response->content_type('text/plain');
2080         $c->response->body('Bad Request');
2081         # Note we call finalize and then die here, which escapes
2082         # finalize being called in the enclosing block..
2083         # It in fact couldn't be called, as we don't return $c..
2084         # This is a mess - but I'm unsure you can fix this without
2085         # breaking compat for people doing crazy things (we should set
2086         # the 400 and just return the ctx here IMO, letting finalize get called
2087         # above...
2088         $c->finalize;
2089         die $_;
2090     };
2091
2092     $c->log_request;
2093
2094     return $c;
2095 }
2096
2097 =head2 $c->prepare_action
2098
2099 Prepares action. See L<Catalyst::Dispatcher>.
2100
2101 =cut
2102
2103 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
2104
2105 =head2 $c->prepare_body
2106
2107 Prepares message body.
2108
2109 =cut
2110
2111 sub prepare_body {
2112     my $c = shift;
2113
2114     return if $c->request->_has_body;
2115
2116     # Initialize on-demand data
2117     $c->engine->prepare_body( $c, @_ );
2118     $c->prepare_parameters;
2119     $c->prepare_uploads;
2120 }
2121
2122 =head2 $c->prepare_body_chunk( $chunk )
2123
2124 Prepares a chunk of data before sending it to L<HTTP::Body>.
2125
2126 See L<Catalyst::Engine>.
2127
2128 =cut
2129
2130 sub prepare_body_chunk {
2131     my $c = shift;
2132     $c->engine->prepare_body_chunk( $c, @_ );
2133 }
2134
2135 =head2 $c->prepare_body_parameters
2136
2137 Prepares body parameters.
2138
2139 =cut
2140
2141 sub prepare_body_parameters {
2142     my $c = shift;
2143     $c->engine->prepare_body_parameters( $c, @_ );
2144 }
2145
2146 =head2 $c->prepare_connection
2147
2148 Prepares connection.
2149
2150 =cut
2151
2152 sub prepare_connection {
2153     my $c = shift;
2154     # XXX - This is called on the engine (not the request) to maintain
2155     #       Engine::PSGI back compat.
2156     $c->engine->prepare_connection($c);
2157 }
2158
2159 =head2 $c->prepare_cookies
2160
2161 Prepares cookies by ensuring that the attribute on the request
2162 object has been built.
2163
2164 =cut
2165
2166 sub prepare_cookies { my $c = shift; $c->request->cookies }
2167
2168 =head2 $c->prepare_headers
2169
2170 Prepares request headers by ensuring that the attribute on the request
2171 object has been built.
2172
2173 =cut
2174
2175 sub prepare_headers { my $c = shift; $c->request->headers }
2176
2177 =head2 $c->prepare_parameters
2178
2179 Prepares parameters.
2180
2181 =cut
2182
2183 sub prepare_parameters {
2184     my $c = shift;
2185     $c->prepare_body_parameters;
2186     $c->engine->prepare_parameters( $c, @_ );
2187 }
2188
2189 =head2 $c->prepare_path
2190
2191 Prepares path and base.
2192
2193 =cut
2194
2195 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2196
2197 =head2 $c->prepare_query_parameters
2198
2199 Prepares query parameters.
2200
2201 =cut
2202
2203 sub prepare_query_parameters {
2204     my $c = shift;
2205
2206     $c->engine->prepare_query_parameters( $c, @_ );
2207 }
2208
2209 =head2 $c->log_request
2210
2211 Writes information about the request to the debug logs.  This includes:
2212
2213 =over 4
2214
2215 =item * Request method, path, and remote IP address
2216
2217 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2218
2219 =item * Request parameters
2220
2221 =item * File uploads
2222
2223 =back
2224
2225 =cut
2226
2227 sub log_request {
2228     my $c = shift;
2229
2230     return unless $c->debug;
2231
2232     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2233     my $request = $dump->[1];
2234
2235     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2236     $method ||= '';
2237     $path = '/' unless length $path;
2238     $address ||= '';
2239     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2240
2241     $c->log_request_headers($request->headers);
2242
2243     if ( my $keywords = $request->query_keywords ) {
2244         $c->log->debug("Query keywords are: $keywords");
2245     }
2246
2247     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2248
2249     $c->log_request_uploads($request);
2250 }
2251
2252 =head2 $c->log_response
2253
2254 Writes information about the response to the debug logs by calling
2255 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2256
2257 =cut
2258
2259 sub log_response {
2260     my $c = shift;
2261
2262     return unless $c->debug;
2263
2264     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2265     my $response = $dump->[1];
2266
2267     $c->log_response_status_line($response);
2268     $c->log_response_headers($response->headers);
2269 }
2270
2271 =head2 $c->log_response_status_line($response)
2272
2273 Writes one line of information about the response to the debug logs.  This includes:
2274
2275 =over 4
2276
2277 =item * Response status code
2278
2279 =item * Content-Type header (if present)
2280
2281 =item * Content-Length header (if present)
2282
2283 =back
2284
2285 =cut
2286
2287 sub log_response_status_line {
2288     my ($c, $response) = @_;
2289
2290     $c->log->debug(
2291         sprintf(
2292             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2293             $response->status                            || 'unknown',
2294             $response->headers->header('Content-Type')   || 'unknown',
2295             $response->headers->header('Content-Length') || 'unknown'
2296         )
2297     );
2298 }
2299
2300 =head2 $c->log_response_headers($headers);
2301
2302 Hook method which can be wrapped by plugins to log the response headers.
2303 No-op in the default implementation.
2304
2305 =cut
2306
2307 sub log_response_headers {}
2308
2309 =head2 $c->log_request_parameters( query => {}, body => {} )
2310
2311 Logs request parameters to debug logs
2312
2313 =cut
2314
2315 sub log_request_parameters {
2316     my $c          = shift;
2317     my %all_params = @_;
2318
2319     return unless $c->debug;
2320
2321     my $column_width = Catalyst::Utils::term_width() - 44;
2322     foreach my $type (qw(query body)) {
2323         my $params = $all_params{$type};
2324         next if ! keys %$params;
2325         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2326         for my $key ( sort keys %$params ) {
2327             my $param = $params->{$key};
2328             my $value = defined($param) ? $param : '';
2329             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2330         }
2331         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2332     }
2333 }
2334
2335 =head2 $c->log_request_uploads
2336
2337 Logs file uploads included in the request to the debug logs.
2338 The parameter name, filename, file type, and file size are all included in
2339 the debug logs.
2340
2341 =cut
2342
2343 sub log_request_uploads {
2344     my $c = shift;
2345     my $request = shift;
2346     return unless $c->debug;
2347     my $uploads = $request->uploads;
2348     if ( keys %$uploads ) {
2349         my $t = Text::SimpleTable->new(
2350             [ 12, 'Parameter' ],
2351             [ 26, 'Filename' ],
2352             [ 18, 'Type' ],
2353             [ 9,  'Size' ]
2354         );
2355         for my $key ( sort keys %$uploads ) {
2356             my $upload = $uploads->{$key};
2357             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2358                 $t->row( $key, $u->filename, $u->type, $u->size );
2359             }
2360         }
2361         $c->log->debug( "File Uploads are:\n" . $t->draw );
2362     }
2363 }
2364
2365 =head2 $c->log_request_headers($headers);
2366
2367 Hook method which can be wrapped by plugins to log the request headers.
2368 No-op in the default implementation.
2369
2370 =cut
2371
2372 sub log_request_headers {}
2373
2374 =head2 $c->log_headers($type => $headers)
2375
2376 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2377
2378 =cut
2379
2380 sub log_headers {
2381     my $c       = shift;
2382     my $type    = shift;
2383     my $headers = shift;    # an HTTP::Headers instance
2384
2385     return unless $c->debug;
2386
2387     my $column_width = Catalyst::Utils::term_width() - 28;
2388     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2389     $headers->scan(
2390         sub {
2391             my ( $name, $value ) = @_;
2392             $t->row( $name, $value );
2393         }
2394     );
2395     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2396 }
2397
2398
2399 =head2 $c->prepare_read
2400
2401 Prepares the input for reading.
2402
2403 =cut
2404
2405 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2406
2407 =head2 $c->prepare_request
2408
2409 Prepares the engine request.
2410
2411 =cut
2412
2413 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2414
2415 =head2 $c->prepare_uploads
2416
2417 Prepares uploads.
2418
2419 =cut
2420
2421 sub prepare_uploads {
2422     my $c = shift;
2423
2424     $c->engine->prepare_uploads( $c, @_ );
2425 }
2426
2427 =head2 $c->prepare_write
2428
2429 Prepares the output for writing.
2430
2431 =cut
2432
2433 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2434
2435 =head2 $c->request_class
2436
2437 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2438
2439 =head2 $c->response_class
2440
2441 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2442
2443 =head2 $c->read( [$maxlength] )
2444
2445 Reads a chunk of data from the request body. This method is designed to
2446 be used in a while loop, reading C<$maxlength> bytes on every call.
2447 C<$maxlength> defaults to the size of the request if not specified.
2448
2449 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2450 directly.
2451
2452 Warning: If you use read(), Catalyst will not process the body,
2453 so you will not be able to access POST parameters or file uploads via
2454 $c->request.  You must handle all body parsing yourself.
2455
2456 =cut
2457
2458 sub read { my $c = shift; return $c->request->read( @_ ) }
2459
2460 =head2 $c->run
2461
2462 Starts the engine.
2463
2464 =cut
2465
2466 sub run {
2467   my $app = shift;
2468   $app->_make_immutable_if_needed;
2469   $app->engine_loader->needs_psgi_engine_compat_hack ?
2470     $app->engine->run($app, @_) :
2471       $app->engine->run( $app, $app->_finalized_psgi_app, @_ );
2472 }
2473
2474 sub _make_immutable_if_needed {
2475     my $class = shift;
2476     my $meta = Class::MOP::get_metaclass_by_name($class);
2477     my $isa_ca = $class->isa('Class::Accessor::Fast') || $class->isa('Class::Accessor');
2478     if (
2479         $meta->is_immutable
2480         && ! { $meta->immutable_options }->{replace_constructor}
2481         && $isa_ca
2482     ) {
2483         warn("You made your application class ($class) immutable, "
2484             . "but did not inline the\nconstructor. "
2485             . "This will break catalyst, as your app \@ISA "
2486             . "Class::Accessor(::Fast)?\nPlease pass "
2487             . "(replace_constructor => 1)\nwhen making your class immutable.\n");
2488     }
2489     unless ($meta->is_immutable) {
2490         # XXX - FIXME warning here as you should make your app immutable yourself.
2491         $meta->make_immutable(
2492             replace_constructor => 1,
2493         );
2494     }
2495 }
2496
2497 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2498
2499 Sets an action in a given namespace.
2500
2501 =cut
2502
2503 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2504
2505 =head2 $c->setup_actions($component)
2506
2507 Sets up actions for a component.
2508
2509 =cut
2510
2511 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2512
2513 =head2 $c->setup_components
2514
2515 This method is called internally to set up the application's components.
2516
2517 It finds modules by calling the L<locate_components> method, expands them to
2518 package names with the L<expand_component_module> method, and then installs
2519 each component into the application.
2520
2521 The C<setup_components> config option is passed to both of the above methods.
2522
2523 Installation of each component is performed by the L<setup_component> method,
2524 below.
2525
2526 =cut
2527
2528 sub setup_components {
2529     my $class = shift;
2530
2531     my $config  = $class->config->{ setup_components };
2532
2533     my @comps = $class->locate_components($config);
2534     my %comps = map { $_ => 1 } @comps;
2535
2536     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2537     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2538         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2539     ) if $deprecatedcatalyst_component_names;
2540
2541     for my $component ( @comps ) {
2542
2543         # We pass ignore_loaded here so that overlay files for (e.g.)
2544         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2545         # we know M::P::O found a file on disk so this is safe
2546
2547         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2548     }
2549
2550     for my $component (@comps) {
2551         my $instance = $class->components->{ $component } = $class->setup_component($component);
2552         my @expanded_components = $instance->can('expand_modules')
2553             ? $instance->expand_modules( $component, $config )
2554             : $class->expand_component_module( $component, $config );
2555         for my $component (@expanded_components) {
2556             next if $comps{$component};
2557             $class->components->{ $component } = $class->setup_component($component);
2558         }
2559     }
2560 }
2561
2562 =head2 $c->locate_components( $setup_component_config )
2563
2564 This method is meant to provide a list of component modules that should be
2565 setup for the application.  By default, it will use L<Module::Pluggable>.
2566
2567 Specify a C<setup_components> config option to pass additional options directly
2568 to L<Module::Pluggable>. To add additional search paths, specify a key named
2569 C<search_extra> as an array reference. Items in the array beginning with C<::>
2570 will have the application class name prepended to them.
2571
2572 =cut
2573
2574 sub locate_components {
2575     my $class  = shift;
2576     my $config = shift;
2577
2578     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2579     my $extra   = delete $config->{ search_extra } || [];
2580
2581     push @paths, @$extra;
2582
2583     my $locator = Module::Pluggable::Object->new(
2584         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2585         %$config
2586     );
2587
2588     # XXX think about ditching this sort entirely
2589     my @comps = sort { length $a <=> length $b } $locator->plugins;
2590
2591     return @comps;
2592 }
2593
2594 =head2 $c->expand_component_module( $component, $setup_component_config )
2595
2596 Components found by C<locate_components> will be passed to this method, which
2597 is expected to return a list of component (package) names to be set up.
2598
2599 =cut
2600
2601 sub expand_component_module {
2602     my ($class, $module) = @_;
2603     return Devel::InnerPackage::list_packages( $module );
2604 }
2605
2606 =head2 $c->setup_component
2607
2608 =cut
2609
2610 sub setup_component {
2611     my( $class, $component ) = @_;
2612
2613     unless ( $component->can( 'COMPONENT' ) ) {
2614         return $component;
2615     }
2616
2617     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2618     my $config = $class->config->{ $suffix } || {};
2619     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2620     # methods also pass it. local to avoid pointlessly shitting in config
2621     # for the debug screen, as $component is already the key name.
2622     local $config->{catalyst_component_name} = $component;
2623
2624     my $instance = eval { $component->COMPONENT( $class, $config ); };
2625
2626     if ( my $error = $@ ) {
2627         chomp $error;
2628         Catalyst::Exception->throw(
2629             message => qq/Couldn't instantiate component "$component", "$error"/
2630         );
2631     }
2632
2633     unless (blessed $instance) {
2634         my $metaclass = Moose::Util::find_meta($component);
2635         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2636         my $component_method_from = $method_meta->associated_metaclass->name;
2637         my $value = defined($instance) ? $instance : 'undef';
2638         Catalyst::Exception->throw(
2639             message =>
2640             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2641         );
2642     }
2643     return $instance;
2644 }
2645
2646 =head2 $c->setup_dispatcher
2647
2648 Sets up dispatcher.
2649
2650 =cut
2651
2652 sub setup_dispatcher {
2653     my ( $class, $dispatcher ) = @_;
2654
2655     if ($dispatcher) {
2656         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2657     }
2658
2659     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2660         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2661     }
2662
2663     unless ($dispatcher) {
2664         $dispatcher = $class->dispatcher_class;
2665     }
2666
2667     Class::MOP::load_class($dispatcher);
2668
2669     # dispatcher instance
2670     $class->dispatcher( $dispatcher->new );
2671 }
2672
2673 =head2 $c->setup_engine
2674
2675 Sets up engine.
2676
2677 =cut
2678
2679 sub engine_class {
2680     my ($class, $requested_engine) = @_;
2681
2682     if (!$class->engine_loader || $requested_engine) {
2683         $class->engine_loader(
2684             Catalyst::EngineLoader->new({
2685                 application_name => $class,
2686                 (defined $requested_engine
2687                      ? (catalyst_engine_class => $requested_engine) : ()),
2688             }),
2689         );
2690     }
2691
2692     $class->engine_loader->catalyst_engine_class;
2693 }
2694
2695 sub setup_engine {
2696     my ($class, $requested_engine) = @_;
2697
2698     my $engine = do {
2699         my $loader = $class->engine_loader;
2700
2701         if (!$loader || $requested_engine) {
2702             $loader = Catalyst::EngineLoader->new({
2703                 application_name => $class,
2704                 (defined $requested_engine
2705                      ? (requested_engine => $requested_engine) : ()),
2706             }),
2707
2708             $class->engine_loader($loader);
2709         }
2710
2711         $loader->catalyst_engine_class;
2712     };
2713
2714     # Don't really setup_engine -- see _setup_psgi_app for explanation.
2715     return if $class->loading_psgi_file;
2716
2717     Class::MOP::load_class($engine);
2718
2719     if ($ENV{MOD_PERL}) {
2720         my $apache = $class->engine_loader->auto;
2721
2722         my $meta = find_meta($class);
2723         my $was_immutable = $meta->is_immutable;
2724         my %immutable_options = $meta->immutable_options;
2725         $meta->make_mutable if $was_immutable;
2726
2727         $meta->add_method(handler => sub {
2728             my $r = shift;
2729             my $psgi_app = $class->_finalized_psgi_app;
2730             $apache->call_app($r, $psgi_app);
2731         });
2732
2733         $meta->make_immutable(%immutable_options) if $was_immutable;
2734     }
2735
2736     $class->engine( $engine->new );
2737
2738     return;
2739 }
2740
2741 ## This exists just to supply a prebuild psgi app for mod_perl and for the
2742 ## build in server support (back compat support for pre psgi port behavior).
2743 ## This is so that we don't build a new psgi app for each request when using
2744 ## the mod_perl handler or the built in servers (http and fcgi, etc).
2745
2746 sub _finalized_psgi_app {
2747     my ($app) = @_;
2748
2749     unless ($app->_psgi_app) {
2750         my $psgi_app = $app->_setup_psgi_app;
2751         $app->_psgi_app($psgi_app);
2752     }
2753
2754     return $app->_psgi_app;
2755 }
2756
2757 ## Look for a psgi file like 'myapp_web.psgi' (if the app is MyApp::Web) in the
2758 ## home directory and load that and return it (just assume it is doing the
2759 ## right thing :) ).  If that does not exist, call $app->psgi_app, wrap that
2760 ## in default_middleware and return it ( this is for backward compatibility
2761 ## with pre psgi port behavior ).
2762
2763 sub _setup_psgi_app {
2764     my ($app) = @_;
2765
2766     for my $home (Path::Class::Dir->new($app->config->{home})) {
2767         my $psgi_file = $home->file(
2768             Catalyst::Utils::appprefix($app) . '.psgi',
2769         );
2770
2771         next unless -e $psgi_file;
2772
2773         # If $psgi_file calls ->setup_engine, it's doing so to load
2774         # Catalyst::Engine::PSGI. But if it does that, we're only going to
2775         # throw away the loaded PSGI-app and load the 5.9 Catalyst::Engine
2776         # anyway. So set a flag (ick) that tells setup_engine not to populate
2777         # $c->engine or do any other things we might regret.
2778
2779         $app->loading_psgi_file(1);
2780         my $psgi_app = Plack::Util::load_psgi($psgi_file);
2781         $app->loading_psgi_file(0);
2782
2783         return $psgi_app
2784             unless $app->engine_loader->needs_psgi_engine_compat_hack;
2785
2786         warn <<"EOW";
2787 Found a legacy Catalyst::Engine::PSGI .psgi file at ${psgi_file}.
2788
2789 Its content has been ignored. Please consult the Catalyst::Upgrading
2790 documentation on how to upgrade from Catalyst::Engine::PSGI.
2791 EOW
2792     }
2793
2794     return $app->apply_default_middlewares($app->psgi_app);
2795 }
2796
2797 =head2 $c->apply_default_middlewares
2798
2799 Adds the following L<Plack> middlewares to your application, since they are
2800 useful and commonly needed:
2801
2802 L<Plack::Middleware::ReverseProxy>, (conditionally added based on the status
2803 of your $ENV{REMOTE_ADDR}, and can be forced on with C<using_frontend_proxy>
2804 or forced off with C<ignore_frontend_proxy>), L<Plack::Middleware::LighttpdScriptNameFix>
2805 (if you are using Lighttpd), L<Plack::Middleware::IIS6ScriptNameFix> (always
2806 applied since this middleware is smart enough to conditionally apply itself).
2807
2808 Additionally if we detect we are using Nginx, we add a bit of custom middleware
2809 to solve some problems with the way that server handles $ENV{PATH_INFO} and
2810 $ENV{SCRIPT_NAME}
2811
2812 =cut
2813
2814
2815 sub apply_default_middlewares {
2816     my ($app, $psgi_app) = @_;
2817
2818     $psgi_app = Plack::Middleware::Conditional->wrap(
2819         $psgi_app,
2820         builder   => sub { Plack::Middleware::ReverseProxy->wrap($_[0]) },
2821         condition => sub {
2822             my ($env) = @_;
2823             return if $app->config->{ignore_frontend_proxy};
2824             return $env->{REMOTE_ADDR} eq '127.0.0.1'
2825                 || $app->config->{using_frontend_proxy};
2826         },
2827     );
2828
2829     # If we're running under Lighttpd, swap PATH_INFO and SCRIPT_NAME
2830     # http://lists.scsys.co.uk/pipermail/catalyst/2006-June/008361.html
2831     $psgi_app = Plack::Middleware::Conditional->wrap(
2832         $psgi_app,
2833         builder   => sub { Plack::Middleware::LighttpdScriptNameFix->wrap($_[0]) },
2834         condition => sub {
2835             my ($env) = @_;
2836             return unless $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!lighttpd[-/]1\.(\d+\.\d+)!;
2837             return unless $1 < 4.23;
2838             1;
2839         },
2840     );
2841
2842     # we're applying this unconditionally as the middleware itself already makes
2843     # sure it doesn't fuck things up if it's not running under one of the right
2844     # IIS versions
2845     $psgi_app = Plack::Middleware::IIS6ScriptNameFix->wrap($psgi_app);
2846
2847     # And another IIS issue, this time with IIS7.
2848     $psgi_app = Plack::Middleware::Conditional->wrap(
2849         $psgi_app,
2850         builder => sub { Plack::Middleware::IIS7KeepAliveFix->wrap($_[0]) },
2851         condition => sub {
2852             my ($env) = @_;
2853             return $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!IIS/7\.[0-9]!;
2854         },
2855     );
2856
2857     return $psgi_app;
2858 }
2859
2860 =head2 $c->psgi_app
2861
2862 Returns a PSGI application code reference for the catalyst application
2863 C<$c>. This is the bare application without any middlewares
2864 applied. C<${myapp}.psgi> is not taken into account.
2865
2866 This is what you want to be using to retrieve the PSGI application code
2867 reference of your Catalyst application for use in F<.psgi> files.
2868
2869 =cut
2870
2871 sub psgi_app {
2872     my ($app) = @_;
2873     my $psgi = $app->engine->build_psgi_app($app);
2874     return $app->Catalyst::Utils::apply_registered_middleware($psgi);
2875 }
2876
2877 =head2 $c->setup_home
2878
2879 Sets up the home directory.
2880
2881 =cut
2882
2883 sub setup_home {
2884     my ( $class, $home ) = @_;
2885
2886     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2887         $home = $env;
2888     }
2889
2890     $home ||= Catalyst::Utils::home($class);
2891
2892     if ($home) {
2893         #I remember recently being scolded for assigning config values like this
2894         $class->config->{home} ||= $home;
2895         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2896     }
2897 }
2898
2899 =head2 $c->setup_log
2900
2901 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2902 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2903 log to.
2904
2905 This method also installs a C<debug> method that returns a true value into the
2906 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2907 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2908
2909 Note that if the log has already been setup, by either a previous call to
2910 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2911 that this method won't actually set up the log object.
2912
2913 =cut
2914
2915 sub setup_log {
2916     my ( $class, $levels ) = @_;
2917
2918     $levels ||= '';
2919     $levels =~ s/^\s+//;
2920     $levels =~ s/\s+$//;
2921     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2922
2923     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2924     if ( defined $env_debug ) {
2925         $levels{debug} = 1 if $env_debug; # Ugly!
2926         delete($levels{debug}) unless $env_debug;
2927     }
2928
2929     unless ( $class->log ) {
2930         $class->log( Catalyst::Log->new(keys %levels) );
2931     }
2932
2933     if ( $levels{debug} ) {
2934         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2935         $class->log->debug('Debug messages enabled');
2936     }
2937 }
2938
2939 =head2 $c->setup_plugins
2940
2941 Sets up plugins.
2942
2943 =cut
2944
2945 =head2 $c->setup_stats
2946
2947 Sets up timing statistics class.
2948
2949 =cut
2950
2951 sub setup_stats {
2952     my ( $class, $stats ) = @_;
2953
2954     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2955
2956     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2957     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2958         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2959         $class->log->debug('Statistics enabled');
2960     }
2961 }
2962
2963
2964 =head2 $c->registered_plugins
2965
2966 Returns a sorted list of the plugins which have either been stated in the
2967 import list.
2968
2969 If passed a given plugin name, it will report a boolean value indicating
2970 whether or not that plugin is loaded.  A fully qualified name is required if
2971 the plugin name does not begin with C<Catalyst::Plugin::>.
2972
2973  if ($c->registered_plugins('Some::Plugin')) {
2974      ...
2975  }
2976
2977 =cut
2978
2979 {
2980
2981     sub registered_plugins {
2982         my $proto = shift;
2983         return sort keys %{ $proto->_plugins } unless @_;
2984         my $plugin = shift;
2985         return 1 if exists $proto->_plugins->{$plugin};
2986         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2987     }
2988
2989     sub _register_plugin {
2990         my ( $proto, $plugin, $instant ) = @_;
2991         my $class = ref $proto || $proto;
2992
2993         Class::MOP::load_class( $plugin );
2994         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
2995             if $plugin->isa( 'Catalyst::Component' );
2996         my $plugin_meta = Moose::Meta::Class->create($plugin);
2997         if (!$plugin_meta->has_method('new')
2998             && ( $plugin->isa('Class::Accessor::Fast') || $plugin->isa('Class::Accessor') ) ) {
2999             $plugin_meta->add_method('new', Moose::Object->meta->get_method('new'))
3000         }
3001         if (!$instant && !$proto->_plugins->{$plugin}) {
3002             my $meta = Class::MOP::get_metaclass_by_name($class);
3003             $meta->superclasses($plugin, $meta->superclasses);
3004         }
3005         $proto->_plugins->{$plugin} = 1;
3006         return $class;
3007     }
3008
3009     sub _default_plugins { return qw(Unicode::Encoding) }
3010
3011     sub setup_plugins {
3012         my ( $class, $plugins ) = @_;
3013
3014         $class->_plugins( {} ) unless $class->_plugins;
3015         $plugins = [ grep {
3016             m/Unicode::Encoding/ ? do {
3017                 $class->log->warn(
3018                     'Unicode::Encoding plugin is auto-applied,'
3019                     . ' please remove this from your appclass'
3020                     . ' and make sure to define "encoding" config'
3021                 );
3022                 unless (exists $class->config->{'encoding'}) {
3023                   $class->config->{'encoding'} = 'UTF-8';
3024                 }
3025                 () }
3026                 : $_
3027         } @$plugins ];
3028         push @$plugins, $class->_default_plugins;
3029         $plugins = Data::OptList::mkopt($plugins || []);
3030
3031         my @plugins = map {
3032             [ Catalyst::Utils::resolve_namespace(
3033                   $class . '::Plugin',
3034                   'Catalyst::Plugin', $_->[0]
3035               ),
3036               $_->[1],
3037             ]
3038          } @{ $plugins };
3039
3040         for my $plugin ( reverse @plugins ) {
3041             Class::MOP::load_class($plugin->[0], $plugin->[1]);
3042             my $meta = find_meta($plugin->[0]);
3043             next if $meta && $meta->isa('Moose::Meta::Role');
3044
3045             $class->_register_plugin($plugin->[0]);
3046         }
3047
3048         my @roles =
3049             map  { $_->[0]->name, $_->[1] }
3050             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
3051             map  { [find_meta($_->[0]), $_->[1]] }
3052             @plugins;
3053
3054         Moose::Util::apply_all_roles(
3055             $class => @roles
3056         ) if @roles;
3057     }
3058 }
3059
3060 =head2 registered_middlewares
3061
3062 Read only accessor that returns an array of all the middleware in the order
3063 that they were added (which is the REVERSE of the order they will be applied).
3064
3065 The values returned will be either instances of L<Plack::Middleware> or of a
3066 compatible interface, or a coderef, which is assumed to be inlined middleware
3067
3068 =head2 setup_middleware (?@middleware)
3069
3070 Read configuration information stored in configuration key 'psgi_middleware'
3071 and invoke L</register_middleware> for each middleware prototype found.  See
3072 under L</CONFIGURATION> information regarding L</psgi_middleware> and how to
3073 use it to enable L<Plack::Middleware>
3074
3075 This method is automatically called during 'setup' of your application, so
3076 you really don't need to invoke it.
3077
3078 When we read middleware definitions from configuration, we reverse the list
3079 which sounds odd but is likely how you expect it to work if you have prior
3080 experience with L<Plack::Builder> or if you previously used the plugin
3081 L<Catalyst::Plugin::EnableMiddleware> (which is now considered deprecated)
3082
3083 You can pass middleware definitions to this as well, from the application
3084 class if you like.
3085
3086 =cut
3087
3088 sub registered_middlewares {
3089     my $class = shift;
3090     if(my $middleware = $class->_psgi_middleware) {
3091         return @$middleware;
3092     } else {
3093         die "You cannot call ->registered_middlewares until middleware has been setup";
3094     }
3095 }
3096
3097 sub setup_middleware {
3098     my ($class, @middleware_definitions) = @_;
3099     push @middleware_definitions, reverse(
3100       @{$class->config->{'psgi_middleware'}||[]});
3101
3102     my @middleware = ();
3103     while(my $next = shift(@middleware_definitions)) {
3104         if(ref $next) {
3105             if(Scalar::Util::blessed $next && $next->can('wrap')) {
3106                 push @middleware, $next;
3107             } elsif(ref $next eq 'CODE') {
3108                 push @middleware, $next;
3109             } elsif(ref $next eq 'HASH') {
3110                 my $namespace = shift @middleware_definitions;
3111                 my $mw = $class->Catalyst::Utils::build_middleware($namespace, %$next);
3112                 push @middleware, $mw;
3113             } else {
3114               die "I can't handle middleware definition ${\ref $next}";
3115             }
3116         } else {
3117           my $mw = $class->Catalyst::Utils::build_middleware($next);
3118           push @middleware, $mw;
3119         }
3120     }
3121
3122     $class->_psgi_middleware(\@middleware);
3123 }
3124
3125 =head2 $c->stack
3126
3127 Returns an arrayref of the internal execution stack (actions that are
3128 currently executing).
3129
3130 =head2 $c->stats
3131
3132 Returns the current timing statistics object. By default Catalyst uses
3133 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
3134 L<< stats_class|/"$c->stats_class" >>.
3135
3136 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
3137 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
3138 profile explicitly, although MyApp.pm still won't profile nor output anything
3139 by itself.
3140
3141 =head2 $c->stats_class
3142
3143 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
3144
3145 =head2 $c->use_stats
3146
3147 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
3148
3149 Note that this is a static method, not an accessor and should be overridden
3150 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
3151
3152 =cut
3153
3154 sub use_stats { 0 }
3155
3156
3157 =head2 $c->write( $data )
3158
3159 Writes $data to the output stream. When using this method directly, you
3160 will need to manually set the C<Content-Length> header to the length of
3161 your output data, if known.
3162
3163 =cut
3164
3165 sub write {
3166     my $c = shift;
3167
3168     # Finalize headers if someone manually writes output (for compat)
3169     $c->finalize_headers;
3170
3171     return $c->response->write( @_ );
3172 }
3173
3174 =head2 version
3175
3176 Returns the Catalyst version number. Mostly useful for "powered by"
3177 messages in template systems.
3178
3179 =cut
3180
3181 sub version { return $Catalyst::VERSION }
3182
3183 =head1 CONFIGURATION
3184
3185 There are a number of 'base' config variables which can be set:
3186
3187 =over
3188
3189 =item *
3190
3191 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
3192
3193 =item *
3194
3195 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
3196
3197 =item *
3198
3199 C<disable_component_resolution_regex_fallback> - Turns
3200 off the deprecated component resolution functionality so
3201 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
3202 are called then regex search will not be attempted on string values and
3203 instead C<undef> will be returned.
3204
3205 =item *
3206
3207 C<home> - The application home directory. In an uninstalled application,
3208 this is the top level application directory. In an installed application,
3209 this will be the directory containing C<< MyApp.pm >>.
3210
3211 =item *
3212
3213 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
3214
3215 =item *
3216
3217 C<name> - The name of the application in debug messages and the debug and
3218 welcome screens
3219
3220 =item *
3221
3222 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
3223 until it is accessed. This allows you to (for example) check authentication (and reject
3224 the upload) before actually receiving all the data. See L</ON-DEMAND PARSER>
3225
3226 =item *
3227
3228 C<root> - The root directory for templates. Usually this is just a
3229 subdirectory of the home directory, but you can set it to change the
3230 templates to a different directory.
3231
3232 =item *
3233
3234 C<search_extra> - Array reference passed to Module::Pluggable to for additional
3235 namespaces from which components will be loaded (and constructed and stored in
3236 C<< $c->components >>).
3237
3238 =item *
3239
3240 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
3241 to be shown in hit debug tables in the test server.
3242
3243 =item *
3244
3245 C<use_request_uri_for_path> - Controls if the C<REQUEST_URI> or C<PATH_INFO> environment
3246 variable should be used for determining the request path.
3247
3248 Most web server environments pass the requested path to the application using environment variables,
3249 from which Catalyst has to reconstruct the request base (i.e. the top level path to / in the application,
3250 exposed as C<< $c->request->base >>) and the request path below that base.
3251
3252 There are two methods of doing this, both of which have advantages and disadvantages. Which method is used
3253 is determined by the C<< $c->config(use_request_uri_for_path) >> setting (which can either be true or false).
3254
3255 =over
3256
3257 =item use_request_uri_for_path => 0
3258
3259 This is the default (and the) traditional method that Catalyst has used for determining the path information.
3260 The path is generated from a combination of the C<PATH_INFO> and C<SCRIPT_NAME> environment variables.
3261 The allows the application to behave correctly when C<mod_rewrite> is being used to redirect requests
3262 into the application, as these variables are adjusted by mod_rewrite to take account for the redirect.
3263
3264 However this method has the major disadvantage that it is impossible to correctly decode some elements
3265 of the path, as RFC 3875 says: "C<< Unlike a URI path, the PATH_INFO is not URL-encoded, and cannot
3266 contain path-segment parameters. >>" This means PATH_INFO is B<always> decoded, and therefore Catalyst
3267 can't distinguish / vs %2F in paths (in addition to other encoded values).
3268
3269 =item use_request_uri_for_path => 1
3270
3271 This method uses the C<REQUEST_URI> and C<SCRIPT_NAME> environment variables. As C<REQUEST_URI> is never
3272 decoded, this means that applications using this mode can correctly handle URIs including the %2F character
3273 (i.e. with C<AllowEncodedSlashes> set to C<On> in Apache).
3274
3275 Given that this method of path resolution is provably more correct, it is recommended that you use
3276 this unless you have a specific need to deploy your application in a non-standard environment, and you are
3277 aware of the implications of not being able to handle encoded URI paths correctly.
3278
3279 However it also means that in a number of cases when the app isn't installed directly at a path, but instead
3280 is having paths rewritten into it (e.g. as a .cgi/fcgi in a public_html directory, with mod_rewrite in a
3281 .htaccess file, or when SSI is used to rewrite pages into the app, or when sub-paths of the app are exposed
3282 at other URIs than that which the app is 'normally' based at with C<mod_rewrite>), the resolution of
3283 C<< $c->request->base >> will be incorrect.
3284
3285 =back
3286
3287 =item *
3288
3289 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
3290
3291 =item *
3292
3293 C<encoding> - See L</ENCODING>
3294
3295 =item *
3296
3297 C<abort_chain_on_error_fix>
3298
3299 When there is an error in an action chain, the default behavior is to continue
3300 processing the remaining actions and then catch the error upon chain end.  This
3301 can lead to running actions when the application is in an unexpected state.  If
3302 you have this issue, setting this config value to true will promptly exit a
3303 chain when there is an error raised in any action (thus terminating the chain
3304 early.)
3305
3306 use like:
3307
3308     __PACKAGE__->config(abort_chain_on_error_fix => 1);
3309
3310 In the future this might become the default behavior.
3311
3312 =item *
3313
3314 C<psgi_middleware> - See L<PSGI MIDDLEWARE>.
3315
3316 =back
3317
3318 =head1 INTERNAL ACTIONS
3319
3320 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
3321 C<_ACTION>, and C<_END>. These are by default not shown in the private
3322 action table, but you can make them visible with a config parameter.
3323
3324     MyApp->config(show_internal_actions => 1);
3325
3326 =head1 ON-DEMAND PARSER
3327
3328 The request body is usually parsed at the beginning of a request,
3329 but if you want to handle input yourself, you can enable on-demand
3330 parsing with a config parameter.
3331
3332     MyApp->config(parse_on_demand => 1);
3333
3334 =head1 PROXY SUPPORT
3335
3336 Many production servers operate using the common double-server approach,
3337 with a lightweight frontend web server passing requests to a larger
3338 backend server. An application running on the backend server must deal
3339 with two problems: the remote user always appears to be C<127.0.0.1> and
3340 the server's hostname will appear to be C<localhost> regardless of the
3341 virtual host that the user connected through.
3342
3343 Catalyst will automatically detect this situation when you are running
3344 the frontend and backend servers on the same machine. The following
3345 changes are made to the request.
3346
3347     $c->req->address is set to the user's real IP address, as read from
3348     the HTTP X-Forwarded-For header.
3349
3350     The host value for $c->req->base and $c->req->uri is set to the real
3351     host, as read from the HTTP X-Forwarded-Host header.
3352
3353 Additionally, you may be running your backend application on an insecure
3354 connection (port 80) while your frontend proxy is running under SSL.  If there
3355 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
3356 tell Catalyst what port the frontend listens on.  This will allow all URIs to
3357 be created properly.
3358
3359 In the case of passing in:
3360
3361     X-Forwarded-Port: 443
3362
3363 All calls to C<uri_for> will result in an https link, as is expected.
3364
3365 Obviously, your web server must support these headers for this to work.
3366
3367 In a more complex server farm environment where you may have your
3368 frontend proxy server(s) on different machines, you will need to set a
3369 configuration option to tell Catalyst to read the proxied data from the
3370 headers.
3371
3372     MyApp->config(using_frontend_proxy => 1);
3373
3374 If you do not wish to use the proxy support at all, you may set:
3375
3376     MyApp->config(ignore_frontend_proxy => 0);
3377
3378 =head2 Note about psgi files
3379
3380 Note that if you supply your own .psgi file, calling
3381 C<< MyApp->psgi_app(@_); >>, then B<this will not happen automatically>.
3382
3383 You either need to apply L<Plack::Middleware::ReverseProxy> yourself
3384 in your psgi, for example:
3385
3386     builder {
3387         enable "Plack::Middleware::ReverseProxy";
3388         MyApp->psgi_app
3389     };
3390
3391 This will unconditionally add the ReverseProxy support, or you need to call
3392 C<< $app = MyApp->apply_default_middlewares($app) >> (to conditionally
3393 apply the support depending upon your config).
3394
3395 See L<Catalyst::PSGI> for more information.
3396
3397 =head1 THREAD SAFETY
3398
3399 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
3400 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
3401 believe the Catalyst core to be thread-safe.
3402
3403 If you plan to operate in a threaded environment, remember that all other
3404 modules you are using must also be thread-safe. Some modules, most notably
3405 L<DBD::SQLite>, are not thread-safe.
3406
3407 =head1 PSGI MIDDLEWARE
3408
3409 You can define middleware, defined as L<Plack::Middleware> or a compatible
3410 interface in configuration.  Your middleware definitions are in the form of an
3411 arrayref under the configuration key C<psgi_middleware>.  Here's an example
3412 with details to follow:
3413
3414     package MyApp::Web;
3415
3416     use Catalyst;
3417     use Plack::Middleware::StackTrace;
3418
3419     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
3420
3421     __PACKAGE__->config(
3422       'psgi_middleware', [
3423         'Debug',
3424         '+MyApp::Custom',
3425         $stacktrace_middleware,
3426         'Session' => {store => 'File'},
3427         sub {
3428           my $app = shift;
3429           return sub {
3430             my $env = shift;
3431             $env->{myapp.customkey} = 'helloworld';
3432             $app->($env);
3433           },
3434         },
3435       ],
3436     );
3437
3438     __PACKAGE__->setup;
3439
3440 So the general form is:
3441
3442     __PACKAGE__->config(psgi_middleware => \@middleware_definitions);
3443
3444 Where C<@middleware> is one or more of the following, applied in the REVERSE of
3445 the order listed (to make it function similarly to L<Plack::Builder>:
3446
3447 =over 4
3448
3449 =item Middleware Object
3450
3451 An already initialized object that conforms to the L<Plack::Middleware>
3452 specification:
3453
3454     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
3455
3456     __PACKAGE__->config(
3457       'psgi_middleware', [
3458         $stacktrace_middleware,
3459       ]);
3460
3461
3462 =item coderef
3463
3464 A coderef that is an inlined middleware:
3465
3466     __PACKAGE__->config(
3467       'psgi_middleware', [
3468         sub {
3469           my $app = shift;
3470           return sub {
3471             my $env = shift;
3472             if($env->{PATH_INFO} =~m/forced/) {
3473               Plack::App::File
3474                 ->new(file=>TestApp->path_to(qw/share static forced.txt/))
3475                 ->call($env);
3476             } else {
3477               return $app->($env);
3478             }
3479          },
3480       },
3481     ]);
3482
3483
3484
3485 =item a scalar
3486
3487 We assume the scalar refers to a namespace after normalizing it using the
3488 following rules:
3489
3490 (1) If the scalar is prefixed with a "+" (as in C<+MyApp::Foo>) then the full string
3491 is assumed to be 'as is', and we just install and use the middleware.
3492
3493 (2) If the scalar begins with "Plack::Middleware" or your application namespace
3494 (the package name of your Catalyst application subclass), we also assume then
3495 that it is a full namespace, and use it.
3496
3497 (3) Lastly, we then assume that the scalar is a partial namespace, and attempt to
3498 resolve it first by looking for it under your application namespace (for example
3499 if you application is "MyApp::Web" and the scalar is "MyMiddleware", we'd look
3500 under "MyApp::Web::Middleware::MyMiddleware") and if we don't find it there, we
3501 will then look under the regular L<Plack::Middleware> namespace (i.e. for the
3502 previous we'd try "Plack::Middleware::MyMiddleware").  We look under your application
3503 namespace first to let you 'override' common L<Plack::Middleware> locally, should
3504 you find that a good idea.
3505
3506 Examples:
3507
3508     package MyApp::Web;
3509
3510     __PACKAGE__->config(
3511       'psgi_middleware', [
3512         'Debug',  ## MyAppWeb::Middleware::Debug->wrap or Plack::Middleware::Debug->wrap
3513         'Plack::Middleware::Stacktrace', ## Plack::Middleware::Stacktrace->wrap
3514         '+MyApp::Custom',  ## MyApp::Custom->wrap
3515       ],
3516     );
3517
3518 =item a scalar followed by a hashref
3519
3520 Just like the previous, except the following C<HashRef> is used as arguments
3521 to initialize the middleware object.
3522
3523     __PACKAGE__->config(
3524       'psgi_middleware', [
3525          'Session' => {store => 'File'},
3526     ]);
3527
3528 =back
3529
3530 Please see L<PSGI> for more on middleware.
3531
3532 =head1 ENCODING
3533
3534 On request, decodes all params from encoding into a sequence of
3535 logical characters. On response, encodes body into encoding.
3536
3537 =head2 Methods
3538
3539 =over 4
3540
3541 =item encoding
3542
3543 Returns an instance of an C<Encode> encoding
3544
3545     print $c->encoding->name
3546
3547 =item handle_unicode_encoding_exception ($exception_context)
3548
3549 Method called when decoding process for a request fails.
3550
3551 An C<$exception_context> hashref is provided to allow you to override the
3552 behaviour of your application when given data with incorrect encodings.
3553
3554 The default method throws exceptions in the case of invalid request parameters
3555 (resulting in a 500 error), but ignores errors in upload filenames.
3556
3557 The keys passed in the C<$exception_context> hash are:
3558
3559 =over
3560
3561 =item param_value
3562
3563 The value which was not able to be decoded.
3564
3565 =item error_msg
3566
3567 The exception received from L<Encode>.
3568
3569 =item encoding_step
3570
3571 What type of data was being decoded. Valid values are (currently)
3572 C<params> - for request parameters / arguments / captures
3573 and C<uploads> - for request upload filenames.
3574
3575 =back
3576
3577 =back
3578
3579 =head1 SUPPORT
3580
3581 IRC:
3582
3583     Join #catalyst on irc.perl.org.
3584
3585 Mailing Lists:
3586
3587     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
3588     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
3589
3590 Web:
3591
3592     http://catalyst.perl.org
3593
3594 Wiki:
3595
3596     http://dev.catalyst.perl.org
3597
3598 =head1 SEE ALSO
3599
3600 =head2 L<Task::Catalyst> - All you need to start with Catalyst
3601
3602 =head2 L<Catalyst::Manual> - The Catalyst Manual
3603
3604 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
3605
3606 =head2 L<Catalyst::Engine> - Core engine
3607
3608 =head2 L<Catalyst::Log> - Log class.
3609
3610 =head2 L<Catalyst::Request> - Request object
3611
3612 =head2 L<Catalyst::Response> - Response object
3613
3614 =head2 L<Catalyst::Test> - The test suite.
3615
3616 =head1 PROJECT FOUNDER
3617
3618 sri: Sebastian Riedel <sri@cpan.org>
3619
3620 =head1 CONTRIBUTORS
3621
3622 abw: Andy Wardley
3623
3624 acme: Leon Brocard <leon@astray.com>
3625
3626 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
3627
3628 Andrew Bramble
3629
3630 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
3631
3632 Andrew Ruthven
3633
3634 andyg: Andy Grundman <andy@hybridized.org>
3635
3636 audreyt: Audrey Tang
3637
3638 bricas: Brian Cassidy <bricas@cpan.org>
3639
3640 Caelum: Rafael Kitover <rkitover@io.com>
3641
3642 chansen: Christian Hansen
3643
3644 chicks: Christopher Hicks
3645
3646 Chisel Wright C<pause@herlpacker.co.uk>
3647
3648 Danijel Milicevic C<me@danijel.de>
3649
3650 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
3651
3652 David Naughton, C<naughton@umn.edu>
3653
3654 David E. Wheeler
3655
3656 dhoss: Devin Austin <dhoss@cpan.org>
3657
3658 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
3659
3660 Drew Taylor
3661
3662 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
3663
3664 esskar: Sascha Kiefer
3665
3666 fireartist: Carl Franks <cfranks@cpan.org>
3667
3668 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
3669
3670 gabb: Danijel Milicevic
3671
3672 Gary Ashton Jones
3673
3674 Gavin Henry C<ghenry@perl.me.uk>
3675
3676 Geoff Richards
3677
3678 groditi: Guillermo Roditi <groditi@gmail.com>
3679
3680 hobbs: Andrew Rodland <andrew@cleverdomain.org>
3681
3682 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
3683
3684 jcamacho: Juan Camacho
3685
3686 jester: Jesse Sheidlower C<jester@panix.com>
3687
3688 jhannah: Jay Hannah <jay@jays.net>
3689
3690 Jody Belka
3691
3692 Johan Lindstrom
3693
3694 jon: Jon Schutz <jjschutz@cpan.org>
3695
3696 Jonathan Rockway C<< <jrockway@cpan.org> >>
3697
3698 Kieren Diment C<kd@totaldatasolution.com>
3699
3700 konobi: Scott McWhirter <konobi@cpan.org>
3701
3702 marcus: Marcus Ramberg <mramberg@cpan.org>
3703
3704 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
3705
3706 mgrimes: Mark Grimes <mgrimes@cpan.org>
3707
3708 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
3709
3710 mugwump: Sam Vilain
3711
3712 naughton: David Naughton
3713
3714 ningu: David Kamholz <dkamholz@cpan.org>
3715
3716 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
3717
3718 numa: Dan Sully <daniel@cpan.org>
3719
3720 obra: Jesse Vincent
3721
3722 Octavian Rasnita
3723
3724 omega: Andreas Marienborg
3725
3726 Oleg Kostyuk <cub.uanic@gmail.com>
3727
3728 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
3729
3730 rafl: Florian Ragwitz <rafl@debian.org>
3731
3732 random: Roland Lammel <lammel@cpan.org>
3733
3734 Robert Sedlacek C<< <rs@474.at> >>
3735
3736 SpiceMan: Marcel Montes
3737
3738 sky: Arthur Bergman
3739
3740 szbalint: Balint Szilakszi <szbalint@cpan.org>
3741
3742 t0m: Tomas Doran <bobtfish@bobtfish.net>
3743
3744 Ulf Edvinsson
3745
3746 Viljo Marrandi C<vilts@yahoo.com>
3747
3748 Will Hawes C<info@whawes.co.uk>
3749
3750 willert: Sebastian Willert <willert@cpan.org>
3751
3752 wreis: Wallace Reis <wreis@cpan.org>
3753
3754 Yuval Kogman, C<nothingmuch@woobling.org>
3755
3756 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
3757
3758 dd070: Dhaval Dhanani <dhaval070@gmail.com>
3759
3760 =head1 COPYRIGHT
3761
3762 Copyright (c) 2005, the above named PROJECT FOUNDER and CONTRIBUTORS.
3763
3764 =head1 LICENSE
3765
3766 This library is free software. You can redistribute it and/or modify it under
3767 the same terms as Perl itself.
3768
3769 =cut
3770
3771 no Moose;
3772
3773 __PACKAGE__->meta->make_immutable;
3774
3775 1;