lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use strict;
   4 use base 'Catalyst::Component';
   5 use bytes;
   6 use Catalyst::Exception;
   7 use Catalyst::Log;
   8 use Catalyst::Request;
   9 use Catalyst::Request::Upload;
  10 use Catalyst::Response;
  11 use Catalyst::Utils;
  12 use Catalyst::Controller;
  13 use Devel::InnerPackage ();
  14 use File::stat;
  15 use Module::Pluggable::Object ();
  16 use NEXT;
  17 use Text::SimpleTable ();
  18 use Path::Class::Dir ();
  19 use Path::Class::File ();
  20 use Time::HiRes qw/gettimeofday tv_interval/;
  21 use URI ();
  22 use Scalar::Util qw/weaken blessed/;
  23 use Tree::Simple qw/use_weak_refs/;
  24 use Tree::Simple::Visitor::FindByUID;
  25 use attributes;
  26 use utf8;
  27 use Carp qw/croak/;
  28
  29 BEGIN { require 5.008001; }
  30
  31 __PACKAGE__->mk_accessors(
  32     qw/counter request response state action stack namespace stats/
  33 );
  34
  35 attributes->import( __PACKAGE__, \&namespace, 'lvalue' );
  36
  37 sub depth { scalar @{ shift->stack || [] }; }
  38
  39 # Laziness++
  40 *comp = \&component;
  41 *req  = \&request;
  42 *res  = \&response;
  43
  44 # For backwards compatibility
  45 *finalize_output = \&finalize_body;
  46
  47 # For statistics
  48 our $COUNT     = 1;
  49 our $START     = time;
  50 our $RECURSION = 1000;
  51 our $DETACH    = "catalyst_detach\n";
  52
  53 __PACKAGE__->mk_classdata($_)
  54   for qw/components arguments dispatcher engine log dispatcher_class
  55   engine_class context_class request_class response_class setup_finished/;
  56
  57 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  58 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  59 __PACKAGE__->request_class('Catalyst::Request');
  60 __PACKAGE__->response_class('Catalyst::Response');
  61
  62 # Remember to update this in Catalyst::Runtime as well!
  63
  64 our $VERSION = '5.7000';
  65
  66 sub import {
  67     my ( $class, @arguments ) = @_;
  68
  69     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  70     # callers @ISA.
  71     return unless $class eq 'Catalyst';
  72
  73     my $caller = caller(0);
  74
  75     unless ( $caller->isa('Catalyst') ) {
  76         no strict 'refs';
  77         push @{"$caller\::ISA"}, $class, 'Catalyst::Controller';
  78     }
  79
  80     $caller->arguments( [@arguments] );
  81     $caller->setup_home;
  82 }
  83
  84 =head1 NAME
  85
  86 Catalyst - The Elegant MVC Web Application Framework
  87
  88 =head1 SYNOPSIS
  89
  90     # Install Catalyst::Devel for helpers and other development tools
  91     # use the helper to create a new application
  92     catalyst.pl MyApp
  93
  94     # add models, views, controllers
  95     script/myapp_create.pl model Database DBIC::SchemaLoader dbi:SQLite:/path/to/db
  96     script/myapp_create.pl view TT TT
  97     script/myapp_create.pl controller Search
  98
  99     # built in testserver -- use -r to restart automatically on changes
 100     script/myapp_server.pl
 101
 102     # command line testing interface
 103     script/myapp_test.pl /yada
 104
 105     ### in lib/MyApp.pm
 106     use Catalyst qw/-Debug/; # include plugins here as well
 107
 108         ### In lib/MyApp/Controller/Root.pm (autocreated)
 109     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 110         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 111         $c->stash->{template} = 'foo.tt'; # set the template
 112         # lookup something from db -- stash vars are passed to TT
 113         $c->stash->{data} =
 114           $c->model('Database::Foo')->search( { country => $args[0] } );
 115         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 116             $c->forward( 'bar' ); # process another action
 117             # do something else after forward returns
 118         }
 119     }
 120
 121     # The foo.tt TT template can use the stash data from the database
 122     [% WHILE (item = data.next) %]
 123         [% item.foo %]
 124     [% END %]
 125
 126     # called for /bar/of/soap, /bar/of/soap/10, etc.
 127     sub bar : Path('/bar/of/soap') { ... }
 128
 129     # called for all actions, from the top-most controller downwards
 130     sub auto : Private {
 131         my ( $self, $c ) = @_;
 132         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 133             $c->res->redirect( '/login' ); # require login
 134             return 0; # abort request and go immediately to end()
 135         }
 136         return 1; # success; carry on to next action
 137     }
 138
 139     # called after all actions are finished
 140     sub end : Private {
 141         my ( $self, $c ) = @_;
 142         if ( scalar @{ $c->error } ) { ... } # handle errors
 143         return if $c->res->body; # already have a response
 144         $c->forward( 'MyApp::View::TT' ); # render template
 145     }
 146
 147     ### in MyApp/Controller/Foo.pm
 148     # called for /foo/bar
 149     sub bar : Local { ... }
 150
 151     # called for /blargle
 152     sub blargle : Global { ... }
 153
 154     # an index action matches /foo, but not /foo/1, etc.
 155     sub index : Private { ... }
 156
 157     ### in MyApp/Controller/Foo/Bar.pm
 158     # called for /foo/bar/baz
 159     sub baz : Local { ... }
 160
 161     # first Root auto is called, then Foo auto, then this
 162     sub auto : Private { ... }
 163
 164     # powerful regular expression paths are also possible
 165     sub details : Regex('^product/(\w+)/details$') {
 166         my ( $self, $c ) = @_;
 167         # extract the (\w+) from the URI
 168         my $product = $c->req->captures->[0];
 169     }
 170
 171 See L<Catalyst::Manual::Intro> for additional information.
 172
 173 =head1 DESCRIPTION
 174
 175 Catalyst is a modern framework for making web applications without the
 176 pain usually associated with this process. This document is a reference
 177 to the main Catalyst application. If you are a new user, we suggest you
 178 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 179
 180 See L<Catalyst::Manual> for more documentation.
 181
 182 Catalyst plugins can be loaded by naming them as arguments to the "use
 183 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 184 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 185 C<My::Module>.
 186
 187     use Catalyst qw/My::Module/;
 188
 189 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 190 fully qualify the name by using a unary plus:
 191
 192     use Catalyst qw/
 193         My::Module
 194         +Fully::Qualified::Plugin::Name
 195     /;
 196
 197 Special flags like C<-Debug> and C<-Engine> can also be specified as
 198 arguments when Catalyst is loaded:
 199
 200     use Catalyst qw/-Debug My::Module/;
 201
 202 The position of plugins and flags in the chain is important, because
 203 they are loaded in the order in which they appear.
 204
 205 The following flags are supported:
 206
 207 =head2 -Debug
 208
 209 Enables debug output. You can also force this setting from the system
 210 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 211 settings override the application, with <MYAPP>_DEBUG having the highest
 212 priority.
 213
 214 =head2 -Engine
 215
 216 Forces Catalyst to use a specific engine. Omit the
 217 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 218
 219     use Catalyst qw/-Engine=CGI/;
 220
 221 =head2 -Home
 222
 223 Forces Catalyst to use a specific home directory, e.g.:
 224
 225     use Catalyst qw[-Home=/usr/mst];
 226
 227 =head2 -Log
 228
 229 Specifies log level.
 230
 231 =head1 METHODS
 232
 233 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 234
 235 =head2 $c->action
 236
 237 Returns a L<Catalyst::Action> object for the current action, which
 238 stringifies to the action name. See L<Catalyst::Action>.
 239
 240 =head2 $c->namespace
 241
 242 Returns the namespace of the current action, i.e., the URI prefix
 243 corresponding to the controller of the current action. For example:
 244
 245     # in Controller::Foo::Bar
 246     $c->namespace; # returns 'foo/bar';
 247
 248 =head2 $c->request
 249
 250 =head2 $c->req
 251
 252 Returns the current L<Catalyst::Request> object, giving access to
 253 information about the current client request (including parameters,
 254 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 255
 256 =head2 REQUEST FLOW HANDLING
 257
 258 =head2 $c->forward( $action [, \@arguments ] )
 259
 260 =head2 $c->forward( $class, $method, [, \@arguments ] )
 261
 262 Forwards processing to another action, by its private name. If you give a
 263 class name but no method, C<process()> is called. You may also optionally
 264 pass arguments in an arrayref. The action will receive the arguments in
 265 C<@_> and C<$c-E<gt>req-E<gt>args>. Upon returning from the function,
 266 C<$c-E<gt>req-E<gt>args> will be restored to the previous values.
 267
 268 Any data C<return>ed from the action forwarded to, will be returned by the
 269 call to forward.
 270
 271     my $foodata = $c->forward('/foo');
 272     $c->forward('index');
 273     $c->forward(qw/MyApp::Model::DBIC::Foo do_stuff/);
 274     $c->forward('MyApp::View::TT');
 275
 276 Note that forward implies an C<<eval { }>> around the call (actually
 277 C<execute> does), thus de-fatalizing all 'dies' within the called
 278 action. If you want C<die> to propagate you need to do something like:
 279
 280     $c->forward('foo');
 281     die $c->error if $c->error;
 282
 283 Or make sure to always return true values from your actions and write
 284 your code like this:
 285
 286     $c->forward('foo') || return;
 287
 288 =cut
 289
 290 sub forward { my $c = shift; $c->dispatcher->forward( $c, @_ ) }
 291
 292 =head2 $c->detach( $action [, \@arguments ] )
 293
 294 =head2 $c->detach( $class, $method, [, \@arguments ] )
 295
 296 The same as C<forward>, but doesn't return to the previous action when
 297 processing is finished.
 298
 299 =cut
 300
 301 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 302
 303 =head2 $c->response
 304
 305 =head2 $c->res
 306
 307 Returns the current L<Catalyst::Response> object, q.v.
 308
 309 =head2 $c->stash
 310
 311 Returns a hashref to the stash, which may be used to store data and pass
 312 it between components during a request. You can also set hash keys by
 313 passing arguments. The stash is automatically sent to the view. The
 314 stash is cleared at the end of a request; it cannot be used for
 315 persistent storage (for this you must use a session; see
 316 L<Catalyst::Plugin::Session> for a complete system integrated with
 317 Catalyst).
 318
 319     $c->stash->{foo} = $bar;
 320     $c->stash( { moose => 'majestic', qux => 0 } );
 321     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 322
 323     # stash is automatically passed to the view for use in a template
 324     $c->forward( 'MyApp::V::TT' );
 325
 326 =cut
 327
 328 sub stash {
 329     my $c = shift;
 330     if (@_) {
 331         my $stash = @_ > 1 ? {@_} : $_[0];
 332         croak('stash takes a hash or hashref') unless ref $stash;
 333         foreach my $key ( keys %$stash ) {
 334             $c->{stash}->{$key} = $stash->{$key};
 335         }
 336     }
 337     return $c->{stash};
 338 }
 339
 340 =head2 $c->error
 341
 342 =head2 $c->error($error, ...)
 343
 344 =head2 $c->error($arrayref)
 345
 346 Returns an arrayref containing error messages.  If Catalyst encounters an
 347 error while processing a request, it stores the error in $c->error.  This
 348 method should not be used to store non-fatal error messages.
 349
 350     my @error = @{ $c->error };
 351
 352 Add a new error.
 353
 354     $c->error('Something bad happened');
 355
 356 =cut
 357
 358 sub error {
 359     my $c = shift;
 360     if ( $_[0] ) {
 361         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 362         croak @$error unless ref $c;
 363         push @{ $c->{error} }, @$error;
 364     }
 365     elsif ( defined $_[0] ) { $c->{error} = undef }
 366     return $c->{error} || [];
 367 }
 368
 369
 370 =head2 $c->state
 371
 372 Contains the return value of the last executed action.
 373
 374 =head2 $c->clear_errors
 375
 376 Clear errors.  You probably don't want to clear the errors unless you are
 377 implementing a custom error screen.
 378
 379 This is equivalent to running
 380
 381     $c->error(0);
 382
 383 =cut
 384
 385 sub clear_errors {
 386     my $c = shift;
 387     $c->error(0);
 388 }
 389
 390
 391 # search via regex
 392 sub _comp_search {
 393     my ( $c, @names ) = @_;
 394
 395     foreach my $name (@names) {
 396         foreach my $component ( keys %{ $c->components } ) {
 397             return $c->components->{$component} if $component =~ /$name/i;
 398         }
 399     }
 400
 401     return undef;
 402 }
 403
 404 # try explicit component names
 405 sub _comp_explicit {
 406     my ( $c, @names ) = @_;
 407
 408     foreach my $try (@names) {
 409         return $c->components->{$try} if ( exists $c->components->{$try} );
 410     }
 411
 412     return undef;
 413 }
 414
 415 # like component, but try just these prefixes before regex searching,
 416 #  and do not try to return "sort keys %{ $c->components }"
 417 sub _comp_prefixes {
 418     my ( $c, $name, @prefixes ) = @_;
 419
 420     my $appclass = ref $c || $c;
 421
 422     my @names = map { "${appclass}::${_}::${name}" } @prefixes;
 423
 424     my $comp = $c->_comp_explicit(@names);
 425     return $comp if defined($comp);
 426     $comp = $c->_comp_search($name);
 427     return $comp;
 428 }
 429
 430 # Find possible names for a prefix
 431
 432 sub _comp_names {
 433     my ( $c, @prefixes ) = @_;
 434
 435     my $appclass = ref $c || $c;
 436
 437     my @pre = map { "${appclass}::${_}::" } @prefixes;
 438
 439     my @names;
 440
 441     COMPONENT: foreach my $comp ($c->component) {
 442         foreach my $p (@pre) {
 443             if ($comp =~ s/^$p//) {
 444                 push(@names, $comp);
 445                 next COMPONENT;
 446             }
 447         }
 448     }
 449
 450     return @names;
 451 }
 452
 453 # Return a component if only one matches.
 454 sub _comp_singular {
 455     my ( $c, @prefixes ) = @_;
 456
 457     my $appclass = ref $c || $c;
 458
 459     my ( $comp, $rest ) =
 460       map { $c->_comp_search("^${appclass}::${_}::") } @prefixes;
 461     return $comp unless $rest;
 462 }
 463
 464 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 465 sub _filter_component {
 466     my ( $c, $comp, @args ) = @_;
 467     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 468         return $comp->ACCEPT_CONTEXT( $c, @args );
 469     }
 470     else { return $comp }
 471 }
 472
 473 =head2 COMPONENT ACCESSORS
 474
 475 =head2 $c->controller($name)
 476
 477 Gets a L<Catalyst::Controller> instance by name.
 478
 479     $c->controller('Foo')->do_stuff;
 480
 481 If the name is omitted, will return the controller for the dispatched
 482 action.
 483
 484 =cut
 485
 486 sub controller {
 487     my ( $c, $name, @args ) = @_;
 488     return $c->_filter_component( $c->_comp_prefixes( $name, qw/Controller C/ ),
 489         @args )
 490       if ($name);
 491     return $c->component( $c->action->class );
 492 }
 493
 494 =head2 $c->model($name)
 495
 496 Gets a L<Catalyst::Model> instance by name.
 497
 498     $c->model('Foo')->do_stuff;
 499
 500 If the name is omitted, it will look for a config setting 'default_model',
 501 or check if there is only one view, and return it if that's the case.
 502
 503 =cut
 504
 505 sub model {
 506     my ( $c, $name, @args ) = @_;
 507     return $c->_filter_component( $c->_comp_prefixes( $name, qw/Model M/ ),
 508         @args )
 509       if $name;
 510     return $c->component( $c->config->{default_model} )
 511       if $c->config->{default_model};
 512     return $c->_filter_component( $c->_comp_singular(qw/Model M/), @args );
 513
 514 }
 515
 516 =head2 $c->controllers
 517
 518 Returns the available names which can be passed to $c->controller
 519
 520 =cut
 521
 522 sub controllers {
 523     my ( $c ) = @_;
 524     return $c->_comp_names(qw/Controller C/);
 525 }
 526
 527
 528 =head2 $c->view($name)
 529
 530 Gets a L<Catalyst::View> instance by name.
 531
 532     $c->view('Foo')->do_stuff;
 533
 534 If the name is omitted, it will look for a config setting
 535 'default_view', or check if there is only one view, and forward to it if
 536 that's the case.
 537
 538 =cut
 539
 540 sub view {
 541     my ( $c, $name, @args ) = @_;
 542     return $c->_filter_component( $c->_comp_prefixes( $name, qw/View V/ ),
 543         @args )
 544       if $name;
 545     return $c->component( $c->config->{default_view} )
 546       if $c->config->{default_view};
 547     return $c->_filter_component( $c->_comp_singular(qw/View V/) );
 548 }
 549
 550 =head2 $c->models
 551
 552 Returns the available names which can be passed to $c->model
 553
 554 =cut
 555
 556 sub models {
 557     my ( $c ) = @_;
 558     return $c->_comp_names(qw/Model M/);
 559 }
 560
 561
 562 =head2 $c->views
 563
 564 Returns the available names which can be passed to $c->view
 565
 566 =cut
 567
 568 sub views {
 569     my ( $c ) = @_;
 570     return $c->_comp_names(qw/View V/);
 571 }
 572
 573 =head2 $c->comp($name)
 574
 575 =head2 $c->component($name)
 576
 577 Gets a component object by name. This method is no longer recommended,
 578 unless you want to get a specific component by full
 579 class. C<$c-E<gt>controller>, C<$c-E<gt>model>, and C<$c-E<gt>view>
 580 should be used instead.
 581
 582 =cut
 583
 584 sub component {
 585     my $c = shift;
 586
 587     if (@_) {
 588
 589         my $name = shift;
 590
 591         my $appclass = ref $c || $c;
 592
 593         my @names = (
 594             $name, "${appclass}::${name}",
 595             map { "${appclass}::${_}::${name}" }
 596               qw/Model M Controller C View V/
 597         );
 598
 599         my $comp = $c->_comp_explicit(@names);
 600         return $c->_filter_component( $comp, @_ ) if defined($comp);
 601
 602         $comp = $c->_comp_search($name);
 603         return $c->_filter_component( $comp, @_ ) if defined($comp);
 604     }
 605
 606     return sort keys %{ $c->components };
 607 }
 608
 609
 610
 611 =head2 CLASS DATA AND HELPER CLASSES
 612
 613 =head2 $c->config
 614
 615 Returns or takes a hashref containing the application's configuration.
 616
 617     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 618
 619 You can also use a L<YAML> config file like myapp.yml in your
 620 applications home directory.
 621
 622     ---
 623     db: dsn:SQLite:foo.db
 624
 625
 626 =cut
 627
 628 sub config {
 629     my $c = shift;
 630
 631     $c->log->warn("Setting config after setup has been run is not a good idea.")
 632       if ( @_ and $c->setup_finished );
 633
 634     $c->NEXT::config(@_);
 635 }
 636
 637 =head2 $c->log
 638
 639 Returns the logging object instance. Unless it is already set, Catalyst
 640 sets this up with a L<Catalyst::Log> object. To use your own log class,
 641 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 642 C<< __PACKAGE__->setup >>.
 643
 644  __PACKAGE__->log( MyLogger->new );
 645  __PACKAGE__->setup;
 646
 647 And later:
 648
 649     $c->log->info( 'Now logging with my own logger!' );
 650
 651 Your log class should implement the methods described in
 652 L<Catalyst::Log>.
 653
 654
 655 =head2 $c->debug
 656
 657 Overload to enable debug messages (same as -Debug option).
 658
 659 Note that this is a static method, not an accessor and should be overloaded
 660 by declaring "sub debug { 1 }" in your MyApp.pm, not by calling $c->debug(1).
 661
 662 =cut
 663
 664 sub debug { 0 }
 665
 666 =head2 $c->dispatcher
 667
 668 Returns the dispatcher instance. Stringifies to class name. See
 669 L<Catalyst::Dispatcher>.
 670
 671 =head2 $c->engine
 672
 673 Returns the engine instance. Stringifies to the class name. See
 674 L<Catalyst::Engine>.
 675
 676
 677 =head2 UTILITY METHODS
 678
 679 =head2 $c->path_to(@path)
 680
 681 Merges C<@path> with C<$c-E<gt>config-E<gt>{home}> and returns a
 682 L<Path::Class> object.
 683
 684 For example:
 685
 686     $c->path_to( 'db', 'sqlite.db' );
 687
 688 =cut
 689
 690 sub path_to {
 691     my ( $c, @path ) = @_;
 692     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 693     if ( -d $path ) { return $path }
 694     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 695 }
 696
 697 =head2 $c->plugin( $name, $class, @args )
 698
 699 Helper method for plugins. It creates a classdata accessor/mutator and
 700 loads and instantiates the given class.
 701
 702     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 703
 704     $c->prototype->define_javascript_functions;
 705
 706 =cut
 707
 708 sub plugin {
 709     my ( $class, $name, $plugin, @args ) = @_;
 710     $class->_register_plugin( $plugin, 1 );
 711
 712     eval { $plugin->import };
 713     $class->mk_classdata($name);
 714     my $obj;
 715     eval { $obj = $plugin->new(@args) };
 716
 717     if ($@) {
 718         Catalyst::Exception->throw( message =>
 719               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 720     }
 721
 722     $class->$name($obj);
 723     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 724       if $class->debug;
 725 }
 726
 727 =head2 MyApp->setup
 728
 729 Initializes the dispatcher and engine, loads any plugins, and loads the
 730 model, view, and controller components. You may also specify an array
 731 of plugins to load here, if you choose to not load them in the C<use
 732 Catalyst> line.
 733
 734     MyApp->setup;
 735     MyApp->setup( qw/-Debug/ );
 736
 737 =cut
 738
 739 sub setup {
 740     my ( $class, @arguments ) = @_;
 741
 742     $class->log->warn("Running setup twice is not a good idea.")
 743       if ( $class->setup_finished );
 744
 745     unless ( $class->isa('Catalyst') ) {
 746
 747         Catalyst::Exception->throw(
 748             message => qq/'$class' does not inherit from Catalyst/ );
 749     }
 750
 751     if ( $class->arguments ) {
 752         @arguments = ( @arguments, @{ $class->arguments } );
 753     }
 754
 755     # Process options
 756     my $flags = {};
 757
 758     foreach (@arguments) {
 759
 760         if (/^-Debug$/) {
 761             $flags->{log} =
 762               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
 763         }
 764         elsif (/^-(\w+)=?(.*)$/) {
 765             $flags->{ lc $1 } = $2;
 766         }
 767         else {
 768             push @{ $flags->{plugins} }, $_;
 769         }
 770     }
 771
 772     $class->setup_home( delete $flags->{home} );
 773
 774     $class->setup_log( delete $flags->{log} );
 775     $class->setup_plugins( delete $flags->{plugins} );
 776     $class->setup_dispatcher( delete $flags->{dispatcher} );
 777     $class->setup_engine( delete $flags->{engine} );
 778
 779     for my $flag ( sort keys %{$flags} ) {
 780
 781         if ( my $code = $class->can( 'setup_' . $flag ) ) {
 782             &$code( $class, delete $flags->{$flag} );
 783         }
 784         else {
 785             $class->log->warn(qq/Unknown flag "$flag"/);
 786         }
 787     }
 788
 789     eval { require Catalyst::Devel; };
 790     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
 791         $class->log->warn(<<"EOF");
 792 You are running an old script!
 793
 794   Please update by running (this will overwrite existing files):
 795     catalyst.pl -force -scripts $class
 796
 797   or (this will not overwrite existing files):
 798     catalyst.pl -scripts $class
 799 EOF
 800     }
 801
 802     if ( $class->debug ) {
 803         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
 804
 805         if (@plugins) {
 806             my $t = Text::SimpleTable->new(74);
 807             $t->row($_) for @plugins;
 808             $class->log->debug( "Loaded plugins:\n" . $t->draw );
 809         }
 810
 811         my $dispatcher = $class->dispatcher;
 812         my $engine     = $class->engine;
 813         my $home       = $class->config->{home};
 814
 815         $class->log->debug(qq/Loaded dispatcher "$dispatcher"/);
 816         $class->log->debug(qq/Loaded engine "$engine"/);
 817
 818         $home
 819           ? ( -d $home )
 820           ? $class->log->debug(qq/Found home "$home"/)
 821           : $class->log->debug(qq/Home "$home" doesn't exist/)
 822           : $class->log->debug(q/Couldn't find home/);
 823     }
 824
 825     # Call plugins setup
 826     {
 827         no warnings qw/redefine/;
 828         local *setup = sub { };
 829         $class->setup;
 830     }
 831
 832     # Initialize our data structure
 833     $class->components( {} );
 834
 835     $class->setup_components;
 836
 837     if ( $class->debug ) {
 838         my $t = Text::SimpleTable->new( [ 63, 'Class' ], [ 8, 'Type' ] );
 839         for my $comp ( sort keys %{ $class->components } ) {
 840             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
 841             $t->row( $comp, $type );
 842         }
 843         $class->log->debug( "Loaded components:\n" . $t->draw )
 844           if ( keys %{ $class->components } );
 845     }
 846
 847     # Add our self to components, since we are also a component
 848     $class->components->{$class} = $class;
 849
 850     $class->setup_actions;
 851
 852     if ( $class->debug ) {
 853         my $name = $class->config->{name} || 'Application';
 854         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
 855     }
 856     $class->log->_flush() if $class->log->can('_flush');
 857
 858     $class->setup_finished(1);
 859 }
 860
 861 =head2 $c->uri_for( $path, @args?, \%query_values? )
 862
 863 Merges path with C<< $c->request->base >> for absolute URIs and with
 864 C<< $c->namespace >> for relative URIs, then returns a normalized L<URI>
 865 object. If any args are passed, they are added at the end of the path.
 866 If the last argument to C<uri_for> is a hash reference, it is assumed to
 867 contain GET parameter key/value pairs, which will be appended to the URI
 868 in standard fashion.
 869
 870 Instead of C<$path>, you can also optionally pass a C<$action> object
 871 which will be resolved to a path using
 872 C<< $c->dispatcher->uri_for_action >>; if the first element of
 873 C<@args> is an arrayref it is treated as a list of captures to be passed
 874 to C<uri_for_action>.
 875
 876 =cut
 877
 878 sub uri_for {
 879     my ( $c, $path, @args ) = @_;
 880     my $base     = $c->request->base->clone;
 881     my $basepath = $base->path;
 882     $basepath =~ s/\/$//;
 883     $basepath .= '/';
 884     my $namespace = $c->namespace || '';
 885
 886     if ( Scalar::Util::blessed($path) ) { # action object
 887         my $captures = ( scalar @args && ref $args[0] eq 'ARRAY'
 888                          ? shift(@args)
 889                          : [] );
 890         $path = $c->dispatcher->uri_for_action($path, $captures);
 891         return undef unless defined($path);
 892     }
 893
 894     # massage namespace, empty if absolute path
 895     $namespace =~ s/^\/// if $namespace;
 896     $namespace .= '/' if $namespace;
 897     $path ||= '';
 898     $namespace = '' if $path =~ /^\//;
 899     $path =~ s/^\///;
 900
 901     my $params =
 902       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
 903
 904     for my $value ( values %$params ) {
 905         for ( ref $value eq 'ARRAY' ? @$value : $value ) {
 906             $_ = "$_";
 907             utf8::encode( $_ );
 908         }
 909     };
 910
 911     # join args with '/', or a blank string
 912     my $args = ( scalar @args ? '/' . join( '/', @args ) : '' );
 913     $args =~ s/^\/// unless $path;
 914     my $res =
 915       URI->new_abs( URI->new_abs( "$path$args", "$basepath$namespace" ), $base )
 916       ->canonical;
 917     $res->query_form(%$params);
 918     $res;
 919 }
 920
 921 =head2 $c->welcome_message
 922
 923 Returns the Catalyst welcome HTML page.
 924
 925 =cut
 926
 927 sub welcome_message {
 928     my $c      = shift;
 929     my $name   = $c->config->{name};
 930     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
 931     my $prefix = Catalyst::Utils::appprefix( ref $c );
 932     $c->response->content_type('text/html; charset=utf-8');
 933     return <<"EOF";
 934 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
 935     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
 936 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
 937     <head>
 938         <meta http-equiv="Content-Language" content="en" />
 939         <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
 940         <title>$name on Catalyst $VERSION</title>
 941         <style type="text/css">
 942             body {
 943                 color: #000;
 944                 background-color: #eee;
 945             }
 946             div#content {
 947                 width: 640px;
 948                 margin-left: auto;
 949                 margin-right: auto;
 950                 margin-top: 10px;
 951                 margin-bottom: 10px;
 952                 text-align: left;
 953                 background-color: #ccc;
 954                 border: 1px solid #aaa;
 955             }
 956             p, h1, h2 {
 957                 margin-left: 20px;
 958                 margin-right: 20px;
 959                 font-family: verdana, tahoma, sans-serif;
 960             }
 961             a {
 962                 font-family: verdana, tahoma, sans-serif;
 963             }
 964             :link, :visited {
 965                     text-decoration: none;
 966                     color: #b00;
 967                     border-bottom: 1px dotted #bbb;
 968             }
 969             :link:hover, :visited:hover {
 970                     color: #555;
 971             }
 972             div#topbar {
 973                 margin: 0px;
 974             }
 975             pre {
 976                 margin: 10px;
 977                 padding: 8px;
 978             }
 979             div#answers {
 980                 padding: 8px;
 981                 margin: 10px;
 982                 background-color: #fff;
 983                 border: 1px solid #aaa;
 984             }
 985             h1 {
 986                 font-size: 0.9em;
 987                 font-weight: normal;
 988                 text-align: center;
 989             }
 990             h2 {
 991                 font-size: 1.0em;
 992             }
 993             p {
 994                 font-size: 0.9em;
 995             }
 996             p img {
 997                 float: right;
 998                 margin-left: 10px;
 999             }
