lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use B::Hooks::EndOfScope ();
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use File::stat;
  20 use Module::Pluggable::Object ();
  21 use Text::SimpleTable ();
  22 use Path::Class::Dir ();
  23 use Path::Class::File ();
  24 use URI ();
  25 use URI::http;
  26 use URI::https;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use List::MoreUtils qw/uniq/;
  31 use attributes;
  32 use utf8;
  33 use Carp qw/croak carp shortmess/;
  34
  35 BEGIN { require 5.008004; }
  36
  37 has stack => (is => 'ro', default => sub { [] });
  38 has stash => (is => 'rw', default => sub { {} });
  39 has state => (is => 'rw', default => 0);
  40 has stats => (is => 'rw');
  41 has action => (is => 'rw');
  42 has counter => (is => 'rw', default => sub { {} });
  43 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  44 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  45 has namespace => (is => 'rw');
  46
  47 sub depth { scalar @{ shift->stack || [] }; }
  48 sub comp { shift->component(@_) }
  49
  50 sub req {
  51     my $self = shift; return $self->request(@_);
  52 }
  53 sub res {
  54     my $self = shift; return $self->response(@_);
  55 }
  56
  57 # For backwards compatibility
  58 sub finalize_output { shift->finalize_body(@_) };
  59
  60 # For statistics
  61 our $COUNT     = 1;
  62 our $START     = time;
  63 our $RECURSION = 1000;
  64 our $DETACH    = Catalyst::Exception::Detach->new;
  65 our $GO        = Catalyst::Exception::Go->new;
  66
  67 #I imagine that very few of these really need to be class variables. if any.
  68 #maybe we should just make them attributes with a default?
  69 __PACKAGE__->mk_classdata($_)
  70   for qw/components arguments dispatcher engine log dispatcher_class
  71   engine_class context_class request_class response_class stats_class
  72   setup_finished/;
  73
  74 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  75 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  76 __PACKAGE__->request_class('Catalyst::Request');
  77 __PACKAGE__->response_class('Catalyst::Response');
  78 __PACKAGE__->stats_class('Catalyst::Stats');
  79
  80 # Remember to update this in Catalyst::Runtime as well!
  81
  82 our $VERSION = '5.80032';
  83
  84 sub import {
  85     my ( $class, @arguments ) = @_;
  86
  87     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  88     # callers @ISA.
  89     return unless $class eq 'Catalyst';
  90
  91     my $caller = caller();
  92     return if $caller eq 'main';
  93
  94     my $meta = Moose::Meta::Class->initialize($caller);
  95     unless ( $caller->isa('Catalyst') ) {
  96         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
  97         $meta->superclasses(@superclasses);
  98     }
  99     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 100     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 101
 102     unless( $meta->has_method('meta') ){
 103         if ($Moose::VERSION >= 1.15) {
 104             $meta->_add_meta_method('meta');
 105         }
 106         else {
 107             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 108         }
 109     }
 110
 111     $caller->arguments( [@arguments] );
 112     $caller->setup_home;
 113 }
 114
 115 sub _application { $_[0] }
 116
 117 =head1 NAME
 118
 119 Catalyst - The Elegant MVC Web Application Framework
 120
 121 =head1 SYNOPSIS
 122
 123 See the L<Catalyst::Manual> distribution for comprehensive
 124 documentation and tutorials.
 125
 126     # Install Catalyst::Devel for helpers and other development tools
 127     # use the helper to create a new application
 128     catalyst.pl MyApp
 129
 130     # add models, views, controllers
 131     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 132     script/myapp_create.pl view MyTemplate TT
 133     script/myapp_create.pl controller Search
 134
 135     # built in testserver -- use -r to restart automatically on changes
 136     # --help to see all available options
 137     script/myapp_server.pl
 138
 139     # command line testing interface
 140     script/myapp_test.pl /yada
 141
 142     ### in lib/MyApp.pm
 143     use Catalyst qw/-Debug/; # include plugins here as well
 144
 145     ### In lib/MyApp/Controller/Root.pm (autocreated)
 146     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 147         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 148         $c->stash->{template} = 'foo.tt'; # set the template
 149         # lookup something from db -- stash vars are passed to TT
 150         $c->stash->{data} =
 151           $c->model('Database::Foo')->search( { country => $args[0] } );
 152         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 153             $c->forward( 'bar' ); # process another action
 154             # do something else after forward returns
 155         }
 156     }
 157
 158     # The foo.tt TT template can use the stash data from the database
 159     [% WHILE (item = data.next) %]
 160         [% item.foo %]
 161     [% END %]
 162
 163     # called for /bar/of/soap, /bar/of/soap/10, etc.
 164     sub bar : Path('/bar/of/soap') { ... }
 165
 166     # called for all actions, from the top-most controller downwards
 167     sub auto : Private {
 168         my ( $self, $c ) = @_;
 169         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 170             $c->res->redirect( '/login' ); # require login
 171             return 0; # abort request and go immediately to end()
 172         }
 173         return 1; # success; carry on to next action
 174     }
 175
 176     # called after all actions are finished
 177     sub end : Private {
 178         my ( $self, $c ) = @_;
 179         if ( scalar @{ $c->error } ) { ... } # handle errors
 180         return if $c->res->body; # already have a response
 181         $c->forward( 'MyApp::View::TT' ); # render template
 182     }
 183
 184     ### in MyApp/Controller/Foo.pm
 185     # called for /foo/bar
 186     sub bar : Local { ... }
 187
 188     # called for /blargle
 189     sub blargle : Global { ... }
 190
 191     # an index action matches /foo, but not /foo/1, etc.
 192     sub index : Private { ... }
 193
 194     ### in MyApp/Controller/Foo/Bar.pm
 195     # called for /foo/bar/baz
 196     sub baz : Local { ... }
 197
 198     # first Root auto is called, then Foo auto, then this
 199     sub auto : Private { ... }
 200
 201     # powerful regular expression paths are also possible
 202     sub details : Regex('^product/(\w+)/details$') {
 203         my ( $self, $c ) = @_;
 204         # extract the (\w+) from the URI
 205         my $product = $c->req->captures->[0];
 206     }
 207
 208 See L<Catalyst::Manual::Intro> for additional information.
 209
 210 =head1 DESCRIPTION
 211
 212 Catalyst is a modern framework for making web applications without the
 213 pain usually associated with this process. This document is a reference
 214 to the main Catalyst application. If you are a new user, we suggest you
 215 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 216
 217 See L<Catalyst::Manual> for more documentation.
 218
 219 Catalyst plugins can be loaded by naming them as arguments to the "use
 220 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 221 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 222 C<My::Module>.
 223
 224     use Catalyst qw/My::Module/;
 225
 226 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 227 fully qualify the name by using a unary plus:
 228
 229     use Catalyst qw/
 230         My::Module
 231         +Fully::Qualified::Plugin::Name
 232     /;
 233
 234 Special flags like C<-Debug> and C<-Engine> can also be specified as
 235 arguments when Catalyst is loaded:
 236
 237     use Catalyst qw/-Debug My::Module/;
 238
 239 The position of plugins and flags in the chain is important, because
 240 they are loaded in the order in which they appear.
 241
 242 The following flags are supported:
 243
 244 =head2 -Debug
 245
 246 Enables debug output. You can also force this setting from the system
 247 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 248 settings override the application, with <MYAPP>_DEBUG having the highest
 249 priority.
 250
 251 This sets the log level to 'debug' and enables full debug output on the
 252 error screen. If you only want the latter, see L<< $c->debug >>.
 253
 254 =head2 -Engine
 255
 256 Forces Catalyst to use a specific engine. Omit the
 257 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 258
 259     use Catalyst qw/-Engine=CGI/;
 260
 261 =head2 -Home
 262
 263 Forces Catalyst to use a specific home directory, e.g.:
 264
 265     use Catalyst qw[-Home=/usr/mst];
 266
 267 This can also be done in the shell environment by setting either the
 268 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 269 is replaced with the uppercased name of your application, any "::" in
 270 the name will be replaced with underscores, e.g. MyApp::Web should use
 271 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 272
 273 If none of these are set, Catalyst will attempt to automatically detect the
 274 home directory. If you are working in a development envirnoment, Catalyst
 275 will try and find the directory containing either Makefile.PL, Build.PL or
 276 dist.ini. If the application has been installed into the system (i.e.
 277 you have done C<make install>), then Catalyst will use the path to your
 278 application module, without the .pm extension (ie, /foo/MyApp if your
 279 application was installed at /foo/MyApp.pm)
 280
 281 =head2 -Log
 282
 283     use Catalyst '-Log=warn,fatal,error';
 284
 285 Specifies a comma-delimited list of log levels.
 286
 287 =head2 -Stats
 288
 289 Enables statistics collection and reporting.
 290
 291    use Catalyst qw/-Stats=1/;
 292
 293 You can also force this setting from the system environment with CATALYST_STATS
 294 or <MYAPP>_STATS. The environment settings override the application, with
 295 <MYAPP>_STATS having the highest priority.
 296
 297 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 298
 299 =head1 METHODS
 300
 301 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 302
 303 =head2 $c->action
 304
 305 Returns a L<Catalyst::Action> object for the current action, which
 306 stringifies to the action name. See L<Catalyst::Action>.
 307
 308 =head2 $c->namespace
 309
 310 Returns the namespace of the current action, i.e., the URI prefix
 311 corresponding to the controller of the current action. For example:
 312
 313     # in Controller::Foo::Bar
 314     $c->namespace; # returns 'foo/bar';
 315
 316 =head2 $c->request
 317
 318 =head2 $c->req
 319
 320 Returns the current L<Catalyst::Request> object, giving access to
 321 information about the current client request (including parameters,
 322 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 323
 324 =head2 REQUEST FLOW HANDLING
 325
 326 =head2 $c->forward( $action [, \@arguments ] )
 327
 328 =head2 $c->forward( $class, $method, [, \@arguments ] )
 329
 330 Forwards processing to another action, by its private name. If you give a
 331 class name but no method, C<process()> is called. You may also optionally
 332 pass arguments in an arrayref. The action will receive the arguments in
 333 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 334 C<< $c->req->args >> will be restored to the previous values.
 335
 336 Any data C<return>ed from the action forwarded to, will be returned by the
 337 call to forward.
 338
 339     my $foodata = $c->forward('/foo');
 340     $c->forward('index');
 341     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 342     $c->forward('View::TT');
 343
 344 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 345 an C<< eval { } >> around the call (actually
 346 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus de-fatalizing
 347 all 'dies' within the called action. If you want C<die> to propagate you
 348 need to do something like:
 349
 350     $c->forward('foo');
 351     die join "\n", @{ $c->error } if @{ $c->error };
 352
 353 Or make sure to always return true values from your actions and write
 354 your code like this:
 355
 356     $c->forward('foo') || return;
 357
 358 Another note is that C<< $c->forward >> always returns a scalar because it
 359 actually returns $c->state which operates in a scalar context.
 360 Thus, something like:
 361
 362     return @array;
 363
 364 in an action that is forwarded to is going to return a scalar,
 365 i.e. how many items are in that array, which is probably not what you want.
 366 If you need to return an array then return a reference to it,
 367 or stash it like so:
 368
 369     $c->stash->{array} = \@array;
 370
 371 and access it from the stash.
 372
 373 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 374
 375 =cut
 376
 377 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 378
 379 =head2 $c->detach( $action [, \@arguments ] )
 380
 381 =head2 $c->detach( $class, $method, [, \@arguments ] )
 382
 383 =head2 $c->detach()
 384
 385 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 386 doesn't return to the previous action when processing is finished.
 387
 388 When called with no arguments it escapes the processing chain entirely.
 389
 390 =cut
 391
 392 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 393
 394 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 395
 396 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 397
 398 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 399 but does a full dispatch, instead of just calling the new C<$action> /
 400 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 401 you go to are called, just like a new request.
 402
 403 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 404 This means, for example, that C<< $c->action >> methods such as
 405 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 406 L<reverse|Catalyst::Action/reverse> return information for the visited action
 407 when they are invoked within the visited action.  This is different from the
 408 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 409 continues to use the $c->action object from the caller action even when
 410 invoked from the callee.
 411
 412 C<< $c->stash >> is kept unchanged.
 413
 414 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 415 allows you to "wrap" another action, just as it would have been called by
 416 dispatching from a URL, while the analogous
 417 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 418 transfer control to another action as if it had been reached directly from a URL.
 419
 420 =cut
 421
 422 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 423
 424 =head2 $c->go( $action [, \@captures, \@arguments ] )
 425
 426 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 427
 428 The relationship between C<go> and
 429 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 430 the relationship between
 431 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 432 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 433 C<< $c->go >> will perform a full dispatch on the specified action or method,
 434 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 435 C<go> escapes the processing of the current request chain on completion, and
 436 does not return to its caller.
 437
 438 @arguments are arguments to the final destination of $action. @captures are
 439 arguments to the intermediate steps, if any, on the way to the final sub of
 440 $action.
 441
 442 =cut
 443
 444 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 445
 446 =head2 $c->response
 447
 448 =head2 $c->res
 449
 450 Returns the current L<Catalyst::Response> object, see there for details.
 451
 452 =head2 $c->stash
 453
 454 Returns a hashref to the stash, which may be used to store data and pass
 455 it between components during a request. You can also set hash keys by
 456 passing arguments. The stash is automatically sent to the view. The
 457 stash is cleared at the end of a request; it cannot be used for
 458 persistent storage (for this you must use a session; see
 459 L<Catalyst::Plugin::Session> for a complete system integrated with
 460 Catalyst).
 461
 462     $c->stash->{foo} = $bar;
 463     $c->stash( { moose => 'majestic', qux => 0 } );
 464     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 465
 466     # stash is automatically passed to the view for use in a template
 467     $c->forward( 'MyApp::View::TT' );
 468
 469 =cut
 470
 471 around stash => sub {
 472     my $orig = shift;
 473     my $c = shift;
 474     my $stash = $orig->($c);
 475     if (@_) {
 476         my $new_stash = @_ > 1 ? {@_} : $_[0];
 477         croak('stash takes a hash or hashref') unless ref $new_stash;
 478         foreach my $key ( keys %$new_stash ) {
 479           $stash->{$key} = $new_stash->{$key};
 480         }
 481     }
 482
 483     return $stash;
 484 };
 485
 486
 487 =head2 $c->error
 488
 489 =head2 $c->error($error, ...)
 490
 491 =head2 $c->error($arrayref)
 492
 493 Returns an arrayref containing error messages.  If Catalyst encounters an
 494 error while processing a request, it stores the error in $c->error.  This
 495 method should only be used to store fatal error messages.
 496
 497     my @error = @{ $c->error };
 498
 499 Add a new error.
 500
 501     $c->error('Something bad happened');
 502
 503 =cut
 504
 505 sub error {
 506     my $c = shift;
 507     if ( $_[0] ) {
 508         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 509         croak @$error unless ref $c;
 510         push @{ $c->{error} }, @$error;
 511     }
 512     elsif ( defined $_[0] ) { $c->{error} = undef }
 513     return $c->{error} || [];
 514 }
 515
 516
 517 =head2 $c->state
 518
 519 Contains the return value of the last executed action.
 520 Note that << $c->state >> operates in a scalar context which means that all
 521 values it returns are scalar.
 522
 523 =head2 $c->clear_errors
 524
 525 Clear errors.  You probably don't want to clear the errors unless you are
 526 implementing a custom error screen.
 527
 528 This is equivalent to running
 529
 530     $c->error(0);
 531
 532 =cut
 533
 534 sub clear_errors {
 535     my $c = shift;
 536     $c->error(0);
 537 }
 538
 539 sub _comp_search_prefixes {
 540     my $c = shift;
 541     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 542 }
 543
 544 # search components given a name and some prefixes
 545 sub _comp_names_search_prefixes {
 546     my ( $c, $name, @prefixes ) = @_;
 547     my $appclass = ref $c || $c;
 548     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 549     $filter = qr/$filter/; # Compile regex now rather than once per loop
 550
 551     # map the original component name to the sub part that we will search against
 552     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 553         grep { /$filter/ } keys %{ $c->components };
 554
 555     # undef for a name will return all
 556     return keys %eligible if !defined $name;
 557
 558     my $query  = ref $name ? $name : qr/^$name$/i;
 559     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 560
 561     return @result if @result;
 562
 563     $c->log->warn("Looking for '$name', but nothing was found.");
 564
 565     return;
 566 }
 567
 568 # Find possible names for a prefix
 569 sub _comp_names {
 570     my ( $c, @prefixes ) = @_;
 571     my $appclass = ref $c || $c;
 572
 573     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 574
 575     my @names = map { s{$filter}{}; $_; }
 576         $c->_comp_names_search_prefixes( undef, @prefixes );
 577
 578     return @names;
 579 }
 580
 581 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 582 sub _filter_component {
 583     my ( $c, $comp, @args ) = @_;
 584
 585     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 586         return $comp->ACCEPT_CONTEXT( $c, @args );
 587     }
 588
 589     return $comp;
 590 }
 591
 592 =head2 COMPONENT ACCESSORS
 593
 594 =head2 $c->controller($name)
 595
 596 Gets a L<Catalyst::Controller> instance by name.
 597
 598     $c->controller('Foo')->do_stuff;
 599
 600 If the name is omitted, will return the controller for the dispatched
 601 action.
 602
 603 If you want to search for controllers, pass in a regexp as the argument.
 604
 605     # find all controllers that start with Foo
 606     my @foo_controllers = $c->controller(qr{^Foo});
 607
 608
 609 =cut
 610
 611 sub controller {
 612     my ( $c, $name, @args ) = @_;
 613
 614     my $appclass = ref($c) || $c;
 615     if( $name ) {
 616         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 617             my $comps = $c->components;
 618             my $check = $appclass."::Controller::".$name;
 619             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 620         }
 621         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 622         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 623         return $c->_filter_component( $result[ 0 ], @args );
 624     }
 625
 626     return $c->component( $c->action->class );
 627 }
 628
 629 =head2 $c->model($name)
 630
 631 Gets a L<Catalyst::Model> instance by name.
 632
 633     $c->model('Foo')->do_stuff;
 634
 635 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 636
 637 If the name is omitted, it will look for
 638  - a model object in $c->stash->{current_model_instance}, then
 639  - a model name in $c->stash->{current_model}, then
 640  - a config setting 'default_model', or
 641  - check if there is only one model, and return it if that's the case.
 642
 643 If you want to search for models, pass in a regexp as the argument.
 644
 645     # find all models that start with Foo
 646     my @foo_models = $c->model(qr{^Foo});
 647
 648 =cut
 649
 650 sub model {
 651     my ( $c, $name, @args ) = @_;
 652     my $appclass = ref($c) || $c;
 653     if( $name ) {
 654         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 655             my $comps = $c->components;
 656             my $check = $appclass."::Model::".$name;
 657             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 658         }
 659         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 660         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 661         return $c->_filter_component( $result[ 0 ], @args );
 662     }
 663
 664     if (ref $c) {
 665         return $c->stash->{current_model_instance}
 666           if $c->stash->{current_model_instance};
 667         return $c->model( $c->stash->{current_model} )
 668           if $c->stash->{current_model};
 669     }
 670     return $c->model( $appclass->config->{default_model} )
 671       if $appclass->config->{default_model};
 672
 673     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 674
 675     if( $rest ) {
 676         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 677         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 678         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 679         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 680         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 681     }
 682
 683     return $c->_filter_component( $comp );
 684 }
 685
 686
 687 =head2 $c->view($name)
 688
 689 Gets a L<Catalyst::View> instance by name.
 690
 691     $c->view('Foo')->do_stuff;
 692
 693 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 694
 695 If the name is omitted, it will look for
 696  - a view object in $c->stash->{current_view_instance}, then
 697  - a view name in $c->stash->{current_view}, then
 698  - a config setting 'default_view', or
 699  - check if there is only one view, and return it if that's the case.
 700
 701 If you want to search for views, pass in a regexp as the argument.
 702
 703     # find all views that start with Foo
 704     my @foo_views = $c->view(qr{^Foo});
 705
 706 =cut
 707
 708 sub view {
 709     my ( $c, $name, @args ) = @_;
 710
 711     my $appclass = ref($c) || $c;
 712     if( $name ) {
 713         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 714             my $comps = $c->components;
 715             my $check = $appclass."::View::".$name;
 716             if( exists $comps->{$check} ) {
 717                 return $c->_filter_component( $comps->{$check}, @args );
 718             }
 719             else {
 720                 $c->log->warn( "Attempted to use view '$check', but does not exist" );
 721             }
 722         }
 723         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 724         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 725         return $c->_filter_component( $result[ 0 ], @args );
 726     }
 727
 728     if (ref $c) {
 729         return $c->stash->{current_view_instance}
 730           if $c->stash->{current_view_instance};
 731         return $c->view( $c->stash->{current_view} )
 732           if $c->stash->{current_view};
 733     }
 734     return $c->view( $appclass->config->{default_view} )
 735       if $appclass->config->{default_view};
 736
 737     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 738
 739     if( $rest ) {
 740         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 741         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 742         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 743         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 744         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 745     }
 746
 747     return $c->_filter_component( $comp );
 748 }
 749
 750 =head2 $c->controllers
 751
 752 Returns the available names which can be passed to $c->controller
 753
 754 =cut
 755
 756 sub controllers {
 757     my ( $c ) = @_;
 758     return $c->_comp_names(qw/Controller C/);
 759 }
 760
 761 =head2 $c->models
 762
 763 Returns the available names which can be passed to $c->model
 764
 765 =cut
 766
 767 sub models {
 768     my ( $c ) = @_;
 769     return $c->_comp_names(qw/Model M/);
 770 }
 771
 772
 773 =head2 $c->views
 774
 775 Returns the available names which can be passed to $c->view
 776
 777 =cut
 778
 779 sub views {
 780     my ( $c ) = @_;
 781     return $c->_comp_names(qw/View V/);
 782 }
 783
 784 =head2 $c->comp($name)
 785
 786 =head2 $c->component($name)
 787
 788 Gets a component object by name. This method is not recommended,
 789 unless you want to get a specific component by full
 790 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 791 should be used instead.
 792
 793 If C<$name> is a regexp, a list of components matched against the full
 794 component name will be returned.
 795
 796 =cut
 797
 798 sub component {
 799     my ( $c, $name, @args ) = @_;
 800
 801     if( $name ) {
 802         my $comps = $c->components;
 803
 804         if( !ref $name ) {
 805             # is it the exact name?
 806             return $c->_filter_component( $comps->{ $name }, @args )
 807                        if exists $comps->{ $name };
 808
 809             # perhaps we just omitted "MyApp"?
 810             my $composed = ( ref $c || $c ) . "::${name}";
 811             return $c->_filter_component( $comps->{ $composed }, @args )
 812                        if exists $comps->{ $composed };
 813
 814             # search all of the models, views and controllers
 815             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 816             return $c->_filter_component( $comp, @args ) if $comp;
 817         }
 818         else {
 819             my @result = grep { m{$name} } keys %{ $c->components };
 820             return map { $c->_filter_component( $_, @args ) } @result;
 821         }
 822
 823         # I would expect to return an empty list here, but that breaks back-compat
 824     }
 825
 826     # fallback
 827     return sort keys %{ $c->components };
 828 }
 829
 830 =head2 CLASS DATA AND HELPER CLASSES
 831
 832 =head2 $c->config
 833
 834 Returns or takes a hashref containing the application's configuration.
 835
 836     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 837
 838 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 839 like C<myapp.conf> in your applications home directory. See
 840 L<Catalyst::Plugin::ConfigLoader>.
 841
 842 =head3 Cascading configuration
 843
 844 The config method is present on all Catalyst components, and configuration
 845 will be merged when an application is started. Configuration loaded with
 846 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 847 followed by configuration in your top level C<MyApp> class. These two
 848 configurations are merged, and then configuration data whose hash key matches a
 849 component name is merged with configuration for that component.
 850
 851 The configuration for a component is then passed to the C<new> method when a
 852 component is constructed.
 853
 854 For example:
 855
 856     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 857     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 858
 859 will mean that C<MyApp::Model::Foo> receives the following data when
 860 constructed:
 861
 862     MyApp::Model::Foo->new({
 863         bar => 'baz',
 864         quux => 'frob',
 865         overrides => 'me',
 866     });
 867
 868 It's common practice to use a Moose attribute
 869 on the receiving component to access the config value.
 870
 871     package MyApp::Model::Foo;
 872
 873     use Moose;
 874
 875     # this attr will receive 'baz' at construction time
 876     has 'bar' => (
 877         is  => 'rw',
 878         isa => 'Str',
 879     );
 880
 881 You can then get the value 'baz' by calling $c->model('Foo')->bar
 882 (or $self->bar inside code in the model).
 883
 884 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
 885 as a way of reading config within your code, as this B<will not> give you the
 886 correctly merged config back. You B<MUST> take the config values supplied to
 887 the constructor and use those instead.
 888
 889 =cut
 890
 891 around config => sub {
 892     my $orig = shift;
 893     my $c = shift;
 894
 895     croak('Setting config after setup has been run is not allowed.')
 896         if ( @_ and $c->setup_finished );
 897
 898     $c->$orig(@_);
 899 };
 900
 901 =head2 $c->log
 902
 903 Returns the logging object instance. Unless it is already set, Catalyst
 904 sets this up with a L<Catalyst::Log> object. To use your own log class,
 905 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 906 C<< __PACKAGE__->setup >>.
 907
 908  __PACKAGE__->log( MyLogger->new );
 909  __PACKAGE__->setup;
 910
 911 And later:
 912
 913     $c->log->info( 'Now logging with my own logger!' );
 914
 915 Your log class should implement the methods described in
 916 L<Catalyst::Log>.
 917
 918
 919 =head2 $c->debug
 920
 921 Returns 1 if debug mode is enabled, 0 otherwise.
 922
 923 You can enable debug mode in several ways:
 924
 925 =over
 926
 927 =item By calling myapp_server.pl with the -d flag
 928
 929 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 930
 931 =item The -Debug option in your MyApp.pm
 932
 933 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 934
 935 =back
 936
 937 The first three also set the log level to 'debug'.
 938
 939 Calling C<< $c->debug(1) >> has no effect.
 940
 941 =cut
 942
 943 sub debug { 0 }
 944
 945 =head2 $c->dispatcher
 946
 947 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
 948
 949 =head2 $c->engine
 950
 951 Returns the engine instance. See L<Catalyst::Engine>.
 952
 953
 954 =head2 UTILITY METHODS
 955
 956 =head2 $c->path_to(@path)
 957
 958 Merges C<@path> with C<< $c->config->{home} >> and returns a
 959 L<Path::Class::Dir> object. Note you can usually use this object as
 960 a filename, but sometimes you will have to explicitly stringify it
 961 yourself by calling the C<< ->stringify >> method.
 962
 963 For example:
 964
 965     $c->path_to( 'db', 'sqlite.db' );
 966
 967 =cut
 968
 969 sub path_to {
 970     my ( $c, @path ) = @_;
 971     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 972     if ( -d $path ) { return $path }
 973     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 974 }
 975
 976 =head2 $c->plugin( $name, $class, @args )
 977
 978 Helper method for plugins. It creates a class data accessor/mutator and
 979 loads and instantiates the given class.
 980
 981     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 982
 983     $c->prototype->define_javascript_functions;
 984
 985 B<Note:> This method of adding plugins is deprecated. The ability
 986 to add plugins like this B<will be removed> in a Catalyst 5.81.
 987 Please do not use this functionality in new code.
 988
 989 =cut
 990
 991 sub plugin {
 992     my ( $class, $name, $plugin, @args ) = @_;
 993
 994     # See block comment in t/unit_core_plugin.t
 995     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in Catalyst 5.81/);
 996
 997     $class->_register_plugin( $plugin, 1 );
 998
 999     eval { $plugin->import };