1000             span#appname {
1001                 font-weight: bold;
1002                 font-size: 1.6em;
1003             }
1004         </style>
1005     </head>
1006     <body>
1007         <div id="content">
1008             <div id="topbar">
1009                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1010                     $VERSION</h1>
1011              </div>
1012              <div id="answers">
1013                  <p>
1014                  <img src="$logo" alt="Catalyst Logo" />
1015                  </p>
1016                  <p>Welcome to the wonderful world of Catalyst.
1017                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1018                     framework will make web development something you had
1019                     never expected it to be: Fun, rewarding, and quick.</p>
1020                  <h2>What to do now?</h2>
1021                  <p>That really depends  on what <b>you</b> want to do.
1022                     We do, however, provide you with a few starting points.</p>
1023                  <p>If you want to jump right into web development with Catalyst
1024                     you might want to check out the documentation.</p>
1025                  <pre><code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1026 perldoc <a href="http://cpansearch.perl.org/dist/Catalyst/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1027 perldoc <a href="http://cpansearch.perl.org/dist/Catalyst/lib/Catalyst/Manual.pod">Catalyst::Manual</a></code></pre>
1028                  <h2>What to do next?</h2>
1029                  <p>Next it's time to write an actual application. Use the
1030                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1031                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1032                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1033                     they can save you a lot of work.</p>
1034                     <pre><code>script/${prefix}_create.pl -help</code></pre>
1035                     <p>Also, be sure to check out the vast and growing
1036                     collection of <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3APlugin%3A%3A&amp;mode=all">plugins for Catalyst on CPAN</a>;
1037                     you are likely to find what you need there.
1038                     </p>
1039
1040                  <h2>Need help?</h2>
1041                  <p>Catalyst has a very active community. Here are the main places to
1042                     get in touch with us.</p>
1043                  <ul>
1044                      <li>
1045                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1046                      </li>
1047                      <li>
1048                          <a href="http://lists.rawmode.org/mailman/listinfo/catalyst">Mailing-List</a>
1049                      </li>
1050                      <li>
1051                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1052                      </li>
1053                  </ul>
1054                  <h2>In conclusion</h2>
1055                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1056                     as we enjoyed making it. Please contact us if you have ideas
1057                     for improvement or other feedback.</p>
1058              </div>
1059          </div>
1060     </body>
1061 </html>
1062 EOF
1063 }
1064
1065 =head1 INTERNAL METHODS
1066
1067 These methods are not meant to be used by end users.
1068
1069 =head2 $c->components
1070
1071 Returns a hash of components.
1072
1073 =head2 $c->context_class
1074
1075 Returns or sets the context class.
1076
1077 =head2 $c->counter
1078
1079 Returns a hashref containing coderefs and execution counts (needed for
1080 deep recursion detection).
1081
1082 =head2 $c->depth
1083
1084 Returns the number of actions on the current internal execution stack.
1085
1086 =head2 $c->dispatch
1087
1088 Dispatches a request to actions.
1089
1090 =cut
1091
1092 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1093
1094 =head2 $c->dispatcher_class
1095
1096 Returns or sets the dispatcher class.
1097
1098 =head2 $c->dump_these
1099
1100 Returns a list of 2-element array references (name, structure) pairs
1101 that will be dumped on the error page in debug mode.
1102
1103 =cut
1104
1105 sub dump_these {
1106     my $c = shift;
1107     [ Request => $c->req ],
1108     [ Response => $c->res ],
1109     [ Stash => $c->stash ],
1110     [ Config => $c->config ];
1111 }
1112
1113 =head2 $c->engine_class
1114
1115 Returns or sets the engine class.
1116
1117 =head2 $c->execute( $class, $coderef )
1118
1119 Execute a coderef in given class and catch exceptions. Errors are available
1120 via $c->error.
1121
1122 =cut
1123
1124 sub execute {
1125     my ( $c, $class, $code ) = @_;
1126     $class = $c->component($class) || $class;
1127     $c->state(0);
1128
1129     if ( $c->depth >= $RECURSION ) {
1130         my $action = "$code";
1131         $action = "/$action" unless $action =~ /->/;
1132         my $error = qq/Deep recursion detected calling "$action"/;
1133         $c->log->error($error);
1134         $c->error($error);
1135         $c->state(0);
1136         return $c->state;
1137     }
1138
1139     my $stats_info = $c->_stats_start_execute( $code ) if $c->debug;
1140
1141     push( @{ $c->stack }, $code );
1142
1143     eval { $c->state( &$code( $class, $c, @{ $c->req->args } ) || 0 ) };
1144
1145     $c->_stats_finish_execute( $stats_info ) if $c->debug and $stats_info;
1146
1147     my $last = pop( @{ $c->stack } );
1148
1149     if ( my $error = $@ ) {
1150         if ( $error eq $DETACH ) { die $DETACH if $c->depth > 1 }
1151         else {
1152             unless ( ref $error ) {
1153                 no warnings 'uninitialized';
1154                 chomp $error;
1155                 my $class = $last->class;
1156                 my $name  = $last->name;
1157                 $error = qq/Caught exception in $class->$name "$error"/;
1158             }
1159             $c->error($error);
1160             $c->state(0);
1161         }
1162     }
1163     return $c->state;
1164 }
1165
1166 sub _stats_start_execute {
1167     my ( $c, $code ) = @_;
1168
1169     return if ( ( $code->name =~ /^_.*/ )
1170         && ( !$c->config->{show_internal_actions} ) );
1171
1172     $c->counter->{"$code"}++;
1173
1174     my $action = "$code";
1175     $action = "/$action" unless $action =~ /->/;
1176
1177     # determine if the call was the result of a forward
1178     # this is done by walking up the call stack and looking for a calling
1179     # sub of Catalyst::forward before the eval
1180     my $callsub = q{};
1181     for my $index ( 2 .. 11 ) {
1182         last
1183         if ( ( caller($index) )[0] eq 'Catalyst'
1184             && ( caller($index) )[3] eq '(eval)' );
1185
1186         if ( ( caller($index) )[3] =~ /forward$/ ) {
1187             $callsub = ( caller($index) )[3];
1188             $action  = "-> $action";
1189             last;
1190         }
1191     }
1192
1193     my $node = Tree::Simple->new(
1194         {
1195             action  => $action,
1196             elapsed => undef,     # to be filled in later
1197             comment => "",
1198         }
1199     );
1200     $node->setUID( "$code" . $c->counter->{"$code"} );
1201
1202     # is this a root-level call or a forwarded call?
1203     if ( $callsub =~ /forward$/ ) {
1204
1205         # forward, locate the caller
1206         if ( my $parent = $c->stack->[-1] ) {
1207             my $visitor = Tree::Simple::Visitor::FindByUID->new;
1208             $visitor->searchForUID(
1209                 "$parent" . $c->counter->{"$parent"} );
1210             $c->stats->accept($visitor);
1211             if ( my $result = $visitor->getResult ) {
1212                 $result->addChild($node);
1213             }
1214         }
1215         else {
1216
1217             # forward with no caller may come from a plugin
1218             $c->stats->addChild($node);
1219         }
1220     }
1221     else {
1222
1223         # root-level call
1224         $c->stats->addChild($node);
1225     }
1226
1227     return {
1228         start   => [gettimeofday],
1229         node    => $node,
1230     };
1231 }
1232
1233 sub _stats_finish_execute {
1234     my ( $c, $info ) = @_;
1235     my $elapsed = tv_interval $info->{start};
1236     my $value = $info->{node}->getNodeValue;
1237     $value->{elapsed} = sprintf( '%fs', $elapsed );
1238 }
1239
1240 =head2 $c->_localize_fields( sub { }, \%keys );
1241
1242 =cut
1243
1244 sub _localize_fields {
1245     my ( $c, $localized, $code ) = ( @_ );
1246
1247     my $request = delete $localized->{request} || {};
1248     my $response = delete $localized->{response} || {};
1249
1250     local @{ $c }{ keys %$localized } = values %$localized;
1251     local @{ $c->request }{ keys %$request } = values %$request;
1252     local @{ $c->response }{ keys %$response } = values %$response;
1253
1254     $code->();
1255 }
1256
1257 =head2 $c->finalize
1258
1259 Finalizes the request.
1260
1261 =cut
1262
1263 sub finalize {
1264     my $c = shift;
1265
1266     for my $error ( @{ $c->error } ) {
1267         $c->log->error($error);
1268     }
1269
1270     # Allow engine to handle finalize flow (for POE)
1271     if ( $c->engine->can('finalize') ) {
1272         $c->engine->finalize($c);
1273     }
1274     else {
1275
1276         $c->finalize_uploads;
1277
1278         # Error
1279         if ( $#{ $c->error } >= 0 ) {
1280             $c->finalize_error;
1281         }
1282
1283         $c->finalize_headers;
1284
1285         # HEAD request
1286         if ( $c->request->method eq 'HEAD' ) {
1287             $c->response->body('');
1288         }
1289
1290         $c->finalize_body;
1291     }
1292
1293     return $c->response->status;
1294 }
1295
1296 =head2 $c->finalize_body
1297
1298 Finalizes body.
1299
1300 =cut
1301
1302 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1303
1304 =head2 $c->finalize_cookies
1305
1306 Finalizes cookies.
1307
1308 =cut
1309
1310 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1311
1312 =head2 $c->finalize_error
1313
1314 Finalizes error.
1315
1316 =cut
1317
1318 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1319
1320 =head2 $c->finalize_headers
1321
1322 Finalizes headers.
1323
1324 =cut
1325
1326 sub finalize_headers {
1327     my $c = shift;
1328
1329     # Check if we already finalized headers
1330     return if $c->response->{_finalized_headers};
1331
1332     # Handle redirects
1333     if ( my $location = $c->response->redirect ) {
1334         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1335         $c->response->header( Location => $location );
1336     }
1337
1338     # Content-Length
1339     if ( $c->response->body && !$c->response->content_length ) {
1340
1341         # get the length from a filehandle
1342         if ( blessed( $c->response->body ) && $c->response->body->can('read') )
1343         {
1344             if ( my $stat = stat $c->response->body ) {
1345                 $c->response->content_length( $stat->size );
1346             }
1347             else {
1348                 $c->log->warn('Serving filehandle without a content-length');
1349             }
1350         }
1351         else {
1352             $c->response->content_length( bytes::length( $c->response->body ) );
1353         }
1354     }
1355
1356     # Errors
1357     if ( $c->response->status =~ /^(1\d\d|[23]04)$/ ) {
1358         $c->response->headers->remove_header("Content-Length");
1359         $c->response->body('');
1360     }
1361
1362     $c->finalize_cookies;
1363
1364     $c->engine->finalize_headers( $c, @_ );
1365
1366     # Done
1367     $c->response->{_finalized_headers} = 1;
1368 }
1369
1370 =head2 $c->finalize_output
1371
1372 An alias for finalize_body.
1373
1374 =head2 $c->finalize_read
1375
1376 Finalizes the input after reading is complete.
1377
1378 =cut
1379
1380 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1381
1382 =head2 $c->finalize_uploads
1383
1384 Finalizes uploads. Cleans up any temporary files.
1385
1386 =cut
1387
1388 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1389
1390 =head2 $c->get_action( $action, $namespace )
1391
1392 Gets an action in a given namespace.
1393
1394 =cut
1395
1396 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1397
1398 =head2 $c->get_actions( $action, $namespace )
1399
1400 Gets all actions of a given name in a namespace and all parent
1401 namespaces.
1402
1403 =cut
1404
1405 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1406
1407 =head2 $c->handle_request( $class, @arguments )
1408
1409 Called to handle each HTTP request.
1410
1411 =cut
1412
1413 sub handle_request {
1414     my ( $class, @arguments ) = @_;
1415
1416     # Always expect worst case!
1417     my $status = -1;
1418     eval {
1419         if ($class->debug) {
1420             my $start = [gettimeofday];
1421             my $c = $class->prepare(@arguments);
1422             $c->stats(Tree::Simple->new);
1423             $c->dispatch;
1424             $status = $c->finalize;
1425
1426             my $elapsed = tv_interval $start;
1427             $elapsed = sprintf '%f', $elapsed;
1428             my $av = sprintf '%.3f',
1429               ( $elapsed == 0 ? '??' : ( 1 / $elapsed ) );
1430             my $t = Text::SimpleTable->new( [ 62, 'Action' ], [ 9, 'Time' ] );
1431
1432             $c->stats->traverse(
1433                 sub {
1434                     my $action = shift;
1435                     my $stat   = $action->getNodeValue;
1436                     $t->row( ( q{ } x $action->getDepth ) . $stat->{action} . $stat->{comment},
1437                         $stat->{elapsed} || '??' );
1438                 }
1439             );
1440
1441             $class->log->info(
1442                 "Request took ${elapsed}s ($av/s)\n" . $t->draw );
1443         }
1444         else {
1445             my $c = $class->prepare(@arguments);
1446             $c->dispatch;
1447             $status = $c->finalize;
1448         }
1449     };
1450
1451     if ( my $error = $@ ) {
1452         chomp $error;
1453         $class->log->error(qq/Caught exception in engine "$error"/);
1454     }
1455
1456     $COUNT++;
1457     $class->log->_flush() if $class->log->can('_flush');
1458     return $status;
1459 }
1460
1461 =head2 $c->prepare( @arguments )
1462
1463 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1464 etc.).
1465
1466 =cut
1467
1468 sub prepare {
1469     my ( $class, @arguments ) = @_;
1470
1471     $class->context_class( ref $class || $class ) unless $class->context_class;
1472     my $c = $class->context_class->new(
1473         {
1474             counter => {},
1475             stack   => [],
1476             request => $class->request_class->new(
1477                 {
1478                     arguments        => [],
1479                     body_parameters  => {},
1480                     cookies          => {},
1481                     headers          => HTTP::Headers->new,
1482                     parameters       => {},
1483                     query_parameters => {},
1484                     secure           => 0,
1485                     captures         => [],
1486                     uploads          => {}
1487                 }
1488             ),
1489             response => $class->response_class->new(
1490                 {
1491                     body    => '',
1492                     cookies => {},
1493                     headers => HTTP::Headers->new(),
1494                     status  => 200
1495                 }
1496             ),
1497             stash => {},
1498             state => 0
1499         }
1500     );
1501
1502     # For on-demand data
1503     $c->request->{_context}  = $c;
1504     $c->response->{_context} = $c;
1505     weaken( $c->request->{_context} );
1506     weaken( $c->response->{_context} );
1507
1508     if ( $c->debug ) {
1509         my $secs = time - $START || 1;
1510         my $av = sprintf '%.3f', $COUNT / $secs;
1511         my $time = localtime time;
1512         $c->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1513         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1514     }
1515
1516     # Allow engine to direct the prepare flow (for POE)
1517     if ( $c->engine->can('prepare') ) {
1518         $c->engine->prepare( $c, @arguments );
1519     }
1520     else {
1521         $c->prepare_request(@arguments);
1522         $c->prepare_connection;
1523         $c->prepare_query_parameters;
1524         $c->prepare_headers;
1525         $c->prepare_cookies;
1526         $c->prepare_path;
1527
1528         # On-demand parsing
1529         $c->prepare_body unless $c->config->{parse_on_demand};
1530     }
1531
1532     my $method  = $c->req->method  || '';
1533     my $path    = $c->req->path    || '/';
1534     my $address = $c->req->address || '';
1535
1536     $c->log->debug(qq/"$method" request for "$path" from "$address"/)
1537       if $c->debug;
1538
1539     $c->prepare_action;
1540
1541     return $c;
1542 }
1543
1544 =head2 $c->prepare_action
1545
1546 Prepares action. See L<Catalyst::Dispatcher>.
1547
1548 =cut
1549
1550 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1551
1552 =head2 $c->prepare_body
1553
1554 Prepares message body.
1555
1556 =cut
1557
1558 sub prepare_body {
1559     my $c = shift;
1560
1561     # Do we run for the first time?
1562     return if defined $c->request->{_body};
1563
1564     # Initialize on-demand data
1565     $c->engine->prepare_body( $c, @_ );
1566     $c->prepare_parameters;
1567     $c->prepare_uploads;
1568
1569     if ( $c->debug && keys %{ $c->req->body_parameters } ) {
1570         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1571         for my $key ( sort keys %{ $c->req->body_parameters } ) {
1572             my $param = $c->req->body_parameters->{$key};
1573             my $value = defined($param) ? $param : '';
1574             $t->row( $key,
1575                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1576         }
1577         $c->log->debug( "Body Parameters are:\n" . $t->draw );
1578     }
1579 }
1580
1581 =head2 $c->prepare_body_chunk( $chunk )
1582
1583 Prepares a chunk of data before sending it to L<HTTP::Body>.
1584
1585 See L<Catalyst::Engine>.
1586
1587 =cut
1588
1589 sub prepare_body_chunk {
1590     my $c = shift;
1591     $c->engine->prepare_body_chunk( $c, @_ );
1592 }
1593
1594 =head2 $c->prepare_body_parameters
1595
1596 Prepares body parameters.
1597
1598 =cut
1599
1600 sub prepare_body_parameters {
1601     my $c = shift;
1602     $c->engine->prepare_body_parameters( $c, @_ );
1603 }
1604
1605 =head2 $c->prepare_connection
1606
1607 Prepares connection.
1608
1609 =cut
1610
1611 sub prepare_connection {
1612     my $c = shift;
1613     $c->engine->prepare_connection( $c, @_ );
1614 }
1615
1616 =head2 $c->prepare_cookies
1617
1618 Prepares cookies.
1619
1620 =cut
1621
1622 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
1623
1624 =head2 $c->prepare_headers
1625
1626 Prepares headers.
1627
1628 =cut
1629
1630 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
1631
1632 =head2 $c->prepare_parameters
1633
1634 Prepares parameters.
1635
1636 =cut
1637
1638 sub prepare_parameters {
1639     my $c = shift;
1640     $c->prepare_body_parameters;
1641     $c->engine->prepare_parameters( $c, @_ );
1642 }
1643
1644 =head2 $c->prepare_path
1645
1646 Prepares path and base.
1647
1648 =cut
1649
1650 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
1651
1652 =head2 $c->prepare_query_parameters
1653
1654 Prepares query parameters.
1655
1656 =cut
1657
1658 sub prepare_query_parameters {
1659     my $c = shift;
1660
1661     $c->engine->prepare_query_parameters( $c, @_ );
1662
1663     if ( $c->debug && keys %{ $c->request->query_parameters } ) {
1664         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1665         for my $key ( sort keys %{ $c->req->query_parameters } ) {
1666             my $param = $c->req->query_parameters->{$key};
1667             my $value = defined($param) ? $param : '';
1668             $t->row( $key,
1669                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1670         }
1671         $c->log->debug( "Query Parameters are:\n" . $t->draw );
1672     }
1673 }
1674
1675 =head2 $c->prepare_read
1676
1677 Prepares the input for reading.
1678
1679 =cut
1680
1681 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
1682
1683 =head2 $c->prepare_request
1684
1685 Prepares the engine request.
1686
1687 =cut
1688
1689 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
1690
1691 =head2 $c->prepare_uploads
1692
1693 Prepares uploads.
1694
1695 =cut
1696
1697 sub prepare_uploads {
1698     my $c = shift;
1699
1700     $c->engine->prepare_uploads( $c, @_ );
1701
1702     if ( $c->debug && keys %{ $c->request->uploads } ) {
1703         my $t = Text::SimpleTable->new(
1704             [ 12, 'Parameter' ],
1705             [ 26, 'Filename' ],
1706             [ 18, 'Type' ],
1707             [ 9,  'Size' ]
1708         );
1709         for my $key ( sort keys %{ $c->request->uploads } ) {
1710             my $upload = $c->request->uploads->{$key};
1711             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
1712                 $t->row( $key, $u->filename, $u->type, $u->size );
1713             }
1714         }
1715         $c->log->debug( "File Uploads are:\n" . $t->draw );
1716     }
1717 }
1718
1719 =head2 $c->prepare_write
1720
1721 Prepares the output for writing.
1722
1723 =cut
1724
1725 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
1726
1727 =head2 $c->request_class
1728
1729 Returns or sets the request class.
1730
1731 =head2 $c->response_class
1732
1733 Returns or sets the response class.
1734
1735 =head2 $c->read( [$maxlength] )
1736
1737 Reads a chunk of data from the request body. This method is designed to
1738 be used in a while loop, reading C<$maxlength> bytes on every call.
1739 C<$maxlength> defaults to the size of the request if not specified.
1740
1741 You have to set C<MyApp-E<gt>config-E<gt>{parse_on_demand}> to use this
1742 directly.
1743
1744 =cut
1745
1746 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
1747
1748 =head2 $c->run
1749
1750 Starts the engine.
1751
1752 =cut
1753
1754 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
1755
1756 =head2 $c->set_action( $action, $code, $namespace, $attrs )
1757
1758 Sets an action in a given namespace.
1759
1760 =cut
1761
1762 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
1763
1764 =head2 $c->setup_actions($component)
1765
1766 Sets up actions for a component.
1767
1768 =cut
1769
1770 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
1771
1772 =head2 $c->setup_components
1773
1774 Sets up components. Specify a C<setup_components> config option to pass
1775 additional options directly to L<Module::Pluggable>. To add additional
1776 search paths, specify a key named C<search_extra> as an array
1777 reference. Items in the array beginning with C<::> will have the
1778 application class name prepended to them.
1779
1780 =cut
1781
1782 sub setup_components {
1783     my $class = shift;
1784
1785     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
1786     my $config  = $class->config->{ setup_components };
1787     my $extra   = delete $config->{ search_extra } || [];
1788
1789     push @paths, @$extra;
1790
1791     my $locator = Module::Pluggable::Object->new(
1792         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
1793         %$config
1794     );
1795
1796     for my $component ( sort { length $a <=> length $b } $locator->plugins ) {
1797         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
1798
1799         my $module  = $class->setup_component( $component );
1800         my %modules = (
1801             $component => $module,
1802             map {
1803                 $_ => $class->setup_component( $_ )
1804             } Devel::InnerPackage::list_packages( $component )
1805         );
1806
1807         for my $key ( keys %modules ) {
1808             $class->components->{ $key } = $modules{ $key };
1809         }
1810     }
1811 }
1812
1813 =head2 $c->setup_component
1814
1815 =cut
1816
1817 sub setup_component {
1818     my( $class, $component ) = @_;
1819
1820     unless ( $component->can( 'COMPONENT' ) ) {
1821         return $component;
1822     }
1823
1824     my $suffix = Catalyst::Utils::class2classsuffix( $component );
1825     my $config = $class->config->{ $suffix } || {};
1826
1827     my $instance = eval { $component->COMPONENT( $class, $config ); };
1828
1829     if ( my $error = $@ ) {
1830         chomp $error;
1831         Catalyst::Exception->throw(
1832             message => qq/Couldn't instantiate component "$component", "$error"/
1833         );
1834     }
1835
1836     Catalyst::Exception->throw(
1837         message =>
1838         qq/Couldn't instantiate component "$component", "COMPONENT() didn't return an object-like value"/
1839     ) unless eval { $instance->can( 'can' ) };
1840
1841     return $instance;
1842 }
1843
1844 =head2 $c->setup_dispatcher
1845
1846 Sets up dispatcher.
1847
1848 =cut
1849
1850 sub setup_dispatcher {
1851     my ( $class, $dispatcher ) = @_;
1852
1853     if ($dispatcher) {
1854         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
1855     }
1856
1857     if ( $ENV{CATALYST_DISPATCHER} ) {
1858         $dispatcher = 'Catalyst::Dispatcher::' . $ENV{CATALYST_DISPATCHER};
1859     }
1860
1861     if ( $ENV{ uc($class) . '_DISPATCHER' } ) {
1862         $dispatcher =
1863           'Catalyst::Dispatcher::' . $ENV{ uc($class) . '_DISPATCHER' };
1864     }
1865
1866     unless ($dispatcher) {
1867         $dispatcher = $class->dispatcher_class;
1868     }
1869
1870     unless (Class::Inspector->loaded($dispatcher)) {
1871         require Class::Inspector->filename($dispatcher);
1872     }
1873
1874     # dispatcher instance
1875     $class->dispatcher( $dispatcher->new );
1876 }
1877
1878 =head2 $c->setup_engine
1879
1880 Sets up engine.
1881
1882 =cut
1883
1884 sub setup_engine {
1885     my ( $class, $engine ) = @_;
1886
1887     if ($engine) {
1888         $engine = 'Catalyst::Engine::' . $engine;
1889     }
1890
1891     if ( $ENV{CATALYST_ENGINE} ) {
1892         $engine = 'Catalyst::Engine::' . $ENV{CATALYST_ENGINE};
1893     }
1894
1895     if ( $ENV{ uc($class) . '_ENGINE' } ) {
1896         $engine = 'Catalyst::Engine::' . $ENV{ uc($class) . '_ENGINE' };
1897     }
1898
1899     if ( $ENV{MOD_PERL} ) {
1900
1901         # create the apache method
1902         {
1903             no strict 'refs';
1904             *{"$class\::apache"} = sub { shift->engine->apache };
1905         }
1906
1907         my ( $software, $version ) =
1908           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
1909
1910         $version =~ s/_//g;
1911         $version =~ s/(\.[^.]+)\./$1/g;
1912
1913         if ( $software eq 'mod_perl' ) {
1914
1915             if ( !$engine ) {
1916
1917                 if ( $version >= 1.99922 ) {
1918                     $engine = 'Catalyst::Engine::Apache2::MP20';
1919                 }
1920
1921                 elsif ( $version >= 1.9901 ) {
1922                     $engine = 'Catalyst::Engine::Apache2::MP19';
1923                 }
1924
1925                 elsif ( $version >= 1.24 ) {
1926                     $engine = 'Catalyst::Engine::Apache::MP13';
1927                 }
1928
1929                 else {
1930                     Catalyst::Exception->throw( message =>
1931                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
1932                 }
1933
1934             }
1935
1936             # install the correct mod_perl handler
1937             if ( $version >= 1.9901 ) {
1938                 *handler = sub  : method {
1939                     shift->handle_request(@_);
1940                 };
1941             }
1942             else {
1943                 *handler = sub ($$) { shift->handle_request(@_) };
1944             }
1945
1946         }
1947
1948         elsif ( $software eq 'Zeus-Perl' ) {
1949             $engine = 'Catalyst::Engine::Zeus';
1950         }
1951
1952         else {
1953             Catalyst::Exception->throw(
1954                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
1955         }
1956     }
1957
1958     unless ($engine) {
1959         $engine = $class->engine_class;
1960     }
1961
1962     unless (Class::Inspector->loaded($engine)) {
1963         require Class::Inspector->filename($engine);
1964     }
1965
1966     # check for old engines that are no longer compatible
1967     my $old_engine;
1968     if ( $engine->isa('Catalyst::Engine::Apache')
1969         && !Catalyst::Engine::Apache->VERSION )
1970     {
1971         $old_engine = 1;
1972     }
1973
1974     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
1975         && Catalyst::Engine::Server->VERSION le '0.02' )
1976     {
1977         $old_engine = 1;
1978     }
1979
1980     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
1981         && $engine->VERSION eq '0.01' )
1982     {
1983         $old_engine = 1;
1984     }
1985
1986     elsif ($engine->isa('Catalyst::Engine::Zeus')
1987         && $engine->VERSION eq '0.01' )
1988     {
1989         $old_engine = 1;
1990     }
1991
1992     if ($old_engine) {
1993         Catalyst::Exception->throw( message =>
1994               qq/Engine "$engine" is not supported by this version of Catalyst/
1995         );
1996     }
1997
1998     # engine instance
1999     $class->engine( $engine->new );
2000 }
2001
2002 =head2 $c->setup_home
2003
2004 Sets up the home directory.
2005
2006 =cut
2007
2008 sub setup_home {
2009     my ( $class, $home ) = @_;
2010
2011     if ( $ENV{CATALYST_HOME} ) {
2012         $home = $ENV{CATALYST_HOME};
2013     }
2014
2015     if ( $ENV{ uc($class) . '_HOME' } ) {
2016         $home = $ENV{ uc($class) . '_HOME' };
2017     }
2018
2019     unless ($home) {
2020         $home = Catalyst::Utils::home($class);
2021     }
2022
2023     if ($home) {
2024         $class->config->{home} ||= $home;
2025         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2026     }
2027 }
2028
2029 =head2 $c->setup_log
2030
2031 Sets up log.
2032
2033 =cut
2034
2035 sub setup_log {
2036     my ( $class, $debug ) = @_;
2037
2038     unless ( $class->log ) {
2039         $class->log( Catalyst::Log->new );
2040     }
2041
2042     my $app_flag = Catalyst::Utils::class2env($class) . '_DEBUG';
2043
2044     if (
2045           ( defined( $ENV{CATALYST_DEBUG} ) || defined( $ENV{$app_flag} ) )
2046         ? ( $ENV{CATALYST_DEBUG} || $ENV{$app_flag} )
2047         : $debug
2048       )
2049     {
2050         no strict 'refs';
2051         *{"$class\::debug"} = sub { 1 };
2052         $class->log->debug('Debug messages enabled');
2053     }
2054 }
2055
2056 =head2 $c->setup_plugins
2057
2058 Sets up plugins.
2059
2060 =cut
2061
2062 =head2 $c->registered_plugins
2063
2064 Returns a sorted list of the plugins which have either been stated in the
2065 import list or which have been added via C<< MyApp->plugin(@args); >>.
2066
2067 If passed a given plugin name, it will report a boolean value indicating
2068 whether or not that plugin is loaded.  A fully qualified name is required if
2069 the plugin name does not begin with C<Catalyst::Plugin::>.
2070
2071  if ($c->registered_plugins('Some::Plugin')) {
2072      ...
2073  }
2074
2075 =cut
2076
2077 {
2078
2079     sub registered_plugins {
2080         my $proto = shift;
2081         return sort keys %{ $proto->_plugins } unless @_;
2082         my $plugin = shift;
2083         return 1 if exists $proto->_plugins->{$plugin};
2084         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2085     }
2086
2087     sub _register_plugin {
2088         my ( $proto, $plugin, $instant ) = @_;
2089         my $class = ref $proto || $proto;
2090
2091         unless (Class::Inspector->loaded($plugin)) {
2092             require Class::Inspector->filename($plugin);
2093         }
2094
2095         $proto->_plugins->{$plugin} = 1;
2096         unless ($instant) {
2097             no strict 'refs';
2098             unshift @{"$class\::ISA"}, $plugin;
2099         }
2100         return $class;
2101     }
2102
2103     sub setup_plugins {
2104         my ( $class, $plugins ) = @_;
2105
2106         $class->_plugins( {} ) unless $class->_plugins;
2107         $plugins ||= [];
2108         for my $plugin ( reverse @$plugins ) {
2109
2110             unless ( $plugin =~ s/\A\+// ) {
2111                 $plugin = "Catalyst::Plugin::$plugin";
2112             }
2113
2114             $class->_register_plugin($plugin);
2115         }
2116     }
2117 }
2118
2119 =head2 $c->stack
2120
2121 Returns an arrayref of the internal execution stack (actions that are
2122 currently executing).
2123
2124 =head2 $c->write( $data )
2125
2126 Writes $data to the output stream. When using this method directly, you
2127 will need to manually set the C<Content-Length> header to the length of
2128 your output data, if known.
2129
2130 =cut
2131
2132 sub write {
2133     my $c = shift;
2134
2135     # Finalize headers if someone manually writes output
2136     $c->finalize_headers;
2137
2138     return $c->engine->write( $c, @_ );
2139 }
2140
2141 =head2 version
2142
2143 Returns the Catalyst version number. Mostly useful for "powered by"
2144 messages in template systems.
2145
2146 =cut
2147
2148 sub version { return $Catalyst::VERSION }
2149
2150 =head1 INTERNAL ACTIONS
2151
2152 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2153 C<_ACTION>, and C<_END>. These are by default not shown in the private
2154 action table, but you can make them visible with a config parameter.
2155
2156     MyApp->config->{show_internal_actions} = 1;
2157
2158 =head1 CASE SENSITIVITY
2159
2160 By default Catalyst is not case sensitive, so C<MyApp::C::FOO::Bar> is
2161 mapped to C</foo/bar>. You can activate case sensitivity with a config
2162 parameter.
2163
2164     MyApp->config->{case_sensitive} = 1;
2165
2166 This causes C<MyApp::C::Foo::Bar> to map to C</Foo/Bar>.
2167
2168 =head1 ON-DEMAND PARSER
2169
2170 The request body is usually parsed at the beginning of a request,
2171 but if you want to handle input yourself or speed things up a bit,
2172 you can enable on-demand parsing with a config parameter.
2173
2174     MyApp->config->{parse_on_demand} = 1;
2175
2176 =head1 PROXY SUPPORT
2177
2178 Many production servers operate using the common double-server approach,
2179 with a lightweight frontend web server passing requests to a larger
2180 backend server. An application running on the backend server must deal
2181 with two problems: the remote user always appears to be C<127.0.0.1> and
2182 the server's hostname will appear to be C<localhost> regardless of the
2183 virtual host that the user connected through.
2184
2185 Catalyst will automatically detect this situation when you are running
2186 the frontend and backend servers on the same machine. The following
2187 changes are made to the request.
2188
2189     $c->req->address is set to the user's real IP address, as read from
2190     the HTTP X-Forwarded-For header.
2191
2192     The host value for $c->req->base and $c->req->uri is set to the real
2193     host, as read from the HTTP X-Forwarded-Host header.
2194
2195 Obviously, your web server must support these headers for this to work.
2196
2197 In a more complex server farm environment where you may have your
2198 frontend proxy server(s) on different machines, you will need to set a
2199 configuration option to tell Catalyst to read the proxied data from the
2200 headers.
2201
2202     MyApp->config->{using_frontend_proxy} = 1;
2203
2204 If you do not wish to use the proxy support at all, you may set:
2205
2206     MyApp->config->{ignore_frontend_proxy} = 1;
2207
2208 =head1 THREAD SAFETY
2209
2210 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2211 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2212 believe the Catalyst core to be thread-safe.
2213
2214 If you plan to operate in a threaded environment, remember that all other
2215 modules you are using must also be thread-safe. Some modules, most notably
2216 L<DBD::SQLite>, are not thread-safe.
2217
2218 =head1 SUPPORT
2219
2220 IRC:
2221
2222     Join #catalyst on irc.perl.org.
2223
2224 Mailing Lists:
2225
2226     http://lists.rawmode.org/mailman/listinfo/catalyst
2227     http://lists.rawmode.org/mailman/listinfo/catalyst-dev
2228
2229 Web:
2230
2231     http://catalyst.perl.org
2232
2233 Wiki:
2234
2235     http://dev.catalyst.perl.org
2236
2237 =head1 SEE ALSO
2238
2239 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2240
2241 =head2 L<Catalyst::Manual> - The Catalyst Manual
2242
2243 =head2 L<Catalyst::Component>, L<Catalyst::Base> - Base classes for components
2244
2245 =head2 L<Catalyst::Engine> - Core engine
2246
2247 =head2 L<Catalyst::Log> - Log class.
2248
2249 =head2 L<Catalyst::Request> - Request object
2250
2251 =head2 L<Catalyst::Response> - Response object
2252
2253 =head2 L<Catalyst::Test> - The test suite.
2254
2255 =head1 CREDITS
2256
2257 Andy Grundman
2258
2259 Andy Wardley
2260
2261 Andreas Marienborg
2262
2263 Andrew Bramble
2264
2265 Andrew Ford
2266
2267 Andrew Ruthven
2268
2269 Arthur Bergman
2270
2271 Autrijus Tang
2272
2273 Brian Cassidy
2274
2275 Carl Franks
2276
2277 Christian Hansen
2278
2279 Christopher Hicks
2280
2281 Dan Sully
2282
2283 Danijel Milicevic
2284
2285 David Kamholz
2286
2287 David Naughton
2288
2289 Drew Taylor
2290
2291 Gary Ashton Jones
2292
2293 Geoff Richards
2294
2295 Jesse Sheidlower
2296
2297 Jesse Vincent
2298
2299 Jody Belka
2300
2301 Johan Lindstrom
2302
2303 Juan Camacho
2304
2305 Leon Brocard
2306
2307 Marcus Ramberg
2308
2309 Matt S Trout
2310
2311 Robert Sedlacek
2312
2313 Sam Vilain
2314
2315 Sascha Kiefer
2316
2317 Tatsuhiko Miyagawa
2318
2319 Ulf Edvinsson
2320
2321 Yuval Kogman
2322
2323 =head1 AUTHOR
2324
2325 Sebastian Riedel, C<sri@oook.de>
2326
2327 =head1 LICENSE
2328
2329 This library is free software, you can redistribute it and/or modify it under
2330 the same terms as Perl itself.
2331
2332 =cut
2333
2334 1;