1000     $class->mk_classdata($name);
1001     my $obj;
1002     eval { $obj = $plugin->new(@args) };
1003
1004     if ($@) {
1005         Catalyst::Exception->throw( message =>
1006               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1007     }
1008
1009     $class->$name($obj);
1010     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1011       if $class->debug;
1012 }
1013
1014 =head2 MyApp->setup
1015
1016 Initializes the dispatcher and engine, loads any plugins, and loads the
1017 model, view, and controller components. You may also specify an array
1018 of plugins to load here, if you choose to not load them in the C<use
1019 Catalyst> line.
1020
1021     MyApp->setup;
1022     MyApp->setup( qw/-Debug/ );
1023
1024 =cut
1025
1026 sub setup {
1027     my ( $class, @arguments ) = @_;
1028     croak('Running setup more than once')
1029         if ( $class->setup_finished );
1030
1031     unless ( $class->isa('Catalyst') ) {
1032
1033         Catalyst::Exception->throw(
1034             message => qq/'$class' does not inherit from Catalyst/ );
1035     }
1036
1037     if ( $class->arguments ) {
1038         @arguments = ( @arguments, @{ $class->arguments } );
1039     }
1040
1041     # Process options
1042     my $flags = {};
1043
1044     foreach (@arguments) {
1045
1046         if (/^-Debug$/) {
1047             $flags->{log} =
1048               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1049         }
1050         elsif (/^-(\w+)=?(.*)$/) {
1051             $flags->{ lc $1 } = $2;
1052         }
1053         else {
1054             push @{ $flags->{plugins} }, $_;
1055         }
1056     }
1057
1058     $class->setup_home( delete $flags->{home} );
1059
1060     $class->setup_log( delete $flags->{log} );
1061     $class->setup_plugins( delete $flags->{plugins} );
1062     $class->setup_dispatcher( delete $flags->{dispatcher} );
1063     $class->setup_engine( delete $flags->{engine} );
1064     $class->setup_stats( delete $flags->{stats} );
1065
1066     for my $flag ( sort keys %{$flags} ) {
1067
1068         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1069             &$code( $class, delete $flags->{$flag} );
1070         }
1071         else {
1072             $class->log->warn(qq/Unknown flag "$flag"/);
1073         }
1074     }
1075
1076     eval { require Catalyst::Devel; };
1077     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1078         $class->log->warn(<<"EOF");
1079 You are running an old script!
1080
1081   Please update by running (this will overwrite existing files):
1082     catalyst.pl -force -scripts $class
1083
1084   or (this will not overwrite existing files):
1085     catalyst.pl -scripts $class
1086
1087 EOF
1088     }
1089
1090     if ( $class->debug ) {
1091         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1092
1093         if (@plugins) {
1094             my $column_width = Catalyst::Utils::term_width() - 6;
1095             my $t = Text::SimpleTable->new($column_width);
1096             $t->row($_) for @plugins;
1097             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1098         }
1099
1100         my $dispatcher = $class->dispatcher;
1101         my $engine     = $class->engine;
1102         my $home       = $class->config->{home};
1103
1104         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1105         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1106
1107         $home
1108           ? ( -d $home )
1109           ? $class->log->debug(qq/Found home "$home"/)
1110           : $class->log->debug(qq/Home "$home" doesn't exist/)
1111           : $class->log->debug(q/Couldn't find home/);
1112     }
1113
1114     # Call plugins setup, this is stupid and evil.
1115     # Also screws C3 badly on 5.10, hack to avoid.
1116     {
1117         no warnings qw/redefine/;
1118         local *setup = sub { };
1119         $class->setup unless $Catalyst::__AM_RESTARTING;
1120     }
1121
1122     # Initialize our data structure
1123     $class->components( {} );
1124
1125     $class->setup_components;
1126
1127     if ( $class->debug ) {
1128         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1129         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1130         for my $comp ( sort keys %{ $class->components } ) {
1131             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1132             $t->row( $comp, $type );
1133         }
1134         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1135           if ( keys %{ $class->components } );
1136     }
1137
1138     # Add our self to components, since we are also a component
1139     if( $class->isa('Catalyst::Controller') ){
1140       $class->components->{$class} = $class;
1141     }
1142
1143     $class->setup_actions;
1144
1145     if ( $class->debug ) {
1146         my $name = $class->config->{name} || 'Application';
1147         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1148     }
1149
1150     # Make sure that the application class becomes immutable at this point,
1151     B::Hooks::EndOfScope::on_scope_end {
1152         return if $@;
1153         my $meta = Class::MOP::get_metaclass_by_name($class);
1154         if (
1155             $meta->is_immutable
1156             && ! { $meta->immutable_options }->{replace_constructor}
1157             && (
1158                    $class->isa('Class::Accessor::Fast')
1159                 || $class->isa('Class::Accessor')
1160             )
1161         ) {
1162             warn "You made your application class ($class) immutable, "
1163                 . "but did not inline the\nconstructor. "
1164                 . "This will break catalyst, as your app \@ISA "
1165                 . "Class::Accessor(::Fast)?\nPlease pass "
1166                 . "(replace_constructor => 1)\nwhen making your class immutable.\n";
1167         }
1168         $meta->make_immutable(
1169             replace_constructor => 1,
1170         ) unless $meta->is_immutable;
1171     };
1172
1173     if ($class->config->{case_sensitive}) {
1174         $class->log->warn($class . "->config->{case_sensitive} is set.");
1175         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1176     }
1177
1178     $class->setup_finalize;
1179     # Should be the last thing we do so that user things hooking
1180     # setup_finalize can log..
1181     $class->log->_flush() if $class->log->can('_flush');
1182     return 1; # Explicit return true as people have __PACKAGE__->setup as the last thing in their class. HATE.
1183 }
1184
1185 =head2 $app->setup_finalize
1186
1187 A hook to attach modifiers to. This method does not do anything except set the
1188 C<setup_finished> accessor.
1189
1190 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1191
1192 Example:
1193
1194     after setup_finalize => sub {
1195         my $app = shift;
1196
1197         ## do stuff here..
1198     };
1199
1200 =cut
1201
1202 sub setup_finalize {
1203     my ($class) = @_;
1204     $class->setup_finished(1);
1205 }
1206
1207 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1208
1209 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1210
1211 Constructs an absolute L<URI> object based on the application root, the
1212 provided path, and the additional arguments and query parameters provided.
1213 When used as a string, provides a textual URI.  If you need more flexibility
1214 than this (i.e. the option to provide relative URIs etc.) see
1215 L<Catalyst::Plugin::SmartURI>.
1216
1217 If no arguments are provided, the URI for the current action is returned.
1218 To return the current action and also provide @args, use
1219 C<< $c->uri_for( $c->action, @args ) >>.
1220
1221 If the first argument is a string, it is taken as a public URI path relative
1222 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1223 relative to the application root (if it does). It is then merged with
1224 C<< $c->request->base >>; any C<@args> are appended as additional path
1225 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1226
1227 If the first argument is a L<Catalyst::Action> it represents an action which
1228 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1229 optional C<\@captures> argument (an arrayref) allows passing the captured
1230 variables that are needed to fill in the paths of Chained and Regex actions;
1231 once the path is resolved, C<uri_for> continues as though a path was
1232 provided, appending any arguments or parameters and creating an absolute
1233 URI.
1234
1235 The captures for the current request can be found in
1236 C<< $c->request->captures >>, and actions can be resolved using
1237 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1238 path, use C<< $c->uri_for_action >> instead.
1239
1240   # Equivalent to $c->req->uri
1241   $c->uri_for($c->action, $c->req->captures,
1242       @{ $c->req->args }, $c->req->params);
1243
1244   # For the Foo action in the Bar controller
1245   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1246
1247   # Path to a static resource
1248   $c->uri_for('/static/images/logo.png');
1249
1250 =cut
1251
1252 sub uri_for {
1253     my ( $c, $path, @args ) = @_;
1254
1255     if (blessed($path) && $path->isa('Catalyst::Controller')) {
1256         $path = $path->path_prefix;
1257         $path =~ s{/+\z}{};
1258         $path .= '/';
1259     }
1260
1261     undef($path) if (defined $path && $path eq '');
1262
1263     my $params =
1264       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1265
1266     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1267     foreach my $arg (@args) {
1268         utf8::encode($arg) if utf8::is_utf8($arg);
1269         $arg =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1270     }
1271
1272     if ( blessed($path) ) { # action object
1273         s|/|%2F|g for @args;
1274         my $captures = [ map { s|/|%2F|g; $_; }
1275                         ( scalar @args && ref $args[0] eq 'ARRAY'
1276                          ? @{ shift(@args) }
1277                          : ()) ];
1278
1279         foreach my $capture (@$captures) {
1280             utf8::encode($capture) if utf8::is_utf8($capture);
1281             $capture =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1282         }
1283
1284         my $action = $path;
1285         $path = $c->dispatcher->uri_for_action($action, $captures);
1286         if (not defined $path) {
1287             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1288                 if $c->debug;
1289             return undef;
1290         }
1291         $path = '/' if $path eq '';
1292     }
1293
1294     unshift(@args, $path);
1295
1296     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1297         my $namespace = $c->namespace;
1298         if (defined $path) { # cheesy hack to handle path '../foo'
1299            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1300         }
1301         unshift(@args, $namespace || '');
1302     }
1303
1304     # join args with '/', or a blank string
1305     my $args = join('/', grep { defined($_) } @args);
1306     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1307     $args =~ s!^/+!!;
1308     my $base = $c->req->base;
1309     my $class = ref($base);
1310     $base =~ s{(?<!/)$}{/};
1311
1312     my $query = '';
1313
1314     if (my @keys = keys %$params) {
1315       # somewhat lifted from URI::_query's query_form
1316       $query = '?'.join('&', map {
1317           my $val = $params->{$_};
1318           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1319           s/ /+/g;
1320           my $key = $_;
1321           $val = '' unless defined $val;
1322           (map {
1323               my $param = "$_";
1324               utf8::encode( $param ) if utf8::is_utf8($param);
1325               # using the URI::Escape pattern here so utf8 chars survive
1326               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1327               $param =~ s/ /+/g;
1328               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1329       } @keys);
1330     }
1331
1332     my $res = bless(\"${base}${args}${query}", $class);
1333     $res;
1334 }
1335
1336 =head2 $c->uri_for_action( $path, \@captures?, @args?, \%query_values? )
1337
1338 =head2 $c->uri_for_action( $action, \@captures?, @args?, \%query_values? )
1339
1340 =over
1341
1342 =item $path
1343
1344 A private path to the Catalyst action you want to create a URI for.
1345
1346 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1347 >> and passing the resulting C<$action> and the remaining arguments to C<<
1348 $c->uri_for >>.
1349
1350 You can also pass in a Catalyst::Action object, in which case it is passed to
1351 C<< $c->uri_for >>.
1352
1353 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1354
1355 For example, if the action looks like:
1356
1357  package MyApp::Controller::Users;
1358
1359  sub lst : Path('the-list') {}
1360
1361 You can use:
1362
1363  $c->uri_for_action('/users/lst')
1364
1365 and it will create the URI /users/the-list.
1366
1367 =back
1368
1369 =cut
1370
1371 sub uri_for_action {
1372     my ( $c, $path, @args ) = @_;
1373     my $action = blessed($path)
1374       ? $path
1375       : $c->dispatcher->get_action_by_path($path);
1376     unless (defined $action) {
1377       croak "Can't find action for path '$path'";
1378     }
1379     return $c->uri_for( $action, @args );
1380 }
1381
1382 =head2 $c->welcome_message
1383
1384 Returns the Catalyst welcome HTML page.
1385
1386 =cut
1387
1388 sub welcome_message {
1389     my $c      = shift;
1390     my $name   = $c->config->{name};
1391     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1392     my $prefix = Catalyst::Utils::appprefix( ref $c );
1393     $c->response->content_type('text/html; charset=utf-8');
1394     return <<"EOF";
1395 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1396     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1397 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1398     <head>
1399     <meta http-equiv="Content-Language" content="en" />
1400     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1401         <title>$name on Catalyst $VERSION</title>
1402         <style type="text/css">
1403             body {
1404                 color: #000;
1405                 background-color: #eee;
1406             }
1407             div#content {
1408                 width: 640px;
1409                 margin-left: auto;
1410                 margin-right: auto;
1411                 margin-top: 10px;
1412                 margin-bottom: 10px;
1413                 text-align: left;
1414                 background-color: #ccc;
1415                 border: 1px solid #aaa;
1416             }
1417             p, h1, h2 {
1418                 margin-left: 20px;
1419                 margin-right: 20px;
1420                 font-family: verdana, tahoma, sans-serif;
1421             }
1422             a {
1423                 font-family: verdana, tahoma, sans-serif;
1424             }
1425             :link, :visited {
1426                     text-decoration: none;
1427                     color: #b00;
1428                     border-bottom: 1px dotted #bbb;
1429             }
1430             :link:hover, :visited:hover {
1431                     color: #555;
1432             }
1433             div#topbar {
1434                 margin: 0px;
1435             }
1436             pre {
1437                 margin: 10px;
1438                 padding: 8px;
1439             }
1440             div#answers {
1441                 padding: 8px;
1442                 margin: 10px;
1443                 background-color: #fff;
1444                 border: 1px solid #aaa;
1445             }
1446             h1 {
1447                 font-size: 0.9em;
1448                 font-weight: normal;
1449                 text-align: center;
1450             }
1451             h2 {
1452                 font-size: 1.0em;
1453             }
1454             p {
1455                 font-size: 0.9em;
1456             }
1457             p img {
1458                 float: right;
1459                 margin-left: 10px;
1460             }
1461             span#appname {
1462                 font-weight: bold;
1463                 font-size: 1.6em;
1464             }
1465         </style>
1466     </head>
1467     <body>
1468         <div id="content">
1469             <div id="topbar">
1470                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1471                     $VERSION</h1>
1472              </div>
1473              <div id="answers">
1474                  <p>
1475                  <img src="$logo" alt="Catalyst Logo" />
1476                  </p>
1477                  <p>Welcome to the  world of Catalyst.
1478                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1479                     framework will make web development something you had
1480                     never expected it to be: Fun, rewarding, and quick.</p>
1481                  <h2>What to do now?</h2>
1482                  <p>That really depends  on what <b>you</b> want to do.
1483                     We do, however, provide you with a few starting points.</p>
1484                  <p>If you want to jump right into web development with Catalyst
1485                     you might want to start with a tutorial.</p>
1486 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1487 </pre>
1488 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1489 <pre>
1490 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1491 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1492 </code></pre>
1493                  <h2>What to do next?</h2>
1494                  <p>Next it's time to write an actual application. Use the
1495                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1496                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1497                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1498                     they can save you a lot of work.</p>
1499                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1500                     <p>Also, be sure to check out the vast and growing
1501                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1502                     you are likely to find what you need there.
1503                     </p>
1504
1505                  <h2>Need help?</h2>
1506                  <p>Catalyst has a very active community. Here are the main places to
1507                     get in touch with us.</p>
1508                  <ul>
1509                      <li>
1510                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1511                      </li>
1512                      <li>
1513                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1514                      </li>
1515                      <li>
1516                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1517                      </li>
1518                  </ul>
1519                  <h2>In conclusion</h2>
1520                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1521                     as we enjoyed making it. Please contact us if you have ideas
1522                     for improvement or other feedback.</p>
1523              </div>
1524          </div>
1525     </body>
1526 </html>
1527 EOF
1528 }
1529
1530 =head1 INTERNAL METHODS
1531
1532 These methods are not meant to be used by end users.
1533
1534 =head2 $c->components
1535
1536 Returns a hash of components.
1537
1538 =head2 $c->context_class
1539
1540 Returns or sets the context class.
1541
1542 =head2 $c->counter
1543
1544 Returns a hashref containing coderefs and execution counts (needed for
1545 deep recursion detection).
1546
1547 =head2 $c->depth
1548
1549 Returns the number of actions on the current internal execution stack.
1550
1551 =head2 $c->dispatch
1552
1553 Dispatches a request to actions.
1554
1555 =cut
1556
1557 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1558
1559 =head2 $c->dispatcher_class
1560
1561 Returns or sets the dispatcher class.
1562
1563 =head2 $c->dump_these
1564
1565 Returns a list of 2-element array references (name, structure) pairs
1566 that will be dumped on the error page in debug mode.
1567
1568 =cut
1569
1570 sub dump_these {
1571     my $c = shift;
1572     [ Request => $c->req ],
1573     [ Response => $c->res ],
1574     [ Stash => $c->stash ],
1575     [ Config => $c->config ];
1576 }
1577
1578 =head2 $c->engine_class
1579
1580 Returns or sets the engine class.
1581
1582 =head2 $c->execute( $class, $coderef )
1583
1584 Execute a coderef in given class and catch exceptions. Errors are available
1585 via $c->error.
1586
1587 =cut
1588
1589 sub execute {
1590     my ( $c, $class, $code ) = @_;
1591     $class = $c->component($class) || $class;
1592     $c->state(0);
1593
1594     if ( $c->depth >= $RECURSION ) {
1595         my $action = $code->reverse();
1596         $action = "/$action" unless $action =~ /->/;
1597         my $error = qq/Deep recursion detected calling "${action}"/;
1598         $c->log->error($error);
1599         $c->error($error);
1600         $c->state(0);
1601         return $c->state;
1602     }
1603
1604     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1605
1606     push( @{ $c->stack }, $code );
1607
1608     no warnings 'recursion';
1609     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1610     #      I have no idea how, ergo $ret (which appears to fix the issue)
1611     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1612
1613     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1614
1615     my $last = pop( @{ $c->stack } );
1616
1617     if ( my $error = $@ ) {
1618         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1619             $error->rethrow if $c->depth > 1;
1620         }
1621         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1622             $error->rethrow if $c->depth > 0;
1623         }
1624         else {
1625             unless ( ref $error ) {
1626                 no warnings 'uninitialized';
1627                 chomp $error;
1628                 my $class = $last->class;
1629                 my $name  = $last->name;
1630                 $error = qq/Caught exception in $class->$name "$error"/;
1631             }
1632             $c->error($error);
1633         }
1634         $c->state(0);
1635     }
1636     return $c->state;
1637 }
1638
1639 sub _stats_start_execute {
1640     my ( $c, $code ) = @_;
1641     my $appclass = ref($c) || $c;
1642     return if ( ( $code->name =~ /^_.*/ )
1643         && ( !$appclass->config->{show_internal_actions} ) );
1644
1645     my $action_name = $code->reverse();
1646     $c->counter->{$action_name}++;
1647
1648     my $action = $action_name;
1649     $action = "/$action" unless $action =~ /->/;
1650
1651     # determine if the call was the result of a forward
1652     # this is done by walking up the call stack and looking for a calling
1653     # sub of Catalyst::forward before the eval
1654     my $callsub = q{};
1655     for my $index ( 2 .. 11 ) {
1656         last
1657         if ( ( caller($index) )[0] eq 'Catalyst'
1658             && ( caller($index) )[3] eq '(eval)' );
1659
1660         if ( ( caller($index) )[3] =~ /forward$/ ) {
1661             $callsub = ( caller($index) )[3];
1662             $action  = "-> $action";
1663             last;
1664         }
1665     }
1666
1667     my $uid = $action_name . $c->counter->{$action_name};
1668
1669     # is this a root-level call or a forwarded call?
1670     if ( $callsub =~ /forward$/ ) {
1671         my $parent = $c->stack->[-1];
1672
1673         # forward, locate the caller
1674         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1675             $c->stats->profile(
1676                 begin  => $action,
1677                 parent => "$parent" . $c->counter->{"$parent"},
1678                 uid    => $uid,
1679             );
1680         }
1681         else {
1682
1683             # forward with no caller may come from a plugin
1684             $c->stats->profile(
1685                 begin => $action,
1686                 uid   => $uid,
1687             );
1688         }
1689     }
1690     else {
1691
1692         # root-level call
1693         $c->stats->profile(
1694             begin => $action,
1695             uid   => $uid,
1696         );
1697     }
1698     return $action;
1699
1700 }
1701
1702 sub _stats_finish_execute {
1703     my ( $c, $info ) = @_;
1704     $c->stats->profile( end => $info );
1705 }
1706
1707 =head2 $c->finalize
1708
1709 Finalizes the request.
1710
1711 =cut
1712
1713 sub finalize {
1714     my $c = shift;
1715
1716     for my $error ( @{ $c->error } ) {
1717         $c->log->error($error);
1718     }
1719
1720     # Allow engine to handle finalize flow (for POE)
1721     my $engine = $c->engine;
1722     if ( my $code = $engine->can('finalize') ) {
1723         $engine->$code($c);
1724     }
1725     else {
1726
1727         $c->finalize_uploads;
1728
1729         # Error
1730         if ( $#{ $c->error } >= 0 ) {
1731             $c->finalize_error;
1732         }
1733
1734         $c->finalize_headers;
1735
1736         # HEAD request
1737         if ( $c->request->method eq 'HEAD' ) {
1738             $c->response->body('');
1739         }
1740
1741         $c->finalize_body;
1742     }
1743
1744     $c->log_response;
1745
1746     if ($c->use_stats) {
1747         my $elapsed = sprintf '%f', $c->stats->elapsed;
1748         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1749         $c->log->info(
1750             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1751     }
1752
1753     return $c->response->status;
1754 }
1755
1756 =head2 $c->finalize_body
1757
1758 Finalizes body.
1759
1760 =cut
1761
1762 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1763
1764 =head2 $c->finalize_cookies
1765
1766 Finalizes cookies.
1767
1768 =cut
1769
1770 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1771
1772 =head2 $c->finalize_error
1773
1774 Finalizes error.
1775
1776 =cut
1777
1778 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1779
1780 =head2 $c->finalize_headers
1781
1782 Finalizes headers.
1783
1784 =cut
1785
1786 sub finalize_headers {
1787     my $c = shift;
1788
1789     my $response = $c->response; #accessor calls can add up?
1790
1791     # Check if we already finalized headers
1792     return if $response->finalized_headers;
1793
1794     # Handle redirects
1795     if ( my $location = $response->redirect ) {
1796         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1797         $response->header( Location => $location );
1798
1799         if ( !$response->has_body ) {
1800             # Add a default body if none is already present
1801             $response->body(
1802                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1803             );
1804         }
1805     }
1806
1807     # Content-Length
1808     if ( defined $response->body && length $response->body && !$response->content_length ) {
1809
1810         # get the length from a filehandle
1811         if ( blessed( $response->body ) && $response->body->can('read') || ref( $response->body ) eq 'GLOB' )
1812         {
1813             my $stat = stat $response->body;
1814             if ( $stat && $stat->size > 0 ) {
1815                 $response->content_length( $stat->size );
1816             }
1817             else {
1818                 $c->log->warn('Serving filehandle without a content-length');
1819             }
1820         }
1821         else {
1822             # everything should be bytes at this point, but just in case
1823             $response->content_length( length( $response->body ) );
1824         }
1825     }
1826
1827     # Errors
1828     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1829         $response->headers->remove_header("Content-Length");
1830         $response->body('');
1831     }
1832
1833     $c->finalize_cookies;
1834
1835     $c->engine->finalize_headers( $c, @_ );
1836
1837     # Done
1838     $response->finalized_headers(1);
1839 }
1840
1841 =head2 $c->finalize_output
1842
1843 An alias for finalize_body.
1844
1845 =head2 $c->finalize_read
1846
1847 Finalizes the input after reading is complete.
1848
1849 =cut
1850
1851 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1852
1853 =head2 $c->finalize_uploads
1854
1855 Finalizes uploads. Cleans up any temporary files.
1856
1857 =cut
1858
1859 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1860
1861 =head2 $c->get_action( $action, $namespace )
1862
1863 Gets an action in a given namespace.
1864
1865 =cut
1866
1867 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1868
1869 =head2 $c->get_actions( $action, $namespace )
1870
1871 Gets all actions of a given name in a namespace and all parent
1872 namespaces.
1873
1874 =cut
1875
1876 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1877
1878 =head2 $app->handle_request( @arguments )
1879
1880 Called to handle each HTTP request.
1881
1882 =cut
1883
1884 sub handle_request {
1885     my ( $class, @arguments ) = @_;
1886
1887     # Always expect worst case!
1888     my $status = -1;
1889     eval {
1890         if ($class->debug) {
1891             my $secs = time - $START || 1;
1892             my $av = sprintf '%.3f', $COUNT / $secs;
1893             my $time = localtime time;
1894             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1895         }
1896
1897         my $c = $class->prepare(@arguments);
1898         $c->dispatch;
1899         $status = $c->finalize;
1900     };
1901
1902     if ( my $error = $@ ) {
1903         chomp $error;
1904         $class->log->error(qq/Caught exception in engine "$error"/);
1905     }
1906
1907     $COUNT++;
1908
1909     if(my $coderef = $class->log->can('_flush')){
1910         $class->log->$coderef();
1911     }
1912     return $status;
1913 }
1914
1915 =head2 $c->prepare( @arguments )
1916
1917 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1918 etc.).
1919
1920 =cut
1921
1922 sub prepare {
1923     my ( $class, @arguments ) = @_;
1924
1925     # XXX
1926     # After the app/ctxt split, this should become an attribute based on something passed
1927     # into the application.
1928     $class->context_class( ref $class || $class ) unless $class->context_class;
1929
1930     my $c = $class->context_class->new({});
1931
1932     # For on-demand data
1933     $c->request->_context($c);
1934     $c->response->_context($c);
1935
1936     #surely this is not the most efficient way to do things...
1937     $c->stats($class->stats_class->new)->enable($c->use_stats);
1938     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
1939         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1940     }
1941
1942     #XXX reuse coderef from can
1943     # Allow engine to direct the prepare flow (for POE)
1944     if ( $c->engine->can('prepare') ) {
1945         $c->engine->prepare( $c, @arguments );
1946     }
1947     else {
1948         $c->prepare_request(@arguments);
1949         $c->prepare_connection;
1950         $c->prepare_query_parameters;
1951         $c->prepare_headers;
1952         $c->prepare_cookies;
1953         $c->prepare_path;
1954
1955         # Prepare the body for reading, either by prepare_body
1956         # or the user, if they are using $c->read
1957         $c->prepare_read;
1958
1959         # Parse the body unless the user wants it on-demand
1960         unless ( ref($c)->config->{parse_on_demand} ) {
1961             $c->prepare_body;
1962         }
1963     }
1964
1965     my $method  = $c->req->method  || '';
1966     my $path    = $c->req->path;
1967     $path       = '/' unless length $path;
1968     my $address = $c->req->address || '';
1969
1970     $c->log_request;
1971
1972     $c->prepare_action;
1973
1974     return $c;
1975 }
1976
1977 =head2 $c->prepare_action
1978
1979 Prepares action. See L<Catalyst::Dispatcher>.
1980
1981 =cut
1982
1983 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1984
1985 =head2 $c->prepare_body
1986
1987 Prepares message body.
1988
1989 =cut
1990
1991 sub prepare_body {
1992     my $c = shift;
1993
1994     return if $c->request->_has_body;
1995
1996     # Initialize on-demand data
1997     $c->engine->prepare_body( $c, @_ );
1998     $c->prepare_parameters;
1999     $c->prepare_uploads;
2000 }
2001
2002 =head2 $c->prepare_body_chunk( $chunk )
2003
2004 Prepares a chunk of data before sending it to L<HTTP::Body>.
2005
2006 See L<Catalyst::Engine>.
2007
2008 =cut
2009
2010 sub prepare_body_chunk {
2011     my $c = shift;
2012     $c->engine->prepare_body_chunk( $c, @_ );
2013 }
2014
2015 =head2 $c->prepare_body_parameters
2016
2017 Prepares body parameters.
2018
2019 =cut
2020
2021 sub prepare_body_parameters {
2022     my $c = shift;
2023     $c->engine->prepare_body_parameters( $c, @_ );
2024 }
2025
2026 =head2 $c->prepare_connection
2027
2028 Prepares connection.
2029
2030 =cut
2031
2032 sub prepare_connection {
2033     my $c = shift;
2034     $c->engine->prepare_connection( $c, @_ );
2035 }
2036
2037 =head2 $c->prepare_cookies
2038
2039 Prepares cookies.
2040
2041 =cut
2042
2043 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
2044
2045 =head2 $c->prepare_headers
2046
2047 Prepares headers.
2048
2049 =cut
2050
2051 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
2052
2053 =head2 $c->prepare_parameters
2054
2055 Prepares parameters.
2056
2057 =cut
2058
2059 sub prepare_parameters {
2060     my $c = shift;
2061     $c->prepare_body_parameters;
2062     $c->engine->prepare_parameters( $c, @_ );
2063 }
2064
2065 =head2 $c->prepare_path
2066
2067 Prepares path and base.
2068
2069 =cut
2070
2071 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2072
2073 =head2 $c->prepare_query_parameters
2074
2075 Prepares query parameters.
2076
2077 =cut
2078
2079 sub prepare_query_parameters {
2080     my $c = shift;
2081
2082     $c->engine->prepare_query_parameters( $c, @_ );
2083 }
2084
2085 =head2 $c->log_request
2086
2087 Writes information about the request to the debug logs.  This includes:
2088
2089 =over 4
2090
2091 =item * Request method, path, and remote IP address
2092
2093 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2094
2095 =item * Request parameters
2096
2097 =item * File uploads
2098
2099 =back
2100
2101 =cut
2102
2103 sub log_request {
2104     my $c = shift;
2105
2106     return unless $c->debug;
2107
2108     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2109     my $request = $dump->[1];
2110
2111     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2112     $method ||= '';
2113     $path = '/' unless length $path;
2114     $address ||= '';
2115     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2116
2117     $c->log_request_headers($request->headers);
2118
2119     if ( my $keywords = $request->query_keywords ) {
2120         $c->log->debug("Query keywords are: $keywords");
2121     }
2122
2123     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2124
2125     $c->log_request_uploads($request);
2126 }
2127
2128 =head2 $c->log_response
2129
2130 Writes information about the response to the debug logs by calling
2131 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2132
2133 =cut
2134
2135 sub log_response {
2136     my $c = shift;
2137
2138     return unless $c->debug;
2139
2140     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2141     my $response = $dump->[1];
2142
2143     $c->log_response_status_line($response);
2144     $c->log_response_headers($response->headers);
2145 }
2146
2147 =head2 $c->log_response_status_line($response)
2148
2149 Writes one line of information about the response to the debug logs.  This includes:
2150
2151 =over 4
2152
2153 =item * Response status code
2154
2155 =item * Content-Type header (if present)
2156
2157 =item * Content-Length header (if present)
2158
2159 =back
2160
2161 =cut
2162
2163 sub log_response_status_line {
2164     my ($c, $response) = @_;
2165
2166     $c->log->debug(
2167         sprintf(
2168             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2169             $response->status                            || 'unknown',
2170             $response->headers->header('Content-Type')   || 'unknown',
2171             $response->headers->header('Content-Length') || 'unknown'
2172         )
2173     );
2174 }
2175
2176 =head2 $c->log_response_headers($headers);
2177
2178 Hook method which can be wrapped by plugins to log the responseheaders.
2179 No-op in the default implementation.
2180
2181 =cut
2182
2183 sub log_response_headers {}
2184
2185 =head2 $c->log_request_parameters( query => {}, body => {} )
2186
2187 Logs request parameters to debug logs
2188
2189 =cut
2190
2191 sub log_request_parameters {
2192     my $c          = shift;
2193     my %all_params = @_;
2194
2195     return unless $c->debug;
2196
2197     my $column_width = Catalyst::Utils::term_width() - 44;
2198     foreach my $type (qw(query body)) {
2199         my $params = $all_params{$type};
2200         next if ! keys %$params;
2201         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2202         for my $key ( sort keys %$params ) {
2203             my $param = $params->{$key};
2204             my $value = defined($param) ? $param : '';
2205             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2206         }
2207         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2208     }
2209 }
2210
2211 =head2 $c->log_request_uploads
2212
2213 Logs file uploads included in the request to the debug logs.
2214 The parameter name, filename, file type, and file size are all included in
2215 the debug logs.
2216
2217 =cut
2218
2219 sub log_request_uploads {
2220     my $c = shift;
2221     my $request = shift;
2222     return unless $c->debug;
2223     my $uploads = $request->uploads;
2224     if ( keys %$uploads ) {
2225         my $t = Text::SimpleTable->new(
2226             [ 12, 'Parameter' ],
2227             [ 26, 'Filename' ],
2228             [ 18, 'Type' ],
2229             [ 9,  'Size' ]
2230         );
2231         for my $key ( sort keys %$uploads ) {
2232             my $upload = $uploads->{$key};
2233             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2234                 $t->row( $key, $u->filename, $u->type, $u->size );
2235             }
2236         }
2237         $c->log->debug( "File Uploads are:\n" . $t->draw );
2238     }
2239 }
2240
2241 =head2 $c->log_request_headers($headers);
2242
2243 Hook method which can be wrapped by plugins to log the request headers.
2244 No-op in the default implementation.
2245
2246 =cut
2247
2248 sub log_request_headers {}
2249
2250 =head2 $c->log_headers($type => $headers)
2251
2252 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2253
2254 =cut
2255
2256 sub log_headers {
2257     my $c       = shift;
2258     my $type    = shift;
2259     my $headers = shift;    # an HTTP::Headers instance
2260
2261     return unless $c->debug;
2262
2263     my $column_width = Catalyst::Utils::term_width() - 28;
2264     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2265     $headers->scan(
2266         sub {
2267             my ( $name, $value ) = @_;
2268             $t->row( $name, $value );
2269         }
2270     );
2271     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2272 }
2273
2274
2275 =head2 $c->prepare_read
2276
2277 Prepares the input for reading.
2278
2279 =cut
2280
2281 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2282
2283 =head2 $c->prepare_request
2284
2285 Prepares the engine request.
2286
2287 =cut
2288
2289 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2290
2291 =head2 $c->prepare_uploads
2292
2293 Prepares uploads.
2294
2295 =cut
2296
2297 sub prepare_uploads {
2298     my $c = shift;
2299
2300     $c->engine->prepare_uploads( $c, @_ );
2301 }
2302
2303 =head2 $c->prepare_write
2304
2305 Prepares the output for writing.
2306
2307 =cut
2308
2309 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2310
2311 =head2 $c->request_class
2312
2313 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2314
2315 =head2 $c->response_class
2316
2317 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2318
2319 =head2 $c->read( [$maxlength] )
2320
2321 Reads a chunk of data from the request body. This method is designed to
2322 be used in a while loop, reading C<$maxlength> bytes on every call.
2323 C<$maxlength> defaults to the size of the request if not specified.
2324
2325 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2326 directly.
2327
2328 Warning: If you use read(), Catalyst will not process the body,
2329 so you will not be able to access POST parameters or file uploads via
2330 $c->request.  You must handle all body parsing yourself.
2331
2332 =cut
2333
2334 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
2335
2336 =head2 $c->run
2337
2338 Starts the engine.
2339
2340 =cut
2341
2342 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
2343
2344 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2345
2346 Sets an action in a given namespace.
2347
2348 =cut
2349
2350 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2351
2352 =head2 $c->setup_actions($component)
2353
2354 Sets up actions for a component.
2355
2356 =cut
2357
2358 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2359
2360 =head2 $c->setup_components
2361
2362 This method is called internally to set up the application's components.
2363
2364 It finds modules by calling the L<locate_components> method, expands them to
2365 package names with the L<expand_component_module> method, and then installs
2366 each component into the application.
2367
2368 The C<setup_components> config option is passed to both of the above methods.
2369
2370 Installation of each component is performed by the L<setup_component> method,
2371 below.
2372
2373 =cut
2374
2375 sub setup_components {
2376     my $class = shift;
2377
2378     my $config  = $class->config->{ setup_components };
2379
2380     my @comps = $class->locate_components($config);
2381     my %comps = map { $_ => 1 } @comps;
2382
2383     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2384     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2385         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2386     ) if $deprecatedcatalyst_component_names;
2387
2388     for my $component ( @comps ) {
2389
2390         # We pass ignore_loaded here so that overlay files for (e.g.)
2391         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2392         # we know M::P::O found a file on disk so this is safe
2393
2394         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2395     }
2396
2397     for my $component (@comps) {
2398         my $instance = $class->components->{ $component } = $class->setup_component($component);
2399         my @expanded_components = $instance->can('expand_modules')
2400             ? $instance->expand_modules( $component, $config )
2401             : $class->expand_component_module( $component, $config );
2402         for my $component (@expanded_components) {
2403             next if $comps{$component};
2404             $class->components->{ $component } = $class->setup_component($component);
2405         }
2406     }
2407 }
2408
2409 =head2 $c->locate_components( $setup_component_config )
2410
2411 This method is meant to provide a list of component modules that should be
2412 setup for the application.  By default, it will use L<Module::Pluggable>.
2413
2414 Specify a C<setup_components> config option to pass additional options directly
2415 to L<Module::Pluggable>. To add additional search paths, specify a key named
2416 C<search_extra> as an array reference. Items in the array beginning with C<::>
2417 will have the application class name prepended to them.
2418
2419 =cut
2420
2421 sub locate_components {
2422     my $class  = shift;
2423     my $config = shift;
2424
2425     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2426     my $extra   = delete $config->{ search_extra } || [];
2427
2428     push @paths, @$extra;
2429
2430     my $locator = Module::Pluggable::Object->new(
2431         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2432         %$config
2433     );
2434
2435     # XXX think about ditching this sort entirely
2436     my @comps = sort { length $a <=> length $b } $locator->plugins;
2437
2438     return @comps;
2439 }
2440
2441 =head2 $c->expand_component_module( $component, $setup_component_config )
2442
2443 Components found by C<locate_components> will be passed to this method, which
2444 is expected to return a list of component (package) names to be set up.
2445
2446 =cut
2447
2448 sub expand_component_module {
2449     my ($class, $module) = @_;
2450     return Devel::InnerPackage::list_packages( $module );
2451 }
2452
2453 =head2 $c->setup_component
2454
2455 =cut
2456
2457 sub setup_component {
2458     my( $class, $component ) = @_;
2459
2460     unless ( $component->can( 'COMPONENT' ) ) {
2461         return $component;
2462     }
2463
2464     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2465     my $config = $class->config->{ $suffix } || {};
2466     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2467     # methods also pass it. local to avoid pointlessly shitting in config
2468     # for the debug screen, as $component is already the key name.
2469     local $config->{catalyst_component_name} = $component;
2470
2471     my $instance = eval { $component->COMPONENT( $class, $config ); };
2472
2473     if ( my $error = $@ ) {
2474         chomp $error;
2475         Catalyst::Exception->throw(
2476             message => qq/Couldn't instantiate component "$component", "$error"/
2477         );
2478     }
2479
2480     unless (blessed $instance) {
2481         my $metaclass = Moose::Util::find_meta($component);
2482         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2483         my $component_method_from = $method_meta->associated_metaclass->name;
2484         my $value = defined($instance) ? $instance : 'undef';
2485         Catalyst::Exception->throw(
2486             message =>
2487             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2488         );
2489     }
2490     return $instance;
2491 }
2492
2493 =head2 $c->setup_dispatcher
2494
2495 Sets up dispatcher.
2496
2497 =cut
2498
2499 sub setup_dispatcher {
2500     my ( $class, $dispatcher ) = @_;
2501
2502     if ($dispatcher) {
2503         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2504     }
2505
2506     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2507         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2508     }
2509
2510     unless ($dispatcher) {
2511         $dispatcher = $class->dispatcher_class;
2512     }
2513
2514     Class::MOP::load_class($dispatcher);
2515
2516     # dispatcher instance
2517     $class->dispatcher( $dispatcher->new );
2518 }
2519
2520 =head2 $c->setup_engine
2521
2522 Sets up engine.
2523
2524 =cut
2525
2526 sub setup_engine {
2527     my ( $class, $engine ) = @_;
2528
2529     if ($engine) {
2530         $engine = 'Catalyst::Engine::' . $engine;
2531     }
2532
2533     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2534         $engine = 'Catalyst::Engine::' . $env;
2535     }
2536
2537     if ( $ENV{MOD_PERL} ) {
2538         my $meta = Class::MOP::get_metaclass_by_name($class);
2539
2540         # create the apache method
2541         $meta->add_method('apache' => sub { shift->engine->apache });
2542
2543         my ( $software, $version ) =
2544           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2545
2546         $version =~ s/_//g;
2547         $version =~ s/(\.[^.]+)\./$1/g;
2548
2549         if ( $software eq 'mod_perl' ) {
2550
2551             if ( !$engine ) {
2552
2553                 if ( $version >= 1.99922 ) {
2554                     $engine = 'Catalyst::Engine::Apache2::MP20';
2555                 }
2556
2557                 elsif ( $version >= 1.9901 ) {
2558                     $engine = 'Catalyst::Engine::Apache2::MP19';
2559                 }
2560
2561                 elsif ( $version >= 1.24 ) {
2562                     $engine = 'Catalyst::Engine::Apache::MP13';
2563                 }
2564
2565                 else {
2566                     Catalyst::Exception->throw( message =>
2567                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2568                 }
2569
2570             }
2571
2572             # install the correct mod_perl handler
2573             if ( $version >= 1.9901 ) {
2574                 *handler = sub  : method {
2575                     shift->handle_request(@_);
2576                 };
2577             }
2578             else {
2579                 *handler = sub ($$) { shift->handle_request(@_) };
2580             }
2581
2582         }
2583
2584         elsif ( $software eq 'Zeus-Perl' ) {
2585             $engine = 'Catalyst::Engine::Zeus';
2586         }
2587
2588         else {
2589             Catalyst::Exception->throw(
2590                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2591         }
2592     }
2593
2594     unless ($engine) {
2595         $engine = $class->engine_class;
2596     }
2597
2598     Class::MOP::load_class($engine);
2599
2600     # check for old engines that are no longer compatible
2601     my $old_engine;
2602     if ( $engine->isa('Catalyst::Engine::Apache')
2603         && !Catalyst::Engine::Apache->VERSION )
2604     {
2605         $old_engine = 1;
2606     }
2607
2608     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2609         && Catalyst::Engine::Server->VERSION le '0.02' )
2610     {
2611         $old_engine = 1;
2612     }
2613
2614     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2615         && $engine->VERSION eq '0.01' )
2616     {
2617         $old_engine = 1;
2618     }
2619
2620     elsif ($engine->isa('Catalyst::Engine::Zeus')
2621         && $engine->VERSION eq '0.01' )
2622     {
2623         $old_engine = 1;
2624     }
2625
2626     if ($old_engine) {
2627         Catalyst::Exception->throw( message =>
2628               qq/Engine "$engine" is not supported by this version of Catalyst/
2629         );
2630     }
2631
2632     # engine instance
2633     $class->engine( $engine->new );
2634 }
2635
2636 =head2 $c->setup_home
2637
2638 Sets up the home directory.
2639
2640 =cut
2641
2642 sub setup_home {
2643     my ( $class, $home ) = @_;
2644
2645     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2646         $home = $env;
2647     }
2648
2649     $home ||= Catalyst::Utils::home($class);
2650
2651     if ($home) {
2652         #I remember recently being scolded for assigning config values like this
2653         $class->config->{home} ||= $home;
2654         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2655     }
2656 }
2657
2658 =head2 $c->setup_log
2659
2660 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2661 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2662 log to.
2663
2664 This method also installs a C<debug> method that returns a true value into the
2665 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2666 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2667
2668 Note that if the log has already been setup, by either a previous call to
2669 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2670 that this method won't actually set up the log object.
2671
2672 =cut
2673
2674 sub setup_log {
2675     my ( $class, $levels ) = @_;
2676
2677     $levels ||= '';
2678     $levels =~ s/^\s+//;
2679     $levels =~ s/\s+$//;
2680     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2681
2682     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2683     if ( defined $env_debug ) {
2684         $levels{debug} = 1 if $env_debug; # Ugly!
2685         delete($levels{debug}) unless $env_debug;
2686     }
2687
2688     unless ( $class->log ) {
2689         $class->log( Catalyst::Log->new(keys %levels) );
2690     }
2691
2692     if ( $levels{debug} ) {
2693         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2694         $class->log->debug('Debug messages enabled');
2695     }
2696 }
2697
2698 =head2 $c->setup_plugins
2699
2700 Sets up plugins.
2701
2702 =cut
2703
2704 =head2 $c->setup_stats
2705
2706 Sets up timing statistics class.
2707
2708 =cut
2709
2710 sub setup_stats {
2711     my ( $class, $stats ) = @_;
2712
2713     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2714
2715     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2716     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2717         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2718         $class->log->debug('Statistics enabled');
2719     }
2720 }
2721
2722
2723 =head2 $c->registered_plugins
2724
2725 Returns a sorted list of the plugins which have either been stated in the
2726 import list or which have been added via C<< MyApp->plugin(@args); >>.
2727
2728 If passed a given plugin name, it will report a boolean value indicating
2729 whether or not that plugin is loaded.  A fully qualified name is required if
2730 the plugin name does not begin with C<Catalyst::Plugin::>.
2731
2732  if ($c->registered_plugins('Some::Plugin')) {
2733      ...
2734  }
2735
2736 =cut
2737
2738 {
2739
2740     sub registered_plugins {
2741         my $proto = shift;
2742         return sort keys %{ $proto->_plugins } unless @_;
2743         my $plugin = shift;
2744         return 1 if exists $proto->_plugins->{$plugin};
2745         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2746     }
2747
2748     sub _register_plugin {
2749         my ( $proto, $plugin, $instant ) = @_;
2750         my $class = ref $proto || $proto;
2751
2752         Class::MOP::load_class( $plugin );
2753         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
2754             if $plugin->isa( 'Catalyst::Component' );
2755         $proto->_plugins->{$plugin} = 1;
2756         unless ($instant) {
2757             my $meta = Class::MOP::get_metaclass_by_name($class);
2758             $meta->superclasses($plugin, $meta->superclasses);
2759         }
2760         return $class;
2761     }
2762
2763     sub setup_plugins {
2764         my ( $class, $plugins ) = @_;
2765
2766         $class->_plugins( {} ) unless $class->_plugins;
2767         $plugins = Data::OptList::mkopt($plugins || []);
2768
2769         my @plugins = map {
2770             [ Catalyst::Utils::resolve_namespace(
2771                   $class . '::Plugin',
2772                   'Catalyst::Plugin', $_->[0]
2773               ),
2774               $_->[1],
2775             ]
2776          } @{ $plugins };
2777
2778         for my $plugin ( reverse @plugins ) {
2779             Class::MOP::load_class($plugin->[0], $plugin->[1]);
2780             my $meta = find_meta($plugin->[0]);
2781             next if $meta && $meta->isa('Moose::Meta::Role');
2782
2783             $class->_register_plugin($plugin->[0]);
2784         }
2785
2786         my @roles =
2787             map  { $_->[0]->name, $_->[1] }
2788             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
2789             map  { [find_meta($_->[0]), $_->[1]] }
2790             @plugins;
2791
2792         Moose::Util::apply_all_roles(
2793             $class => @roles
2794         ) if @roles;
2795     }
2796 }
2797
2798 =head2 $c->stack
2799
2800 Returns an arrayref of the internal execution stack (actions that are
2801 currently executing).
2802
2803 =head2 $c->stats
2804
2805 Returns the current timing statistics object. By default Catalyst uses
2806 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
2807 L<< stats_class|/"$c->stats_class" >>.
2808
2809 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
2810 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
2811 profile explicitly, although MyApp.pm still won't profile nor output anything
2812 by itself.
2813
2814 =head2 $c->stats_class
2815
2816 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
2817
2818 =head2 $c->use_stats
2819
2820 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
2821
2822 Note that this is a static method, not an accessor and should be overridden
2823 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
2824
2825 =cut
2826
2827 sub use_stats { 0 }
2828
2829
2830 =head2 $c->write( $data )
2831
2832 Writes $data to the output stream. When using this method directly, you
2833 will need to manually set the C<Content-Length> header to the length of
2834 your output data, if known.
2835
2836 =cut
2837
2838 sub write {
2839     my $c = shift;
2840
2841     # Finalize headers if someone manually writes output
2842     $c->finalize_headers;
2843
2844     return $c->engine->write( $c, @_ );
2845 }
2846
2847 =head2 version
2848
2849 Returns the Catalyst version number. Mostly useful for "powered by"
2850 messages in template systems.
2851
2852 =cut
2853
2854 sub version { return $Catalyst::VERSION }
2855
2856 =head1 CONFIGURATION
2857
2858 There are a number of 'base' config variables which can be set:
2859
2860 =over
2861
2862 =item *
2863
2864 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
2865
2866 =item *
2867
2868 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
2869
2870 =item *
2871
2872 C<home> - The application home directory. In an uninstalled application,
2873 this is the top level application directory. In an installed application,
2874 this will be the directory containing C<< MyApp.pm >>.
2875
2876 =item *
2877
2878 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
2879
2880 =item *
2881
2882 C<name> - The name of the application in debug messages and the debug and
2883 welcome screens
2884
2885 =item *
2886
2887 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
2888 until it is accessed. This allows you to (for example) check authentication (and reject
2889 the upload) before actually recieving all the data. See L</ON-DEMAND PARSER>
2890
2891 =item *
2892
2893 C<root> - The root directory for templates. Usually this is just a
2894 subdirectory of the home directory, but you can set it to change the
2895 templates to a different directory.
2896
2897 =item *
2898
2899 C<search_extra> - Array reference passed to Module::Pluggable to for additional
2900 namespaces from which components will be loaded (and constructed and stored in
2901 C<< $c->components >>).
2902
2903 =item *
2904
2905 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
2906 to be shown in hit debug tables in the test server.
2907
2908 =item *
2909
2910 C<use_request_uri_for_path> - Controlls if the C<REQUEST_URI> or C<PATH_INFO> environment
2911 variable should be used for determining the request path. See L<Catalyst::Engine::CGI/PATH DECODING>
2912 for more information.
2913
2914 =item *
2915
2916 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
2917
2918 =back
2919
2920 =head1 INTERNAL ACTIONS
2921
2922 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2923 C<_ACTION>, and C<_END>. These are by default not shown in the private
2924 action table, but you can make them visible with a config parameter.
2925
2926     MyApp->config(show_internal_actions => 1);
2927
2928 =head1 ON-DEMAND PARSER
2929
2930 The request body is usually parsed at the beginning of a request,
2931 but if you want to handle input yourself, you can enable on-demand
2932 parsing with a config parameter.
2933
2934     MyApp->config(parse_on_demand => 1);
2935
2936 =head1 PROXY SUPPORT
2937
2938 Many production servers operate using the common double-server approach,
2939 with a lightweight frontend web server passing requests to a larger
2940 backend server. An application running on the backend server must deal
2941 with two problems: the remote user always appears to be C<127.0.0.1> and
2942 the server's hostname will appear to be C<localhost> regardless of the
2943 virtual host that the user connected through.
2944
2945 Catalyst will automatically detect this situation when you are running
2946 the frontend and backend servers on the same machine. The following
2947 changes are made to the request.
2948
2949     $c->req->address is set to the user's real IP address, as read from
2950     the HTTP X-Forwarded-For header.
2951
2952     The host value for $c->req->base and $c->req->uri is set to the real
2953     host, as read from the HTTP X-Forwarded-Host header.
2954
2955 Additionally, you may be running your backend application on an insecure
2956 connection (port 80) while your frontend proxy is running under SSL.  If there
2957 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
2958 tell Catalyst what port the frontend listens on.  This will allow all URIs to
2959 be created properly.
2960
2961 In the case of passing in:
2962
2963     X-Forwarded-Port: 443
2964
2965 All calls to C<uri_for> will result in an https link, as is expected.
2966
2967 Obviously, your web server must support these headers for this to work.
2968
2969 In a more complex server farm environment where you may have your
2970 frontend proxy server(s) on different machines, you will need to set a
2971 configuration option to tell Catalyst to read the proxied data from the
2972 headers.
2973
2974     MyApp->config(using_frontend_proxy => 1);
2975
2976 If you do not wish to use the proxy support at all, you may set:
2977
2978     MyApp->config(ignore_frontend_proxy => 1);
2979
2980 =head1 THREAD SAFETY
2981
2982 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2983 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2984 believe the Catalyst core to be thread-safe.
2985
2986 If you plan to operate in a threaded environment, remember that all other
2987 modules you are using must also be thread-safe. Some modules, most notably
2988 L<DBD::SQLite>, are not thread-safe.
2989
2990 =head1 SUPPORT
2991
2992 IRC:
2993
2994     Join #catalyst on irc.perl.org.
2995
2996 Mailing Lists:
2997
2998     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
2999     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
3000
3001 Web:
3002
3003     http://catalyst.perl.org
3004
3005 Wiki:
3006
3007     http://dev.catalyst.perl.org
3008
3009 =head1 SEE ALSO
3010
3011 =head2 L<Task::Catalyst> - All you need to start with Catalyst
3012
3013 =head2 L<Catalyst::Manual> - The Catalyst Manual
3014
3015 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
3016
3017 =head2 L<Catalyst::Engine> - Core engine
3018
3019 =head2 L<Catalyst::Log> - Log class.
3020
3021 =head2 L<Catalyst::Request> - Request object
3022
3023 =head2 L<Catalyst::Response> - Response object
3024
3025 =head2 L<Catalyst::Test> - The test suite.
3026
3027 =head1 PROJECT FOUNDER
3028
3029 sri: Sebastian Riedel <sri@cpan.org>
3030
3031 =head1 CONTRIBUTORS
3032
3033 abw: Andy Wardley
3034
3035 acme: Leon Brocard <leon@astray.com>
3036
3037 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
3038
3039 Andrew Bramble
3040
3041 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
3042
3043 Andrew Ruthven
3044
3045 andyg: Andy Grundman <andy@hybridized.org>
3046
3047 audreyt: Audrey Tang
3048
3049 bricas: Brian Cassidy <bricas@cpan.org>
3050
3051 Caelum: Rafael Kitover <rkitover@io.com>
3052
3053 chansen: Christian Hansen
3054
3055 chicks: Christopher Hicks
3056
3057 Chisel Wright C<pause@herlpacker.co.uk>
3058
3059 Danijel Milicevic C<me@danijel.de>
3060
3061 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
3062
3063 David Naughton, C<naughton@umn.edu>
3064
3065 David E. Wheeler
3066
3067 dhoss: Devin Austin <dhoss@cpan.org>
3068
3069 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
3070
3071 Drew Taylor
3072
3073 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
3074
3075 esskar: Sascha Kiefer
3076
3077 fireartist: Carl Franks <cfranks@cpan.org>
3078
3079 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
3080
3081 gabb: Danijel Milicevic
3082
3083 Gary Ashton Jones
3084
3085 Gavin Henry C<ghenry@perl.me.uk>
3086
3087 Geoff Richards
3088
3089 groditi: Guillermo Roditi <groditi@gmail.com>
3090
3091 hobbs: Andrew Rodland <andrew@cleverdomain.org>
3092
3093 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
3094
3095 jcamacho: Juan Camacho
3096
3097 jester: Jesse Sheidlower C<jester@panix.com>
3098
3099 jhannah: Jay Hannah <jay@jays.net>
3100
3101 Jody Belka
3102
3103 Johan Lindstrom
3104
3105 jon: Jon Schutz <jjschutz@cpan.org>
3106
3107 Jonathan Rockway C<< <jrockway@cpan.org> >>
3108
3109 Kieren Diment C<kd@totaldatasolution.com>
3110
3111 konobi: Scott McWhirter <konobi@cpan.org>
3112
3113 marcus: Marcus Ramberg <mramberg@cpan.org>
3114
3115 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
3116
3117 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
3118
3119 mugwump: Sam Vilain
3120
3121 naughton: David Naughton
3122
3123 ningu: David Kamholz <dkamholz@cpan.org>
3124
3125 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
3126
3127 numa: Dan Sully <daniel@cpan.org>
3128
3129 obra: Jesse Vincent
3130
3131 Octavian Rasnita
3132
3133 omega: Andreas Marienborg
3134
3135 Oleg Kostyuk <cub.uanic@gmail.com>
3136
3137 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
3138
3139 rafl: Florian Ragwitz <rafl@debian.org>
3140
3141 random: Roland Lammel <lammel@cpan.org>
3142
3143 Robert Sedlacek C<< <rs@474.at> >>
3144
3145 SpiceMan: Marcel Montes
3146
3147 sky: Arthur Bergman
3148
3149 szbalint: Balint Szilakszi <szbalint@cpan.org>
3150
3151 t0m: Tomas Doran <bobtfish@bobtfish.net>
3152
3153 Ulf Edvinsson
3154
3155 Viljo Marrandi C<vilts@yahoo.com>
3156
3157 Will Hawes C<info@whawes.co.uk>
3158
3159 willert: Sebastian Willert <willert@cpan.org>
3160
3161 wreis: Wallace Reis <wallace@reis.org.br>
3162
3163 Yuval Kogman, C<nothingmuch@woobling.org>
3164
3165 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
3166
3167 dd070: Dhaval Dhanani <dhaval070@gmail.com>
3168
3169 =head1 COPYRIGHT
3170
3171 Copyright (c) 2005, the above named PROJECT FOUNDER and CONTRIBUTORS.
3172
3173 =head1 LICENSE
3174
3175 This library is free software. You can redistribute it and/or modify it under
3176 the same terms as Perl itself.
3177
3178 =cut
3179
3180 no Moose;
3181
3182 __PACKAGE__->meta->make_immutable;
3183
3184 1;